SUM.FLERE.HVIS funktion

Modul
Indhold
Indholdsfortegnelse 🔎︎

# SUM.FLERE.HVIS-funktion

Returnerer summen af værdier i celler i et område, der opfylder flere kriterier i flere områder.

### Syntaks

SUM.FLERE.HVIS(Funktions_område; Område1; Kriterie1 [ ; Område2; Kriterie2 [;...]]))

Funktionsområde – påkrævet argument. Et område af celler, navnet på et navngivet område eller en etiket for en kolonne eller række, som indeholder værdier til beregning af summen.

Kriterie1 – krævet argument. Et strengudtryk, der repræsenterer en logisk betingelse eller en cellereference til et sådant strengudtryk. Udtrykket kan indeholde tekst, tal, regulære udtryk eller pladsholdere (, hvis de er aktiveret i beregningsindstillingerne).

Område2 – Valgfri. Område2 og alle de følgende betyder det samme som Område1.

Kriterie2 – Valgfri. Kriterie2 og alle efterfølgende kriterier betyder det samme som Kriterie1.

Funktionsområde og Område1, Område2... skal have samme størrelse, ellers returnerer funktionen err:502 - ugyldigt argument.

Den logiske relation mellem kriterier kan defineres som logisk OG (Konjunktion). Med andre ord, hvis og kun hvis alle givne kriterier opfyldes, vil en værdi fra den korresponderende celle af det givne Funktions_område blive taget med i udregningen.

Funktionen kan have op til 255 argumenter, hviket betyder at du kan give 127 kriterieområder og kriterier for dem.

Hvis en celle indeholder SAND, betragtes det som 1, og hvis en celle indeholder FALSK betragtes det som 0 (nul).

Denne funktion er en del af Open Document Format for Office Applications (OpenDocument) standard Version 1.2. (ISO/IEC 26300:2-2015)

### Eksempler

#### Betragt den følgende tabel

| A | B | C
1 | Produktnavn | Salg | Indtægt
2 | blyant | 20 | 65
3 | kuglepen | 35 | 85
4 | notesblok | 20 | 190
5 | bog | 17 | 180
6 | penalhus | ikke | ikke

I alle eksempler herunder, indeholder området for beregning af summen række #6, men den ignoreres, fordi den indeholder tekst.

#### Simpelt brug

=SUM.FLERE.HVIS(B2:B6;B2:B6;">=20")

Beregner summen af værdier i området B2:B6 der er større end eller lig med 20. Returner 75, fordi den femte række ikke opfylder kriteriet.

=SUM.FLERE.HVIS(C2:C6;B2:B6;">=20";C2:C6;">70")

Beregner summen af værdier i området C2:C6, som er større end 70 og korresponderer med celler i området B2:B6 der er større end eller lig med 20. Returnerer 275, fordi den anden og femte række ikke opfylder mindst ét kriterium.

#### Bruger regulære udtryk og indlejrede funktioner

=SUM.FLERE.HVIS(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAKS(B2:B6))

Beregner summen af værdier i området C2:C6, som korresponderer med alle værdier i området B2:B6, undtaget områdets minimums- og maksimumsværdier. Returnerer 255, fordi tredje og femte række ikke opfylder mindst et af kriterierne.

=SUM.FLERE.HVIS(C2:C6;A2:A6;"pen.*";B2:B6;"<"&MAKS(B2:B6))

Beregner summen af værdier i området C2:C6 der korresponderer med alle celler i området A2:A6 som begynder med "pen" og til alle celler i området B2:B6 med undtagelse af dettes maksimum. Returnerer 65, fordi kun anden række opfylder alle kriterier.

#### Reference til en celle som kriterium

Hvis du har brug for nemt at kunne ændre et kriterium, kan du med fordel angive dette i en celle og benytte en reference til denne celle i betingelsen for SUM.FLERE.HVIS funktionen. For eksempel, ovenstående funktion kan omskrives til følgende:

=SUM.FLERE.HVIS(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MAKS(B2:B6))

Hvis E2 = pen, returnerer funktionen 65, fordi kæden til cellen erstattes af dennes indhold.

Relaterede emner

SUM, SUM.HVIS

TÆL.FLERE.HVIS, MINHVISER, MAKSHVISER, MIDDEL.HVIS, SUM.FLERE.HVIS

Liste over regulære udtryk