Modulo
Contenuto
Indice 🔎︎

## Funzione MEDIA.PIÙ.SE

Restituisce la media aritmetica di tutte le celle all'interno di un intervallo che soddisfi più condizioni determinate. La funzione MEDIA.PIÙ.SE somma tutti i risultati che corrispondono ai test logici e divide per la quantità dei valori selezionati.

### Sintassi

MEDIA.PIÙ.SE(Intervallo_Funz; Intervallo1; Criterio1 [ ; Intervallo; Criterio2 [;...]]))

intervallo_media – argomento obbligatorio. È un intervallo di celle, il nome di un'area indicata, la dicitura di una colonna o di una riga che contiene valori per il calcolo della media.

Criterio1: argomento richiesto. Un'espressione che rappresenta una condizione logica o un riferimento di cella a tale espressione. L'espressione può contenere testo, numeri, espressioni regolari o caratteri jolly (se abilitati nelle opzioni di calcolo).

Intervallo2 – opzionale. Intervallo2 e tutto ciò che segue hanno lo stesso significato di Intervallo1.

Criterio2 – opzionale. Criterio2 e tutto ciò che segue hanno lo stesso significato di Criterio1.

Intervallo_Funz e Intervallo1, Intervallo2... devono possedere la stessa dimensione, in caso contrario la funzione restituisce err:502 - Argomento non valido.

La relazione logica tra i criteri definibili come E logico (congiunzione). In altre parole, se, e solo se, tutti i criteri sono soddisfatti, viene inserito nel calcolo un valore derivante dalla cella corrispondente del Intervallo_Func specificato.

La funzione può possedere fino a 255 argomenti, nel senso che potete specificare 127 intervalli di criteri e i criteri ad essi relativi.

Se una cella contenesse VERO, sarebbe considerata 1; se contenesse FALSO, sarebbe considerata 0 (zero).

Questa funzione appartiene all'Open Document Format for Office Applications (OpenDocument), versione standard 1.2 (ISO/IEC 26300:2-2015).

### Esempi

#### Considerate la tabella seguente

| A | B | C
1 | Nome prodotto | Vendite | Ricavo
2 | matita | 20 | 65
3 | penna | 35 | 85
4 | notebook | 20 | 190
5 | libro | 17 | 180
6 | astuccio | non | non

In tutti gli esempi riportati sotto, gli intervalli per il calcolo contengono la riga #6, che viene ignorata poiché contiene testo.

#### Uso semplice

=MEDIA.PIÙ.SE(B2:B6;B2:B6;">=20")

Calcola la media per i valori dell'intervallo B2:B6, maggiori o uguali a 20. Restituisce 25, perché la quinta riga non soddisfa il criterio.

=MEDIA.PIÙ.SE(C2:C6;B2:B6;">=20";C2:C6;">70")

Calcola la media per i valori dell'intervallo C2:C6 maggiori di 70 e che corrispondono alle celle B2:B6 con valori maggiori o uguali a 20. Restituisce 137,5, perché la seconda e la quinta riga non soddisfano almeno un criterio.

#### Uso delle espressioni regolari e delle funzioni annidate

=MEDIA.PIÙ.SE(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Calcola la media per i valori dell'intervallo C2:C6 che corrispondono a tutti i valori dell'intervallo B2:B6, eccetto il suo minimo e massimo. Restituisce 127,5, perché la terza e la quinta riga non soddisfano almeno un criterio.

=MEDIA.PIÙ.SE(C2:C6;A2:A6;"pen.*";B2:B6;"<"&MAX(B2:B6))

Calcola la media per i valori dell'intervallo C2:C6 che corrispondono a tutte le celle dell'intervallo A2:B6 che iniziano con "pen" e a tutte le celle dell'intervallo B2:B6, eccetto il suo massimo. Restituisce 65, perché solo la seconda riga soddisfa tutti i criteri.

#### Fare riferimento a una cella come criterio

Per cambiare in modo facile un criterio, potete specificarlo in una cella separata, utilizzando un riferimento alla cella all'interno della condizione della funzione MEDIA.PIÙ.SE. Per esempio, la funzione sopra citata può essere riscritta nel modo seguente:

=MEDIA.PIÙ.SE(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

Se E2 = pen, la funzione restituisce 65, perché il collegamento alla cella è sostituito dal suo contenuto.

Argomenti correlati

MEDIA, MEDIA.VALORI, MEDIA.DEV, MEDIA.SE

CONTA.PIÙ.SE, MIN.PIÙ.SE, MAX.PIÙ.SE, MEDIA.PIÙ.SE, SOMMA.PIÙ.SE

Elenco delle espressioni regolari