Modul
Indhold
Indholdsfortegnelse 🔎︎

# Tekstfunktioner

Denne sektion indeholder beskrivelser af Tekst-funktionerne.

For at tilgå denne kommando...

Indsæt - Funktion - Kategori Tekst

## ARABERTAL

Beregner værdien af et romertal. Værdien skal være i intervallet mellem 0 og 3999.

### Syntaks

ARABERTAL(Tekst)

Tekst er teksten, som repræsenterer et romertal.

### Eksempel

=ARABERTAL("MXIV") returnerer 1014

=ARABERTAL("MMII") returnerer 2002

## ASC

ASC funktionen konverterer fuldbredde til halvbredde ASCII og katakana tegn. Returnerer en tekststreng.

Find en konverteringstabel på https://wiki.documentfoundation.org/Calc/Features/JIS_and_ASC_functions.

### Syntaks

ASC("Tekst")

Tekst er den tekst, som indeholder tegn, der skal konverteres.

Se også JIS funktionen.

## BAHTTEKST

Konverterer et tal til Thaitekst, inklusive Thaivalutanavne.

### Syntaks

BAHTTEKST(Tal)

Tal er vilkårligt tal. "Baht" bliver føjet til den hele del af tallet, og "Satang" bliver føjet til decimaldelen af tallet.

### Eksempel

=BAHTTEKST(12,65) returnerer en streng i Thaitegn med betydningen "Tolv Baht og femogtres Satang".

## BASIS (BASE på engelsk)

Konverterer et positivt heltal til et tal (som tekst) i et andet talsystem, defineret ved basistallet fra talsystemet. Cifrene 0-9 og bogstaverne A-Z bruges.

### Syntaks

BASIS(Tal; Grundtal; [Minimumslængde])

Tal er det positive heltal, der skal konverteres.

Grundtal indikerer talsystemets basis. Det kan være et vilkårligt positivt heltal mellem 2 og 36.

Minimumslængde (valgfri) bestemmer minimumslængden af tegnsekvensen, der er blevet oprettet. Hvis teksten er kortere end den indikerede minimumslængde, bliver nuller tilføjet til venstre for strengen.

### Eksempel

=BASIS(17; 10; 4) returnerer 0017 i det decimale talsystem (titalssystemet).

=BASIS(17; 2) returnerer 10001 i det binære talsystem.

=BASIS(255; 16; 4) returnerer 00FF i det heksadecimale talsystem.

## DECIMAL

Konverterer tekst med tegn fra et talsystem til et positivt heltal i den givne grundtal. Grundtal skal være i intervallet 2 til 36. Mellemrum og tabulatorer ignoreres. Feltet Tekst skelner ikke mellem store og små bogstaver.

Hvis det angivne grundtal er 16, ses der bort fra et indledende X, x, 0x eller 0X, og et h eller H i slutningen. Hvis grundtal er 2, ses der bort fra et tilføjet B eller b. Andre tegn, som ikke hører til talsystemet, genererer en fejl.

### Syntaks

DECIMAL("Tekst"; Grundtal)

Tekst er den tekst, der skal konverteres. For at skelne mellem et hexadecimalt tal, såsom A1, og referencen til celle A1, skal du placere tallet i anførselstegn, for eksempel "A1" eller "FACE".

Grundtal indikerer talsystemets basis. Det kan være et vilkårligt positivt heltal mellem 2 og 36.

### Eksempel

=DECIMAL("17"; 10) returnerer 17.

=DECIMAL("FACE"; 16) returnerer 64206.

=DECIMAL("0101"; 2) returnerer 5.

## EKSAKT (EXACT på engelsk)

Sammenligner to tekststrenge og returnerer SAND hvis de er identiske. Denne funktion skelner mellem store og små bogstaver.

### Syntaks

EKSAKT("Tekst1"; "Tekst2")

Tekst1 refererer til den første tekst, der skal sammenlignes.

Tekst2 refererer til den anden tekst, der skal sammenlignes.

### Eksempel

=EKSAKT("microsystems"; "Microsystems") returnerer FALSK.

## ERSTAT (REPLACE på engelsk)

Erstatter en del af en tekststreng med en anden tekststreng. Denne funktion kan bruges til at erstatte både tegn og tal (som automatisk bliver konverteret til tekst). Resultatet for funktionen er altid vist som tekst. Hvis du tilsigter at udføre videre beregninger med tal som er blevet erstattet af tekst, skal du konvertere den tilbage til et tal ved hjælp af VÆRDI funktionen.

Hvilken som helst tekst som indeholder tal skal være omgivet af anførselstegn hvis du ikke ønsker det skal fortolkes som et tal men automatisk betragtes som tekst.

### Syntaks

ERSTAT("Tekst"; Placering; Længde; "NyTekst")

Tekst henviser til den tekst hvoraf en del skal erstattes.

Placering henviser til placeringen indeni teksten hvor erstatningen vil begynde.

Længde er antal tegn i Tekst som skal erstattes.

NyTekst refererer til teksten som erstatter Tekst.

### Eksempel

ERSTAT("1234567"; 1; 1; "444") returnerer "444234567". Et tegn på placeringen 1 er erstattet af den fuldstændige NyTekst

## FAST (FIXED på engelsk)

Returnerer et tal som tekst med et bestemt antal decimaler og med eller uden et tusindtalsskilletegn.

### Syntaks

FAST(Tal; Decimaler; IngenTusindtalsskilletegn)

Tal henviser til det tal, der skal formateres.

Decimaler angiver det antal decimaler der skal vises.

IngenTusindtalsskilletegn (valgfri) bestemmer om der skal bruges skilletegn for hvert tusindtal. Hvis parameteren er et tal forskellig fra 0, undertrykkes skilletegnene. Hvis parameteren er lig med 0 eller ikke er angivet, vil tusindtalsskilletegn blive benyttet som angivet i aktuelle lokalitetsindstilling blive vist.

### Eksempel

=FAST(1234567,89;3) returnerer 1.234.567,890 som et tekststreng.

=FAST(1234567,89;3;1) returnerer 1234567.890 som en tekststreng.

## FIND

Returnerer positionen på en tekststreng i en anden streng. Du kan også definere hvor søgningen skal begynde. Søgeordet kan være et tal eller en vilkårlig streng af tegn. Søgningen skelner mellem store og små bogstaver.

### Syntaks

FIND("FindTekst"; "Tekst"; Placering)

FindTekst refererer til teksten, der skal findes.

Tekst er teksten, hvori søgningen finder sted.

Placering (valgfri) er positionen i teksten hvorfra søgningen starter.

### Eksempel

=FIND(76; 998877665544) returnerer 6.

## GENTAG (REPT på engelsk)

Gentager en tekststreng i et givet antal kopier.

### Syntaks

GENTAG("Tekst"; Antal)

Tekst er den tekst, der skal gentages.

Antal er antallet af gentagelser.

Resultatet kan højst være 255 tegn.

### Eksempel

=GENTAG("God morgen";2) returnerer God morgenGod morgen.

## HØJRE (RIGHT på engelsk)

Returnerer tegnene længst til højre i en tekst.

### Syntaks

HØJRE("Tekst"; Antal)

Tekst er teksten hvor den højre del skal findes.

Antal (valgfri) er antal tegn fra den højre del af teksten.

### Eksempel

=HØJRE("Sun"; 2) returnerer un.

## HØJREB (RIGHTB på engelsk)

Returnerer det/de sidste tegn i en tekst med double bytes characters sets (DBCS).

### Syntaks

HØJREB("Tekst"; Antal_bytes)

Tekst er den tekst hvoraf den højre del skal bestemmes.

Antal_bytes (valgfri) angiver antallet af tegn, som du ønsker RIGHTB skal uddrage, angivet i bytes.

### Eksempler

HØJREB("中国";1) returnerer " " (1 byte er kun et halvt DBCS tegn og derfor returneres et blanktegn).

HØJREB("中国";2) returnerer "国" (2 bytes udgør et helt DBCS tegn).

HØJREB("中国";3) returnerer " 国" (3 bytes udgør ½ DBCS tegn og et helt DBCS tegn; et blanktegn returneres for det første halve tegn).

HØJREB("中国";4) returnerer "中国" (4 bytes udgør to fulde DBCS tegn).

HØJREB("office";3) returnerer "ice" (3 ikke-DBCS tegn hver bestående af 1 byte).

## JIS

JIS-funktionen konverterer halvbredde til fuldbredde ASCII- og katakanategn. Returnerer en tekststreng.

Find en konverteringstabel på https://wiki.documentfoundation.org/Calc/Features/JIS_and_ASC_functions.

### Syntaks

JIS("tekst")

Tekst er den tekst, som indeholder tegn, der skal konverteres.

Se også funktionen ASC.

## KODE (CODE på engelsk)

Returnerer en numerisk kode for det første tegn i en tekst.

### Syntaks

KODE("Tekst")

Tekst er teksten for hvilken koden for det første tegn skal findes.

Koder større end 127 kan afhænge af dit systems tegnsæt (for eksempel iso-8859-1, iso-8859-2, Windows-1252, Windows-1250) og som følge der af ikke være kompatibel.

### Eksempel

=KODE("Hieronymus") returnerer 72, =KODE("hieroglyfisk") returnerer 104.

Koden, der bruges her, refererer ikke til ASCII, men til den aktuelt indlæste kodetabel.

## KR (DOLLAR på engelsk)

Konverterer et tal til et beløb i valutaformatet, afrundet til et angivet antal decimaler. I Værdi-feltet indtastes det tal, der skal konverteres til valuta. Desuden kan du indtaste antal decimaler i feltet Decimaler. Hvis ingen værdi er specificeret, vises alle tal i valutaformat med to decimaler.

Valutaformatet indstiller du i dine systemindstillinger.

### Syntaks

KR(Værdi; Decimaler)

Værdi er et tal, en reference til en celle med et tal, eller en formel, som returnerer et tal.

Decimaler er antallet af decimaler.

### Eksempel

=KR(255) returnerer kr. 255,00.

KR(367,456;2) returnerer kr. 367,46. Brug det decimaltegn som svarer til den aktuelle lokalitetsindstilling.

## LÆNGDE (LEN på engelsk)

Returnerer længden af en streng inklusiv mellemrum.

### Syntaks

LÆNGDE("Tekst")

Tekst er teksten hvis længde skal findes.

### Eksempel

=LÆNGDE("God eftermiddag") returnerer 15.

=LÆNGDE(12345,67) returnerer 8.

## LÆNGDEB (LENB på engelsk)

For sprog med dobbeltbyte-tegnsæt (DBCS) returnerer denne funktion antallet af bytes, som benyttes til at repræsentere tegnene i en tekststreng.

### Syntaks

LÆNGDEB("Tekst")

Tekst er teksten hvis længde skal findes.

### Eksempler

LÆNGDEB("中") returnerer 2 (et DBCS tegn består af 2 bytes).

LÆNGDEB("中国") returnerer 4 (to DBCS tegn hver på 2 bytes).

LÆNGDEB("office") returnerer 6 (seks ikke-DBCS tegn hver på 1 byte).

=LÆNGDEB("God eftermiddag") returnerer 15.

=LÆNGDEB(12345,67) returnerer 8.

## MIDT

Returnerer en del af en tekststreng. Parametrene angiver startpositionen og antal tegn.

### Syntaks

MIDT("Tekst"; StartVed; Antal)

Tekst er den tekst som indeholder tegnene der skal findes.

StartVed er placeringen af det første tegn i kildeteksten der skal findes.

Antal angiver antal tegn der skal findes i teksten.

### Eksempel

=MIDT("office";2;2) returnerer ff.

## MIDTB (MIDB på engelsk)

Returnerer en tekststreng fra en DBCS-tekst (tekst med dobbeltbyte-tegnsæt). Parametrene angiver startpositionen og antallet af tegn.

### Syntaks

MIDB("Tekst"; StartVed; Antal_bytes)

Tekst er den tekst som indeholder tegnene der skal findes.

Start er positionen for det første tegn i den tekst du vil uddrage.

Antal_bytes angiver det antal tegn MIDB vil returnere fra tekst, i bytes.

### Eksempler

MIDTB("中国";1;0) returnerer "" (0 bytes er altid en tom streng).

MIDTB("中国";1;1) returnerer " " (1 byte er kun et halvt DBCS tegn og derfor er resultatet et blanktegn).

MIDTB("中国";1;2) returnerer "中" (2 bytes udgør et fuldt DBCS tegn).

MIDTB("中国";1;3) returnerer "中 " (3 bytes udgør 1½ DBCS tegn; den sidste byte resulterer i et blanktegn).

MIDTB("中国";1;4) returnerer "中国" (4 bytes udgør to fulde DBCS tegn).

MIDB("中国";2;1) returnerer " " (byte-placering to er ikke ved starten af tegnet i et DBCS tegn; et blanktegn returneres).

MIDTB("中国";2;2) returnerer " " (byte position 2 peger på den sidste halvdel af det første tegn i en DBCS streng; de 2 bytes, der udbedes, udgør derfor den sidste halvdel af det første tegn og den første halvdel af det andet tegn i strengen; derfor returneres 2 blanktegn).

MIDTB("中国";2;3) returnerer " 国" (byte position 2 er ikke i starten af et tegn i en DBCS streng; derfor returneres et blanktegn for byte position 2).

MIDTB("中国";3;1) returnerer " " (byte position 3 er i starten af et DBCS tegn, men 1 byte er kun et halvt DBCS tegn og derfor returneres et blanktegn).

MIDTB("中国";3;2) returnerer "国" (byte position 3 er i starten af et DBCS tegn, og 2 bytes udgør et DBCS tegn).

MIDTB("office";2;3) returnerer "ffi" (byte position 2 er i begyndelsen af et ikke-DBCS tegn, og bytes i en ikke-DBCS streng udgør 3 tegn).

## RENS (CLEAN på engelsk)

Alle kontroltegn fjernes fra strengen.

### Syntaks

RENS("Tekst")

Tekst refererer til teksten, hvorfra alle tegn der ikke kan udskrives fjernes.

## ROMERTAL

Konverterer et tal til et romertal. Værdiområdet skal være mellem 0 og 3999, tilstandene kan være heltal fra 0 til 4.

### Syntaks

ROMERTAL(Tal; Tilstand)

Tal er tallet som skal konverteres til et romertal.

Tilstand (valgfri) angiver graden af simplificering. Jo højere værdi, jo større er simplificeringen på romertallet.

### Eksempel

=ROMERTAL(999) returnerer CMXCIX

=ROMERTAL(999; 0) returnerer CMXCIX

=ROMERTAL (999; 1) returnerer LMVLIV

=ROMERTAL(999; 2) returnerer XMIX

=ROMERTAL(999; 3) returnerer VMIV

=ROMERTAL(999; 4) returnerer IM

## SAMMENKÆDNING (CONCATENATE på engelsk)

Kombinerer flere tekststrenge til i én streng.

### Syntaks

SAMMENKÆDNING(Tekst1; ...; Tekst30)

Tekst1; Tekst2; ... repræsenterer op til 30 tekstpassager, som skal kombineres til én streng.

### Eksempel

=SAMMENKÆDNING("Godmorgen "; "Fr. "; "Jensen") returnerer: Godmorgen Fr. Jensen.

## SMÅ.BOGSTAVER (LOWER på engelsk)

Konverterer alle store bogstaver i en tekststreng til små bogstaver.

### Syntaks

SMÅ.BOGSTAVER("Tekst")

Tekst refererer til den tekst, der skal konverteres.

### Eksempel

=SMÅ.BOGSTAVER("Sol") returnerer sol.

## STORE.BOGSTAVER (UPPER på engelsk)

Konverterer strengen angivet i feltet Tekst til store bogstaver.

### Syntaks

STORE.BOGSTAVER("Tekst")

Tekst henviser til den tekst med små bogstaver du vil konvertere til store bogstaver.

### Eksempel

=STORE.BOGSTAVER("God morgen") returnerer GOD MORGEN.

## STORT.FORBOGSTAV (PROPER på engelsk)

Konverterer første bogstav i alle ord til stort bogstav i en tekststreng.

### Syntaks

STORT.FORBOGSTAV("Tekst")

Tekst refererer til den tekst, der skal konverteres.

### Eksempel

=STORT.FORBOGSTAV("open office") returnerer Open Office.

## SØG (SEARCH på engelsk)

Returnerer placeringen af et tekstsegment indenfor en tekststreng. Du kan sætte starten på søgningen som en mulighed. Søgeteksten kan være et tal eller en sekvens af tegn. Søgningen gør ikke forskel på store og små bogstaver.

Søgningen understøtter regulære udtryk. Du kan indtaste "alle.*", for eksempel for at søge efter den første placering af "alle" fulgt af hvilke som helst tegn. Hvis du vil søge efter en tekst der også er et regulært udtryk, skal du foranstille alle tegn med tegnene '\'. Du kan skifte automatisk evaluering af regulære udtryk til og fra i LibreOffice - IndstillingerFunktioner - Indstillinger
- LibreOffice Calc - Beregn.

### Syntaks

SØG("FindTekst"; "Tekst"; Placering)

FindTekst er den tekst, der skal søges efter.

Tekst er teksten der skal søges i.

Placering (valgfri) er den placering i teksten hvor søgningen skal starte.

### Eksempel

=SØG(54; 998877665544) returnerer 10.

## T

Denne funktion returnerer målteksten eller en tom tekststreng, hvis målet ikke er en tekst.

### Syntaks

T(Værdi)

Hvis Værdi er en tekststreng eller refererer til en tekststreng, returnerer T denne tekststreng; ellers returnerer den en tom tekststreng.

### Eksempel

=T(12345) returnerer en tom streng "".

=T("12345") returnerer strengen 12345.

## TEGN (CHAR på engelsk)

Konverterer et tal til et tegn ifølge den aktuelle kodetabel. Tallet kan være et to- eller trecifret heltal.

Koder større end 127 kan afhænge af dit systems tegnsæt (for eksempel iso-8859-1, iso-8859-2, Windows-1252, Windows-1250) og som følge der af ikke være kompatibel.

### Syntaks

TEGN(Tal)

Tal er et heltal mellem 1 og 255, som repræsenterer tegnets talværdi.

### Eksempel

TEGN(100) returnerer tegnet d.

="abc" & TEGN(10) & "def" indsætter et linjeskiftskontroltegn ind i strengen.

## TEKST (TEXT på engelsk)

Konverterer et tal til tekst ifølge et givet formater.

### Syntaks

TEKST(Tal; Format)

Tal er den numeriske værdi som skal konverteres.

Format er teksten som angiver formatet. Brug decimal og tusindtalsskilletegn ifølge sprogindstillingen i cellens formater.

### Eksempel

=TEKST(12,34567;"###,##") returnerer teksten 12,35

=TEKST(12,34567;"000,00")returnerer teksten 012,35

## TRIM

Fjerner mellemrum fra en streng og efterlader kun et enkelt mellemrumstegn mellem ord.

### Syntaks

TRIM("Tekst")

Tekst henviser til teksten hvor mellemrum vil blive fjernet.

### Eksempel

=TRIM(" hej verden ") returnerer hej verden uden indledende og efterfølgende mellemrum, og med et enkelt mellemrum mellem ordene.

## UDSKIFT (SUBSTITUTE på engelsk)

Udskifter delord i en tekst.

### Syntaks

UDSKIFT("Tekst"; "SøgTekst"; "NyTekst"; Forekomst)

Tekst er teksten hvor tekstsegmentet skal udskiftes.

SøgTekst er tekstsegmentet som skal erstattes (et antal gange).

NyTekst er teksten som skal erstatte tekstsegmentet.

Forekomst (valgfri) angiver hvilken forekomst af søgeteksten, der skal erstattes. Hvis denne parameter mangler, erstattes alle forekomster.

### Eksempel

=UDSKIFT("123123123";"3";"abc") returnerer 12abc12abc12abc

=UDSKIFT("123123123";"3";"abc";2) returnerer 12312abc123

## UNICHAR

Konverterer et kodetal til et Unicode-tegn eller -bogstav.

### Syntaks

UNICHAR(nummer)

### Eksempel

=UNICHAR(169) returnerer copyrighttegnet ©.

Se også UNICODE() funktionen.

## UNICODE

Returnerer den numeriske kode for det første Unicodetegn i en tekststreng.

### Syntaks

UNICODE("Tekst")

### Eksempel

=UNICODE("©") returnerer unicodeværdien 169 for copyrighttegnet.

Se også UNICHAR() funktionen.

## VENSTRE (LEFT på engelsk)

Returnerer det eller de første tegn i en tekststreng.

### Syntaks

VENSTRE("Tekst"; Antal)

Tekst er teksten, hvor de første tegn skal findes.

Antal (valgfri) specificerer antal tegn i begyndelsen af teksten. Hvis denne parameter ikke er angivet, returneres ét tegn.

### Eksempel

=VENSTRE("resultat"; 3) returnerer "res".

## VENSTREB (LEFTB på engelsk)

Returnerer de første tegn af en DBCS-tekst.

### Syntaks

VENSTREB("Tekst"; Antal_bytes)

Tekst er teksten, hvorfra de første tegn skal findes.

Antal_bytes (valgfri) angiver det antal tegn, som du ønsker LEFTB skal udtage, baseret på bytes. Hvis denne parameter ikke er defineret, returneres et enkelt tegn.

### Eksempler

VENSTREB("中国";1) returnerer " " (1 bit er kun halvdelen af et DBCS-tegn og et blanktegn returneres i stedet).

VENSTREB("中国";2) returnerer "中" (2 bit danner et komplet DBCS-tegn).

VENSTREB("中国";3) returnerer "中 " (3 bit danner halvandet DBCS-tegn og det sidste tegn returnerer derfor et blanktegn).

VENSTREB("中国";4) returnerer "中国" (4 bit danne to komplette DBCS-tegn).

VENSTREB("office";3) returnerer "off" (3 ikke-DBCS-tegn som hver består af 1 bit).

## VÆRDI (VALUE på engelsk)

Konverterer en tekststreng til et tal.

### Syntaks

VÆRDI("Tekst")

Tekst er den tekst, der skal konverteres til et tal.

### Eksempel

=VÆRDI("4321") returnerer 4321.

Relaterede emner

Funktioner efter kategori