টেক্সট ফাংশন

Module
Contents
Index 🔎︎

# Text Functions

This section contains descriptions of the Text functions.

এই নির্দেশাবলীতে সন্নিবেশ করতে...

সন্নিবেশ - ফাংশন - শ্রেণী পাঠ্য

## ARABIC

রোমান সংখ্যার মান গণনা করে। মানের পরিসর অবশ্যই ০ এবং ৩৯৯৯ এর মধ্যে হবে।

### সিনট্যাক্স

ARABIC("Text")

পাঠ্য হলো পাঠ্য যা একটি রোমান সংখ্যা নির্দেশ করে থাকে।

### উদাহরণ

=ARABIC("MXIV") ১০১৪ প্রদান করে

=ARABIC("MMII") ২০০২ প্রদান করে

## ASC

ASC ফাংশন পূর্ণ-প্রস্থের ASCII এবং কাটাকানা অক্ষরকে অর্ধ-প্রস্থে রূপান্তর করে। একটি টেক্সট স্ট্রিং প্রদান করে।

See https://wiki.documentfoundation.org/Calc/Features/JIS_and_ASC_functions for a conversion table.

### সিনট্যাক্স

ASC("Text")

পাঠ্য হলো একটি পাঠ্য যাতে রূপান্তর করা হবে এমন অক্ষর বিদ্যমান।

JIS ফাংশনটিও দেখুন।

## BAHTTEXT

একটি সংখ্যাকে থাই টেক্সটে রূপান্তর করে, থাই মুদ্রার নাম সহকারে।

### সিনট্যাক্স

BAHTTEXT(Number)

Number হলো যেকোনো সংখ্যা। "Baht" সংখ্যার অখন্ড অংশের শেষে যোগ করা হয়, এবং "Satang" সংখ্যার দশমিক অংশের শেষে যোগ করা হয়।

### উদাহরণ

=BAHTTEXT(12.65) থাই অক্ষরে একটি স্ট্রিং প্রদান করে, যার অর্থ "বারো বাত এবং পয়ষট্রি সাতাং।

## BASE

একটি ধনাত্মক পূর্ণ সংখ্যাকে সুনির্দিষ্ট বেসে সংখ্যায়ন সিস্টেম হতে টেক্সটে পরিবর্তন করে। ০-৯ ডিজিট এবং A-Z বর্ণ ব্যবহার করা হয়।

### সিনট্যাক্স

BASE(Number; Radix; [MinimumLength])

সংখ্যা হলো রূপান্তর করা হবে এমন একটি ধনাত্বক ইনটিজার।

রেডিক্স সংখ্যা সিস্টেমের ভিত্তি নির্দেশ করে থাকে। ২ এবং ৩৬ এর মধ্যে যেকোনো একটি ধনাত্মক ইনটিজার।

MinimumLength (ঐচ্ছিক) অক্ষরের ক্রমের সর্বনিম্ন দৈর্ঘ্য নির্ধারণ করে, যা তৈরি করা হয়েছে। যদি টেক্সটটি নির্দেশিত সর্মনিম্ন দৈর্ঘ্যের তুলনায় ছোট হয়, স্ট্রিংয়ের বামে শূন্য যোগ করা হয়।

### উদাহরণ

=BASE(17;10;4) বাইনারি ব্যবস্থায় ০০১৭ প্রদান করে।

=BASE(17;2) বাইনারি ব্যবস্থায় ১০০০১ প্রদান করে।

=BASE(255;16;4) হেক্সাডেসিমাল পদ্ধতিতে 00FF প্রদান করে থাকে।

## CHAR

বর্তমান কোড টেবিল অনুসারে একটি সংখ্যাকে অক্ষরে রূপান্তর করে। সংখ্যাটি দুই-ডিজিট বা তিন-ডিজিটের পূর্ণ সংখ্যা হতে পারে।

১২৭ অপেক্ষা বড় কোডসমূহ আপনার সিস্টেমের অক্ষর ম্যাপিংয়ের উপর নির্ভর করতে পারে (উদাহরণস্বরূপ, iso-8859-1, iso-8859-2, Windows-1252, Windows-1250), এবং এ কারণে সুবহনীয় নাও হতে পারে।

### সিনট্যাক্স

CHAR(Number)

সংখ্যা হলো অক্ষরের জন্য কোড মান নির্দেশ করার জন্য ১ থেকে ২৫৫ এর মধ্যে একটি সংখ্যা।

### উদাহরণ

=CHAR(100) d অক্ষরটি প্রদান করে।

="abc" & CHAR(10) & "def" স্ট্রিং এ একটি নতুনলাইন অক্ষর সন্নিবেশ করানো হয়।

## CLEAN

স্ট্রিং হতে সকল অমুদ্রণীয় অক্ষর অপসারণ করা হয়।

### সিনট্যাক্স

CLEAN("Text")

পাঠ্য পাঠ্য নির্দেশ করে থাকে যা থেকে সকল অমুদ্রণযোগ্য অক্ষর অপসারণ করা হয়।

## CODE

একটি টেক্সট স্ট্রিংয়ে প্রথম অক্ষরের জন্য সংখ্যাসূচক কোড প্রদান করে।

### সিনট্যাক্স

CODE("Text")

পাঠ্য হলো একটি পাঠ্য যার জন্য প্রথম অক্ষরের কোড খুঁজে পাওয়া যাবে।

১২৭ অপেক্ষা বড় কোডসমূহ আপনার সিস্টেমের অক্ষর ম্যাপিংয়ের উপর নির্ভর করতে পারে (উদাহরণস্বরূপ, iso-8859-1, iso-8859-2, Windows-1252, Windows-1250), এবং এ কারণে সুবহনীয় নাও হতে পারে।

### উদাহরণ

=CODE("Hieronymus") ৭২ প্রদান করে, =CODE("hieroglyphic") ১০৪ প্রদান করে।

এখানে ব্যবহৃত কোড ASCII কে নির্দেশ করে না, কিন্তু বর্তমানে লোডকৃত কোড টেবিলকে নির্দেশ করে।

## CONCATENATE

বিভিন্ন টেক্সট স্ট্রিংকে একত্রিত করে একটি স্ট্রিংয়ে রূপান্তর করে।

### সিনট্যাক্স

CONCATENATE("Text1"; ...; "Text30")

Text 1; Text 2; ... সর্বোচ্চ ৩০টি টেক্সট অনুচ্ছেদকে উল্লেখ করে, যাদেরকে একটি স্ট্রিংয়ে রূপান্তর করা হবে।

### উদাহরণ

=CONCATENATE("Good ";"Morning ";"Mrs. ";"Doe") Good Morning Mrs. Doe প্রদান করে।

## DECIMAL

টেক্সটকে সংখ্যা ব্যবস্থাহতে প্রদেয় ভিত্তি সংখ্যা পদ্ধতির একটি ধনাতত্বক পূর্ণ সংখ্যাতে রূপান্তর করে। সংখ্যা পদ্ধতিটি অবশ্যই ২ হতে ৩৬ এর মধ্যে থাকতে হবে। ফাঁকা স্থান এবং ট্যাব অবজ্ঞা করা হয়। টেক্সট ক্ষেত্রটি অবস্থা-সংবেদনশীল নয়।

যদি রেডিক্স ১৬ হয়, একটি নেতৃত্বদানকারী x অথবা X অথবা 0x অথবা 0X, এবং একটি সংযুক্ত h অথবা H, হলো অবহেলিত। যদি রেডিক্স ২ হয়, একটি সংযুক্ত b অথবা B অবহেলিত হয়। অন্য অক্ষর য়া সংখ্যা ব্যবস্থাতে নয় তা ত্রুটি উৎপাদন করে।

### সিনট্যাক্স

DECIMAL("Text"; Radix)

Text হলো এমন টেক্সট, যা রূপান্তর করা হবে। একটি হেক্সাডেসিমেল সংখ্যা, যেমন A1 এবং A1 ঘরের রেফারেন্সের মধ্যে পার্থক্য তৈরি করে, আপনাকে অবশ্যই সংখ্যাটি একটি উদ্ধৃতি চিহ্নের মধ্যে স্থাপন করতে হবে, যেমন, "A1" বা "FACE"।

রেডিক্স সংখ্যা সিস্টেমের ভিত্তি নির্দেশ করে থাকে। ২ এবং ৩৬ এর মধ্যে যেকোনো একটি ধনাত্মক ইনটিজার।

### উদাহরণ

=DECIMAL("17";10) ১৭ প্রদান করে।

=DECIMAL("FACE";16) ৬৪২০৬ প্রদান করে।

=DECIMAL("0101";2) ৫ প্রদান করে।

## DOLLAR

একটি সখ্যাকে মুদ্রা বিন্যাসে একটি পরিমানে রূপান্তর করা হয়, একটি উল্লেখিত ডেসিমেল স্থানের দিকে পূর্ণ সংখ্যায় পরিবর্তন করে। মান ক্ষেত্রে মুদ্রাতে রূপান্তরযোগ্য সংখ্যা সন্নিবেশ করান। ঐচ্ছিকভাবে, ডেসিমেল স্থানের ডেসিমেল ক্ষেত্রে সংখ্যাটি প্বেশ করাতে পারেন। যদি কোন মান উল্লেখিত না হয়, মুদ্রা বিন্যাসে সকল সংখ্যা দুই ডেসিমেল স্থান দ্বারা প্রদর্শিত হবে।

আপনার সিস্টেমের সেটিংয়ে আপনি মুদ্রার বিন্যাস নির্ধারণ করেন।

### সিনট্যাক্স

DOLLAR(Value; Decimals)

Value হলো একটি সংখ্যা, সংখ্যা রয়েছে এমন একটি ঘরের রেফারেন্স, বা সংখ্যা প্রদান করে এমন একটি সূত্র।

দশমিক হলো দশমিক স্থানের ঐচ্ছিক সংখ্যা।

### উদাহরণ

=DOLLAR(255) $২৫৫.০০ প্রদান করে।

=DOLLAR(367.456;2) $৩৬৭.৪৬ প্রদান করে। বর্তমান লোক্যাল সেটিং এর সাথে সঙ্গতিপূর্ণ দশমিক বিভাজক ব্যবহার করুন।

## EXACT

দুইটি টেক্সট স্ট্রিং তুলনা করা হয় এবং যদি তারা একই রকম হয়, তবে TRUE প্রদান করে। এই ফাংশনটি অক্ষরের ছাঁদ-নির্ভরশীল নয়।

### সিনট্যাক্স

EXACT("Text1"; "Text2")

Text1 তুলনা করার জন্য প্রথম পাঠ্য নির্দেশ করে থাকে।

Text2 হলো তুলনা করার জন্য দ্বিতীয় পাঠ্য।

### উদাহরণ

=EXACT("microsystems";"Microsystems") FALSE প্রদান করে।

## FIND

Returns the position of a string of text within another string.You can also define where to begin the search. The search term can be a number or any string of characters. The search is case-sensitive.

### সিনট্যাক্স

FIND("FindText"; "Text"; Position)

FindText খুঁজে পাওয়া যাবে এমন পাঠ্য নির্দেশ করে থাকে।

পাঠ্য হলো পাঠ্য যেখানে অনুসন্ধান করা হয়।

অবস্থান (ঐচ্ছিক) হলো পাঠ্যের মধ্যে একটি স্থান যেখান থেকে অনুসন্ধান শুরু করা হয়।

### উদাহরণ

=FIND(76;998877665544) ৬ প্রদান করে।

## FIXED

সুনির্দিষ্ট সংখ্যক দশমিক স্থান এবং ঐচ্ছিক সহস্র বিভাজক সহ একটি সংখ্যা টেক্সট হিসাবে প্রদান করে।

### সিনট্যাক্স

FIXED(Number; Decimals; NoThousandsSeparators)

সংখ্যা ফরম্যাট করা হবে এমন সংখ্যা নির্দেশ করে থাকে।

দশমিক প্রদর্শন করা হবে এমন সংখ্যার দশমিক স্থান নির্দেশ করে থাকে।

NoThousandsSeparators (ঐচ্ছিক), সহস্র বিভাজক ব্যবহৃত হবে কিনা তা নির্ধারণ করে। যদি প্যারামিটারটি ০ ব্যতীত অন্য কোনো সংখ্যা হয়, সহস্র বিভাজক বাদ দেয়া হয়। যদি প্যারামিটারটি ০ এর সমান হয় বা অনুপস্থিত থাকে, আপনার বর্তমান লোক্যাল সেটিং এর সহস্র বিভাজক প্রদর্শিত হয়।

### উদাহরণ

=FIXED(1234567.89;3) টেক্সট স্ট্রিং হিসেবে ১,২৩৪,৫৬৭.৮৯০ প্রদান করে।

=FIXED(1234567.89;3;1) টেক্সট স্ট্রিং হিসেবে ১২৩৪৫৬৭.৮৯০ প্রদান করে।

## JIS

JIS ফাংশন অর্ধ-প্রস্থ হতে পূর্ণ-প্রস্থের ASCII এবং কাটাকানা অক্ষরে রূপান্তর করে। একটি টেক্সট স্ট্রিং প্রদান করে।4

See https://wiki.documentfoundation.org/Calc/Features/JIS_and_ASC_functions for a conversion table.

### সিনট্যাক্স

JIS("Text")

পাঠ্য হলো একটি পাঠ্য যাতে রূপান্তর করা হবে এমন অক্ষর বিদ্যমান।

ASC ফাংশনও দেখুন।

## LEFT

প্রথম অক্ষর বা টেক্সটের অক্ষর প্রদান করে।

### সিনট্যাক্স

LEFT("Text"; Number)

Text হলো একটি টেক্সট, যেখান থেকে প্রারম্ভিক আংশিক শব্দ নির্ধারণ করে।

Number (ঐচ্ছিক), প্রারম্ভিক টেক্সটের জন্য অক্ষরের সংখ্যা উল্লেখ করে। যদি এই প্যারামিটারটি নির্ধারিত না থাকে, একটি অক্ষর প্রদান করা হয়।

### উদাহরণ

=LEFT("output";3) “out” প্রদান করে।

## LEFTB

Returns the first characters of a DBCS text.

### সিনট্যাক্স

LEFTB("Text"; Number_bytes)

Text is the text where the initial partial words are to be determined.

Number_bytes (optional) specifies the number of characters you want LEFTB to extract, based on bytes. If this parameter is not defined, one character is returned.

### উদাহরণসমূহ

LEFTB("中国";1) returns " " (1 byte is only half a DBCS character and a space character is returned instead).

LEFTB("中国";2) returns "中" (2 bytes constitute one complete DBCS character).

LEFTB("中国";3) returns "中 " (3 bytes constitute one DBCS character and a half; the last character returned is therefore a space character).

LEFTB("中国";4) returns "中国" (4 bytes constitute two complete DBCS characters).

LEFTB("office";3) returns "off" (3 non-DBCS characters each consisting of 1 byte).

## LEN

স্পেস সহ স্ট্রিংয়ের দৈর্ঘ্য প্রদান করে।

### সিনট্যাক্স

LEN("Text")

পাঠ্য হলো পাঠ্য যার দৈর্ঘ্য নির্ধারণ করা হবে।

### উদাহরণ

=LEN("Good Afternoon") ১৪ প্রদান করে।

=LEN(12345.67) ৮ প্রদান করে।

## LENB

For double-byte character set (DBCS) languages, returns the number of bytes used to represent the characters in a text string.

### সিনট্যাক্স

LENB("Text")

পাঠ্য হলো পাঠ্য যার দৈর্ঘ্য নির্ধারণ করা হবে।

### উদাহরণসমূহ

LENB("中") returns 2 (1 DBCS character consisting of 2 bytes).

LENB("中国") returns 4 (2 DBCS characters each consisting of 2 bytes).

LENB("office") returns 6 (6 non-DBCS characters each consisting of 1 byte).

=LENB("Good Afternoon") returns 14.

=LENB(12345.67) returns 8.

## LOWER

একটি টেক্সট স্ট্রিংয়ের সকল বড় হাতের অক্ষরকে ছোট হাতের অক্ষরে রূপান্তর করে।

### সিনট্যাক্স

LOWER("Text")

পাঠ্য রূপান্তর করা হবে এমন পাঠ্য নির্দেশ করে থাকে।

### উদাহরণ

=LOWER("Sun") sun প্রদান করে।

## MID

একটি টেক্সটের টেক্সট স্ট্রিং প্রদান করে। প্যারামিটারসমূহ শুরুর অবস্থান এবং অক্ষরের সংখ্যা উল্লেখ করে।

### সিনট্যাক্স

MID("Text"; Start; Number)

পাঠ্য হলো টেনে বের করে আনার জন্য একটি অক্ষর সম্বলিত পাঠ্য।

শুরু হলো টেনে বের করে আনার জন্য পাঠ্যের অফম অক্ষরের অবস্থান।

সংখ্যা পাঠ্যের একটি অংশের অক্ষরের সংখ্যা উল্লেখ করে থাকে।

### উদাহরণ

=MID("office";2;2) ff প্রদান করে।

## MIDB

Returns a text string of a DBCS text. The parameters specify the starting position and the number of characters.

### সিনট্যাক্স

MIDB("Text"; Start; Number_bytes)

পাঠ্য হলো টেনে বের করে আনার জন্য একটি অক্ষর সম্বলিত পাঠ্য।

Start is the position of the first character in the text to extract.

Number_bytes specifies the number of characters MIDB will return from text, in bytes.

### উদাহরণসমূহ

MIDB("中国";1;0) returns "" (0 bytes is always an empty string).

MIDB("中国";1;1) returns " " (1 byte is only half a DBCS character and therefore the result is a space character).

MIDB("中国";1;2) returns "中" (2 bytes constitute one complete DBCS character).

MIDB("中国";1;3) returns "中 " (3 bytes constitute one and a half DBCS character; the last byte results in a space character).

MIDB("中国";1;4) returns "中国" (4 bytes constitute two complete DBCS characters).

MIDB("中国";2;1) returns " " (byte position 2 is not at the beginning of a character in a DBCS string; 1 space character is returned).

MIDB("中国";2;2) returns " " (byte position 2 points to the last half of the first character in the DBCS string; the 2 bytes asked for therefore constitutes the last half of the first character and the first half of the second character in the string; 2 space characters are therefore returned).

MIDB("中国";2;3) returns " 国" (byte position 2 is not at the beginning of a character in a DBCS string; a space character is returned for byte position 2).

MIDB("中国";3;1) returns " " (byte position 3 is at the beginning of a character in a DBCS string, but 1 byte is only half a DBCS character and a space character is therefore returned instead).

MIDB("中国";3;2) returns "国" (byte position 3 is at the beginning of a character in a DBCS string, and 2 bytes constitute one DBCS character).

MIDB("office";2;3) returns "ffi" (byte position 2 is at the beginning of a character in a non-DBCS string, and 3 bytes of a non-DBCS string constitute 3 characters).

## PROPER

একটি টেক্সট স্ট্রিংয়ের সকল শব্দের প্রথম অক্ষর বড় হাতের অক্ষরে পরিবর্তন করে।

### সিনট্যাক্স

PROPER("Text")

পাঠ্য রূপান্তর করা হবে এমন পাঠ্য নির্দেশ করে থাকে।

### উদাহরণ

=PROPER("open office") ওপেন অফিস প্রদান করে।

## REPLACE

একটি ভিন্ন টেক্সট স্ট্রিং দ্বারা একটি টেক্সট স্ট্রিংয়ের অংশ প্রতিস্থাপন করে। এই ফাংশনটি অক্ষর এবং সংখ্যা উভয়ই প্রতিস্থাপন করতে ব্যবহৃত হতে পারে (যেগুলো স্বয়ংক্রিয়ভাবে টেক্সটে রূপান্তর করা হয়েছে)। ফাংশনের ফলাফল সবসময় টেক্সট হিসেবে প্রদর্শিত হয়। আপনি যদি সংখ্যা দ্বারা পরবর্তী গণনা সম্পাদনা করতে চান, যা টেক্সট দ্বারা প্রতিস্থাপন করা হয়েছে, আপনাকে VALUE ফাংশন ব্যবহার করে পুনরায় এটাকে সংখ্যায় রূপান্তর করতে হবে।

সংখ্যা যুক্ত যেকোনো টেক্সট অবশ্যই একটি উদ্ধৃতি চিহ্নের থাকবে, যদি আপনি এটাকে সংখ্যা হিসেবে প্রকাশ করতে না চান বা স্বয়ংক্রিয়ভাবে টেক্সটে রূপান্তর করতে না চান।

### সিনট্যাক্স

REPLACE("Text"; Position; Length; "NewText")

পাঠ্য পাঠ্য নির্দেশ করে যার একটি অংশ প্রতিস্থাপন করা হবে।

অবস্থান পাঠ্যের মধ্যে একটি অবস্থান নির্দেশ করে যেখানে পুনরায় স্থাপন করা শুরু হবে।

দৈর্ঘ্য হলো প্রতিস্থাপন করা হবে এমন পাঠ্য তে বিদ্যমান অক্ষরের সংখ্যা।

NewText পাঠ্য নির্দেশ করে থাকে যা পাঠ্য প্রতিস্থাপন করে থাকে।

### উদাহরণ

=REPLACE("1234567";1;1;"444") "444234567" প্রদান করে থাকে। অবস্থান ১ এর একটি অক্ষর সম্পূর্ণ NewText দ্বারা প্রতিস্থাপন করা হয়।

## REPT

একটি অক্ষরের স্ট্রিং প্রদত্ত অনুলিপি সংখ্যা অনুসারে পুনরাবৃত্ত হয়।

### সিনট্যাক্স

REPT("Text"; Number)

পাঠ্য হলো পুনরাবৃত্তি করা হবে এমন পাঠ্য।

সংখ্যা হলো পুনরাবৃত্তির জন্য সংখ্যা।

ফলাফল সর্বোচ্চ ২৫৫ অক্ষরের হতে পারে।

### উদাহরণ

=REPT("Good morning";2) Good morningGood morning প্রদান করে থাকে।

## RIGHT

টেক্সটের সর্বশেষ অক্ষর বা অক্ষরসমূহ প্রদান করে।

### সিনট্যাক্স

RIGHT("Text"; Number)

পাঠ্য হলো পাঠ্য যার সঠিক অংশটি নির্ধারণ করা হবে।

সংখ্যা (ঐচ্ছিক) হলো পাঠ্যের ডান পাশের অক্ষর সংখ্যা।

### উদাহরণ

=RIGHT("Sun";2) un প্রদান করে।

## RIGHTB

Returns the last character or characters of a text with double bytes characters sets (DBCS).

### সিনট্যাক্স

RIGHTB("Text"; Number_bytes)

Text is the text of which the right part is to be determined.

Number_bytes (optional) specifies the number of characters you want RIGHTB to extract, based on bytes.

### উদাহরণসমূহ

RIGHTB("中国";1) returns " " (1 byte is only half a DBCS character and a space character is returned instead).

RIGHTB("中国";2) returns "国" (2 bytes constitute one complete DBCS character).

RIGHTB("中国";3) returns " 国" (3 bytes constitute one half DBCS character and one whole DBCS character; a space is returned for the first half).

RIGHTB("中国";4) returns "中国" (4 bytes constitute two complete DBCS characters).

RIGHTB("office";3) returns "ice" (3 non-DBCS characters each consisting of 1 byte).

## ROMAN

একটি সংখ্যাকে রোমান সংখ্যাতে রূপান্তর করে। মানের পরিসর অবশ্যই ০ এবং ৩৯৯৯ এর মধ্যবর্তী হবে, মোড ০ হতে ৪ এর মধ্যবর্তী পূর্ণসংখ্যা হতে পারে।

### সিনট্যাক্স

ROMAN(Number; Mode)

সংখ্যা হলো একটি সংখ্যা যা একটি রোমান সংখ্যাসূচকে রূপান্তর করা যাবে।

Mode (ঐচ্ছিক) সরলীকরণের মাত্রা নির্দেশ করে। মান যত বড় হয়, রোমান সংখ্যা তত সরলীকরণ করা যায়।

### উদাহরণ

=ROMAN(999) CMXCIX প্রদান করে

=ROMAN(999;0) CMXCIX প্রদান করে

=ROMAN (999;1) LMVLIV প্রদান করে

=ROMAN(999;2) XMIX প্রদান করে

=ROMAN(999;3) VMIV প্রদান করে

=ROMAN(999;4) IM প্রদান করে

## SEARCH

একটি অক্ষর স্ট্রিংয়ের মধ্যবর্তী টেক্সট অংশের অবস্থান প্রদান করে। আপনি বিকল্পভাবে অনুসন্ধানের শুরু নির্ধারণ করতে পারেন। অনুসন্ধান টেক্সটটি সংখ্যা বা অক্ষরের যেকোনো ক্রম হতে পারে। অনুসন্ধানটি অক্ষরের ছাঁদ-নির্ভরশীল নয়।

The search supports regular expressions. You can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must precede every character with a \ character. You can switch the automatic evaluation of regular expression on and off in LibreOffice - PreferencesTools - Options
- LibreOffice Calc - Calculate.

### সিনট্যাক্স

SEARCH("FindText"; "Text"; Position)

FindText হলো অনুসন্ধান করা হবে এমন একটি পাঠ্য।

পাঠ্য হলো একটি পাঠ্য যেখানে অনুসন্ধান করা হবে।

অবস্থান (ঐচ্ছিক) হলো পাঠ্যের মধ্যে বিদ্যমান একটি অবস্থান যেখান থেকে অনুসন্ধান শুরু হয়।

### উদাহরণ

=SEARCH(54;998877665544) ১০ প্রদান করে।

## SUBSTITUTE

একটি স্ট্রিংয়ের পুরনো টেক্সটকে নতুন টেক্সট দিয়ে প্রতিস্থাপন করে।

### সিনট্যাক্স

SUBSTITUTE("Text"; "SearchText"; "NewText"; Occurrence)

পাঠ্য হলো পাঠ্য যাতে পাঠ্যের অংশ বিনিময় করা যাবে।

SearchText হলো একটি পাঠ্য অংশ যা প্রতিস্থাপন করা যাবে (কিছু সময়)।

NewText হলো পাঠ্য অংশ প্রতিস্থাপন করার জন্য পাঠ্য।

Occurrence (ঐচ্ছিক) নির্দেশ করে যে অনুসন্ধান টেক্সট কতবার প্রতিস্থাপন করা হবে। যদি এই প্যারামিটারটি অনুপস্তিত থাকে, অনুসন্ধান টেক্সটটি যতবার পাওয়া যাবে ততবার প্রতিস্থাপন করা হবে।

### উদাহরণ

=SUBSTITUTE("123123123";"3";"abc") 12abc12abc12abc প্রদান করে

=SUBSTITUTE("123123123";"3";"abc";2) 12312abc123 প্রদান করে।

## T

এই ফাংশনটি উদ্দিষ্ট টেক্সট প্রদান করে, বা যদি লক্ষ্যবস্তুটি টেক্সট না হয়, ফাঁকা টেক্সট স্ট্রিং প্রদান করে।

### সিনট্যাক্স

T(Value)

যদি Value টেক্সট স্ট্রিং হয় বা একটি টেক্সট স্ট্রিংকে উল্লেখ করে ,T ঐ টেক্সট স্ট্রিংকে প্রদান করে; অন্যথায় এটা একটি ফাঁকা টেক্সট স্ট্রিং প্রদান করে।

### উদাহরণ

=T(12345) একটি ফাঁকা স্ট্রিং প্রদান করে।

=T("12345") ১২৩৪৫ স্ট্রিং প্রদান করে।

## TEXT

একটি প্রদত্ত ফরম্যাট অনুসারে একটি সংখ্যাকে টেক্সটে রূপান্তর করে।

### সিনট্যাক্স

TEXT(Number; Format)

সংখ্যা হলো রূপান্তর করা হবে এমন একটি সংখ্যাসূচক মান।

Format হলো একটি টেক্সট, যা ফরম্যাট নির্ধারণ করে। ঘরের বিন্যাসে নির্ধারিত ভাষা অনুসারে দশমিক এবং সহস্র বিভাজক ব্যবহার করুন।

### উদাহরণ

=TEXT(12.34567;"###.##") ১২.৩৫ লেখা প্রদান করে

=TEXT(12.34567;"000.00") ০১২.৩৫ লেখা প্রদান করে

## TRIM

স্ট্রিং থেকে ফাঁকা স্থান সরিয়ে ফেলে, শব্দের মধ্যে শুধুমাত্র এক অক্ষর সমান ফাঁকা স্থান রাখে।

### সিনট্যাক্স

TRIM("Text")

Text refers to text in which spaces are to be removed.

### উদাহরণ

=TRIM(" hello world ") returns hello world without leading and trailing spaces and with single space between words.

## UNICHAR

একটি কোড সংখ্যাকে উইনিকোড অক্ষর অথবা বর্ণে রূপান্তর করে থাকে।

### সিনট্যাক্স

UNICHAR(number)

### উদাহরণ

=UNICHAR(169) কপিরাইট অক্ষর © প্রদান করে।

See also the UNICODE() function.

## UNICODE

একটি পাঠ্য স্ট্রিং এ সংখ্যাসূচক কোডটিকে প্রথম উইনিকোড অক্ষর হিসেবে প্রদান করে থাকে।

### সিনট্যাক্স

UNICODE("Text")

### উদাহরণ

=UNICODE("©") কপিরাইট অক্ষরের জন্য 169 ইউনিকোড ক্রম প্রদান করে থাকে।

See also the UNICHAR() function.

## UPPER

text ক্ষেত্রে উল্লেখিত স্ট্রিংকে বড় হাতের অক্ষরে রূপান্তর করে।

### সিনট্যাক্স

UPPER("Text")

Text ছোট হাতের অক্ষরের স্ট্রিং উল্লেখ করে, যা আপনি বড় হাতের অক্ষরে রূপান্তর করতে চান।

### উদাহরণ

=UPPER("Good Morning") GOOD MORNING প্রদান করে।

## VALUE

একটি টেক্সট স্ট্রিংকে সংখ্যায় রূপান্তর করে।

### সিনট্যাক্স

VALUE("Text")

পাঠ্য হলো সংখ্যায় রূপান্তরিত হবে এমন পাঠ্য।

### উদাহরণ

=VALUE("4321") ৪৩২১ প্রদান করে।

সংশ্লিষ্ট প্রসঙ্গ

Functions by Category