GAP (HeLP) - Chapter 3: Further functions

Goto Chapter: Top 1 2 3 4 5 6 Bib Ind
[Top of Book] [Contents] [Previous Chapter] [Next Chapter]

[MathJax off]

3 Further functions
3.1 Checks for specific orders
3.1-1 HeLP_WithGivenOrder
3.1-2 HeLP_WithGivenOrderAndPA
3.1-3 HeLP_WithGivenOrderAndPAAndSpecificSystem
3.2 Checks for specific orders with s-constant characters
3.2-1 HeLP_WithGivenOrderSConstant
3.2-2 HeLP_AddGaloisCharacterSums
3.3 Checks for all orders
3.3-1 HeLP_AllOrders
3.3-2 HeLP_AllOrdersPQ
3.4 Changing the used Character Table
3.4-1 HeLP_ChangeCharKeepSols
3.4-2 HeLP_Reset
3.5 Influencing how the Systems of Inequalities are solved
3.5-1 HeLP_Solver
3.5-2 HeLP_UseRedund
3.5-3 HeLP_Change4ti2Precision
3.5-4 HeLP_Vertices
3.6 Checking solutions, calculating and checking solutions
3.6-1 HeLP_VerifySolution
3.6-2 HeLP_FindAndVerifySolution
3.6-3 HeLP_PossiblePartialAugmentationsOfPowers
3.7 The Wagner test
3.7-1 HeLP_WagnerTest
3.8 Output
3.8-1 HeLP_PrintSolution
3.9 Eigenvalue multiplicities and character values
3.9-1 HeLP_MultiplicitiesOfEigenvalues
3.9-2 HeLP_CharacterValue

### 3 Further functions

A short remark is probably in order on the three global variables the package is using: `HeLP_CT`, `HeLP_sol` and `HeLP_settings`. The first one stores the character table for which the last calculations were performed, the second one containing at the `k`'s spot the already calculated admissible partial augmentations of elements of order \(k\) (and its powers \(u^d\) for \(d \not= k\) a divisor of \(k\)). If a function of the HeLP-package is called with a character table different from the one saved in `HeLP_CT` then the package tries to check if the character tables belong to the same group. This can be done in particular for tables from the ATLAS. If this check is successful the solutions already written in `HeLP_sol` are kept, otherwise this variable is reset. For a more detailed account see Sections 4.2, 5.2 and `HeLP_ChangeCharKeepSols` (3.4-1). In most situations, the user does not have to worry about this, the program will take care of it as far as possible. `HeLP_settings` is a varaible which is used to store some settings of the program.

#### 3.1 Checks for specific orders

##### 3.1-1 HeLP_WithGivenOrder

`‣ HeLP_WithGivenOrder`( CharacterTable|ListOfClassFunctions, ord ) | ( function )

Returns: List of admissible partial augmentations

Calculates the admissible partial augmentations for elements of order ord using only the data given in the first argument. The first argument can be an ordinary character table, a Brauer table, or a list of class functions, all having the same underlying character table. This function only uses the constraints of the HeLP method (from the class functions given), but does not apply the Wagner test 5.4. If the constraints allow only a finite number of solutions, these lists will be written in `HeLP_sol[ord]`. If for divisors \(d\) of ord solutions are already calculated and stored in `HeLP_sol[d]`, these will be used, otherwise the function `HeLP_WithGivenOrder` will first be applied to this order and the data given in the first argument.

    gap> C := CharacterTable("A5");
    CharacterTable( "A5" )
    gap> HeLP_WithGivenOrder(C, 5);
    #I  Number of solutions for elements of order 5: 2; stored in HeLP_sol[5].
    [ [ [ 0, 1 ] ], [ [ 1, 0 ] ] ]
    gap> HeLP_PrintSolution(5);
    Solutions for elements of order 5:
    [ [               u ],.
      [  [ "5a", "5b" ] ],
      [             --- ],
      [        [ 0, 1 ] ],
      [        [ 1, 0 ] ] ]

Tests which partial augmentations for elements of order 5 are admissible.

    gap> C := CharacterTable("A6");
    CharacterTable( "A6" )
    gap> HeLP_WithGivenOrder(C, 4);
    #I  Number of solutions for elements of order 4: 4; stored in HeLP_sol[4].
    [ [ [ 1 ], [ -1, 2 ] ], [ [ 1 ], [ 2, -1 ] ], [ [ 1 ], [ 1, 0 ] ],
      [ [ 1 ], [ 0, 1 ] ] ]
    gap> HeLP_sol[4];
    [ [ [ 1 ], [ -1, 2 ] ], [ [ 1 ], [ 2, -1 ] ], [ [ 1 ], [ 1, 0 ] ],
      [ [ 1 ], [ 0, 1 ] ] ]

Two of the non-trivial partial augmentations can be eliminated by using the Brauer table modulo the prime \(3\):

    gap> HeLP_WithGivenOrder(C mod 3, 4);
    #I  Number of solutions for elements of order 4: 2; stored in HeLP_sol[4].
    [ [ [ 1 ], [ 1, 0 ] ], [ [ 1 ], [ 0, 1 ] ] ]

When using `HeLP_ZC` also the last remaining non-trivial partial augmentation disappears, as this function applies the Wagner test, cf. 5.4 and `HeLP_WagnerTest` (3.7-1):

    gap> HeLP_ZC(C);
    #I  ZC can't be solved, using the given data, for the orders: [ 6 ].
    false
    gap> HeLP_sol[4]; HeLP_sol[6];
    [ [ [ 1 ], [ 0, 1 ] ] ]
    [ [ [ 1 ], [ 0, 1 ], [ -2, 2, 1 ] ], [ [ 1 ], [ 1, 0 ], [ -2, 1, 2 ] ] ]

The following example demonstrates how one can use lists of characters to obtain constraints for partial augmentations:

    gap> C := CharacterTable("L2(49).2_1");
    CharacterTable( "L2(49).2_1" )
    gap> HeLP_WithGivenOrder(Irr(C), 7);;
    #I  Number of solutions for elements of order 7: 1; stored in HeLP_sol[7].
    gap> HeLP_WithGivenOrder(Irr(C){[2]}, 14);
    #I  The given data admit infinitely many solutions for elements of order 14.
    gap> HeLP_WithGivenOrder(Irr(C){[44]}, 14);
    #I  The given data admit infinitely many solutions for elements of order 14.
    gap> HeLP_WithGivenOrder(Irr(C){[2,44]}, 14);
    #I  Number of solutions for elements of order 14: 0; stored in HeLP_sol[14].
    [  ]

Brauer tables can provide more restrictions on partial augmentations of certain torsion units:

    gap> C := CharacterTable("J1");
    CharacterTable( "J1" )
    gap> HeLP_WithGivenOrder(C, 6);;
    #I  Number of solutions for elements of order 6: 73; stored in HeLP_sol[6].
    gap> B := C mod 11;
    BrauerTable( "J1", 11 )
    gap> HeLP_WithGivenOrder(B, 6);;
    #I  Number of solutions for elements of order 6: 6; stored in HeLP_sol[6].
    gap> HeLP_WithGivenOrder(Irr(B){[2,3]}, 6);;
    #I  Number of solutions for elements of order 6: 6; stored in HeLP_sol[6].
    gap> HeLP_PrintSolution(6);
    Solutions for elements of order 6:
    [ [                   u^3,                   u^2,                     u ],
      [              [ "2a" ],              [ "3a" ],  [ "2a", "3a", "6a" ] ],
      [                   ---,                   ---,                   --- ],
      [                 [ 1 ],                 [ 1 ],          [ -2, 0, 3 ] ],
      [                 [ 1 ],                 [ 1 ],          [ 2, 0, -1 ] ],
      [                 [ 1 ],                 [ 1 ],           [ 0, 0, 1 ] ],
      [                 [ 1 ],                 [ 1 ],          [ -4, 3, 2 ] ],
      [                 [ 1 ],                 [ 1 ],          [ 0, 3, -2 ] ],
      [                 [ 1 ],                 [ 1 ],          [ -2, 3, 0 ] ] ]

The result of the previous example can be found in [BJK11].

When dealing with many variables using lists of characters instead of a complete character table might also speed up the calculations a lot, see Section 4.3.

    gap> C := CharacterTable("L2(27)");
    CharacterTable( "L2(27)" )
    gap> HeLP_WithGivenOrder(C,7);;
    #I  Number of solutions for elements of order 7: 78; stored in HeLP_sol[7].
    gap> SetInfoLevel(HeLP_Info,4);
    gap> HeLP_WithGivenOrder(C,3*7);
    #I      Solutions for order 3 not yet calculated.  Restart for this order.
    #I  Number of solutions for elements of order 21: 0; stored in HeLP_sol[21].
    [  ]
    gap> SetInfoLevel(HeLP_Info,1);

`HeLP_WithGivenOrder` often needs to consider many cases. Set the info class HeLP_Info to a level 4 or higher to keep track of the progress, see Section 4.4 on info levels.

##### 3.1-2 HeLP_WithGivenOrderAndPA

`‣ HeLP_WithGivenOrderAndPA`( CharacterTable|ListOfClassFunctions, ord, partaugs ) | ( function )

Returns: List of admissible partial augmentations

Calculates the admissible partial augmentations for elements of order ord using only the data given in the first argument. The first argument can be an ordinary character table, a Brauer table, or a list of class functions, all having the same underlying character table. The function uses the partial augmentations for the powers \(u^d\) with \(d\) divisors of \(k\) different from \(1\) and \(k\) given in partaugs. Here, the \(d\)'s have to be in a descending order (i.e. the orders of the \(u^d\)'s are ascending). This function only uses the constraints of the HeLP method, but does not apply the Wagner test 5.4. Note that this function will not affect `HeLP_sol`.

    gap> G := SmallGroup(48,33);; StructureDescription(G);
    "SL(2,3) : C2"
    gap> C := CharacterTable(G);;
    gap> HeLP_WithGivenOrder(C, 4);;
    #I  Number of solutions for elements of order 4: 4; stored in HeLP_sol[4].
    gap> HeLP_WithGivenOrder(C, 6);;
    #I  Number of solutions for elements of order 6: 2; stored in HeLP_sol[6].
    gap> HeLP_sol[4]; HeLP_sol[6];
    [ [ [ 1, 0 ], [ 0, 1, 0, 0, 0 ] ], [ [ 1, 0 ], [ 0, 0, 0, 0, 1 ] ],
      [ [ 1, 0 ], [ 0, 0, 0, 1, 0 ] ], [ [ 1, 0 ], [ 0, 0, 1, 0, 0 ] ] ]
    [ [ [ 1, 0 ], [ 0, 1 ], [ 0, 0, 0, 0, 1, 0 ] ],
      [ [ 1, 0 ], [ 1, 0 ], [ 0, 0, 0, 0, 0, 1 ] ] ]
    gap> HeLP_WithGivenOrderAndPA(C, 12, [ [ 1, 0 ],  [ 0, 1 ], [ 0, 0, 0, 0, 1 ],
    >     [ 0, 0, 0, 0, 1, 0 ] ]);
    #I  Number of solutions for elements of order 12 with these partial augmentation
    s for the powers: 1.
    [ [ [ 1, 0 ], [ 0, 1 ], [ 0, 0, 0, 0, 1 ], [ 0, 0, 0, 0, 1, 0 ],
          [ 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0 ] ] ]
    gap> HeLP_WithGivenOrderAndPA(C, 12, [ [ 1, 0 ],  [ 0, 1 ], [ 0, 0, 0, 1, 0 ],
    >     [ 0, 0, 0, 0, 1, 0 ] ]);
    #I  Number of solutions for elements of order 12 with these partial augmentation
    s for the powers: 0.
    [  ]

In the calls of `HeLP_WithGivenOrderAndPA` the function uses the following partial augmentations:

- `[ 1, 0 ]` for the element \(u^6\) of order 2,

- `[ 0, 1 ]` for the element \(u^4\) of order 3,

- `[ 0, 0, 0, 0, 1 ]` and `[ 0, 0, 0, 1, 0 ]` for the element \(u^3\) of order 4 respectively,

- `[ 0, 0, 0, 0, 1, 0 ]` for the element \(u^2\) of order 6.

##### 3.1-3 HeLP_WithGivenOrderAndPAAndSpecificSystem

`‣ HeLP_WithGivenOrderAndPAAndSpecificSystem`( list, ord, partaugs[, b] ) | ( function )

Returns: List of admissible partial augmentations

Calculates the admissible partial augmentations for elements of order ord using only the data given in the first argument. The first argument is a list, which can contains as entries characters or pairs with first entry a character and second entrie an integer or a mixture of these. The first argument is understood as follows: If a character \(\chi\) is not given in a pair all inequalities obtainable by this character are used. If it is given in a pair with the integer \(m\) the inequalities obtainable from the multiplicity of `E(ord)` taken to the power \(m\) as an eigenvalue of a representation affording \(\chi\) are used. The function uses the partial augmentations for the powers \(u^d\) with \(d\) divisors of \(k\) different from \(1\) and \(k\) given in partaugs. Here, the \(d\)'s have to be in a descending order (i.e. the orders of the \(u^d\)'s are ascending). This function only uses the constraints of the HeLP method, but does not apply the Wagner test 5.4. Note that this function will not affect `HeLP_sol`.

    gap> C := CharacterTable("A5");
    CharacterTable( "A5" )
    gap> chi := Irr(C)[2];; psi := Irr(C)[4];
    Character( CharacterTable( "A5" ), [ 4, 0, 1, -1, -1 ] )
    gap> HeLP_WithGivenOrderAndPAAndSpecificSystem([[chi, 1], [chi, 2]],
    >  5, [ ], true);
    [ [ [ [ 0, 1 ] ], [ [ 1, 0 ] ] ], [ [ -3/5, 2/5 ], [ 2/5, -3/5 ] ], [ 3/5, 3/5 ] ]
    gap> sol5 := HeLP_WithGivenOrderAndPAAndSpecificSystem([[chi, 1], [chi, 2]],
    >  5, [ ]);
    [ [ [ 0, 1 ] ], [ [ 1, 0 ] ] ]

The inequalities in the above examples are:

\[\frac{-3}{5}\varepsilon_{5a}(u) + \frac{2}{5}\varepsilon_{5b}(u) + \frac{3}{5} \in \mathbb{Z}_{\geq 0} \ \ {\rm{and}} \ \ \frac{2}{5}\varepsilon_{5a}(u) + \frac{-3}{5}\varepsilon_{5b}(u) + \frac{3}{5} \in \mathbb{Z}_{\geq 0}. \]

Continuing the above example:

    gap> HeLP_WithGivenOrderAndPAAndSpecificSystem([psi],
    >  2*5, [[1], sol5[1][1]], true);
    [ [  ], [ [ 0, -2/5, -2/5 ], [ 0, -1/10, -1/10 ], [ 0, 1/10, 1/10 ],
     [ 0, -1/10, -1/10 ], [ 0, 1/10, 1/10 ], [ 0, 2/5, 2/5 ],
     [ 0, 1/10, 1/10 ], [ 0, -1/10, -1/10 ], [ 0, 1/10, 1/10 ],
    [ 0, -1/10, -1/10 ] ], [ 0, 1/2, 1/2, 1/2, 1/2, 0, 1/2, 1/2, 1/2, 1/2 ] ]
    gap> HeLP_WithGivenOrderAndPAAndSpecificSystem([[psi, 0], [psi, 2], [psi, 5]],
    >  2*5, [[1], sol5[2][1]], true);
    [ [  ], [ [ 0, -2/5, -2/5 ], [ 0, 1/10, 1/10 ], [ 0, 2/5, 2/5 ] ], [ 0, 1/2, 0 ] ]

#### 3.2 Checks for specific orders with s-constant characters

When considering elements of order \(st\) (in absence of elements of this order in the group ; in particular when trying to prove (PQ)) and there are several conjugacy classes of elements of order \(s\), it might be useful to consider \(s\)-constant characters (cf. Section 5.5) to reduce the computational complexity.

##### 3.2-1 HeLP_WithGivenOrderSConstant

`‣ HeLP_WithGivenOrderSConstant`( CharacterTable|ListOfClassFunctions, s, t ) | ( function )

Returns: List of admissible "partial augmentations" or `"infinite"`

Calculates the admissible partial augmentations for elements \(u\) of order \(s*t\) using only the \(s\)-constant class functions that are contained in the first argument. The first argument can be an ordinary character table, a Brauer table, or a list of class functions, all having the same underlying character table. s and t have to be different prime numbers, such that there are elements of order s and t in the group, but no elements of order \(s*t\).

The function filters which class functions given in the first argument are constant on all conjugacy classes of elements of order s. For the element \(u^s\) of order t the partial augmentations given in `HeLP_sol[t]` are used. If they are not yet calculated, the function calculates them first, using the data given in the first argument and stores them in `HeLP_sol[t]`. This function only uses the constraints of the HeLP method, but does not apply the Wagner test 5.4. If these calculations allow an infinite number of solutions of elements of order \(st\) the function returns `"infinite"`, otherwiese it returns the finite list of solutions for elements of order \(s*t\). The first entry of every solution is a list of the partial augmentations of \(u^s\) and the second entry is a list of the "partial augmentations" for \(u\): the first entry of this list is the sum of the partial augmentations on all classes of elements of order s and the other entries are the partial augmentations on the classes of order t. Only in the case that the existence of units of order \(s*t\) can be excluded by this function the variable `HeLP_sol[s*t]` will be affected and `HeLP_sol[s*t]` will be set to `[ ]`.

    gap> C := CharacterTable("A6");;
    gap> HeLP_WithGivenOrder(C, 6);
    #I  Number of solutions for elements of order 6: 2; stored in HeLP_sol[6].
    [ [ [ 1 ], [ 0, 1 ], [ -2, 2, 1 ] ], [ [ 1 ], [ 1, 0 ], [ -2, 1, 2 ] ] ]
    gap> HeLP_WithGivenOrderSConstant(C, 2, 3);
    [ [ [ 0, 1 ], [ -2, 2, 1 ] ], [ [ 1, 0 ], [ -2, 1, 2 ] ] ]
    gap> HeLP_WithGivenOrderSConstant(C, 3, 2);
    [ [ [ 1 ], [ 3, -2 ] ] ]

    gap> C := CharacterTable("Sz(8)");;
    gap> SetInfoLevel(HeLP_Info, 4);
    gap> HeLP_WithGivenOrderSConstant(C, 7, 13);
    #I    Partial augmentations for elements of order 13 not yet calculated.  Restar
    t for this order.
    #I    Number of non-trivial 7-constant characters in the list: 7.
    [  ]
    gap> SetInfoLevel(HeLP_Info, 1);

The last example can also be checked by using all characters in `C`, but this takes notably longer.

    gap> C := CharacterTable("Sz(32)");
    CharacterTable( "Sz(32)" )
    gap> L := Filtered(OrdersClassRepresentatives(C), x-> x = 31);; Size(L);
    15           # I.e. HeLP_WithGivenOrder(C,31) would take hopelessly long
    gap> HeLP_WithGivenOrderSConstant(C mod 2, 31, 5);
    [  ]
    gap> IsBound(HeLP_sol[31]);
    false

We still have no clue about elements of order 31, but there are none of order 5*31.

##### 3.2-2 HeLP_AddGaloisCharacterSums

`‣ HeLP_AddGaloisCharacterSums`( CT ) | ( function )

Returns: List of characters

Given an ordinary character table CT the function calculates the orbits under the action of the Galois group and returns a list of characters containing the ones contained in CT and the ones obtained by summing up the Galois-orbits.

#### 3.3 Checks for all orders

##### 3.3-1 HeLP_AllOrders

`‣ HeLP_AllOrders`( CharacterTable|Group ) | ( function )

Returns: `true` if (ZC) can be solved using the given data, `false` otherwise

This function does almost the same as `HeLP_ZC` (2.1-1). It checks whether the Zassenhaus Conjecture can be verified for a group, but does not compute the partial augmentations of elements of order \(k\), if `HeLP_sol[k]` already exists. It does however verify the solutions given in `HeLP_sol` using all available tables for the group, see `HeLP_VerifySolution` (3.6-1). Thus some precalculations using e.g. `HeLP_WithGivenOrder` (3.1-1) are respected. In contrast to `HeLP_ZC` (2.1-1) this function also does not check whether the group is nilpotent to use the Weiss-result to have an immediate positive solution for (ZC).

This function is interesting if one wants to save time or possesses some information, which was not obtained using this package and was entered manually into `HeLP_sol`.

    gap> C := CharacterTable(PSL(2,7));
    CharacterTable( Group([ (3,7,5)(4,8,6), (1,2,6)(3,4,8) ]) )
    gap> HeLP_ZC(C);
    #I  The Brauer tables for the following primes are not available: [ 2, 3, 7 ].
    #I  (ZC) can't be solved, using the given data, for the orders: [ 6 ].
    false
    gap> HeLP_sol[6] := [ ];
    [  ]
    gap> HeLP_AllOrders(C);
    true

##### 3.3-2 HeLP_AllOrdersPQ

`‣ HeLP_AllOrdersPQ`( CharacterTable|Group ) | ( function )

Returns: `true` if (PQ) can be solved using the given data, `false` otherwise

This function does almost the same as `HeLP_PQ` (2.2-1). It checks whether the Prime Graph Question can be verified for a group, but does not compute the partial augmentations of elements of order \(k\), if `HeLP_sol[k]` already exists. Thus some precalculations using e.g. `HeLP_WithGivenOrder` (3.1-1) are respected. In contrast to `HeLP_PQ` (2.2-1) this function also does not check whether the group is solvable to use the Kimmerle-result to have an immediate positive solution for (ZC).

This function is interesting if one wants to save time or possesses some information, which was not obtained using this package and was entered manually into `HeLP_sol`.

    gap> C := CharacterTable("A12");
    CharacterTable( "A12" )
    gap> HeLP_WithGivenOrder(Irr(C){[2, 4, 7]}, 2);;
    #I  Number of solutions for elements of order 2: 37; stored in HeLP_sol[2].
    gap> HeLP_WithGivenOrderSConstant(C mod 3,11,2);
    [  ]
    gap> HeLP_WithGivenOrder(Irr(C mod 2){[2, 3, 4, 6]}, 3);;
    #I  Number of solutions for elements of order 3: 99; stored in HeLP_sol[3].
    gap> HeLP_WithGivenOrderSConstant(C mod 2, 11, 3);
    [  ]
    gap> HeLP_AllOrdersPQ(C);
    true

Thus the Prime Graph Question holds for the alternating group of degree 12. Just using `HeLP_PQ(C)` would take hopelessly long.

#### 3.4 Changing the used Character Table

##### 3.4-1 HeLP_ChangeCharKeepSols

`‣ HeLP_ChangeCharKeepSols`( CT ) | ( function )

Returns: nothing

This function changes the used character table to the character table CT and keeps all the solutions calculated so far. It is in this case the responsibility of the user that the tables belong to the same group and the ordering of the conjugacy classes in CT is consistent with the one in the previously used table. This function can be used to change from one table of the group to another, e.g. from a Brauer table to the ordinary table if the calculations will involve \(p\)-singular elements. (In case the involved character tables come from the ATLAS and their InfoText begins with "origin: ATLAS of finite groups", this is done automatically by the program.) A user may also use characters, which are normally not accessible in GAP.

To keep track of the change of the character tables one can set HeLP_Info to level 5. In this first example it is not realized that the character tables belong to the same group, so the solutions for elements of order 2 are recalculated (they have been reset, as another character table is used).

    gap> SetInfoLevel(HeLP_Info, 5);
    gap> C := CharacterTable(SymmetricGroup(4));
    CharacterTable( Sym( [ 1 .. 4 ] ) )
    gap> HeLP_WithGivenOrder(C mod 2, 3);
    #I  USED CHARACTER TABLE CHANGED TO BrauerTable( SymmetricGroup( [ 1 .. 4 ] ), 2
     ), ALL GLOBAL VARIABLES RESET.
    #I  Number of solutions for elements of order 3: 1; stored in HeLP_sol[3].
    [ [ [ 1 ] ] ]
    gap> HeLP_WithGivenOrder(C, 2*3);
    #I  USED CHARACTER TABLE CHANGED TO CharacterTable( SymmetricGroup( [ 1 .. 4 ] )
     ), ALL GLOBAL VARIABLES RESET.
    #I      Solutions for order 2 not yet calculated.  Restart for this order.
    #I      Solutions for order 3 not yet calculated.  Restart for this order.
    #I  Number of solutions for elements of order 6: 0; stored in HeLP_sol[6].
    [  ]

The recalculations of the solutions can be avoided by calling `HeLP_ChangeCharKeepSols` before using another character table.

    gap> D := CharacterTable(SymmetricGroup(4));
    CharacterTable( Sym( [ 1 .. 4 ] ) )
    gap> HeLP_WithGivenOrder(D mod 2, 3);
    #I  USED CHARACTER TABLE CHANGED TO BrauerTable( SymmetricGroup( [ 1 .. 4 ] ), 2
     ), ALL GLOBAL VARIABLES RESET.
    #I  Number of solutions for elements of order 3: 1; stored in HeLP_sol[3].
    [ [ [ 1 ] ] ]
    gap> HeLP_ChangeCharKeepSols(D);
    #I  WARNING: Change used character table without checking if the character table
    s have the same underlying groups and the ordering of the conjugacy classes are
    the same!
    gap> HeLP_WithGivenOrder(D, 2*3);
    #I  Using same character table as until now; all known solutions kept.
    #I      Solutions for order 2 not yet calculated.  Restart for this order.
    #I  Number of solutions for elements of order 6: 0; stored in HeLP_sol[6].
    [  ]

When using tables from the ATLAS this is done automatically:

    gap> CA := CharacterTable("A5");
    CharacterTable( "A5" )
    gap> HeLP_WithGivenOrder(CA mod 2, 5);
    #I  USED CHARACTER TABLE CHANGED TO BrauerTable( "A5", 2 ), ALL GLOBAL VARIABLES
     RESET.
    #I  Testing possibility 1 out of 1.
    #I  Number of solutions for elements of order 5: 2; stored in HeLP_sol[5].
    [ [ [ 0, 1 ] ], [ [ 1, 0 ] ] ]
    gap> HeLP_WithGivenOrder(CA, 2*5);
    #I  Using character table of the same group; all known solutions kept.
    #I      Solutions for order 2 not yet calculated.  Restart for this order.
    #I  Number of solutions for elements of order 10: 0; stored in HeLP_sol[10].
    [  ]
    gap> SetInfoLevel(HeLP_Info, 1);

##### 3.4-2 HeLP_Reset

`‣ HeLP_Reset`( ) | ( function )

Returns: nothing

This function delets all the values calculated so far and resets the global variables `HeLP_CT` and `HeLP_CT` to their initial value `[ [ [1] ] ]` and `CharacterTable(SmallGroup(1,1))` respectively.

#### 3.5 Influencing how the Systems of Inequalities are solved

HeLP uses currently three external programs (i.e. programs that are not part of the GAP-system): zsolve from 4ti2 and/or normaliz to solve the systems of linear inequalities and redund from lrslib to simplify the inequlities before handing them over to the solver (HeLP can also be used without lrslib installed. In general it is recommanded to have lrslib installed, if 4ti2 is used as the solver). The following functions can be used to influence the behaviour of these external programms.

##### 3.5-1 HeLP_Solver

`‣ HeLP_Solver`( [string] ) | ( function )

Returns: nothing

This function can be used to change the solver used for the HeLP-system between 4ti2 and normaliz. If the function is called without an argument it prints which solver is currently used. If the argument it is called with is one of the stings "4ti2" or "normaliz", then the solver used for future calculations is changed to the one given as argument in case this solver is found by the HeLP-package. If both solvers are found when the package is loaded normaliz is taken as default.

##### 3.5-2 HeLP_UseRedund

`‣ HeLP_UseRedund`( bool ) | ( function )

Returns: nothing

This function determines whether HeLP uses 'redund' from the lrslib-package to remove redundant equations from the HeLP system. If bool is `true` 'redund' will be used in all calculation that follow, if it is `false`, 'redund' will not be used (which might take significantly longer). If 'redund' was not found by GAP a warning will be printed and the calculations will be performed without 'redund'. As default 'redund' will be used in all calculations, if 4ti2 is the chosen solver, and 'redund' will not be used, if normaliz is used.

##### 3.5-3 HeLP_Change4ti2Precision

`‣ HeLP_Change4ti2Precision`( string ) | ( function )

Returns: nothing

This function changes the maximum precision of the calculations of 4ti2 to solve the occurring systems of linear inequalities. The possible arguments are `"32"`, `"64"` and `"gmp"`. After calling the function the new precision will be used until this function is used again. The default value is `"32"`. A higher precision causes slower calculations. But this function might be used to increase the precision of 4ti2, when one gets an error message like "Error, 4ti2 Error: Results were near maximum precision (32bit). Please restart with higher precision!" stating that the results were close to the maximum 4ti2-precision. normaliz does automatically change its precision, when it reaches an overflow.

Sometimes it is desirable to perform calculations without redund (even if it is installed and in many cases improves the performance of the package) or with a higher precision. For example, determining the partial augmentations for units of order \(14\) for `SmallGroup(392, 30)` involves very long calculations (when called with redund and precision 32) or cause errors (when called without redund and precision 32). However, the following works in a reasonable time.

    gap> C := CharacterTable(SmallGroup(392,30));
    CharacterTable( <pc group of size 392 with 5 generators> )
    gap> HeLP_Solver("4ti2");
    '4ti2' will be used from now on.
    gap> HeLP_UseRedund(false);
    The calculations will be performed without using 'redund' from now on.
    gap> HeLP_ZC(C);
    Error, 4ti2 Error:
    Results were near maximum precision (32bit).
    Please restart with higher precision!
    If you continue, your results might be wrong called from
    4ti2Interface_zsolve_equalities_and_inequalities(
     [ ListWithIdenticalEntries( Size( T[1] ), 1 ) ], [ 1 ], temp[1], - temp[2]
     ) called from
    HeLP_TestSystemINTERNAL( W[1], W[2], k, arg[3] ) called from
    HeLP_WithGivenOrderAndPAINTERNAL( C, k, pa ) called from
    HeLP_WithGivenOrderINTERNAL( Irr( T ), k ) called from
    <function "HeLP_ZC">( <arguments> )
     called from read-eval loop at line 19 of *stdin*
    you can 'quit;' to quit to outer loop, or
    you can 'return;' to continue
    gap> brk> quit;
    #I  Options stack has been reset
    gap> HeLP_Change4ti2Precision("64");
    The calculations of 4ti2 will be performed with precision 64 from now on.
    gap> HeLP_ZC(C);
    true

##### 3.5-4 HeLP_Vertices

`‣ HeLP_Vertices`( string ) | ( function )

Returns: nothing

If normlaiz is used as the solver of the HeLP-system this function influences, whether the "VerticesOfPolyhedron" are computed by normaliz. By default these are only computed, if the system has a trivial solution. The function takes "vertices", "novertices" and "default" as arguments. If you do not understand what this means, don't worry.

#### 3.6 Checking solutions, calculating and checking solutions

##### 3.6-1 HeLP_VerifySolution

`‣ HeLP_VerifySolution`( CharacterTable|ListOfClassFunctions, k[, list_paraugs] ) | ( function )

Returns: List of admissible partial augmentations

This function checks which of the partial augmentations for elements of order `k` given in `HeLP_sol[k]` or the optional third argument `list_paraugs` fulfill the HeLP equations obtained from the characters in the first argument. This function does not solve any inequalities, but only checks, if the given partial augmentations fulfill them. It is for this reason often faster then e.g. `HeLP_WithGivenOrder` (3.1-1).

If there is no third argument given, i.e. the augmentations from `HeLP_sol[k]` are used, the result overwrites `HeLP_sol[k]`.

    gap> C := CharacterTable("A6");;
    gap> HeLP_WithGivenOrder(C, 4);
    #I  Number of solutions for elements of order 4: 4; stored in HeLP_sol[4].
    [ [ [ 1 ], [ -1, 2 ] ], [ [ 1 ], [ 2, -1 ] ], [ [ 1 ], [ 1, 0 ] ],
      [ [ 1 ], [ 0, 1 ] ] ]
    gap> HeLP_VerifySolution(C mod 3, 4);
    [ [ [ 1 ], [ 1, 0 ] ], [ [ 1 ], [ 0, 1 ] ] ]
    gap> HeLP_sol[4];
    [ [ [ 1 ], [ 1, 0 ] ], [ [ 1 ], [ 0, 1 ] ] ]

    gap> C := CharacterTable("S12");;
    gap> HeLP_WithGivenOrder(Irr(C mod 5){[2..6]}, 2);;
    #I  Number of solutions for elements of order 2: 563; stored in HeLP_sol[2].
    gap> HeLP_VerifySolution(C mod 5, 2);;
    gap> Size(HeLP_sol[2]);
    387
    gap> HeLP_VerifySolution(C mod 3, 2);;
    gap> Size(HeLP_sol[2]);
    324

Using `HeLP_WithGivenOrder(C mod 5, 2)` or `HeLP_WithGivenOrder(C mod 3, 2)` takes much longer since in that case a bigger system of inequalities must be solved.

##### 3.6-2 HeLP_FindAndVerifySolution

`‣ HeLP_FindAndVerifySolution`( CharacterTable|ListOfClassFunctions, k ) | ( function )

Returns: List of admissible partial augmentations or "infinite"

This function provides the same functionality as `HeLP_WithGivenOrder` (3.1-1) but instead of constructiong the corresponding system with all characters from the first argument CharacterTable|ListOfClassFunctions it does it consecutively with larger sets of characters from the argument until a finite list of solutions is found and then applies `HeLP_VerifySolution` (3.6-1) to these solutions with the entirety of the class functions in the first argument.

This function is sometimes faster than `HeLP_WithGivenOrder` (3.1-1), but the output is the same, thus the examples from `HeLP_WithGivenOrder` (3.1-1) also apply here.

##### 3.6-3 HeLP_PossiblePartialAugmentationsOfPowers

`‣ HeLP_PossiblePartialAugmentationsOfPowers`( n ) | ( function )

Returns: List of partial augmentations of powers.

This function provides the possible partial augmentations of the powers of units of a given order \(n,\) if the partial augmentations if units of order \(n/p\) have been already computed for all primes \(p\) dividing \(n.\) The possibilities are sorted in the same way as, if the order \(n\) is checked with any other function like e.g. `HeLP_WithGivenOrder` (3.1-1) or `HeLP_ZC` (2.1-1). Thus, if the InfoLevel is high enough and one obtains that the computation of some possibility is taking too long, one can check it using `HeLP_WithGivenOrderAndPA` (3.1-2).

    gap> SetInfoLevel(HeLP_Info,4);
    gap> C := CharacterTable(SmallGroup(160,91));
    CharacterTable( <pc group of size 160 with 6 generators> )
    gap> HeLP_WithGivenOrder(C,4);;
    #I      Solutions for order 2 not yet calculated.  Restart for this order.
    #I  Number of solutions for elements of order 4: 22; stored in HeLP_sol[4].
    gap> HeLP_WithGivenOrder(C,10);;
    #I      Solutions for order 5 not yet calculated.  Restart for this order.
    #I  Number of solutions for elements of order 10: 6; stored in HeLP_sol[10].
    gap> LP := HeLP_PossiblePartialAugmentationsOfPowers(20);;
    gap> HeLP_WithGivenOrderAndPA(Irr(C){[2..20]},20,LP[1]);
    #I  Number of solutions for elements of order 20 with these partial augmentations
     for the powers: 0.
    [  ]

#### 3.7 The Wagner test

##### 3.7-1 HeLP_WagnerTest

`‣ HeLP_WagnerTest`( k[, list_paraugs, OrdinaryCharacterTable] ) | ( function )

Returns: List of admissible partial augmentations

This function applies the Wagner test (cf. Section 5.4) to the given data. If only the order k is given as argument, the Wagner test will be applied to the solutions stored in `HeLP_sol[k]`. If the arguments are the order k, a list of possible solutions list_paraugs and an ordinary character table OrdinaryCharacterTable it applies the test to the solutions given in list_paraugs and using the number of conjugacy classes for elements a divisor of k, which will be extracted from the head of OrdinaryCharacterTable.

    gap> C := CharacterTable("M11");
    CharacterTable( "M11" )
    gap> HeLP_WithGivenOrder(C,8);;
    #I  Number of solutions for elements of order 8: 36; stored in HeLP_sol[8].
    gap> HeLP_sol[8] := HeLP_WagnerTest(8);;
    gap> Size(HeLP_sol[8]);
    24

Thus the Wagner-Test eliminates 12 possible partial augmentations for elements of order 8. Continuing the example:

    gap> HeLP_WithGivenOrder(C,12);
    #I  Number of solutions for elements of order 12: 7; stored in HeLP_sol[12].
    [ [ [ 1 ], [ 1 ], [ 2, -1 ], [ 0, 3, -2 ], [ 1, 0, -1, 1 ] ],
      [ [ 1 ], [ 1 ], [ 1, 0 ], [ 0, 3, -2 ], [ 0, 0, 0, 1 ] ],
      [ [ 1 ], [ 1 ], [ -1, 2 ], [ 0, 3, -2 ], [ 0, 0, 2, -1 ] ],
      [ [ 1 ], [ 1 ], [ 0, 1 ], [ 0, 3, -2 ], [ 1, 0, 1, -1 ] ],
      [ [ 1 ], [ 1 ], [ 0, 1 ], [ 0, 3, -2 ], [ -1, 0, 1, 1 ] ],
      [ [ 1 ], [ 1 ], [ 1, 0 ], [ 0, -3, 4 ], [ 0, 0, 0, 1 ] ],
      [ [ 1 ], [ 1 ], [ -1, 2 ], [ 0, -3, 4 ], [ 1, 0, -1, 1 ] ] ]
    gap> HeLP_sol[12] := HeLP_WagnerTest(12);
    [ [ [ 1 ], [ 1 ], [ 1, 0 ], [ 0, 3, -2 ], [ 0, 0, 0, 1 ] ],
      [ [ 1 ], [ 1 ], [ -1, 2 ], [ 0, 3, -2 ], [ 0, 0, 2, -1 ] ],
      [ [ 1 ], [ 1 ], [ 1, 0 ], [ 0, -3, 4 ], [ 0, 0, 0, 1 ] ] ]
    gap> HeLP_sol[4] := HeLP_WagnerTest(4);;
    gap> HeLP_WithGivenOrder(C,12);
    #I  Number of solutions for elements of order 12: 3; stored in HeLP_sol[12].
    [ [ [ 1 ], [ 1 ], [ 2, -1 ], [ 0, 3, -2 ], [ 1, 0, -1, 1 ] ],
      [ [ 1 ], [ 1 ], [ 0, 1 ], [ 0, 3, -2 ], [ 1, 0, 1, -1 ] ],
      [ [ 1 ], [ 1 ], [ 0, 1 ], [ 0, 3, -2 ], [ -1, 0, 1, 1 ] ] ]
    gap> HeLP_sol[12] := HeLP_WagnerTest(12);
    [  ]

Thus there are no normalized units of order 12 in the integral group ring of \(M_{11}.\)

    gap> C := CharacterTable("M22");
    CharacterTable( "M22" )
    gap> HeLP_WagnerTest(12, [ [ [1], [1], [1,0], [0,0,1], [-3,3,2,3,-4] ] ],C);
    [  ]

This example is taken from the appendix of [BKL08].

Sometimes the Wagner-Test may even prove the Zassenhaus Conjecture:

    gap> G := SmallGroup(96,187);
    <pc group of size 96 with 6 generators>
    gap> C := CharacterTable(G);
    CharacterTable( <pc group of size 96 with 6 generators> )
    gap> HeLP_WithGivenOrder(C,4);;
    #I  Number of solutions for elements of order 4: 34; stored in HeLP_sol[4].
    gap> HeLP_WagnerTest(4);
    [ [ [ 0, 0, 1, 0, 0 ], [ 0, 0, 0, 0, 0, 0, 0, 0, 1 ] ],
      [ [ 0, 0, 1, 0, 0 ], [ 0, 0, 0, 0, 0, 0, 1, 0, 0 ] ],
      [ [ 0, 1, 0, 0, 0 ], [ 0, 0, 0, 0, 0, 1, 0, 0, 0 ] ],
      [ [ 0, 1, 0, 0, 0 ], [ 0, 0, 0, 0, 0, 0, 0, 1, 0 ] ] ]
    gap> HeLP_ZC(C);
    true

#### 3.8 Output

##### 3.8-1 HeLP_PrintSolution

`‣ HeLP_PrintSolution`( [k] ) | ( function )

Returns: nothing

This function prints the possible solutions in a pretty way. If a positive integer k as argument is given, then it prints the admissible partial augmentations of units of order k, if they are already calculated. If no argument is given, the function prints information on all orders for which there are already informations.

    gap> C := CharacterTable("A5");;
    gap> HeLP_ZC(C);
    true
    gap> HeLP_PrintSolution();
    Solutions for elements of order 2:
    [ [         u ],
      [  [ "2a" ] ],
      [       --- ],
      [     [ 1 ] ] ]
    Solutions for elements of order 3:
    [ [         u ],
      [  [ "3a" ] ],
      [       --- ],
      [     [ 1 ] ] ]
    Solutions for elements of order 5:
    [ [               u ],
      [  [ "5a", "5b" ] ],
      [             --- ],
      [        [ 0, 1 ] ],
      [        [ 1, 0 ] ] ]
    There are no admissible partial augmentations for elements of order 6.
    There are no admissible partial augmentations for elements of order 10.
    There are no admissible partial augmentations for elements of order 15.
    There are no admissible partial augmentations for elements of order 30.
    gap> C := CharacterTable("A6");;
    gap> HeLP_ZC(C);
    #I  ZC can't be solved, using the given data, for the orders: [ 6 ].
    false
    gap> HeLP_PrintSolution(6);
    Solutions for elements of order 6:
    [ [                   u^3,                   u^2,                     u ],
      [              [ "2a" ],        [ "3a", "3b" ],  [ "2a", "3a", "3b" ] ],
      [                   ---,                   ---,                   --- ],
      [                 [ 1 ],              [ 0, 1 ],          [ -2, 2, 1 ] ],
      [                 [ 1 ],              [ 1, 0 ],          [ -2, 1, 2 ] ] ]

#### 3.9 Eigenvalue multiplicities and character values

##### 3.9-1 HeLP_MultiplicitiesOfEigenvalues

`‣ HeLP_MultiplicitiesOfEigenvalues`( chi, k, paraugs ) | ( function )

Returns: a list of multiplicities of eigenvalues

The returned list contains at the \(l\)-th spot the multiplicity of `E(k)^(l-1)` as eigenvalue of a unit \(u\) of order k under the representation corresponding to chi having the partial augmentations paraugs for the elements \(u^d\) for divisors \(d\) different from k.

##### 3.9-2 HeLP_CharacterValue

`‣ HeLP_CharacterValue`( chi, k, paraug ) | ( function )

Returns: the character value \(chi(u)\)

The function returns the character value \(chi(u)\) of an element \(u\) of order \(k\) having the partial augmentations paraug.

    gap> C := CharacterTable("A6");;
    gap> HeLP_WithGivenOrder(C, 6);
    #I  Number of solutions for elements of order 6: 2; stored in HeLP_sol[6].
    [ [ [ 1 ], [ 0, 1 ], [ -2, 2, 1 ] ], [ [ 1 ], [ 1, 0 ], [ -2, 1, 2 ] ] ]
    gap> chi := Irr(C)[2];;   # a character of degree 5
    gap> HeLP_MultiplicitiesOfEigenvalues(chi, 6, HeLP_sol[6][2]);
    [ 1, 0, 1, 2, 1, 0 ]
    gap> HeLP_CharacterValue(chi, 6, HeLP_sol[6][2][3]);
    -2
    gap> HeLP_CharacterValue(chi, 6, [-2,1,2]);
    -2
    gap> HeLP_CharacterValue(chi, 6, [-2,2,1]);
    1

These eigenvalues were computed manually by M. Hertweck and may be found in [Her08c].

[Top of Book] [Contents] [Previous Chapter] [Next Chapter]
Goto Chapter: Top 1 2 3 4 5 6 Bib Ind

generated by GAPDoc2HTML