MavenPublication - Gradle DSL Version 5.1

# MavenPublication

API Documentation: | `MavenPublication`

A `MavenPublication` is the representation/configuration of how Gradle should publish something in Maven format. You directly add a named Maven Publication the project's `publishing.publications` container by providing `MavenPublication` as the type.

    publishing {
      publications {
        myPublicationName(MavenPublication) {
          // Configure the publication here
        }
      }
    }

The default Maven POM identifying attributes are mapped as follows:

- `groupId` - `project.group`
- `artifactId` - `project.name`
- `version` - `project.version`

For certain common use cases, it's often sufficient to specify the component to publish, and nothing more (`MavenPublication.from(org.gradle.api.component.SoftwareComponent)`. The published component is used to determine which artifacts to publish, and which dependencies should be listed in the generated POM file.

To add additional artifacts to the set published, use the `MavenPublication.artifact(java.lang.Object)` and `MavenPublication.artifact(java.lang.Object, org.gradle.api.Action)` methods. You can also completely replace the set of published artifacts using `MavenPublication.setArtifacts(java.lang.Iterable)`. Together, these methods give you full control over what artifacts will be published.

To customize the metadata published in the generated POM, set properties, e.g. `MavenPom.getDescription()`, on the POM returned via the `MavenPublication.getPom()` method or directly by an action (or closure) passed into `MavenPublication.pom(org.gradle.api.Action)`. As a last resort, it is possible to modify the generated POM using the `MavenPom.withXml(org.gradle.api.Action)` method.

### Example of publishing a Java module with a source artifact and a customized POM

    apply plugin: "java"
    apply plugin: "maven-publish"

    task sourceJar(type: Jar) {
      from sourceSets.main.allJava
      classifier "sources"
    }

    publishing {
      publications {
        myPublication(MavenPublication) {
          from components.java
          artifact sourceJar
          pom {
            name = "Demo"
            description = "A demonstration of Maven POM customization"
            url = "http://www.example.com/project"
            licenses {
              license {
                name = "The Apache License, Version 2.0"
                url = "http://www.apache.org/licenses/LICENSE-2.0.txt"
              }
            }
            developers {
              developer {
                id = "johnd"
                name = "John Doe"
                email = "john.doe@example.com"
              }
            }
            scm {
              connection = "scm:svn:http://subversion.example.com/svn/project/trunk/"
              developerConnection = "scm:svn:https://subversion.example.com/svn/project/trunk/"
              url = "http://subversion.example.com/svn/project/trunk/"
            }
          }
        }
      }
    }

### Properties

Property | Description
`artifactId` | The artifactId for this publication.
`artifacts` | The complete set of artifacts for this publication.
`groupId` | The groupId for this publication.
`pom` | The POM that will be published.
`version` | The version for this publication.

### Methods

Method | Description
`artifact(source)` | Creates a custom `MavenArtifact` to be included in the publication. The `artifact` method can take a variety of input:
`artifact(source, config)` | Creates an `MavenArtifact` to be included in the publication, which is configured by the associated action. The first parameter is used to create a custom artifact and add it to the publication, as per `MavenPublication.artifact(java.lang.Object)`. The created `MavenArtifact` is then configured using the supplied action, which can override the extension or classifier of the artifact. This method also accepts the configure action as a closure argument, by type coercion.
`from(component)` | Provides the software component that should be published.
`pom(configure)` | Configures the POM that will be published. The supplied action will be executed against the `MavenPublication.getPom()` result. This method also accepts a closure argument, by type coercion.
`setArtifacts(sources)` | Clears any previously added artifacts from `MavenPublication.getArtifacts()` and creates artifacts from the specified sources. Each supplied source is interpreted as per `MavenPublication.artifact(java.lang.Object)`. For example, to exclude the dependencies declared by a component and instead use a custom set of artifacts:

### Script blocks

No script blocks

### Property details

#### `String` `artifactId`

The artifactId for this publication.

#### `MavenArtifactSet` `artifacts`

The complete set of artifacts for this publication.

#### `String` `groupId`

The groupId for this publication.

#### `MavenPom` `pom` (read-only)

The POM that will be published.

#### `String` `version`

The version for this publication.

### Method details

#### `MavenArtifact` `artifact`(`Object` source)

Creates a custom `MavenArtifact` to be included in the publication. The `artifact` method can take a variety of input:

- A `PublishArtifact` instance. Extension and classifier values are taken from the wrapped instance.
- An `AbstractArchiveTask` instance. Extension and classifier values are taken from the wrapped instance.
- Anything that can be resolved to a `File` via the `Project.file(java.lang.Object)` method. Extension and classifier values are interpolated from the file name.
- A `Map` that contains a 'source' entry that can be resolved as any of the other input types, including file. This map can contain a 'classifier' and an 'extension' entry to further configure the constructed artifact.

The following example demonstrates the addition of various custom artifacts.

    apply plugin: "maven-publish"

    task sourceJar(type: Jar) {
      classifier "sources"
    }

    publishing {
      publications {
        maven(MavenPublication) {
          artifact sourceJar // Publish the output of the sourceJar task
          artifact 'my-file-name.jar' // Publish a file created outside of the build
          artifact source: sourceJar, classifier: 'src', extension: 'zip'
        }
      }
    }

#### `MavenArtifact` `artifact`(`Object` source, ``Action`<? super `MavenArtifact`>` config)

Creates an `MavenArtifact` to be included in the publication, which is configured by the associated action. The first parameter is used to create a custom artifact and add it to the publication, as per `MavenPublication.artifact(java.lang.Object)`. The created `MavenArtifact` is then configured using the supplied action, which can override the extension or classifier of the artifact. This method also accepts the configure action as a closure argument, by type coercion.

    apply plugin: "maven-publish"

    task sourceJar(type: Jar) {
      classifier "sources"
    }

    publishing {
      publications {
        maven(MavenPublication) {
          artifact(sourceJar) {
            // These values will be used instead of the values from the task. The task values will not be updated.
            classifier "src"
            extension "zip"
          }
          artifact("my-docs-file.htm") {
            classifier "documentation"
            extension "html"
          }
        }
      }
    }

#### `void` `from`(`SoftwareComponent` component)

Provides the software component that should be published.

- Any artifacts declared by the component will be included in the publication.
- The dependencies declared by the component will be included in the published meta-data.

Currently 2 types of component are supported: 'components.java' (added by the JavaPlugin) and 'components.web' (added by the WarPlugin). For any individual MavenPublication, only a single component can be provided in this way. The following example demonstrates how to publish the 'java' component to a Maven repository.

    apply plugin: "java"
    apply plugin: "maven-publish"

    publishing {
      publications {
        maven(MavenPublication) {
          from components.java
        }
      }
    }

#### `void` `pom`(``Action`<? super `MavenPom`>` configure)

Configures the POM that will be published. The supplied action will be executed against the `MavenPublication.getPom()` result. This method also accepts a closure argument, by type coercion.

#### `void` `setArtifacts`(``Iterable`<?>` sources)

Clears any previously added artifacts from `MavenPublication.getArtifacts()` and creates artifacts from the specified sources. Each supplied source is interpreted as per `MavenPublication.artifact(java.lang.Object)`. For example, to exclude the dependencies declared by a component and instead use a custom set of artifacts:

    apply plugin: "java"
    apply plugin: "maven-publish"

    task sourceJar(type: Jar) {
      classifier "sources"
    }

    publishing {
      publications {
        maven(MavenPublication) {
          from components.java
          artifacts = ["my-custom-jar.jar", sourceJar]
        }
      }
    }