Module
Contenu
Index 🔎︎

# Fonctions logiques

Cette catégorie contient les fonctions logiques.

### Manipulation d'arguments non logiques dans les fonctions logiques

- Zéro (0) est équivalent à FAUX et tous les autres nombres sont équivalents à VRAI.

- Les cellules vides et le texte dans les cellules sont ignorés.

- Une erreur #VALEUR est déclenchée si tous les arguments sont ignorés.

- Une erreur #VALEUR est déclenchée si un argument est du texte direct (non du texte dans une cellule).

- Les erreurs en argument mènent à une erreur.

Pour accéder à cette commande...

Insertion - Fonction - Catégorie Logique

## ET

Renvoie VRAI si tous les arguments sont VRAI. Si l'un des éléments est FAUX, cette fonction renvoie la valeur FAUX.

Les arguments sont soit des expressions logiques (VRAI, 1<5, 2+3=7, B8<10) qui renvoient des valeurs logiques, soit des matrices (A1:C3) contenant des valeurs logiques.

### Syntaxe

ET(valeur_logique1;valeur_logique2;...;valeur_logique30)

valeur_logique1;valeur_logique2;...;valeur_logique30 sont des conditions qui doivent être vérifiées. Toutes les conditions peuvent aussi bien être VRAI ou FAUX. Si une plage est saisie comme paramètre, la fonction utilise toutes les valeurs de la plage. Le résultat est VRAI si la valeur logique de toutes les cellules à l'intérieur de la plage de cellules est VRAI.

### Exemple

La valeur logique des entrées 12<13, 14>12 et 7<6 doit être vérifiée :

=ET(12<13;14>12;7<6) renvoie FAUX.

=ET(FAUX;VRAI) renvoie FAUX.

## FAUX

Renvoie la valeur logique FAUX. La fonction FAUX() ne requiert aucun argument et renvoie toujours la valeur logique FAUX.

### Syntaxe

FAUX()

### Exemple

=FAUX() renvoie FAUX

=NON(FAUX()) renvoie VRAI

## NON

Complète (inverse) une valeur logique.

### Syntaxe

NON(valeur_logique)

ValeurLogique correspond à toute valeur devant être complétée.

### Exemple

=NON(A). Si A=VRAI alors NON(A) sera évalué FAUX.

## OU

Renvoie VRAI si au moins un argument est VRAI. Cette fonction renvoie la valeur FAUX si tous les arguments possèdent la valeur logique FAUX.

Les arguments sont soit des expressions logiques (VRAI, 1<5, 2+3=7, B8<10) qui renvoient des valeurs logiques, soit des matrices (A1:C3) contenant des valeurs logiques.

### Syntaxe

OU(valeur_logique1;valeur_logique2;...;valeur_logique30)

valeur_logique1;valeur_logique2;...;valeur_logique30 sont des conditions devant être vérifiées. Toutes les conditions peuvent être aussi bien VRAI que FAUX. Si une plage est saisie comme paramètre, cette fonction utilise toutes les valeurs de la plage.

### Exemple

La valeur logique des entrées 12<11; 13>22 et 45=45 doit être vérifiée.

=OU(12<11;13>22;45=45) renvoie VRAI.

=OU(FAUX;VRAI) renvoie VRAI.

## SI

Indique un test logique à effectuer.

### Syntaxe

SI(test;alors_valeur;sinon_valeur)

test représente toute valeur ou expression pouvant renvoyer VRAI ou FAUX.

alors_valeur (facultatif) est la valeur qui est renvoyée si le test logique est VRAI.

sinon_valeur (facultatif) est la valeur qui est renvoyée si le test logique est FAUX.

Dans les fonctions LibreOffice Calc, les paramètres marqués comme "facultatifs" peuvent être ignorés lorsqu'ils ne sont pas suivis d'autres paramètres. Par exemple, dans une fonction comportant quatre paramètres, où les deux derniers paramètres sont marqués comme "facultatifs", le paramètre 4 ou les paramètres 3 et 4 peuvent être ignorés, mais le paramètre 3 seul ne peut être ignoré.

### Exemple

=SI(A1>5;100;"trop petit") Si la valeur en A1 est supérieure à 5, la valeur 100 est inscrite dans la cellule active ; sinon, le texte "trop petit" (sans guillemets) est inscrit.

## VRAI

La valeur logique est définie sur VRAI. La fonction VRAI() ne requiert aucun argument et renvoie toujours la valeur logique VRAI.

### Syntaxe

VRAI()

### Exemple

Si A=VRAI et B=FAUX, les exemples suivants s'affichent :

=ET(A;B) renvoie FAUX

=OU(A;B) renvoie VRAI

=NON(ET(A;B)) renvoie VRAI

## XOR

Renvoie vrai si un nombre impair d'arguments est évalué à VRAI.

Les arguments sont soit des expressions logiques (VRAI, 1<5, 2+3=7, B8<10) qui renvoient des valeurs logiques, soit des matrices (A1:C3) contenant des valeurs logiques.

### Syntaxe

XOR(valeur_logique1;valeur_logique2;...;valeur_logique30)

### Exemple

=XOR(VRAI;VRAI) renvoie FAUX

=XOR(VRAI;VRAI;VRAI) renvoie VRAI

=XOR(FAUX;VRAI) renvoie VRAI

Rubriques connexes

Fonctions par catégories