GAP (Wedderga) - Chapter 2: Wedderburn decomposition

Goto Chapter: Top 1 2 3 4 5 6 7 8 9 Bib Ind
[Top of Book] [Contents] [Previous Chapter] [Next Chapter]

[MathJax off]

2 Wedderburn decomposition
2.1 Wedderburn decomposition of a group algebra
2.1-1 WedderburnDecomposition
2.1-2 WedderburnDecompositionInfo
2.2 Simple quotients
2.2-1 SimpleAlgebraByCharacter
2.2-2 SimpleAlgebraByCharacterInfo
2.2-3 SimpleAlgebraByStrongSP
2.2-4 SimpleAlgebraByStrongSPInfo

### 2 Wedderburn decomposition

#### 2.1 Wedderburn decomposition of a group algebra

##### 2.1-1 WedderburnDecomposition

`‣ WedderburnDecomposition`( FG ) | ( attribute )

Returns: A list of simple algebras.

The input FG should be a group algebra of a finite group \(G\) over the field \(F\), where \(F\) is either an abelian number field (i.e. a subfield of a finite cyclotomic extension of the rationals) or a finite field of characteristic coprime with the order of \(G\).

The function returns the list of all Wedderburn components (9.3) of the group algebra FG. If \(F\) is an abelian number field then each Wedderburn component is given as a matrix algebra of a cyclotomic algebra (9.11). If \(F\) is a finite field then the Wedderburn components are given as matrix algebras over finite fields.

    gap> WedderburnDecomposition( GroupRing( GF(5), DihedralGroup(16) ) );
    [ ( GF(5)^[ 1, 1 ] ), ( GF(5)^[ 1, 1 ] ), ( GF(5)^[ 1, 1 ] ),
      ( GF(5)^[ 1, 1 ] ), ( GF(5)^[ 2, 2 ] ), ( GF(5^2)^[ 2, 2 ] ) ]
    gap> WedderburnDecomposition( GroupRing( Rationals, DihedralGroup(16) ) );
    [ Rationals, Rationals, Rationals, Rationals, ( Rationals^[ 2, 2 ] ),
      <crossed product with center NF(8,[ 1, 7 ]) over AsField( NF(8,
        [ 1, 7 ]), CF(8) ) of a group of size 2> ]
    gap> WedderburnDecomposition( GroupRing( CF(5), DihedralGroup(16) ) );
    [ CF(5), CF(5), CF(5), CF(5), ( CF(5)^[ 2, 2 ] ),
      <crossed product with center NF(40,[ 1, 31 ]) over AsField( NF(40,
        [ 1, 31 ]), CF(40) ) of a group of size 2> ]

The previous examples show that if \(D_{16}\) denotes the dihedral group of order \(16\) then the Wedderburn decomposition (9.3) of \(\mathbb F_5 D_{16}\), \(ℚ D_{16}\) and \(ℚ (\xi_5) D_{16}\) are respectively

\[ \mathbb F_5 D_{16} = 4 \mathbb F_5 \oplus M_2( \mathbb F_5 ) \oplus M_2( \mathbb F_{25} ), \]

\[ ℚ D_{16} = 4 ℚ \oplus M_2( ℚ ) \oplus (K(\xi_8)/K,t), \]

and

\[ ℚ (\xi_5) D_{16} = 4 ℚ (\xi_5) \oplus M_2( ℚ (\xi_5) ) \oplus (F(\xi_{40})/F,t), \]

where \((K(\xi_8)/K,t)\) is a cyclotomic algebra (9.11) with the centre \(K=NF(8,[ 1, 7 ])= ℚ (\sqrt{2})\), \((F(\xi_{40})/F,t) = ℚ (\sqrt{2},\xi_5)\) is a cyclotomic algebra with centre \(F=NF(40,[ 1, 31 ])\) and \(\xi_n\) denotes a \(n\)-th root of unity.

Two more examples:

    gap> WedderburnDecomposition( GroupRing( Rationals, SmallGroup(48,15) ) );
    [ Rationals, Rationals, Rationals, Rationals,
      <crossed product with center Rationals over CF(3) of a group of size 2>,
      <crossed product with center Rationals over GaussianRationals of a group of \
    size 2>, <crossed product with center Rationals over CF(3) of a group of size
        2>, <crossed product with center NF(8,[ 1, 7 ]) over AsField( NF(8,
        [ 1, 7 ]), CF(8) ) of a group of size 2>, ( CF(3)^[ 2, 2 ] ),
      <crossed product with center Rationals over CF(12) of a group of size 4> ]
    gap> WedderburnDecomposition( GroupRing( CF(3), SmallGroup(48,15) ) );
    [ CF(3), CF(3), CF(3), CF(3), ( CF(3)^[ 2, 2 ] ),
      <crossed product with center CF(3) over AsField( CF(3), CF(
        12) ) of a group of size 2>, ( CF(3)^[ 2, 2 ] ),
      <crossed product with center NF(24,[ 1, 7 ]) over AsField( NF(24,
        [ 1, 7 ]), CF(24) ) of a group of size 2>, ( CF(3)^[ 2, 2 ] ),
      ( CF(3)^[ 2, 2 ] ), ( <crossed product with center CF(3) over AsField( CF(
        3), CF(12) ) of a group of size 2>^[ 2, 2 ] ) ]

In some cases, in characteristic zero, some entries of the output of `WedderburnDecomposition` do not provide full matrix algebras over a cyclotomic algebra (9.11), but "fractional matrix algebras". That entry is not an algebra that can be used as a GAP object. Instead it is a pair formed by a rational giving the "size" of the matrices and a crossed product. See 9.3 for a theoretical explanation of this phenomenon. In this case a warning message is displayed.

    gap> QG:=GroupRing(Rationals,SmallGroup(240,89));
    <algebra-with-one over Rationals, with 2 generators>
    gap> WedderburnDecomposition(QG);
    Wedderga: Warning!!!
    Some of the Wedderburn components displayed are FRACTIONAL MATRIX ALGEBRAS!!!

    [ Rationals, Rationals, <crossed product with center Rationals over CF(
        5) of a group of size 4>, ( Rationals^[ 4, 4 ] ), ( Rationals^[ 4, 4 ] ),
      ( Rationals^[ 5, 5 ] ), ( Rationals^[ 5, 5 ] ), ( Rationals^[ 6, 6 ] ),
      <crossed product with center NF(12,[ 1, 11 ]) over AsField( NF(12,
        [ 1, 11 ]), NF(60,[ 1, 11 ]) ) of a group of size 4>,
      [ 3/2, <crossed product with center NF(8,[ 1, 7 ]) over AsField( NF(8,
            [ 1, 7 ]), NF(40,[ 1, 31 ]) ) of a group of size 4> ] ]

##### 2.1-2 WedderburnDecompositionInfo

`‣ WedderburnDecompositionInfo`( FG ) | ( attribute )

Returns: A list with each entry a numerical description of a cyclotomic algebra (9.11).

The input FG should be a group algebra of a finite group \(G\) over the field \(F\), where \(F\) is either an abelian number field (i.e. a subfield of a finite cyclotomic extension of the rationals) or a finite field of characteristic coprime to the order of \(G\).

This function is a numerical counterpart of `WedderburnDecomposition` (2.1-1).

It returns a list formed by lists of lengths 2, 4 or 5.

The lists of length 2 are of the form

\[ [n,F], \]

where \(n\) is a positive integer and \(F\) is a field. It represents the \(n\times n\) matrix algebra \(M_n(F)\) over the field \(F\).

The lists of length 4 are of the form

\[ [n,F,k,[d,\alpha,\beta]], \]

where \(F\) is a field and \(n,k,d,\alpha,\beta\) are non-negative integers, satisfying the conditions mentioned in Section 9.12. It represents the \(n\times n\) matrix algebra \(M_n(A)\) over the cyclic algebra

\[ A=F(\xi_k)[u | \xi_k^u = \xi_k^{\alpha}, u^d = \xi_k^{\beta}], \]

where \(\xi_k\) is a primitive \(k\)-th root of unity.

The lists of length 5 are of the form

\[ [n,F,k,[d_i,\alpha_i,\beta_i]_{i=1}^m, [\gamma_{i,j}]_{1\le i < j \le m} ], \]

where \(F\) is a field and \(n,k,d_i,\alpha_i,\beta_i,\gamma_{i,j}\) are non-negative integers. It represents the \(n\times n\) matrix algebra \(M_n(A)\) over the cyclotomic algebra (9.11)

\[ A = F(\xi_k)[g_1,\ldots,g_m \mid \xi_k^{g_i} = \xi_k^{\alpha_i}, g_i^{d_i}=\xi_k^{\beta_i}, g_jg_i=\xi_k^{\gamma_{ij}} g_i g_j], \]

where \(\xi_k\) is a primitive \(k\)-th root of unity (see 9.12).

    gap> WedderburnDecompositionInfo( GroupRing( Rationals, DihedralGroup(16) ) );
    [ [ 1, Rationals ], [ 1, Rationals ], [ 1, Rationals ], [ 1, Rationals ],
      [ 2, Rationals ], [ 1, NF(8,[ 1, 7 ]), 8, [ 2, 7, 0 ] ] ]
    gap> WedderburnDecompositionInfo( GroupRing( CF(5), DihedralGroup(16) ) );
    [ [ 1, CF(5) ], [ 1, CF(5) ], [ 1, CF(5) ], [ 1, CF(5) ], [ 2, CF(5) ],
      [ 1, NF(40,[ 1, 31 ]), 8, [ 2, 7, 0 ] ] ]

The interpretation of the previous example gives rise to the following Wedderburn decompositions (9.3), where \(D_{16}\) is the dihedral group of order 16 and \(\xi_5\) is a primitive \(5\)-th root of unity.

\[ ℚ D_{16} = 4 ℚ \oplus M_2( ℚ ) \oplus M_2( ℚ (\sqrt{2})). \]

\[ ℚ (\xi_5) D_{16} = 4 ℚ (\xi_5) \oplus M_2( ℚ (\xi_5)) \oplus M_2( ℚ (\xi_5,\sqrt{2})). \]

    gap> F:=FreeGroup("a","b");;a:=F.1;;b:=F.2;;rel:=[a^8,a^4*b^2,b^-1*a*b*a];;
    gap> Q16:=F/rel;; QQ16:=GroupRing( Rationals, Q16 );;
    gap> QS4:=GroupRing( Rationals, SymmetricGroup(4) );;
    gap> WedderburnDecomposition(QQ16);
    [ Rationals, Rationals, Rationals, Rationals, ( Rationals^[ 2, 2 ] ),
      <crossed product with center NF(8,[ 1, 7 ]) over AsField( NF(8,
        [ 1, 7 ]), CF(8) ) of a group of size 2> ]
    gap> WedderburnDecomposition( QS4 );
    [ Rationals, Rationals, <crossed product with center Rationals over CF(
        3) of a group of size 2>, ( Rationals^[ 3, 3 ] ), ( Rationals^[ 3, 3 ] ) ]
    gap> WedderburnDecompositionInfo(QQ16);
    [ [ 1, Rationals ], [ 1, Rationals ], [ 1, Rationals ], [ 1, Rationals ],
      [ 2, Rationals ], [ 1, NF(8,[ 1, 7 ]), 8, [ 2, 7, 4 ] ] ]
    gap> WedderburnDecompositionInfo(QS4);
    [ [ 1, Rationals ], [ 1, Rationals ], [ 1, Rationals, 3, [ 2, 2, 0 ] ],
      [ 3, Rationals ], [ 3, Rationals ] ]

In the previous example we computed the Wedderburn decomposition of the rational group algebra \(ℚ Q_{16}\) of the quaternion group of order \(16\) and the rational group algebra \(ℚ S_{4}\) of the symmetric group on four letters. For the two group algebras we used both `WedderburnDecomposition` (2.1-1) and `WedderburnDecompositionInfo`.

The output of `WedderburnDecomposition` (2.1-1) shows that

\[ ℚ Q_{16} = 4 ℚ \oplus M_2( ℚ ) \oplus A, \]

\[ ℚ S_{4} = 2 ℚ \oplus 2 M_3( ℚ ) \oplus B, \]

where \(A\) and \(B\) are crossed products (9.6) with coefficients in the cyclotomic fields \(ℚ (\xi_8)\) and \(ℚ (\xi_3)\) respectively. This output can be used as a GAP object, but it does not give clear information on the structure of the algebras \(A\) and \(B\).

The numerical information displayed by `WedderburnDecompositionInfo` means that

\[ A = ℚ (\xi|\xi^8=1)[g | \xi^g = \xi^7 = \xi^{-1}, g^2 = \xi^4 = -1], \]

\[ B = ℚ (\xi|\xi^3=1)[g | \xi^g = \xi^2 = \xi^{-1}, g^2 = 1]. \]

Both \(A\) and \(B\) are quaternion algebras over its centre which is \(ℚ (\xi+\xi^{-1})\) and the former is equal to \(ℚ (\sqrt{2})\) and \(ℚ\) respectively.

In \(B\), one has \((g+1)(g-1)=0\), while \(g\) is neither \(1\) nor \(-1\). This shows that \(B=M_2( ℚ )\). However the relation \(g^2=-1\) in \(A\) shows that

\[ A=ℚ (\sqrt{2})[i,g|i^2=g^2=-1,ig=-gi] \]

and so \(A\) is a division algebra with centre \(ℚ (\sqrt{2})\), which is a subalgebra of the algebra of Hamiltonian quaternions. This could be deduced also using well known methods on cyclic algebras (see e.g. [Rei03]).

The next example shows the output of `WedderburnDecompositionInfo` for \(ℚ G\) and \(ℚ (\xi_3) G\), where \(G=SmallGroup(48,15)\). The user can compare it with the output of `WedderburnDecomposition` (2.1-1) for the same group in the previous section. Notice that the last entry of the Wedderburn decomposition (9.3) of \(ℚ G\) is not given as a matrix algebra of a cyclic algebra. However, the corresponding entry of \(ℚ (\xi_3) G\) is a matrix algebra of a cyclic algebra.

    gap> WedderburnDecompositionInfo( GroupRing( Rationals, SmallGroup(48,15) ) );
    [ [ 1, Rationals ], [ 1, Rationals ], [ 1, Rationals ], [ 1, Rationals ],
      [ 1, Rationals, 3, [ 2, 2, 0 ] ], [ 1, Rationals, 4, [ 2, 3, 0 ] ],
      [ 1, Rationals, 6, [ 2, 5, 0 ] ], [ 1, NF(8,[ 1, 7 ]), 8, [ 2, 7, 0 ] ],
      [ 2, CF(3) ], [ 1, Rationals, 12, [ [ 2, 5, 3 ], [ 2, 7, 0 ] ], [ [ 3 ] ] ]
     ]
    gap> WedderburnDecompositionInfo( GroupRing( CF(3), SmallGroup(48,15) ) );
    [ [ 1, CF(3) ], [ 1, CF(3) ], [ 1, CF(3) ], [ 1, CF(3) ],
      [ 2, CF(3), 3, [ 1, 1, 0 ] ], [ 1, CF(3), 4, [ 2, 3, 0 ] ],
      [ 2, CF(3), 6, [ 1, 1, 0 ] ], [ 1, NF(24,[ 1, 7 ]), 8, [ 2, 7, 0 ] ],
      [ 2, CF(3) ], [ 2, CF(3) ], [ 2, CF(3), 12, [ 2, 7, 0 ] ] ]

In some cases some of the first entries of the output of `WedderburnDecompositionInfo` are not integers and so the correspoding Wedderburn components (9.3) are given as "fractional matrix algebras" of cyclotomic algebras (9.11). See 9.3 for a theoretical explanation of this phenomenon. In that case a warning message will be displayed during the first call of `WedderburnDecompositionInfo`.

    gap> QG:=GroupRing(Rationals,SmallGroup(240,89));
    <algebra-with-one over Rationals, with 2 generators>
    gap> WedderburnDecompositionInfo(QG);
    Wedderga: Warning!!!
    Some of the Wedderburn components displayed are FRACTIONAL MATRIX ALGEBRAS!!!

    [ [ 1, Rationals ], [ 1, Rationals ], [ 1, Rationals, 10, [ 4, 3, 5 ] ],
      [ 4, Rationals ], [ 4, Rationals ], [ 5, Rationals ], [ 5, Rationals ],
      [ 6, Rationals ], [ 1, NF(12,[ 1, 11 ]), 10, [ 4, 3, 5 ] ],
      [ 3/2, NF(8,[ 1, 7 ]), 10, [ 4, 3, 5 ] ] ]

The interpretation of the output in the previous example gives rise to the following Wedderburn decomposition (9.3) of \(ℚ G\) for \(G\) the small group \([240,89]\):

\[ ℚ G = 2 ℚ \oplus 2 M_4( ℚ ) \oplus 2 M_5( ℚ ) \oplus M_6( ℚ ) \oplus A \oplus B \oplus C \]

where

\[ A = ℚ (\xi_{10})[u|\xi_{10}^u = \xi_{10}^3, u^4 = -1], \]

\(B\) is an algebra of degree \((4*2 )/2 = 4 \) which is Brauer equivalent (9.5) to

\[ B_1 = ℚ (\xi_{60})[u,v|\xi_{60}^u = \xi_{60}^{13}, u^4 = \xi_{60}^5, \xi_{60}^v = \xi_{60}^{11}, v^2 = 1, vu=uv], \]

and \(C\) is an algebra of degree \((4*2)*3/4 = 6 \) which is Brauer equivalent (9.5) to

\[ C_1 = ℚ (\xi_{60})[u,v|\xi_{60}^u = \xi_{60}^7, u^4 = \xi_{60}^5, \xi_{60}^v = \xi_{60}^{31}, v^2 = 1, vu=uv]. \]

The precise description of \(B\) and \(C\) requires the usage of "ad hoc" arguments.

#### 2.2 Simple quotients

##### 2.2-1 SimpleAlgebraByCharacter

`‣ SimpleAlgebraByCharacter`( FG, chi ) | ( operation )

Returns: A simple algebra.

The first input FG should be a semisimple group algebra (9.2) over a finite group \(G\) and the second input should be an irreducible character of \(G\).

The output is a matrix algebra of a cyclotomic algebras (9.11) which is isomorphic to the unique Wedderburn component (9.3) \(A\) of FG such that \(\chi(A)\ne 0\).

    gap> A5 := AlternatingGroup(5);
    Alt( [ 1 .. 5 ] )
    gap> SimpleAlgebraByCharacter( GroupRing( Rationals , A5 ) , Irr( A5 ) [3] );
    ( NF(5,[ 1, 4 ])^[ 3, 3 ] )
    gap> SimpleAlgebraByCharacter( GroupRing( GF(7) , A5 ) , Irr( A5 ) [3] );
    ( GF(7^2)^[ 3, 3 ] )
    gap> G:=SmallGroup(128,100);
    <pc group of size 128 with 7 generators>
    gap> chi4:=Filtered(Irr(G),x->Degree(x)=4);;
    gap> List(chi4,x->SimpleAlgebraByCharacter(GroupRing(Rationals,G),x));
    [ ( <crossed product with center NF(8,[ 1, 3 ]) over AsField( NF(8,
        [ 1, 3 ]), CF(8) ) of a group of size 2>^[ 2, 2 ] ),
      ( <crossed product with center NF(8,[ 1, 3 ]) over AsField( NF(8,
        [ 1, 3 ]), CF(8) ) of a group of size 2>^[ 2, 2 ] ),
      ( <crossed product with center NF(8,[ 1, 3 ]) over AsField( NF(8,
        [ 1, 3 ]), CF(8) ) of a group of size 2>^[ 2, 2 ] ),
      ( <crossed product with center NF(8,[ 1, 3 ]) over AsField( NF(8,
        [ 1, 3 ]), CF(8) ) of a group of size 2>^[ 2, 2 ] ) ]

##### 2.2-2 SimpleAlgebraByCharacterInfo

`‣ SimpleAlgebraByCharacterInfo`( FG, chi ) | ( operation )

Returns: The numerical description of the output of `SimpleAlgebraByCharacter` (2.2-1).

The first input FG is a semisimple group algebra (9.2) over a finite group \(G\) and the second input is an irreducible character of \(G\).

The output is the numerical description 9.12 of the cyclotomic algebra (9.11) which is isomorphic to the unique Wedderburn component (9.3) \(A\) of FG such that \(\chi(A)\ne 0\).

See 9.12 for the interpretation of the numerical information given by the output.

    gap> G:=SmallGroup(128,100);
    <pc group of size 128 with 7 generators>
    gap> QG:=GroupRing(Rationals,G);
    <algebra-with-one over Rationals, with 7 generators>
    gap> chi4:=Filtered(Irr(G),x->Degree(x)=4);;
    gap> List(chi4,x->SimpleAlgebraByCharacterInfo(QG,x));
    [ [ 2, NF(8,[ 1, 3 ]), 8, [ 2, 3, 0 ] ], [ 2, NF(8,[ 1, 3 ]), 8, [ 2, 3, 0 ] ],
      [ 2, NF(8,[ 1, 3 ]), 8, [ 2, 3, 4 ] ], [ 2, NF(8,[ 1, 3 ]), 8, [ 2, 3, 4 ] ] ]

##### 2.2-3 SimpleAlgebraByStrongSP

`‣ SimpleAlgebraByStrongSP`( QG, K, H ) | ( operation )

`‣ SimpleAlgebraByStrongSPNC`( QG, K, H ) | ( operation )

`‣ SimpleAlgebraByStrongSP`( FG, K, H, C ) | ( operation )

`‣ SimpleAlgebraByStrongSPNC`( FG, K, H, C ) | ( operation )

Returns: A simple algebra.

In the three-argument version the input must be formed by a semisimple rational group algebra QG (see 9.2) and two subgroups K and H of \(G\) which form a strong Shoda pair (9.15) of \(G\).

The three-argument version returns the Wedderburn component (9.3) of the rational group algebra QG realized by the strong Shoda pair (K,H).

In the four-argument version the first argument is a semisimple finite group algebra FG, (K,H) is a strong Shoda pair of \(G\) and the fourth input data is either a generating \(q\)-cyclotomic class modulo the index of H in K or a representative of a generating \(q\)-cyclotomic class modulo the index of H in K (see 9.19).

The four-argument version returns the Wedderburn component (9.3) of the finite group algebra FG realized by the strong Shoda pair (K,H) and the cyclotomic class C (or the cyclotomic class containing C).

The versions ending in NC do not check if (K,H) is a strong Shoda pair of \(G\). In the four-argument version it is also not checked whether C is either a generating \(q\)-cyclotomic class modulo the index of H in K or an integer coprime to the index of H in K.

    gap> F:=FreeGroup("a","b");; a:=F.1;; b:=F.2;;
    gap> G:=F/[ a^16, b^2*a^8, b^-1*a*b*a^9 ];; a:=G.1;; b:=G.2;;
    gap> K:=Subgroup(G,[a]);; H:=Subgroup(G,[]);;
    gap> QG:=GroupRing( Rationals, G );;
    gap> FG:=GroupRing( GF(7), G );;
    gap> SimpleAlgebraByStrongSP( QG, K, H );
    <crossed product over CF(16) of a group of size 2>
    gap> SimpleAlgebraByStrongSP( FG, K, H, [1,7] );
    ( GF(7)^[ 2, 2 ] )
    gap> SimpleAlgebraByStrongSP( FG, K, H, 1 );
    ( GF(7)^[ 2, 2 ] )

##### 2.2-4 SimpleAlgebraByStrongSPInfo

`‣ SimpleAlgebraByStrongSPInfo`( QG, K, H ) | ( operation )

`‣ SimpleAlgebraByStrongSPInfoNC`( QG, K, H ) | ( operation )

`‣ SimpleAlgebraByStrongSPInfo`( FG, K, H, C ) | ( operation )

`‣ SimpleAlgebraByStrongSPInfoNC`( FG, K, H, C ) | ( operation )

Returns: A numerical description of one simple algebra.

In the three-argument version the input must be formed by a semisimple rational group algebra (9.2) QG and two subgroups K and H of \(G\) which form a strong Shoda pair (9.15) of \(G\). It returns the numerical information describing the Wedderburn component (9.12) of the rational group algebra QG realized by a the strong Shoda pair (K,H).

In the four-argument version the first input is a semisimple finite group algebra FG, (K,H) is a strong Shoda pair of \(G\) and the fourth input data is either a generating \(q\)-cyclotomic class modulo the index of H in K or a representative of a generating \(q\)-cyclotomic class modulo the index of H in K (9.19). It returns a pair of positive integers \([n,r]\) which represent the \(n\times n\) matrix algebra over the field of order \(r\) which is isomorphic to the Wedderburn component of FG realized by a the strong Shoda pair (K,H) and the cyclotomic class C (or the cyclotomic class containing the integer C).

The versions ending in NC do not check if (K,H) is a strong Shoda pair of \(G\). In the four-argument version it is also not checked whether C is either a generating \(q\)-cyclotomic class modulo the index of H in K or an integer coprime with the index of H in K.

    gap> F:=FreeGroup("a","b");; a:=F.1;; b:=F.2;;
    gap> G:=F/[ a^16, b^2*a^8, b^-1*a*b*a^9 ];; a:=G.1;; b:=G.2;;
    gap> K:=Subgroup(G,[a]);; H:=Subgroup(G,[]);;
    gap> QG:=GroupRing( Rationals, G );;
    gap> FG:=GroupRing( GF(7), G );;
    gap> SimpleAlgebraByStrongSP( QG, K, H );
    <crossed product over CF(16) of a group of size 2>
    gap> SimpleAlgebraByStrongSPInfo( QG, K, H );
    [ 1, NF(16,[ 1, 7 ]), 16, [ [ 2, 7, 8 ] ], [  ] ]
    gap> SimpleAlgebraByStrongSPInfo( FG, K, H, [1,7] );
    [ 2, 7 ]
    gap> SimpleAlgebraByStrongSPInfo( FG, K, H, 1 );
    [ 2, 7 ]

[Top of Book] [Contents] [Previous Chapter] [Next Chapter]
Goto Chapter: Top 1 2 3 4 5 6 7 8 9 Bib Ind

generated by GAPDoc2HTML