Άρθρωμα
Περιεχόμενα
Δείκτης 🔎︎

## Συνάρτηση COUNTIFS

Returns the count of cells that meet criteria in multiple ranges.

### Σύνταξη

COUNTIFS(περιοχή1; κριτήριο1 [; περιοχή2; κριτήριο2 [; ...]])

Περιοχή1 – απαιτούμενο όρισμα. Είναι μια περιοχή κελιών, ένα όνομα μιας ονοματισμένης περιοχής, ή μια ετικέτα μιας στήλης ή μιας γραμμής που περιέχουν τιμές για τη μέτρηση και την εύρεση του αντίστοιχου κριτηρίου.

Criterion1 – required argument. A string expression representing a logical condition or a cell reference to such string expression. The expression can contain text, numbers, regular expressions or wildcards (if enabled in calculation options).

Range2 – Optional. Range2 and all the following mean the same as Range1.

Criterion2 – Optional. Criterion2 and all the following mean the same as Criterion1.

Range1, Range2, ... and Criterion1, Criterion2, ... must have the same size, otherwise the function returns err:502 - Invalid argument.

The logical relation between criteria can be defined as logical AND (conjunction). In other words, if and only if all given criteria are met, a value from the corresponding cell of the given Func_Range is taken into calculation.

The function can have up to 255 arguments, meaning that you can specify 127 criteria ranges and criteria for them.

If a cell contains TRUE, it is treated as 1, if a cell contains FALSE – as 0 (zero).

Αυτή η συνάρτηση είναι τμήμα του προτύπου της μορφής Open Document για εφαρμογές γραφείου (OpenDocument) έκδοσης 1.2. (ISO/IEC 26300:2-2015)

### Παραδείγματα

#### Θεωρήστε τον ακόλουθο πίνακα

| A | B | C
1 | Όνομα προϊόντος | Πωλήσεις | Έσοδα
2 | μολύβι | 20 | 65
3 | στυλό | 35 | 85
4 | σημειωματάριο | 20 | 190
5 | βιβλίο | 17 | 180
6 | κασετίνα | όχι | όχι

In all examples below, ranges for calculation contain the row #6, which is ignored because it contains text.

#### Απλή χρήση

=COUNTIFS(B2:B6;">=20")

Μετρά τον αριθμό των γραμμών στην περιοχή B2:B6 με τιμές μεγαλύτερες από ή ίσες με 20. Επιστρέφει 3, επειδή η πέμπτη και η έκτη γραμμή δεν ικανοποιούν το κριτήριο.

=COUNTIFS(B2:B6;">=20";C2:C6;">70")

Μετρά τον αριθμό των γραμμών που περιέχουν ταυτόχρονα τιμές μεγαλύτερες από 70 στην περιοχή C2:C6 και τιμές μεγαλύτερες από ή ίσες με 20 στην περιοχή B2:B6. Επιστρέφει 2, επειδή η δεύτερη, η πέμπτη και η έκτη γραμμή δεν πληρούν τουλάχιστον ένα κριτήριο.

#### Χρήση κανονικών παραστάσεων και ένθετων συναρτήσεων

=COUNTIFS(B2:B6;"[:alpha:]*")

Μετρά τον αριθμό των γραμμών στην περιοχή B2:B6 που περιέχει μόνο αλφαβητικά σύμβολα. Επιστρέφει 1, επειδή μόνο η έκτη γραμμή πληρεί το κριτήριο.

=COUNTIFS(B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Μετρά τον αριθμό των γραμμών στην περιοχή B2:B6 αποκλείοντας τις γραμμές με ελάχιστες και μέγιστες τιμές αυτής της περιοχής. Επιστρέφει 2, επειδή η τρίτη, η πέμπτη και η έκτη γραμμή δεν πληρούν τουλάχιστον ένα κριτήριο.

=COUNTIFS(A2:A6;"pen.*";B2:B6;"<"&MAX(B2:B6))

Υπολογίζει τον αριθμό των γραμμών που αντιστοιχούν σε όλα τα κελιά της περιοχής A2:A6 που ξεκινούν με "pen" και όλα τα κελιά της περιοχής B2:B6 με εξαίρεση του μεγίστου του. Επιστρέφει 1, επειδή μόνο η δεύτερη γραμμή καλύπτει όλα τα κριτήρια.

#### Αναφορά σε ένα κελί ως ένα κριτήριο

Αν χρειάζεται να αλλάξετε ένα κριτήριο εύκολα, μπορεί να θέλετε να το ορίσετε σε ένα ξεχωριστό κελί και να χρησιμοποιήσετε μια αναφορά σε αυτό το κελί στη συνθήκη της συνάρτησης COUNTIFS. Παραδείγματος χάρη, η παραπάνω συνάρτηση μπορεί να ξαναγραφτεί ως εξής:

=COUNTIFS(A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

Αν E2 = pen, η συνάρτηση επιστρέφει 1, επειδή ο σύνδεσμος στο κελί αντικαθίσταται με το περιεχόμενό του και δουλεύει όπως η παραπάνω συνάρτηση.

Σχετικά θέματα

COUNT, COUNTIF, COUNTBLANK, COUNTA

COUNTIFS, MINIFS, MAXIFS, AVERAGEIFS, SUMIFS

Κατάλογος κανονικών εκφράσεων