Module
Inhoud
Index 🔎︎

# Werkbladfuncties

In deze sectie staan beschrijvingen van de Werkblad-functies met voorbeelden.

Om toegang te krijgen tot deze functie..

Invoegen - Functie - Categorie Werkblad

## FOUT.TYPE

Geeft een getal dat een bepaald type fout aanduidt of de foutwaarde #N/A, als er geen fout is.

## ADDRESS

Geeft een celadres (verwijzing) als tekst volgens de gespecificeerde rij- en kolomnummers. U kunt bepalen of het adres geïnterpreteerd wordt als een absoluut adres (bijvoorbeeld $A$1), een relatief adres (zoals A1) of in een gemengde vorm (A$1 of $A1). U kunt ook de naam van het blad specificeren.

Voor interoperabiliteit ondersteunen de functies ADRES en INDIRECT een optionele parameter om te specificeren of de adresnotatie R1C1 in plaats van de gebruikelijke notatie A1 moet worden gebruikt.

In ADRES wordt de parameter ingevoegd als de vierde parameter, waarbij de optionele parameter voor de bladnaam wordt verschoven naar de vijfde positie.

In INDIRECT wordt de parameter toegevoegd als de tweede parameter.

In beide functies wordt, als de instructie wordt ingevoegd met de waarde 0, de notatie R1C1 gebruikt. Als de instructie niet wordt opgegeven of een andere waarde dan 0 heeft, dan wordt de notatie A1 gebruikt.

In de notatie R1C1 geeft ADRES adressen als tekenreeksen terug met behulp van het uitroepteken '!' als het scheidingsteken voor de bladnaam en INDIRECT verwacht het uitroepteken als scheidingsteken voor de bladnaam. Beide functies gebruiken nog steeds de punt '.' als scheidingsteken voor de bladnaam met de notatie A1.

Bij het openen van documenten in de indeling ODF 1.0/1.1 zullen de ADRES-functies die een bladnaam als vierde parameter weergeven die bladnaam opschuiven om de vijfde parameter te worden. Een nieuwe vierde parameter met de waarde 1 zal worden ingevoegd.

Als ADRES-functies een vierde parameter hebben, zal die parameter worden verwijderd bij het opslaan in de indeling ODF 1.0/1.1.

Sla een werkblad niet op in de oude indeling ODF 1.0/1.1 als de nieuwe vierde parameter van de functie ADRES werd gebruikt met een waarde van 0.

De functie INDIRECT wordt opgeslagen zonder conversie naar de indeling ODF 1.0/1.1. Indien de tweede parameter aanwezig was, zal een oudere versie van Calc een fout voor die functie teruggeven.

### Syntaxis

ADRES(Rij; Kolom; Abs; A1; "Blad")

Rij vertegenwoordigt het rijnummer voor de celverwijzingen

Kolom vertegenwoordigt het getal van de kolom voor de celverwijzing (het getal, niet de letter)

Abs bepaalt het type van de verwijzing:

1: absoluut ($A$1)

2: type rijverwijzing is absoluut; kolomverwijzing is relatief (A$1)

3: rij (relatief); kolom (absoluut) ($A1)

4: relatief (A1)

A1 (optioneel) - indien ingesteld op 0 wordt de notatie R1C1 gebruikt. Als de parameter niet wordt opgegeven of een andere waarde dan 0 heeft, dan wordt de notatie A1 gebruikt.

Blad vertegenwoordigt de naam van het werkblad. Het moet tussen dubbele aanhalingstekens geplaatst worden.

### Voorbeeld:

=ADRES(1;1;2;"Blad2") geeft het volgende terug: Blad2.A$1

Als bovenstaande formule in cel B2 staat en als de cel A1 in blad 2 de waarde -6 bevat, kunt u indirect verwijzen naar de cel, waarnaar verwezen wordt met een functie in B2, door in te voeren =ABS(INDIRECT(B2))t. Het resultaat is de absolute waarde van de celverwijzing die is gespecificeerd in B2, wat in dit geval 6 is.

## BEREIKEN

Geeft het aantal afzonderlijke bereiken dat tot een meervoudig bereik behoort. Een bereik kan uit aaneengesloten cellen of één cel bestaan.

De functie verwacht één enkel argument. Indien u meerdere bereiken opgeeft, moet u ze omsluiten door aanvullende haakjes. Meerdere bereiken kunnen worden ingevoerd met behulp van de puntkomma (;) als scheidingsteken, maar dit wordt automatisch geconverteerd naar de operator tilde (~). De tilde wordt gebruikt om bereiken samen te voegen.

### Syntaxis

BEREIKEN(Verwijzing)

'Verwijzing' staat voor de verwijzing naar een cel of celbereik.

### Voorbeeld

=BEREIKEN((A1:B3;F2;G1)) geeft 3 terug, omdat het een verwijzing is naar drie cellen en/of gebieden. Na de invoer wordt dit geconverteerd naar =BEREIKEN((A1:B3~F2~G1)).

=BEREIKEN(Alle) geeft 1 terug als u een gebied genaamd Alle heeft gedefinieerd onder Gegevens - Bereik definiëren.

## BLADEN

Bepaalt het aantal bladen in een verwijzing. Als u geen parameters invoert, is het resultaat het aantal bladen in het huidige document.

### Syntaxis

BLADEN(Verwijzing)

Verwijzing is de verwijzing naar een blad of een gebied. Deze parameter is optioneel.

### Voorbeeld

=BLADEN(Blad1.A1:Blad3.G12) geeft 3 terug als Blad1, Blad2 en Blad3 in de opgegeven reeks bestaan.

## DDE

Geeft het resultaat van een DDE-gebaseerde koppeling. Als de inhoud van gekoppelde bereiken of secties verandert, verandert de geretourneerde waarde ook. U moet het werkblad opnieuw laden of Bewerken - Koppelingen kiezen om de bijgewerkte koppelingen te zien. Platform-onafhankelijke koppelingen zijn niet toegestaan, zoals een koppeling tussen een LibreOffice-installatie die op een Windows-machine wordt uitgevoerd, en een document dat op een Linux-machine gemaakt is.

### Syntaxis

DDE("Server"; "Bestand"; "Bereik"; Modus)

Server is de naam van een server-toepassing. LibreOfficetoepassingen hebben de servernaam "soffice".

Bestand is de volledige bestandsnaam, inclusief specificatie van het pad.

Bereik is het gebied met de gegevens die geëvalueerd moeten worden.

Modus is een optionele parameter die bepaalt volgens welke methode de DDE-server zijn gegevens naar getallen converteert.

Modus | Effect
0 of ontbreekt | Getalnotatie van het celopmaakprofiel Standaard
1 | Gegevens worden altijd in de standaardindeling voor Amerikaans Engels geïnterpreteerd.
2 | Gegevens worden als tekst opgehaald; geen conversie naar getallen

### Voorbeeld

=DDE("soffice";"c:\office\document\data1.sxc";"blad1.A1") leest de inhoud van cel A1 in blad1 van het LibreOffice Calc-werkblad data1.sxc.

=DDE("soffice";"c:\office\document\motto.odt";"Motto van vandaag") geeft een motto terug in de cel die deze formule bevat. Eerst moet u een regel invoeren in het document motto.odt dat de tekst van het motto bevat en het definiëren als de eerste regel van een sectie genaamd Motto van vandaag (in LibreOffice Writer onder Invoegen - Sectie). Als het motto is aangepast (en opgeslagen) in het LibreOffice Writerdocument wordt het motto bijgewerkt in alle cellen van LibreOffice Calc waarin deze DDE-koppeling is gedefiniëerd.

## DRAAITABEL.OPHALEN

De functie DRAAITABEL.OPHALEN geeft een resultaatwaarde uit een draaitabel weer. De waarde wordt geadresseerd met behulp van veld- en itemnamen, zodat die geldig blijft als de opmaak van de draaitabel verandert.

### Syntaxis

Twee verschillende definities van syntaxis kunnen worden gebruikt:

OPHALEN.DRAAITABEL(Doelveld; Draaitabel; [ Veld 1; Item 1; ... ])

DRAAITABEL.OPHALEN(Draaitabel; Beperkingen)

De tweede syntaxis wordt aangenomen als exact twee parameters worden opgegeven, waarvan de eerste parameter een verwijzing naar een cel of celbereik is. In alle andere gevallen wordt van de eerste syntaxis uitgegaan. De Functie-Assistent toont de eerste syntaxis.

### Syntaxis

Doelveld is een tekenreeks die één van de gegevensvelden van de draaitabel selecteert. De tekenreeks kan de naam van de bronkolom of de naam van het gegevensveld zijn zoals weergegeven in de tabel (zoals "Som - Verkopen").

Draaitabel is een verwijzing naar een cel of celbereik dat is gepositioneerd binnen een draaitabel of een draaitabel bevat. Indien het celbereik meerdere draaitabellen bevat, wordt de tabel gebruikt die het laatst werd gemaakt.

Als er geen Veld n / Item n-paren worden opgegeven, wordt het totaal weergegeven. Anders voegt elk paar een beperking toe waaraan het resultaat moet voldoen. Veld n is de naam van een veld uit de draaitabel. Item n is de naam van een item uit dat veld.

Als de draaitabel slechts één resultaatwaarde bevat die voldoet aan alle beperkingen, of een subtotaalresultaat dat alle overeenkomende waarden samenvat, wordt dat resultaat teruggegeven. Als er geen overeenkomend resultaat, of verschillende resultaten zonder een subtotaal daarvoor is, wordt een fout teruggegeven. Deze voorwaarden zijn van toepassing op resultaten die zijn opgenomen in de draaitabel.

Als de brongegevens items bevatten die worden verborgen door de draaitabel worden zij genegeerd. De volgorde van de Veld-/Itemparen is niet belangrijk. Veld- en itemnamen zijn niet hoofdlettergevoelig.

Als geen beperking voor een paginaveld wordt opgegeven, wordt impliciet de in het veld geselecteerde waarde gebruikt. Indien een beperking voor een paginaveld wordt opgegeven, moet die overeenkomen met de geselecteerde waarde van het veld, anders wordt een fout weergegeven. Paginavelden zijn de velden linksboven in een draaitabel, gevuld met behulp van het gebied "Paginavelden" van het dialoogvenster Assistent draaitabel. Vanuit elk paginaveld kan een item (waarde) worden geselecteerd, hetgeen betekent dat alleen dat item wordt opgenomen in de berekening.

Subtotalen uit de draaitabel worden alleen gebruikt als zij de functie "auto" gebruiken (behalve indien gespecificeerd in de voorwaarde, zie Tweede syntaxis hieronder).

### Syntaxis

Draaitabel heeft dezelfde betekenis als in de eerste syntaxis.

Beperkingen is een spatie-gescheiden lijst. Items mogen tussen aanhalingstekens staan (enkele aanhalingstekens). De gehele tekenreeks moet tussen aanhalingstekens staan (dubbele aanhalingstekens), tenzij u naar de tekenreeks verwijst vanuit een andere cel.

Eén van de ingaves kan de naam van het gegevensveld zijn. De naam van het gegevensveld kan worden weggelaten als de draaitabel slechts één gegevensveld bevat, anders moet het aanwezig zijn.

Elk van de andere ingaves specificeert een beperking in de vorm Veld[Item] (met letterlijke tekens [ en ]), of alleen Item als de itemnaam uniek is binnen alle gebruikte velden in de draaitabel.

Een functienaam kan worden toegevoegd in de vorm Veld[Item;Functie], dat er voor zorgt dat de vergelijkingsbeperking alleen het subtotaal geeft van de waarden die die functie gebruiken. De mogelijke functienamen zijn Som, Aantal, Gemiddelde, Max, Min, Product, Aantal (alleen getallen), StDev (voorbeeld), StDevP (Populatie), Var (voorbeeld) en VarP (Populatie), hoofdletterongevoelig.

## HORIZ.ZOEKEN

Zoekt naar een waarde en verwijzing naar de cellen onder het geselecteerde gebied. Deze functie verifieert of de eerste rij van een matrix een bepaalde waarde bevat. De functie geeft dan de waarde in een rij van de matrix, genoemd in de Index, in dezelfde kolom.

Zoeken ondersteunt reguliere uitdrukkingen. U kunt bijvoorbeeld "all.*", invoeren om de eerste locatie van "all" te vinden, gevolgd door willekeurige tekens. Als u wilt zoeken naar een tekst die ook een reguliere uitdrukking is, moet u elk teken vooraf laten gaan door het teken "\". U kunt de automatische evaluatie van reguliere uitdrukkingen in- en uitschakelen in LibreOffice - VoorkeurenExtra - Opties
- LibreOffice Calc - Berekenen.

### Syntaxis

HORIZ.ZOEKEN (Zoekcriteria; Matrix; Index; Sorteervolgorde)

Zie ook:VERT.ZOEKEN (kolommen en rijen worden omgewisseld)

Afhandelen van lege cellen

## HYPERLINK

Wanneer u op een cel klikt die de HYPERLINK-functie bevat, wordt de hyperlink geopend.

Als u de optionele parameter Celtekst gebruikt, zoekt de formule de URL en wordt vervolgens de tekst weergegeven.

U opent een cel met een hyperlink als volgt via het toetsenbord: selecteer de cel, druk op F2 om de bewerkingsmodus te activeren, zet de cursor voor de hyperlink, druk op Shift+F10 en kies vervolgens Hyperlink openen.

### Syntaxis

HYPERLINK("URL") of HYPERLINK("URL"; "Celtekst")

URL specificeert de doelkoppeling. De optionele parameter Celtekst is de tekst die in de cel wordt weergegeven en het resultaat van de functie. Als de parameter Celtekst niet wordt gespecificeerd, wordt de URL weergegeven in de celtekst en zal worden teruggegeven als het resultaat.

Het getal 0 wordt teruggegeven voor lege cellen en matrixelementen.

### Voorbeeld

=HYPERLINK("http://www.example.org") geeft de tekst "http://www.example.org" weer in de cel en gaat naar de hyperlink http://www.example.org als er op geklikt wordt.

=HYPERLINK("http://www.example.org";"Klik hier") geeft de tekst "Klik hier" weer in de cel en gaat naar de hyperlink http://www.example.org als er op geklikt wordt.

=HYPERLINK("http://www.example.org";12345) geeft het getal 12345 weer in de cel en gaat naar de hyperlink http://www.example.org als er op geklikt wordt.

=HYPERLINK($B4) waar cel B4 http://www.example.org bevat. De functie voegt http://www.example.org toe aan de URL van de cel met de hyperlink en geeft dezelfde tekst terug als die welke is gebruikt als het formuleresultaat.

=HYPERLINK("http://www.";"Klik op ") & "example.org" geeft de tekst Klik op example.org weer in de cel en gaat naar de hyperlink http://www.example.org als er op geklikt wordt.

=HYPERLINK("#Blad1.A1";"Ga naar boven") toont de tekst Ga naar boven en springt naar de cel Blad1.A1 in dit document.

=HYPERLINK("file:///C:/writer.odt#Specificatie";"Ga naar Writer-bladwijzer") geeft de tekst 'Ga naar Writer-bladwijzer' terug, laadt het gespecificeerde tekstdocument en springt naar bladwijzer 'Specificatie'.

## INDEX

INDEX geeft een subbereik terug, gespecificeerd door rij- en kolomnummer of een optionele bereikindex. Afhankelijk van de context geeft INDEX een verwijzing of inhoud terug.

### Syntaxis

INDEX(Verwijzing; Rij; Kolom; Bereik)

Verwijzing is een verwijzing, direct ingevoerd of door een bereiknaam te specificeren Als de verwijzing bestaat uit meerdere bereiken, moet u de verwijzing of bereiknamen tussen haakjes plaatsen.

Rij (optioneel) vertegenwoordigt de index van de rij van het verwijzingsbereik waarvoor een waarde moet worden teruggegeven. Indien nul (geen specifieke rij) worden alle rijen waarnaar wordt verwezen teruggegeven.

Kolom (optioneel) vertegenwoordigt de kolomindex van het verwijzingsbereik waarvoor een waarde moet worden teruggegeven. Indien nul (geen specifieke kolom) worden alle kolommen waarnaar wordt verwezen teruggegeven.

Bereik (optioneel) vertegenwoordigt de index van het subbereik indien verwezen wordt naar een meervoudig bereik.

### Voorbeeld

=INDEX(Prijzen;4;1) geeft de waarde uit rij 4 en kolom 1 uit het databasebereik gedefiniëerd onder Gegevens - Definiëren als Prijzen.

=INDEX(SomX;4;1) geeft de waarde uit het bereik SomX in rij 4 en kolom 1 zoals gedefiniëerd in Blad - Namen - Definiëren.

=INDEX(A1:B6;1) geeft een verwijzing terug naar de eerste rij van A1:B6.

=INDEX(A1:B6;1) geeft een verwijzing terug naar de eerste rij van A1:B6.

=INDEX((multi);4;1) geeft de waarde aan die rij 4 en kolom 1 van het (meervoudige) bereik bevat, die u hebt genoemd onder Blad - Namen - Definiëren als multi. Het meervoudige bereik kan bestaan uit verschillende rechthoekige bereiken, elk met een rij 4 en kolom 1. Als u nu het tweede blok van dit meervoudige bereik wilt aanroepen voer dan het nummer 2 in als de reeksparameter.

=INDEX(A1:B6;1;1) geeft de waarde aan in de linkerbovenhoek van het bereik A1:B6.

=INDEX((meervoudig);0;0;2) geeft een verwijzing terug naar het tweede bereik van het meervoudige bereik.

## INDIRECT

Geeft de verwijzing gespecificeerd door een tekenreeks. Deze functie kan ook gebruikt worden om het gebied van een overeenkomstige tekenreeks te verkrijgen.

Voor interoperabiliteit ondersteunen de functies ADRES en INDIRECT een optionele parameter om te specificeren of de adresnotatie R1C1 in plaats van de gebruikelijke notatie A1 moet worden gebruikt.

In ADRES wordt de parameter ingevoegd als de vierde parameter, waarbij de optionele parameter voor de bladnaam wordt verschoven naar de vijfde positie.

In INDIRECT wordt de parameter toegevoegd als de tweede parameter.

In beide functies wordt, als de instructie wordt ingevoegd met de waarde 0, de notatie R1C1 gebruikt. Als de instructie niet wordt opgegeven of een andere waarde dan 0 heeft, dan wordt de notatie A1 gebruikt.

In de notatie R1C1 geeft ADRES adressen als tekenreeksen terug met behulp van het uitroepteken '!' als het scheidingsteken voor de bladnaam en INDIRECT verwacht het uitroepteken als scheidingsteken voor de bladnaam. Beide functies gebruiken nog steeds de punt '.' als scheidingsteken voor de bladnaam met de notatie A1.

Bij het openen van documenten in de indeling ODF 1.0/1.1 zullen de ADRES-functies die een bladnaam als vierde parameter weergeven die bladnaam opschuiven om de vijfde parameter te worden. Een nieuwe vierde parameter met de waarde 1 zal worden ingevoegd.

Als ADRES-functies een vierde parameter hebben, zal die parameter worden verwijderd bij het opslaan in de indeling ODF 1.0/1.1.

Sla een werkblad niet op in de oude indeling ODF 1.0/1.1 als de nieuwe vierde parameter van de functie ADRES werd gebruikt met een waarde van 0.

De functie INDIRECT wordt opgeslagen zonder conversie naar de indeling ODF 1.0/1.1. Indien de tweede parameter aanwezig was, zal een oudere versie van Calc een fout voor die functie teruggeven.

### Syntaxis

INDIRECT(Verw; A1)

Verw vertegenwoordigt een verwijzing naar een cel of een gebied (in tekstvorm) waarvoor de inhoud moet worden teruggegeven.

A1 (optioneel) - indien ingesteld op 0 wordt de notatie R1C1 gebruikt. Als de parameter niet wordt opgegeven of een andere waarde dan 0 heeft, dan wordt de notatie A1 gebruikt.

Als u een Excel-werkblad opent waarin indirecte adressen gebruikt worden die berekend zijn uit tekenreeksfuncties, worden de bladadressen niet automatisch vertaald. Zo wordt het Excel-adres in INDIRECT("[filename]sheetname!"&B1) niet naar het Calc-adres in INDIRECT("filename#sheetname."&B1) geconverteerd.

### Voorbeeld

=INDIRECT(A1) is gelijk aan 100 als A1 C108 als een verwijzing bevat en cel C108 de waarde 100 bevat.

=SOM(INDIRECT("a1:" & ADRES(1;3))) totaliseert de cellen in het gebied van A1 tot en met de cel met het adres dat gedefinieerd wordt door rij 1 en kolom 3. Dit betekent dat het gebied A1:C1 wordt getotaliseerd.

## KIEZEN

Gebruikt een index om een waarde uit een lijst met tot 30 waarden te geven.

### Syntaxis

KIEZEN(Index; Waarde1; ...; Waarde30)

Index is een verwijzing of getal tussen 1 en 30 waarmee aangegeven wordt welke waarde uit de lijst genomen moet worden.

Waarde1, Waarde2, ..., Waarde30 is de lijst met waarden die als een verwijzing naar een cel of als individuele waarden ingevoerd worden.

### Voorbeeld

=KIEZEN(A1;B1;B2;B3;"Vandaag";"Gisteren";"Morgen") geeft, bijvoorbeeld, de inhoud van cel B2 als A1 = 2; als A1 = 4 geeft de functie de tekst "Vandaag" terug.

## KOLOM

Geeft het kolomnummer van een celverwijzing. Als de verwijzing een cel is, wordt het kolomnummer van de cel geretourneerd; als de parameter een celgebied is, worden de overeenkomstige kolumnummers geretourneerd in een matrix van één rij, als de formule als een matrixformule is ingevoerd. Als de KOLOM-functie met een gebiedsverwijzingsparameter niet gebruikt wordt voor een matrixformule, wordt alleen het kolomnummer van de eerste cel in het gebied vastgesteld.

### Syntaxis

KOLOM(Verwijzing)

Verwijzing is de verwijzing naar een cel of celgebied waarvan het eerste kolomnummer gevonden moet worden.

Als er geen verwijzing is ingevoerd, wordt het kolomnummer gevonden van de cel waarin de formule is ingevoerd. LibreOffice Calc stelt automatisch de verwijzing naar de huidige cel in.

### Voorbeeld

=KOLOM(A1) is gelijk aan 1. Kolom A is de eerste kolom in de tabel.

=Kolom(C3:E3) is gelijk aan 3. Kolom C is de derde kolom in de tabel.

=KOLOM(D3:G10) geeft 4 terug omdat kolom D de vierde kolom is in de tabel en de functie KOLOM niet wordt gebruikt als een matrixformule. (In dit geval wordt de eerste waarde van de matrix altijd gebruikt als het resultaat.)

{=KOLOMMEN(B2:B7)} en =KOLOM(B2:B7) geven beide 2 terug omdat de verwijzing alleen kolom B bevat als de tweede kolom in de tabel. Omdat gebieden met één kolom slechts één kolomnummer hebben maakt het geen verschil of de formule wordt gebruikt als matrixformule of niet.

=KOLOM() geeft 3 terug als de formule werd ingevoerd in kolom C.

{=KOLOM(Konijn)} geeft de één-kolom matrix (3, 4) terug als "Konijn" het benoemde gebied is (C1:D3).

## KOLOMMEN

Geeft het aantal kolommen in de opgegeven verwijzing.

### Syntaxis

KOLOMMEN(Matrix)

Matrix is de verwijzing naar een celbereik waarvan het totale aantal kolommen moet worden gevonden. Het argument kan ook een enkele cel zijn.

### Voorbeeld

=KOLOMMEN(B5) geeft 1 terug omdat een cel slechts één kolom kan bevatten.

=KOLOMMEN(A1:C5) is gelijk aan 3. De verwijzing bestaat uit drie kolommen.

=KOLOMMEN(Konijn) geeft 2 terug als Konijn het benoemde gebied is (C1:D3).

## OPMAAKPROFIEL

Past een opmaakprofiel op de cel met de formule toe. Na een ingestelde periode kan een ander opmaakprofiel toegepast worden. Deze functie geeft altijd de waarde 0, waardoor u hem aan een andere functie kunt toevoegen zonder de waarde te wijzigen. U kunt tegelijk met de functie HUIDIG een kleur op een cel toepassen, afhankelijk van de waarde. Voorbeeld: =...+OPMAAKPROFIEL(ALS(HUIDIG()>3;"rood";"groen")) past de stijl voor rood op de cel toe als de waarde groter is dan 3, zo niet dan wordt de stijl voor groen toegepast. Beide celopmaakprofielen, 'rood' en 'groen', moeten vooraf gedefinieerd worden.

### Syntaxis

OPMAAKPROFIEL("Opmaakprofiel"; Tijd; "Opmaakprofiel2")

Opmaakprofiel is de naam van een celopmaakprofiel dat aan de cel is toegewezen. Namen van opmaakprofielen moeten tussen aanhalingstekens ingevoerd worden.

Tijd is een optioneel tijdbereik in seconden. Als deze parameter ontbreekt, wordt de stijl niet gewijzigd nadat er een bepaalde hoeveelheid tijd verstreken is.

Opmaakprofiel2 is de optionele naam van een celopmaakprofiel dat wordt toegewezen als een bepaalde tijdsperiode voorbij is. Als deze parameter ontbreekt wordt "Standaard" aangenomen.

In de functies van LibreOffice Calc kunnen "optionele" parameters alleen weggelaten worden wanneer er geen parameter volgt. In een functie met vier parameters waarvan de laatste twee als "optioneel" gemarkeerd zijn, kunt u bijvoorbeeld parameter 4 of parameter 3 en 4 weglaten, maar niet alleen parameter 3.

### Voorbeeld

=OPMAAKPROFIEL("Onzichtbaar";60;"Standaard") maakt de cel in transparante opmaak op voor 60 seconden nadat het document werd herberekend of geladen, daarna wordt de opmaak Standaard toegewezen. Beide celopmaakprofielen moeten vooraf zijn gedefiniëerd.

Omdat OPMAAKPROFIEL() een numerieke waarde van nul heeft, wordt deze teruggegeven waarde toegevoegd aan een tekenreeks. Dit kan worden voorkomen door T() te gebruiken zoals in het volgende voorbeeld:

="Tekst"&T(STYLE("mijnOpmaakprofiel"))

Zie ook HUIDIG() voor een ander voorbeeld.

## OPZOEKEN

Geeft de inhoud van een cel weer of uit een één-rij of één-kolom bereik. Optioneel wordt de toegewezen waarde (van dezelfde index) teruggegeven in een andere kolom en rij. Tegengesteld aan VERT.ZOEKEN en HORIZ.ZOEKEN mogen de zoek- en resultaatvector op verschillende posities liggen; zij hoeven niet aanliggend te zijn. Aansluitend daarop moet de zoekvector voor OPZOEKEN oplopend gesorteerd zijn, anders zal de zoekactie geen bruikbare resultaten teruggeven.

Als OPZOEKEN het zoekcriterium niet kan vinden, retourneert de functie de grootste waarde in de zoekvector die minder is dan of gelijk is aan het zoekcriterium.

Zoeken ondersteunt reguliere uitdrukkingen. U kunt bijvoorbeeld "all.*", invoeren om de eerste locatie van "all" te vinden, gevolgd door willekeurige tekens. Als u wilt zoeken naar een tekst die ook een reguliere uitdrukking is, moet u elk teken vooraf laten gaan door het teken "\". U kunt de automatische evaluatie van reguliere uitdrukkingen in- en uitschakelen in LibreOffice - VoorkeurenExtra - Opties
- LibreOffice Calc - Berekenen.

### Syntaxis

OPZOEKEN(Zoekcriterium; Zoekvector; Resultaatvector)

Zoekcriterium is de waarde waarnaar gezocht moet worden; direct ingevoerd of als een verwijzing.

Zoekvector is het gebied van één rij of één kolom dat moet worden doorzocht.

Resultaatvector is een ander één-rij of één-kolom bereik van waaruit het resultaat van de functie wordt genomen. Het resultaat is de cel van de resultaatvector met dezelfde index als het gevonden item in de zoekvector.

Afhandelen van lege cellen

### Voorbeeld

=OPZOEKEN(A1;D1:D100;F1:F100) zoekt naar de corresponderende cel in het bereik D1:D100 voor het getal dat u heeft ingevoerd in A1. Voor het gevonden item wordt de index bepaald, bijvoorbeeld de 12e cel in dit bereik. Dan wordt de inhoud van de 12e cel teruggeven als de waarde van de functie (in de resultaatvector).

## RIJEN

Geeft als resultaat het aantal rijen in een verwijzing of matrix.

### Syntaxis

RIJEN(Matrix)

Matrix is de verwijzing of het benoemde gebied waarvan het totale aantal rijen moet worden bepaald.

### Voorbeeld

=RIJEN(B5) geeft 1 terug omdat een cel slechts één rij bevat.

=RIJEN(A10:B12) geeft 3 terug.

=RIJEN(Konijn) geeft 3 terug als "Konijn" het benoemde gebied is (C1:D3).

## ROW

Geeft het rijnummer van een celverwijzing. Als de verwijzing een cel is, wordt het rijnummer van de cel gegeven. Als de verwijzing een celbereik is, worden de overeenkomstige rijnummers in een matrix met één kolom weergegeven, als de formule als een matrixformule wordt ingevoerd. Als de RIJ-functie met een bereikverwijzing niet in een matrixformule gebruikt wordt, wordt alleen het rijnummer van de eerste bereikcel gegeven.

### Syntaxis

RIJ(Verwijzing)

Verwijzing is een cel, een gebied of de naam van een gebied.

Als u geen verwijzing opgeeft, wordt het rijnummer van de cel waarin de formule is ingevoerd, gevonden. LibreOffice Calc stelt de verwijzing naar de huidige cel automatisch in.

### Voorbeeld

=RIJ(B3) geeft 3 terug omdat de verwijzing wijst naar de derde rij in de tabel.

{=RIJ(D5:D8)} geeft de éénkoloms-matrix (5, 6, 7, 8) terug omdat de gespecificeerde verwijzing de rijen 5 tot en met 8 bevat.

=RIJ(D5:D8) geeft 5 terug omdat de functie RIJ niet is gebruikt als matrixformule en alleen het nummer van de eerste rij van de verwijzing wordt teruggegeven.

{=RIJ(A1:E1)} en =RIJ(A1:E1) geven beide 1 terug omdat de verwijzing slechts 1 rij kan bevatten als de eerste kolom in de tabel. (Omdat gebieden met één rij slechts één rijnummer hebben maakt het geen verschil of de formule wordt gebruikt als matrixformule of niet.)

=RIJ() geeft 3 terug als de formule werd ingevoerd in rij 3.

{=RIJ(Konijn)} geeft de één-kolom matrix (3, 4) terug als "Konijn" het benoemde gebied is (C1:D3).

## SHEET

Geeft het bladnummer van een verwijzing of een tekenreeks die voor een bladnaam staat. Als u geen parameters invoert, is het resultaat het bladnummer van het werkblad met de formule.

### Syntaxis

BLAD(Verwijzing)

Verwijzing is optioneel en is de verwijzing naar een cel, een gebied, of de tekenreeks voor een bladnaam.

### Voorbeeld

=BLAD(Blad2.A1) geeft 2 terug als Blad2 het tweede werkblad is in het werkbladdocument.

## TYPEFOUT

Geeft het getal dat overeenkomt met een foutwaarde in een andere cel. Met behulp van dit getal kunt u de tekst van een foutmelding genereren.

Als er een fout optreedt, wordt met de functie een logische of numerieke waarde als resultaat gegeven.

De statusbalk geeft de vooraf gedefinieerde foutcode van LibreOffice weer, als u op de cel met de fout klikt.

### Syntaxis

TYPEFOUT(Verwijzing)

Verwijzing bevat het adres van de cel waarin de fout optreedt.

### Voorbeeld

De functie =TYPEFOUT(A1) geeft het getal 518 terug als cel A1 toont Fout:518.

## VERGELIJKEN

Geeft de relatieve positie in een matrix van een item dat met een gespecificeerde waarde overeenkomt. De functie geeft de positie van de gevonden waarde in de zoekmatrix als een getal.

### Syntaxis

VERGELIJKEN(Zoekcriterium; Zoekmatrix; Type)

Zoekcriterium is de waarde waarnaar moet worden gezocht in de één-rij of één-kolom matrix.

Zoekmatrix is de doorzochte verwijzing. Een zoekmatrix kan een enkele rij of kolom zijn, of deel van een enkele rij of kolom.

Type kan de waarden 1, 0 of -1 hebben. Als Type = 1 of als deze optionele parameter ontbreekt, wordt aangenomen dat de eerste kolom van de zoekmatrix oplopend is gesorteerd. Als Type = -1 wordt ervan uitgegaan dat de kolom aflopend gesorteerd is. Dit komt overeen met dezelfde functie in Microsoft Excel.

Als Type = 0 worden alleen exacte overeenkomsten gevonden. Als het zoekcriterium meer dan één keer wordt gevonden, geeft de functie de index van de eerste overeenkomende waarde. Alleen als Type = 0 kunt u zoeken met reguliere uitdrukkingen (als dit in de rekenopties is aangezet) of jokertekens (als dit in de rekenopties is aangezet).

De index van de laatste waarde die kleiner is dan of gelijk is aan het zoekcriterium wordt teruggegeven als Type = 1 of als de derde parameter ontbreekt. Dit is zelfs van toepassing als de zoekmatrix niet is gesorteerd. Als Type = -1 wordt de eerste waarde die groter is dan of gelijk is aan teruggegeven.

Zoeken ondersteunt reguliere uitdrukkingen. U kunt bijvoorbeeld "all.*", invoeren om de eerste locatie van "all" te vinden, gevolgd door willekeurige tekens. Als u wilt zoeken naar een tekst die ook een reguliere uitdrukking is, moet u elk teken vooraf laten gaan door het teken "\". U kunt de automatische evaluatie van reguliere uitdrukkingen in- en uitschakelen in LibreOffice - VoorkeurenExtra - Opties
- LibreOffice Calc - Berekenen.

### Voorbeeld

=VERGELIJKEN(200;D1:D100) doorzoekt het gebied D1:D100, dat is gesorteerd op kolom D, naar de waarde 200. Zodra deze waarde wordt bereikt, wordt het rijnummer waarin die werd gevonden teruggegeven. Indien een hogere waarde werd gevonden tijdens het doorzoeken van de kolom, wordt het nummer van de vorige rij teruggegeven.

## VERSCHUIVING

Geeft de waarde van een celverschuiving met een bepaald aantal rijen en kolommen vanaf een bepaald referentiepunt.

### Syntaxis

VERSCHUIVING(Verwijzing; Rijen; Kolommen; Hoogte; Breedte)

Verwijzing is de verwijzing van waaruit de functie zoekt naar de nieuwe verwijzing.

Rijen is het aantal rijen waarmee de verwijzing werd gecorrigeerd naar boven (negatieve waarde) of naar beneden.

Kolommen is het aantal kolommen waarmee de verwijzing werd gecorrigeerd naar links (negatieve waarde) of naar rechts. Gebruik 0 om in dezelfde kolom te blijven.

Hoogte (optioneel) is de verticale hoogte voor een gebied dat begint op de positie van de nieuwe verwijzing.

Breedte (optioneel) is de horizontale breedte voor een gebied dat begint op de positie van de nieuwe verwijzing.

Argumenten Rijen en Kolommen mogen niet leiden tot nul of een negatieve startrij of -kolom.

Argumenten Hoogte en Breedte mogen niet leiden tot nul of een negatief aantal rijen of kolommen

In de functies van LibreOffice Calc kunnen "optionele" parameters alleen weggelaten worden wanneer er geen parameter volgt. In een functie met vier parameters waarvan de laatste twee als "optioneel" gemarkeerd zijn, kunt u bijvoorbeeld parameter 4 of parameter 3 en 4 weglaten, maar niet alleen parameter 3.

### Voorbeeld

=VERSCHUIVING(A1;2;2) geeft de waarde in cel C3 terug (A1 twee rijen en twee kolommen naar beneden verplaatst). Als C3 de waarde 100 bevat geeft deze functie de waarde 100 terug.

=VERSCHUIVING(B2:C3;1;1) geeft een verwijzing naar B2:C3 terug, 1 rij naar beneden en één kolom naar rechts verplaatst (C3:D4).

=VERSCHUIVING(B2:C3;-1;-1) geeft een verwijzing naar B2:C3 terug, 1 rij naar boven en één kolom naar links verplaatst (A1:B2).

=VERSCHUIVING(B2:C3;0;0;3;4) geeft een verwijzing naar B2:C3 terug, herschaald naar 3 rijen en 4 kolommen (B2:E4).

=VERSCHUIVING(B2:C3;1;0;3;4) geeft een verwijzing naar B2:C3 terug, 1 rij naar beneden verplaatst en opnieuw geschaald naar 3 rijen en 4 kolommen (B2:E4).

=SOM(VERSCHUIVING(A1;2;2;5;6)) bepaalt het totaal van het gebied dat begint in cel C3 en een hoogte heeft van 5 rijen en een breedte van 6 kolommen (gebied=C3:H7).

De functie VERSCHUIVING geeft een bereik terug als de hoogte en breedte zijn inbegrepen en moeten dus als een matrixformule worden ingevoerd. Als zowel de hoogte als de breedte niet aanwezig zijn, wordt een celverwijzing teruggegeven.

## VERT.ZOEKEN

Verticaal zoeken met verwijzing naar de aanliggende cellen aan de rechterzijde. Deze functie controleert of een specifieke waarde is opgenomen in de eerste kolom van een matrix. De functie geeft dan de waarde terug in dezelfde rij van de kolom die wordt genoemd bij Index. Als de parameter Sorteren wordt weggelaten of ingesteld op WAAR of één, wordt aangenomen dat de gegevens zijn gesorteerd in oplopende volgorde. In dit geval zal, als het exacte Zoekcriterium niet wordt gevonden, de laatste waarde die kleiner is dan het criterium worden teruggegeven. Als Sorteren is ingesteld op ONWAAR of nul moet een exacte overeenkomst worden gevonden, anders zal de fout FOUT: Waarde niet beschikbaar het resultaat zijn. Dus met de waarde nul behoeven de gegevens niet te zijn gesorteerd in oplopende volgorde.

Zoeken ondersteunt reguliere uitdrukkingen. U kunt bijvoorbeeld "all.*", invoeren om de eerste locatie van "all" te vinden, gevolgd door willekeurige tekens. Als u wilt zoeken naar een tekst die ook een reguliere uitdrukking is, moet u elk teken vooraf laten gaan door het teken "\". U kunt de automatische evaluatie van reguliere uitdrukkingen in- en uitschakelen in LibreOffice - VoorkeurenExtra - Opties
- LibreOffice Calc - Berekenen.

### Syntaxis

=VERT.ZOEKEN (Zoekcriteria; Matrix; Index; Sorteervolgorde)

Zoekcriterium is de waarde waarnaar moet worden gezocht in de eerste kolom van de matrix.

Matrix is de verwijzing, die tenminste twee kolommen moet bevatten.

Index is het getal van de kolom in de matrix dat de waarde bevat die moet worden teruggegeven. De eerste kolom heeft het getal 1.

Sorteervolgorde is een optionele parameter die aangeeft of de eerste kolom in de matrix is gesorteerd in oplopende volgorde. Voer de Booleaanse waarde ONWAAR of nul in als de eerste kolom niet is gesorteerd in oplopende volgorde. Gesorteerde kolommen kunnen veel sneller worden doorzocht en de functie geeft altijd een waarde terug, zelfs als de zoekwaarde niet exact overeenkomt, indien die tussen de hoogste en laagste waarde van de gesorteerde lijst ligt. In ongesorteerde lijsten moet de zoekwaarde exact overeenkomen. In andere gevallen zal de functie dit bericht teruggeven: Fout: Waarde niet beschikbaar.

Afhandelen van lege cellen

### Voorbeeld

U wilt het nummer van een gerecht in het menu in cel A1 invoeren en de naam van het gerecht moet onmiddellijk als tekst verschijnen in de naastgelegen cel (B1). De toewijzing Nummer aan Naam is opgenomen in de matrix D1:E100. D1 bevat 100, E1 bevat de naam Groentensoep enzovoort, voor 100 menu-items. De getallen in kolom D zijn oplopend gesorteerd; dus, de optionele parameter Sorteren is niet nodig.

Voer de volgende formule in B1 in:

=VERT.ZOEKEN(A1;D1:E100;2)

Zodra u een getal in A1 invoert, verschijnt in B1 de overeenkomstige tekst die in de tweede kolom van verwijzing D1:E100 staat. Wanneer u een niet-bestaand getal invoert, wordt de tekst bij het volgende getal naar beneden weergegeven. U kunt dit voorkomen door ONWAAR in te voeren als laatste parameter in de formule, zodat er een foutmelding wordt gegenereerd wanneer er een niet-bestaand getal wordt ingevoerd.

Verwante onderwerpen

Functies per categorie