Module
Inhoud
Index 🔎︎

# Databasefuncties

In deze sectie worden functies besproken die gebruikt worden voor gegevens die als één rij gegevens voor één record georganiseerd zijn.

De categorie Database kan worden verward met een database die is geïntegreerd in LibreOffice. Er bestaat echter geen verband tussen een database in LibreOffice en de categorie Database in LibreOffice Calc.

### Voorbeeldgegevens:

In sommige voorbeelden van functiebeschrijvingen worden de volgende gegevens gebruikt:

Het bereik A1:E10 toont de kinderen die uitgenodigd zijn voor Joe's verjaardagsfeestje. De volgende informatie wordt voor elk item gegeven: kolom A toont de naam, B de groep, dan leeftijd in jaren, afstand tot school in meters en gewicht in kilo's.

| A | B | C | D | E
1 | Naam | Groep | Leeftijd | Afstand naar school | Gewicht
2 | Andy | 3 | 9 | 150 | 40
3 | Betty | 4 | 10 | 1000 | 42
4 | Charles | 3 | 10 | 300 | 51
5 | Daniël | 5 | 11 | 1200 | 48
6 | Eva | 2 | 8 | 650 | 33
7 | Frank | 2 | 7 | 300 | 42
8 | Greta | 1 | 7 | 200 | 36
9 | Harry | 3 | 9 | 1200 | 44
10 | Irene | 2 | 8 | 1000 | 42
11 |  |  |  |  |
12 |  |  |  |  |
13 | Naam | Groep | Leeftijd | Afstand naar school | Gewicht
14 |  |  |  | >600 |
15 |  |  |  |  |
16 | DBAANTAL | 5 |  |  |

De formule in cel B16 is =DBAANTAL(A1:E10;D1;A13:E14)

### Parameters voor databasefuncties:

De volgende items zijn de parameterdefinities voor alle databasefuncties:

Database is het celbereik dat de database definieert.

Databaseveld specificeert de kolom waar de functie op zal werken nadat de zoekcriteria van de eerste parameter zijn toegewezen en de gegevensrijen zijn geselecteerd. Het is niet aan de zoekcriteria zelf gerelateerd. Gebruik het getal 1 om het gehele gegevensbereik te specificeren. Plaats aanhalingstekens rondom de naam van de koprij om naar een kolom te verwijzen met behulp van de naam van de koprij.

Zoekcriteria is het celbereik dat de zoekcriteria bevat. Indien u meerdere criteria in één rij invoert worden zij verbonden met EN. Indien u de criteria in verschillende rijen invoert worden zij verbonden met OF. Lege cellen in het celbereik van de zoekcriteria worden genegeerd.

Kies LibreOffice - VoorkeurenExtra - Opties
- LibreOffice Calc - Berekenen om te bepalen wat LibreOffice Calc doet wanneer er naar identieke items wordt gezocht.

Bekijk ook de Wiki-pagina over Voorwaardelijk aantal en sommatie.

## DBAANTAL

DBAANTAL telt het aantal rijen (records) in een database die aan de opgegeven zoekcriteria voldoen en numerieke waarden in de kolom van het databaseveld bevatten.

Zoeken ondersteunt reguliere uitdrukkingen. U kunt bijvoorbeeld "all.*", invoeren om de eerste locatie van "all" te vinden, gevolgd door willekeurige tekens. Als u wilt zoeken naar een tekst die ook een reguliere uitdrukking is, moet u elk teken vooraf laten gaan door het teken \. U kunt de automatische evaluatie van reguliere uitdrukkingen in- en uitschakelen in LibreOffice - VoorkeurenExtra - Opties
- LibreOffice Calc - Berekenen.

### Syntaxis

DBAANTAL(Database; [Databaseveld]; Zoekcriteria)

Als het Databaseveld argument wordt overgeslagen, geeft DCOUNT het aantal terug van alle records die voldoen aan het criterium. Plaats aanhalingstekens rondom de naam van de koprij om naar een kolom te verwijzen met behulp van de naam van de koprij.

### Voorbeeld

In het bovenstaande voorbeeld (scroll naar boven) willen we weten hoeveel kinderen meer dan 600 meter naar school moeten afleggen. Het resultaat moet worden opgeslagen in cel B16. Zet de cursor in cel B16. Voer de formule =DBAANTAL(A1:E10;D1;A13:E14) in B16 in. De Functie-assistent helpt u om bereiken in te voeren.

Database is het bereik van de gegevens die moeten worden geëvalueerd, inclusief de rijkoppen: in dit geval A1:E10. Databaseveld specificeert de kolom voor de zoekcriteria: in dit geval de kolommen met de numerieke afstandswaarden. Zoekcriteria is het bereik waar u de parameters voor het zoeken in kunt voeren: in dit geval A13:E14.

Verwijder het item >600 in cel D14 en voer onder Groep in cel B14 in 2 en voer >7 in cel C14 rechts daarvan in om uit te vinden hoeveel kinderen in groep twee ouder zijn dan 7 jaar. Het resultaat is 2. Twee kinderen zitten in de tweede groep en zijn ouder dan 7 jaar. Omdat beide criteria in dezelfde rij staan worden zij verbonden met EN.

## DBAANTALC

DBAANTALC telt het aantal rijen (records) in een database die aan de opgegeven zoekcriteria voldoen en numerieke of alfanumerieke waarden bevatten.

Zoeken ondersteunt reguliere uitdrukkingen. U kunt bijvoorbeeld "all.*", invoeren om de eerste locatie van "all" te vinden, gevolgd door willekeurige tekens. Als u wilt zoeken naar een tekst die ook een reguliere uitdrukking is, moet u elk teken vooraf laten gaan door het teken \. U kunt de automatische evaluatie van reguliere uitdrukkingen in- en uitschakelen in LibreOffice - VoorkeurenExtra - Opties
- LibreOffice Calc - Berekenen.

### Syntaxis

DBAANTALC(Database; Databaseveld; Zoekcriteria)

Als het Databaseveld argument wordt overgeslagen, geeft DBAANTALC het aantal terug van alle records die voldoen aan het criterium. Plaats aanhalingstekens rondom de naam van de koprij om naar een kolom te verwijzen met behulp van de naam van de koprij.

### Voorbeeld

In het voorbeeld hierboven (scroll naar boven), kunt u zoeken naar het aantal kinderen waarvan de naam begint met de letter E of een daarop volgende letter. Bewerk de formule in B16 tot =DBAANTALC(A1:E10;"Naam";A13:E14). Verwijder de oude zoekcriteria en voer >=E in onder Naam in veld A14. Het resultaat is 5. Indien u nu alle getallen voor Greta in rij 8 verwijdert, wijzigt het resultaat naar 4. Rij 8 is niet langer opgenomen in de telling omdat het geen waarden meer bevat. De naam Greta is tekst, geen waarde. Merk op dat de parameter Databaseveld moet verwijzen naar een kolom die waarden kan bevatten.

## DBGEMIDDELDE

DBGEMIDDELDE geeft het gemiddelde van de waarden van alle cellen (velden) in alle rijen (databaserecords) die aan de opgegeven zoekcriteria voldoen.

Zoeken ondersteunt reguliere uitdrukkingen. U kunt bijvoorbeeld "all.*", invoeren om de eerste locatie van "all" te vinden, gevolgd door willekeurige tekens. Als u wilt zoeken naar een tekst die ook een reguliere uitdrukking is, moet u elk teken vooraf laten gaan door het teken \. U kunt de automatische evaluatie van reguliere uitdrukkingen in- en uitschakelen in LibreOffice - VoorkeurenExtra - Opties
- LibreOffice Calc - Berekenen.

### Syntaxis

DBGEMIDDELDE(Database; Databaseveld; Zoekcriteria)

Plaats aanhalingstekens rondom de naam van de koprij om naar een kolom te verwijzen met behulp van de naam van de koprij.

### Voorbeeld

Wilt u het gemiddelde gewicht weten van alle kinderen van dezelfde leeftijd in het bovenstaande voorbeeld (omhoog scrollen), dan voert u de volgende formule in B16 in:

=DBGEMIDDELDE (A1:E10;"Gewicht";A13:E14)

Voer in rij 14, onder Leeftijd, onder elkaar 7, 8, 9, enzovoort in. Het gemiddelde gewicht van alle kinderen van dezelfde leeftijd verschijnt.

## DBLEZEN

DBLEZEN geeft de inhoud van de cel waarnaar verwezen wordt in een database, die aan de opgegeven zoekcriteria voldoet. Mocht er een fout optreden, dan geeft de functie #VALUE! als er geen rij is gevonden of Err502 als er meerdere cellen zijn gevonden.

Zoeken ondersteunt reguliere uitdrukkingen. U kunt bijvoorbeeld "all.*", invoeren om de eerste locatie van "all" te vinden, gevolgd door willekeurige tekens. Als u wilt zoeken naar een tekst die ook een reguliere uitdrukking is, moet u elk teken vooraf laten gaan door het teken \. U kunt de automatische evaluatie van reguliere uitdrukkingen in- en uitschakelen in LibreOffice - VoorkeurenExtra - Opties
- LibreOffice Calc - Berekenen.

### Syntaxis

DBLEZEN(Database; Databaseveld; Zoekcriteria)

Plaats aanhalingstekens rondom de naam van de koprij om naar een kolom te verwijzen met behulp van de naam van de koprij.

### Voorbeeld

In het bovenstaande voorbeeld (scroll naar boven) willen we bepalen in welke groep het kind zit, waarvan de naam werd ingevoerd in cel A14. De formule is ingevoerd in cel B16 en verschilt licht van de eerdere voorbeelden omdat slechts één kolom (één databaseveld) kan worden ingevoerd voor Databaseveld. Voer de volgende formule in:

=DBLEZEN(A1:E10;"Groep";A13:E14)

Voer de naam Frank in A14 in en u ziet het resultaat 2. Frank zit in groep twee. Voer "Leeftijd" in plaats van "Groep" in en u zult de leeftijd van Frank krijgen.

Of voer alleen in cel C14 de waarde 11 en verwijder de andere items uit deze rij. Bewerk de formule in B16 als volgt:

=DBLEZEN(A1:E10;"Naam";A13:E14)

Er wordt naar de naam gezocht in plaats van naar de groep. Het antwoord verschijnt direct: Daniël is het enige kind dat 11 jaar oud is.

## DBMAX

DBMAX geeft de maximuminhoud van een cel (veld) in een database (alle records) die aan de opgegeven zoekcriteria voldoet.

Zoeken ondersteunt reguliere uitdrukkingen. U kunt bijvoorbeeld "all.*", invoeren om de eerste locatie van "all" te vinden, gevolgd door willekeurige tekens. Als u wilt zoeken naar een tekst die ook een reguliere uitdrukking is, moet u elk teken vooraf laten gaan door het teken \. U kunt de automatische evaluatie van reguliere uitdrukkingen in- en uitschakelen in LibreOffice - VoorkeurenExtra - Opties
- LibreOffice Calc - Berekenen.

### Syntaxis

DBMAX(Database; Databaseveld; Zoekcriteria)

Plaats aanhalingstekens rondom de naam van de koprij om naar een kolom te verwijzen met behulp van de naam van de koprij.

### Voorbeeld

Wilt u weten hoeveel het zwaarste kind in elke groep woog in het bovenstaande voorbeeld (omhoog scrollen), dan voert u de volgende formule in B16 in:

=DBMAX(A1:E10;"Gewicht";A13:E14)

Voer onder Groep onder elkaar 1, 2, 3, enzovoort in. Nadat u een groepnummer hebt ingevoerd, verschijnt het gewicht van het zwaarste kind in die groep.

## DBMIN

DBMIN geeft de minimuminhoud van een cel (veld) in een database, die aan de opgegeven zoekcriteria voldoet.

Zoeken ondersteunt reguliere uitdrukkingen. U kunt bijvoorbeeld "all.*", invoeren om de eerste locatie van "all" te vinden, gevolgd door willekeurige tekens. Als u wilt zoeken naar een tekst die ook een reguliere uitdrukking is, moet u elk teken vooraf laten gaan door het teken \. U kunt de automatische evaluatie van reguliere uitdrukkingen in- en uitschakelen in LibreOffice - VoorkeurenExtra - Opties
- LibreOffice Calc - Berekenen.

### Syntaxis

DBMIN(Database; Databaseveld; Zoekcriteria)

Plaats aanhalingstekens rondom de naam van de koprij om naar een kolom te verwijzen met behulp van de naam van de koprij.

### Voorbeeld

Wilt u weten wat de kortste afstand naar school is voor de kinderen in elke groep in het bovenstaande voorbeeld (omhoog scrollen), dan voert u de volgende formule in B16 in:

=DBMIN(A1:E10;"Afstand naar school";A13:E14)

Voer in rij 14, onder Leeftijd, onder elkaar in 1, 2, 3, enzovoort. De kortste afstand naar school voor elke groep verschijnt.

## DBPRODUCT

DBPRODUCT vermenigvuldigt alle cellen in een gegevensbereik, waarvan de inhoud aan de zoekcriteria voldoet.

Zoeken ondersteunt reguliere uitdrukkingen. U kunt bijvoorbeeld "all.*", invoeren om de eerste locatie van "all" te vinden, gevolgd door willekeurige tekens. Als u wilt zoeken naar een tekst die ook een reguliere uitdrukking is, moet u elk teken vooraf laten gaan door het teken \. U kunt de automatische evaluatie van reguliere uitdrukkingen in- en uitschakelen in LibreOffice - VoorkeurenExtra - Opties
- LibreOffice Calc - Berekenen.

### Syntaxis

DBPRODUCT(Database; Databaseveld; Zoekcriteria)

Plaats aanhalingstekens rondom de naam van de koprij om naar een kolom te verwijzen met behulp van de naam van de koprij.

### Voorbeeld

Deze functie kan in het bovenstaande voorbeeld van het verjaardagsfeestje (omhoog scrollen) niet zinvol toegepast worden.

## DBSOM

DBSOM geeft het totaal van alle cellen in een databaseveld in alle rijen (records) die aan de opgegeven zoekcriteria voldoen.

Zoeken ondersteunt reguliere uitdrukkingen. U kunt bijvoorbeeld "all.*", invoeren om de eerste locatie van "all" te vinden, gevolgd door willekeurige tekens. Als u wilt zoeken naar een tekst die ook een reguliere uitdrukking is, moet u elk teken vooraf laten gaan door het teken \. U kunt de automatische evaluatie van reguliere uitdrukkingen in- en uitschakelen in LibreOffice - VoorkeurenExtra - Opties
- LibreOffice Calc - Berekenen.

### Syntaxis

DBSOM(Database; Databaseveld; Zoekcriteria)

Plaats aanhalingstekens rondom de naam van de koprij om naar een kolom te verwijzen met behulp van de naam van de koprij.

### Voorbeeld

Wilt u de lengte weten van de gecombineerde afstand naar school van alle kinderen op Joe's verjaardagsfeestje (omhoog scrollen), die tot de tweede groep behoren, dan voert u de volgende formule in B16 in:

=DBSOM(A1:E10;"Afstand naar school";A13:E14)

Voer 2 in rij 14 in onder Groep. De som (1950) van de afstand naar school voor alle kinderen die in groep twee zitten wordt weergegeven.

## DBSTDEV

DBSTDEV berekent de standaardafwijking van een populatie gebaseerd op een steekproef, waarbij de getallen in een databasekolom gebruikt worden die overeenkomen met de opgegeven voorwaarden. De records worden als een steekproef van gegevens beschouwd. Dit betekent dat de kinderen in het voorbeeld voor een doorsnede van alle kinderen staan. Er kan geen representatief voorbeeld verkregen worden uit een steekproefpopulatie van minder dan duizend personen.

Zoeken ondersteunt reguliere uitdrukkingen. U kunt bijvoorbeeld "all.*", invoeren om de eerste locatie van "all" te vinden, gevolgd door willekeurige tekens. Als u wilt zoeken naar een tekst die ook een reguliere uitdrukking is, moet u elk teken vooraf laten gaan door het teken \. U kunt de automatische evaluatie van reguliere uitdrukkingen in- en uitschakelen in LibreOffice - VoorkeurenExtra - Opties
- LibreOffice Calc - Berekenen.

### Syntaxis

DBSTDEV(Database; Databaseveld; Zoekcriteria)

Plaats aanhalingstekens rondom de naam van de koprij om naar een kolom te verwijzen met behulp van de naam van de koprij.

### Voorbeeld

Wilt u de standaardafwijking weten van het gewicht voor alle kinderen van dezelfde leeftijd in het voorbeeld (omhoog scrollen), dan voert u de volgende formule in B16 in:

=DBSTDEV(A1:E10;"Gewicht";A13:E14)

Voer in rij 14, onder Leeftijd, onder elkaar 7, 8, 9, enzovoort in. Het resultaat dat wordt getoond is de standaardafwijking van het gewicht van alle kinderen van deze leeftijd.

## DBSTDEVP

DBSTDEVP berekent de standaardafwijking van een populatie gebaseerd op alle cellen van een gegevensbereik die aan de zoekcriteria voldoen. De records uit het voorbeeld worden als de hele populatie beschouwd.

Zoeken ondersteunt reguliere uitdrukkingen. U kunt bijvoorbeeld "all.*", invoeren om de eerste locatie van "all" te vinden, gevolgd door willekeurige tekens. Als u wilt zoeken naar een tekst die ook een reguliere uitdrukking is, moet u elk teken vooraf laten gaan door het teken \. U kunt de automatische evaluatie van reguliere uitdrukkingen in- en uitschakelen in LibreOffice - VoorkeurenExtra - Opties
- LibreOffice Calc - Berekenen.

### Syntaxis

DBSTDEVP(Database; Databaseveld; Zoekcriteria)

Plaats aanhalingstekens rondom de naam van de koprij om naar een kolom te verwijzen met behulp van de naam van de koprij.

### Voorbeeld

Teneinde de standaardafwijking in het gewicht voor alle kinderen van dezelfde leeftijd op Joe's verjaardagsfeestje te vinden (omhoog scrollen), voert u de volgende formule in B16 in:

=DBSTDEVP(A1:E10;"Gewicht";A13:E14)

Voer in rij 14, onder Leeftijd, onder elkaar 7, 8, 9, enzovoort in. Het resultaat is de standaardafwijking van het gewicht voor alle kinderen van dezelfde leeftijd waarvan het gewicht werd gecontroleerd.

## DBVAR

DBVAR geeft de variantie van alle cellen van een databaseveld in alle records die aan de opgegeven zoekcriteria voldoen. De records uit het voorbeeld worden als een steekproef van gegevens beschouwd. Er kan geen representatief voorbeeld verkregen worden uit een steekproefpopulatie van minder dan duizend mensen.

Zoeken ondersteunt reguliere uitdrukkingen. U kunt bijvoorbeeld "all.*", invoeren om de eerste locatie van "all" te vinden, gevolgd door willekeurige tekens. Als u wilt zoeken naar een tekst die ook een reguliere uitdrukking is, moet u elk teken vooraf laten gaan door het teken \. U kunt de automatische evaluatie van reguliere uitdrukkingen in- en uitschakelen in LibreOffice - VoorkeurenExtra - Opties
- LibreOffice Calc - Berekenen.

### Syntaxis

DBVAR(Database; Databaseveld; Zoekcriteria)

Plaats aanhalingstekens rondom de naam van de koprij om naar een kolom te verwijzen met behulp van de naam van de koprij.

### Voorbeeld

Wilt u de variantie van het gewicht weten van alle kinderen van dezelfde leeftijd in het bovenstaande voorbeeld (omhoog scrollen), dan voert u de volgende formule in B16 in:

=DBVAR(A1:E10;"Gewicht";A13:E14)

Voer in rij 14, onder Leeftijd, onder elkaar 7, 8, 9, enzovoort in. U zult als resultaat de variantie zien van de gewichtwaarden voor alle kinderen van deze leeftijd.

## DBVARP

DBVARP berekent de variantie van alle celwaarden in een databaseveld in alle records die aan de opgegeven zoekcriteria voldoen. De records uit het voorbeeld worden als een complete populatie beschouwd.

Zoeken ondersteunt reguliere uitdrukkingen. U kunt bijvoorbeeld "all.*", invoeren om de eerste locatie van "all" te vinden, gevolgd door willekeurige tekens. Als u wilt zoeken naar een tekst die ook een reguliere uitdrukking is, moet u elk teken vooraf laten gaan door het teken \. U kunt de automatische evaluatie van reguliere uitdrukkingen in- en uitschakelen in LibreOffice - VoorkeurenExtra - Opties
- LibreOffice Calc - Berekenen.

### Syntaxis

DBVARP(Database; Databaseveld; Zoekcriteria)

Plaats aanhalingstekens rondom de naam van de koprij om naar een kolom te verwijzen met behulp van de naam van de koprij.

### Voorbeeld

Teneinde de variantie van het gewicht voor alle kinderen van dezelfde leeftijd op Joe's verjaardagsfeestje te vinden (omhoog scrollen) voert u de volgende formule in B16 in:

=DBVARP(A1:E10;"Gewicht";A13:E14)

Voer in rij 14, onder Leeftijd, onder elkaar 7, 8, 9, enzovoort in. De variantie van de waarden van het gewicht voor alle kinderen van deze leeftijd, die op het verjaardagsfeestje van Joe waren, verschijnt.

Verwante onderwerpen

Functies per categorie