# Black box algorithm to find standard generators of M12
# (Second listed algorithm)

	set F 0
	set G 0
	set V 0
lbl SEMISTD
	rand 1
	ord 1 A
	incr V
	if V gt 1000 then timeout
	if A notin 1 2 3 4 5 6 8 10 11 then fail
	if F eq 0 then
		if A in 4 8 then
			div A 2 B
			pwr B 1 2
			set F 1
		endif
	endif
	if G eq 0 then
		if A eq 10 then
			pwr 5 1 3
			set G 1
		endif
	endif

	if F eq 0 then jmp SEMISTD
	if G eq 0 then jmp SEMISTD
	
	set X 0
lbl ELTORDER3
	incr X
	if X gt 1000 then timeout
	rand 4
	cj 3 4 5
	mu 3 5 6
	ord 6 D
	if D notin 1 2 3 4 5 6 then fail
	if D notin 3 6 then jmp ELTORDER3

	div D 3 E
	pwr E 6 7

	set X 0
lbl CONJUGATE
	incr X
	if X gt 1000 then timeout
	rand 8
	cjr 7 8
	mu 2 7 9
	ord 9 F

	if F notin 2 3 5 6 8 10 11 then fail
	if F noteq 11 then jmp CONJUGATE

	oup 2 2 7
