Net::LDAP::Control::Paged(3)

NAME
Net::LDAP::Control::Paged - LDAPv3 Paged results control object

SYNOPSIS
 use Net::LDAP;
 use Net::LDAP::Control::Paged;
 use Net::LDAP::Constant qw( LDAP_CONTROL_PAGED );

 $ldap = Net::LDAP->new( "ldap.mydomain.eg" );

 $page = Net::LDAP::Control::Paged->new( size => 100 );

 @args = ( base     => "cn=subnets,cn=sites,cn=configuration,$BASE_DN",
           scope    => "subtree",
           filter   => "(objectClass=subnet)",
           callback => \&process_entry, # Call this sub for each entry
           control  => [ $page ],
 );

 my $cookie;
 while (1) {
   # Perform search
   my $mesg = $ldap->search( @args );

   # Only continue on LDAP_SUCCESS
   $mesg->code  and last;

   # Get cookie from paged control
   my($resp)  = $mesg->control( LDAP_CONTROL_PAGED )  or last;
   $cookie    = $resp->cookie;

   # Only continue if cookie is nonempty (= we're not done)
   last  if (!defined($cookie) || !length($cookie));

   # Set cookie in paged control
   $page->cookie($cookie);
 }

 if (defined($cookie) && length($cookie)) {
   # We had an abnormal exit, so let the server know we do not want any more
   $page->cookie($cookie);
   $page->size(0);
   $ldap->search( @args );
 }

DESCRIPTION
"Net::LDAP::Control::Paged" provides an interface for the creation and manipulation of objects that represent the "pagedResultsControl" as described by RFC 2696.

The control is allowed on LDAP search requests ("search" in Net::LDAP) only. On other operations it will - depending on the value of the parameter "critical" - either be ignored or lead to errors.

CONSTRUCTOR ARGUMENTS
In addition to the constructor arguments described in Net::LDAP::Control the following are provided.

cookie
    The value to use as the cookie. This is not normally set when an object is created, but is set from the cookie value returned by the server. This associates a search with a previous search, so the server knows to return the page of entries following the entries it returned the previous time.

size
    The page size that is required. This is the maximum number of entries that the server will return to the search request.

METHODS
As with Net::LDAP::Control each constructor argument described above is also available as a method on the object which will return the current value for the attribute if called without an argument, and set a new value for the attribute if called with an argument.

SEE ALSO
Net::LDAP, Net::LDAP::Control, http://www.ietf.org/rfc/rfc2696.txt

AUTHOR
Graham Barr <gbarr@pobox.com>

Please report any bugs, or post any suggestions, to the perl-ldap mailing list <perl-ldap@perl.org>

COPYRIGHT
Copyright (c) 2000-2004 Graham Barr. All rights reserved. This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.