Άρθρωμα
Περιεχόμενα
Δείκτης 🔎︎

## Συνάρτηση COUNTIFS

Επιστρέφει τον αριθμό των κελιών που ικανοποιούν τα κριτήρια σε πολλαπλές περιοχές.

### Σύνταξη

COUNTIFS(περιοχή1; κριτήριο1 [; περιοχή2; κριτήριο2 [; ...]])

Περιοχή1 – απαιτούμενο όρισμα. Είναι μια περιοχή κελιών, ένα όνομα μιας ονοματισμένης περιοχής, ή μια ετικέτα μιας στήλης ή μιας γραμμής που περιέχουν τιμές για τη μέτρηση και την εύρεση του αντίστοιχου κριτηρίου.

Κριτήριο1 – απαιτείται όρισμα. Μια παράσταση συμβολοσειράς που αναπαριστά λογική προϋπόθεση ή αναφορά κελιού σε τέτοια παράσταση συμβολοσειράς. Η παράσταση μπορεί να περιέχει κείμενο, αριθμούς, κανονικές εκφράσεις ή σύμβολα υποκατάστασης (εάν είναι ενεργό στις επιλογές υπολογισμού).

Περιοχή2 – Προαιρετικά. Η Περιοχή2 και όλα τα ακόλουθα σημαίνουν το ίδιο με την Περιοχή1.

Κριτήριο2 – Προαιρετικό. Το Κριτήριο2 και όλα τα επόμενα σημαίνουν τα ίδια όπως το Κριτήριο1.

Περιοχή1, Περιοχή2, ... και Κριτήριο1, Κριτήριο2, ... πρέπει να έχουν το ίδιο μέγεθος, αλλιώς η συνάρτηση επιστρέφει err:502 - Άκυρο όρισμα.

Η λογική σχέση μεταξύ κριτηρίων μπορεί να οριστεί ως λογικό AND (συνδυασμός). Με άλλα λόγια, εάν και μόνο εάν πληρούνται όλα τα κριτήρια, μια τιμή από το αντίστοιχο κελί της δεδομένης Περιοχής_συνάρτησης λαμβάνεται υπόψη στον υπολογισμό.

Η συνάρτηση μπορεί να έχει μέχρι 255 ορίσματα, που σημαίνει ότι μπορείτε να ορίσετε 127 περιοχές κριτηρίων και κριτήρια για αυτά.

Εάν το κελί περιέχει TRUE, θεωρείται ως 1, εάν ένα κελί περιέχει FALSE – ως 0 (μηδέν).

Αυτή η συνάρτηση είναι τμήμα του προτύπου της μορφής Open Document για εφαρμογές γραφείου (OpenDocument) έκδοσης 1.2. (ISO/IEC 26300:2-2015)

### Παραδείγματα

#### Θεωρήστε τον ακόλουθο πίνακα

| A | B | C
1 | Όνομα προϊόντος | Πωλήσεις | Έσοδα
2 | μολύβι | 20 | 65
3 | στυλό | 35 | 85
4 | σημειωματάριο | 20 | 190
5 | βιβλίο | 17 | 180
6 | κασετίνα | όχι | όχι

Σε όλα τα παρακάτω παραδείγματα, οι περιοχές για τον υπολογισμό περιέχουν τη γραμμή #6 που αγνοείται, επειδή περιέχει κείμενο.

#### Απλή χρήση

=COUNTIFS(B2:B6;">=20")

Μετρά τον αριθμό των γραμμών στην περιοχή B2:B6 με τιμές μεγαλύτερες από ή ίσες με 20. Επιστρέφει 3, επειδή η πέμπτη και η έκτη γραμμή δεν ικανοποιούν το κριτήριο.

=COUNTIFS(B2:B6;">=20";C2:C6;">70")

Μετρά τον αριθμό των γραμμών που περιέχουν ταυτόχρονα τιμές μεγαλύτερες από 70 στην περιοχή C2:C6 και τιμές μεγαλύτερες από ή ίσες με 20 στην περιοχή B2:B6. Επιστρέφει 2, επειδή η δεύτερη, η πέμπτη και η έκτη γραμμή δεν πληρούν τουλάχιστον ένα κριτήριο.

#### Χρήση κανονικών παραστάσεων και ένθετων συναρτήσεων

=COUNTIFS(B2:B6;"[:alpha:]*")

Μετρά τον αριθμό των γραμμών στην περιοχή B2:B6 που περιέχει μόνο αλφαβητικά σύμβολα. Επιστρέφει 1, επειδή μόνο η έκτη γραμμή πληρεί το κριτήριο.

=COUNTIFS(B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Μετρά τον αριθμό των γραμμών στην περιοχή B2:B6 αποκλείοντας τις γραμμές με ελάχιστες και μέγιστες τιμές αυτής της περιοχής. Επιστρέφει 2, επειδή η τρίτη, η πέμπτη και η έκτη γραμμή δεν πληρούν τουλάχιστον ένα κριτήριο.

=COUNTIFS(A2:A6;"pen.*";B2:B6;"<"&MAX(B2:B6))

Υπολογίζει τον αριθμό των γραμμών που αντιστοιχούν σε όλα τα κελιά της περιοχής A2:A6 που ξεκινούν με "pen" και όλα τα κελιά της περιοχής B2:B6 με εξαίρεση του μεγίστου του. Επιστρέφει 1, επειδή μόνο η δεύτερη γραμμή καλύπτει όλα τα κριτήρια.

#### Αναφορά σε ένα κελί ως ένα κριτήριο

Αν χρειάζεται να αλλάξετε ένα κριτήριο εύκολα, μπορεί να θέλετε να το ορίσετε σε ένα ξεχωριστό κελί και να χρησιμοποιήσετε μια αναφορά σε αυτό το κελί στη συνθήκη της συνάρτησης COUNTIFS. Παραδείγματος χάρη, η παραπάνω συνάρτηση μπορεί να ξαναγραφτεί ως εξής:

=COUNTIFS(A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

Αν E2 = pen, η συνάρτηση επιστρέφει 1, επειδή ο σύνδεσμος στο κελί αντικαθίσταται με το περιεχόμενό του και δουλεύει όπως η παραπάνω συνάρτηση.

Σχετικά θέματα

COUNT, COUNTIF, COUNTBLANK, COUNTA

COUNTIFS, MINIFS, MAXIFS, AVERAGEIFS, SUMIFS

Κατάλογος κανονικών εκφράσεων