Modul
Indhald
Innhaldsliste 🔎︎

# MAKSVISS.SANN-funksjonen

Returnerer maksimum av celleverdiane i eit område som oppfyller fleire kriteria i fleire område.

### Syntaks

MAKSVISS.SANN(Funksjons_område; Område1; Kriterium1 [ ; Område2; Kriterium2 [;...]]))

Funksjonsområde – nødvendig argument. Dette kan vera eit celleområde, namnet på eit namngjeve område eller etiketten på ei rad eller ein kolonne som inneheld verdiar som vert brukte for å rekna ut maksimum.

Kriterium1 må ha eit argument. Eit strenguttrykk som representerer eit logisk vilkår eller ein cellereferanse til eit slikt uttrykk. Uttrykket kan innehalda tekst, tal, regulære uttrykk eller jokerteikn (viss det er opna for desse i innstillingane for utrekningane).

Område2 – Valfri. Område2 og alle dei følgjande tyder det same som Område1.

Kriterium2 – Valfritt. Kriterium2 og alle etterfølgjande betyr det same som Kriterium1.

Funksjonsområde og Område1, Område2 … må vera av same storleik. Elles returnerer funksjonen feil:502 - ugyldig argument.

Den logiske relasjonen mellom kriteria kan definerast som logisk OG (konjunksjon). Med andre ord, viss alle gjevne kriteria vert oppfylde, vert verdien frå den tilsvarande cella i det gjevne Funksjons_område tatt med i utrekningane.

Funksjonen kan ha opp til 255 argument. Dette betyr at du kan ha 127 kriterieområde og kriteria for desse.

Viss ei celle inneheld SANN vert dette handtert som 1, medan USANN vert handtert som 0 (null).

Denne funksjonen høyrer til Open Document Format for Office Applications (OpenDocument) standard versjon 1.2. (ISO/IEC 26300:2-2015)

### Eksempel

#### Studer denne tabellen

| A | B | C
1 | Produktnamn | Sal | Inntekt
2 | blyant | 20 | 65
3 | penn | 35 | 85
4 | notisbok | 20 | 190
5 | bok | 17 | 180
6 | penal | ikkje | ikkje

Alle eksempla nedanfor inneheld rad nummer 6, men denne vert ignorert sidan ho inneheld tekst.

#### Enkel bruk

=MAKSVISS.SANN(B2:B6;B2:B6;"<35")

Reknar ut maksimum av verdiane i område B2:B6 som er større enn eller lik 20. Returnerer 35 fordi den femte rada ikkje oppfyller kriteriet.

=MAKSVISS.SANN(C2:C6;B2:B6;">=20";C2:C6;"<90")

Reknar ut maksimum av verdiar i området C2:C6 mindre enn 90 og som svarar til cellene i området B2:B6 med verdiar som er større enn eller lik 20. Returnerer 85 fordi fjerde og femte rada ikkje oppfyller minst eitt kriterium.

#### Bruka regulære uttrykk og nøsta funksjonar

=MAKSVISS.SANN(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAKS(B2:B6))

Reknar ut maksimum for verdiane i område C2:C6 som svarar til alle verdiane i område B2:B6 unntatt den største og minste verdien. Returnerer 190 fordi berre den fjerde rada oppfyller kriteria.

=MAKSVISS.SANN(C2:C6;A2:A6;"pen.*";B2:B6;"<="&MAKS(B2:B6))

Rekbnar ut maksimum av verdiar i området C2:C6 som svarar til alle cellene i området A2:A6 som byrjar med "pen", og til alle cellene i B2:B6 området, unntatt maksimum for desse. Returnerer 85 fordi berre den tredje rada opfyller kriteria.

#### Referanse til ei celle som kriterium

Viss du har bruk for å enkelt å endra eitt vilkår, kan du spesifisera det i ei ekstra celle og laga ein referanse til denne cella i vilkåret for MAKSVISS.SANN-funksjonen. For eksempel kan funksjonen ovanfor omskrivast slik:

=MAKSVISS.SANN(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MAKS(B2:B6))

Viss E2 = "pen", vil funksjonen returnere 65 fordi referansen til cella er bytt ut med innhaldet.

Liknande emne

MAKS, MAKSA, MIN, MINA,

TAL.VISS.SETT, MINVISS.SANN, MAKSVISS.SANN, GJENNOMSNITT.VISS.SETT, SUMMER.VISS.SETT

Liste over regulære uttrykk