Creator-Defined Statements — Ren'Py Documentation

# Creator-Defined Statements

Creator-defined statements allow you to add your own statements to Ren'Py. This makes it possible to add things that are not supported by the current syntax of Ren'Py.

Creator-defined statements must be defined in a `python early` block. What's more, the filename containing the user-defined statement must be be loaded earlier than any file that uses it. Since Ren'Py loads files in Unicode sort order, it generally makes sense to prefix the name of any file containing a user-defined statement with 01, or some other small number.

A user-defined statement cannot be used in the file in which it is defined.

Creator-defined statement are registered using the renpy.register_statement function.

`renpy.` `register_statement`(name, parse=None, lint=None, execute=None, predict=None, next=None, scry=None, block=False, init=False, translatable=False, execute_init=None, label=None, warp=None)

  This registers a user-defined statement.

  name
    This is either a space-separated list of names that begin the statement, or the empty string to define a new default statement (the default statement will replace the say statement).
  block
    When this is False, the statement does not expect a block. When True, it expects a block, but leaves it up to the lexer to parse that block. If the string "script", the block is interpreted as containing one or more Ren'Py script language statements.
  parse
    This is a function that takes a Lexer object. This function should parse the statement, and return an object. This object is passed as an argument to all the other functions. The lexer argument has the following methods:
  lint
    This is called to check the statement. It is passed a single argument, the object returned from parse. It should call renpy.error to report errors.
  execute
    This is a function that is called when the statement executes. It is passed a single argument, the object returned from parse.
  execute_init
    This is a function that is called at init time, at priority 0.
  predict
    This is a function that is called to predict the images used by the statement. It is passed a single argument, the object returned from parse. It should return a list of displayables used by the statement.
  next

    This is a function that is called to determine the next statement.

    If block is not "script", this is passed a single argument, the object returned from the parse function. If block is "script", an additional argument is passed, an object that names the first statement in the block.

    The function should return either a string giving a label to jump to, the second argument to transfer control into the block, or None to continue to the statement after this one.

  label
    This is a function that is called to determine the label of this statement. If it returns a string, that string is used as the statement label, which can be called and jumped to like any other label.
  warp
    This is a function that is called to determine if this statement should execute during warping. If the function exists and returns true, it's run during warp, otherwise the statement is not run during warp.
  scry
    Used internally by Ren'Py.
  init
    True if this statement should be run at init-time. (If the statement is not already inside an init block, it's automatically placed inside an init 0 block.) This calls the execute function, in addition to the execute_init function.

The parse method takes a Lexer object:

class `Lexer`
  `eol`()

    True if the lexer is at the end of the line.

  `match`(re)

    Matches an arbitrary regexp string.

    All of the statements in the lexer that match things are implemented in terms of this function. They first skip whitespace, then attempt to match against the line. If the match succeeds, the matched text is returned. Otherwise, None is returned.

  `keyword`(s)

    Matches s as a keyword.

  `name`()

    Matches a name. This does not match built-in keywords.

  `word`()

    Matches any word, including keywords. Returns the text of the matched word.

  `string`()

    Matches a Ren'Py string.

  `integer`()

    Matches an integer, returns a string containing the integer.

  `float`()

    Matches a floating point number, returns a string containing the floating point number.

  `simple_expression`()

    Matches a simple Python expression, returns it as a string.

  `rest`()

    Skips whitespace, the returns the rest of the line.

  `checkpoint`()

    Returns an opaque object representing the current state of the lexer.

  `revert`(o)

    When o is the object returned from checkpoint(), reverts the state of the lexer to what it was when checkpoint() was called. (This is used for backtracking.)

  `subblock_lexer`()

    Return a Lexer for the block associated with the current line.

  `advance`()

    In a subblock lexer, advances to the next line. This must be called before the first line, so the first line can be parsed.

## Lint Utility Functions

These functions are useful in writing lint functions.

`renpy.` `check_text_tags`(s)

  Checks the text tags in s for correctness. Returns an error string if there is an error, or None if there is no error.

## Example

This creates a new statement `line` that allows lines of text to be specified without quotes.

    python early:

        def parse_smartline(lex):
            who = lex.simple_expression()
            what = lex.rest()
            return (who, what)

        def execute_smartline(o):
            who, what = o
            renpy.say(eval(who), what)

        def lint_smartline(o):
            who, what = o
            try:
                eval(who)
            except:
                renpy.error("Character not defined: %s" % who)

            tte = renpy.check_text_tags(what)
            if tte:
                renpy.error(tte)

        renpy.register_statement("line", parse=parse_smartline, execute=execute_smartline, lint=lint_smartline)

This can be used by writing:

    line e "These quotes will show up," Eileen said, "and don't need to be backslashed."