Módulo
Contenido
Índice 🔎︎

# DIA.LAB.INTL

El resultado es un número que puede formatearse como fecha. Tras hacerlo, el usuario podrá ver la fecha correspondiente a un día situado a un número determinado de días laborables antes o después de la fecha inicial. Existen opciones para definir los días feriados y los correspondientes a los fines de semana. Se puede utilizar el parámetro (o cadena) opcional de fin de semana para definir los días de fin de semana (o los días no laborables de cada semana). Asimismo, de manera opcional, puede definirse una lista de feriados. Los días de fin de semana y los feriados definidos por el usuario no se cuentan como días laborables.

### Sintaxis

WORKDAY.INTL(StartDate; Days; Weekend; Holidays)

FechaInicial es la fecha a partir de la cual el cálculo se lleva a cabo. Si la fecha inicial es una día laborable, el día se incluye en el cálculo. Obligatorio.

Días es el número de días laborables. Un valor positivo equivale a un resultado posterior a la fecha inicial; un valor negativo indica un resultado anterior a la fecha inicial.

FinDeSemana es un parámetro opcional; es un número o una cadena que se emplea para especificar los días de la semana que se consideran fin de semana y no laborables. Los valores numéricos de FinDeSemana definen los días siguientes:

De 1 a 7 para fines de semana de dos días y 11 a 17 para fines de semana de un día.

Número | Fin de semana
1 u omitido | Sábado y domingo
2 | Domingo y lunes
3 | Lunes y martes
4 | Martes y miércoles
5 | Miércoles y jueves
6 | Jueves y viernes
7 | Viernes y sábado
11 | Domingo únicamente
12 | Lunes únicamente
13 | Martes únicamente
14 | Miércoles únicamente
15 | Jueves únicamente
16 | Viernes únicamente
17 | Sábado únicamente

La cadena FinDeSemana proporciona otra manera de definir los días no laborables semanales. Debe contener siete caracteres: ceros (0) por cada día laborable y unos (1) por cada día libre. Estos caracteres representan los días de la semana, comenzando por el lunes. Solo se permiten 0 y 1. «1111111» es una cadena no válida que no debe utilizarse. Para definir, a manera de ejemplo, el sábado y el domingo como días no laborables, puede emplearse «0000011».

Feriados es una lista opcional de fechas que deben contarse como días no laborables. La lista puede proporcionarse en forma de intervalo de celdas.

Cuando escriba fechas como parte de las fórmulas, las barras y los guiones que se usen como separadores de fechas se interpretarán como operadores aritméticos. Por este motivo, las fechas formateadas de este modo no se reconocen como tales y producen cálculos erróneos. Para evitar que las fechas se interpreten como parte de las fórmulas, utilice la fórmula FECHA —p. ej., FECHA(1954;7;20)—, o bien, entrecomíllela y ordene sus componentes según la notación ISO 8601 —p. ej., "1954-07-20"—. Evite utilizar formatos regionales de fechas, como «07/20/54», porque estos pueden conllevar a errores de cálculo si abre el documento en sistemas con una configuración regional distinta.

Unambiguous conversion is possible for ISO 8601 dates and times in their extended formats with separators. If a #VALUE! error occurs, then unselect Generate #VALUE! error in LibreOffice - PreferencesTools - Options
- LibreOffice Calc - Formula, button Details... in section "Detailed Calculation Settings", Conversion from text to number list box.

### Ejemplo

¿Cuál es la fecha correspondiente a 20 días después del 13 de diciembre de 2016? Escriba la fecha inicial en C3 y la cantidad de días laborables en D3.

El parámetro FinDeSemana (número) se puede dejar vacío o definirse como 1 para obtener el fin de semana predeterminado (días no laborables): sábado y domingo.

Las celdas F3 a J3 contienen cinco (5) feriados para Navidad y Año Nuevo en formato de fecha: 24 de diciembre de 2016, 25 de diciembre de 2016, 26 de diciembre de 2016, 31 de diciembre de 2016 y 1 de enero de 2017.

=WORKDAY.INTL(C3;D3;;F3:J3) returns January 11, 2017 in the result cell, say D6 (use date format for the cell).

Para definir el viernes y el sábado como días de fin de semana, otorgue al parámetro de fin de semana el valor 7.

=WORKDAY.INTL(C3;D3;7;F3:J3) returns January 15, 2017 with weekend parameter 7.

Para definir el domingo como día único de fin de semana, otorgue al parámetro de fin de semana el valor 11.

=WORKDAY.INTL(C3;D3;11;F3:J3) returns January 9, 2017.

Alternativamente, puede emplear la cadena «0000001» para definir el domingo como único día del fin de semana.

=WORKDAY.INTL(C3;D3;"0000001";F3:J3) returns January 9, 2017.

Es posible pasar por alto los dos parámetros opcionales —Fin de semana y Feriados— y utilizar la función sin ellos:

=WORKDAY.INTL(C3;D3) gives the result: January 10, 2017.

Temas relacionados

DIAS.LAB

DIAS.LAB.INTL

DIA.LAB

Funciones de fechas