zar
Prev | Orchestra Opcodes and Operators | Next

## zar

zir — Reads from a location in za space at a-rate.

## Description

Reads from a location in za space at a-rate.

## Syntax

    ares zar kndx

## Performance

kndx -- points to the za location to be read.

zar reads the array of floats at kndx in za space, which are ksmps number of a-rate floats to be processed in a k cycle.

## Examples

Here is an example of the zar opcode. It uses the file zar.csd.

Example 1151. Example of the zar opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o zar.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    ; Initialize the ZAK space.
    ; Create 1 a-rate variable and 1 k-rate variable.
    zakinit 1, 1

    ; Instrument #1 -- a simple waveform.
    instr 1
      ; Generate a simple sine waveform.
      asin oscil 20000, 440, 1

      ; Send the sine waveform to za variable #1.
      zaw asin, 1
    endin

    ; Instrument #2 -- generates audio output.
    instr 2
      ; Read za variable #1.
      a1 zar 1

      ; Generate audio output.
      out a1

      ; Clear the za variables, get them ready for
      ; another pass.
      zacl 0, 1
    endin

    </CsInstruments>
    <CsScore>

    ; Table #1, a sine wave.
    f 1 0 16384 10 1

    ; Play Instrument #1 for one second.
    i 1 0 1
    ; Play Instrument #2 for one second.
    i 2 0 1
    e

    </CsScore>
    </CsoundSynthesizer>

## See Also

zarg, zir, zkr

## Credits

Author: Robin Whittle
Australia
May 1997

New in version 3.45

Example written by Kevin Conder.

Prev | Up | Next
zamod | Home | zarg