Module
Inhalte
Index 🔎︎

# Textfunktionen

In diesem Abschnitt werden die Funktionen der Kategorie Text anhand von Beispielen beschrieben.

So greifen Sie auf diesen Befehl zu:

Einfügen - Funktion - Kategorie Text

## ARABISCH

Berechnet den Wert einer römischen Zahl. Der Wertebereich muss zwischen 0 und 3999 liegen.

### Syntax

ARABISCH("Text")

Text ist der Text, der eine römische Zahl darstellt.

### Beispiel

=ARABISCH("MXIV") ergibt 1014

=ARABISCH("MMII") ergibt 2002

## ASC

Die Funktion ASC wandelt ASCII- und Katakana-Zeichen normaler Breite in halbe Breite um und gibt eine Zeichenkette zurück.

Siehe https://wiki.documentfoundation.org/Calc/Features/JIS_and_ASC_functions für eine Umrechnungstabelle.

### Syntax

ASC("Text")

Text ist der Text, der Zeichen enthält, die umgewandelt werden sollen.

Siehe auch JIS-Funktion.

## BAHTTEXT

Wandelt eine Zahl in Thai-Text um, auch die Thai-Währungsnamen.

### Syntax

BAHTTEXT(Zahl)

Zahl ist eine beliebige Zahl. "Baht" wird an die Ganzzahl der Zahl angehängt und "Satang" wird an die Nachkommastelle der Zahl angehängt.

### Beispiel

=BAHTTEXT(12,65) ergibt eine Thai-Zeichenkette mit der Bedeutung "Zwölf Baht und 65 Satang".

## BASIS

Wandelt eine positive ganze Zahl in einen Text aus dem Zahlensystem zur angegebenen Basis um. Dabei werden die Ziffern 0-9 und die Buchstaben A-Z verwendet.

### Syntax

BASIS(Zahl; Zahlenbasis; [Mindestlänge])

Zahl ist die positive Ganzzahl, die umgewandelt werden soll.

Zahlenbasis zeigt die Basis des Zahlensystems an. Es kann sich dabei um eine positive Ganzzahl zwischen 2 und 36 handeln.

Mindestlänge (optional) bestimmt die Mindestlänge der erstellten Zeichenkette. Wenn der Text kürzer als die angegebene Mindestlänge ist, werden links neben der Zeichenkette Nullen hinzugefügt.

### Beispiel

=BASIS(17;10;4) ergibt 0017 im Dezimalsystem.

=BASIS(17;2) ergibt 10001 im Binärsystem.

=BASIS(255;16;4) ergibt 00FF im Hexadezimalsystem.

## CODE

Ergibt den numerischen Code des ersten Zeichens eines Textes beziehungsweise einer Zeichenkette.

### Syntax

CODE("Text")

Text ist der Text, für dessen erstes Zeichen der Code gefunden werden soll.

Codes größer als 127 hängen von ihrer eingestellten System-Zeichencodierung ab (beispielsweise iso-8859-1, iso-8859-2, Windows-1262, Windows-1250) und sind daher nicht portabel.

### Beispiel

=CODE("Hieronymus") ergibt 72, =CODE("hieroglyphisch") ergibt 104.

Bei dem hier verwendeten Code handelt es sich nicht um den ASCII-Code, sondern um den Code der aktuellen Code-Tabelle.

## DEZIMAL

Wandelt Text mit Zeichen aus einem Zahlensystem in eine positive Ganzzahl in der gegebenen Zahlenbasis um. Die Zahlenbasis muss im Bereich von 2 bis 36 liegen. Leer- und Tabulatorzeichen werden ignoriert. Das Feld Text unterscheidet nicht zwischen Groß- und Kleinschreibung.

Bei der Zahlenbasis 16 werden x, X, 0x oder 0X am Anfang und h oder H am Ende ignoriert. Bei der Zahlenbasis 2 werden ein angehängtes b oder B ignoriert. Andere Zeichen, die nicht Bestandteil des Zahlensystems sind, verursachen Fehler.

### Syntax

DEZIMAL("Text"; Zahlenbasis)

Text ist der Text, der umgewandelt werden soll. Um zwischen einer Hexadezimalzahl wie A1 und dem Bezug auf Zelle A1 zu unterscheiden, müssen Sie die Zahl in Anführungszeichen setzen, zum Beispiel "A1" oder "SCHRIFTSCHNITT".

Zahlenbasis zeigt die Basis des Zahlensystems an. Es kann sich dabei um eine positive Ganzzahl zwischen 2 und 36 handeln.

### Beispiel

=DEZIMAL("17";10) ergibt 17.

=DEZIMAL("FACE";16) ergibt 64206.

=DEZIMAL("0101";2) ergibt 5.

## ERSETZEN

Um einen bestimmten Teil einer Zeichenkette durch eine andere Zeichenkette auszuwechseln, können Sie hier den auszuwechselnden Text, die Position, die Länge und den Textersatz festlegen. Es können sowohl Zeichen als auch Zahlen (die automatisch in Text gewandelt werden) mit dieser Funktion ausgetauscht werden. Das Ergebnis der Funktion ist immer ein Text. Um mit einer ersetzten Zahl weiterzurechnen, müssen Sie das Ergebnis mit der Funktion WERT in eine Zahl zurückwandeln.

Text, der Zahlen enthält, ist in Anführungszeichen zu setzen. Anderenfalls wird er als Zahl interpretiert und automatisch in Text konvertiert.

### Syntax

ERSETZEN("Text"; Position; Länge; "NeuerText")

Text ist ein Text, aus dem ein Teil ersetzt wird.

Position bezieht sich auf die Position innerhalb des Textes, wo die Ersetzung beginnt.

Länge ist die Anzahl von Zeichen im Text, der ersetzt werden soll.

NeuerText bezieht sich auf Text, der Text ersetzt.

### Beispiel

=ERSETZEN("1234567";1;1;"444") ergibt "444234567". Ein Zeichen an Position 1 wird durch den vollständigen neuen Text (Parameter NeuerText) ersetzt.

## EUR

Wandelt eine Zahl in einen Betrag im Währungsformat um, der auf eine bestimmte Dezimalstelle gerundet ist. Geben Sie im Feld Wert die Zahl ein, die in eine Währung umgewandelt werden soll. Sie können die Anzahl der Dezimalstellen auch in das Feld Dezimalstellen eingeben. Wenn kein Wert angegeben ist, werden alle Zahlen im Währungsformat mit zwei Dezimalstellen angezeigt.

Das Währungsformat legen Sie in den Systemeinstellungen fest.

### Syntax

EUR(Wert; Dezimalstellen)

Wert ist ein Zahl, ein Bezug auf ein Zelle, in der eine Zahl enthalten ist, oder eine Formel, die eine Zahl ergibt.

Dezimalstellen ist die optionale Anzahl von Dezimalstellen.

### Beispiel

=EUR(255) ergibt 255,00 €.

=EUR(367,456;2) ergibt 367,46 €. Verwenden Sie das Dezimaltrennzeichen, das dem aktuellen Gebietsschema entspricht.

## FEST

Ergibt eine Zahl als Text mit einer gewünschten Anzahl an Dezimalstellen und optional mit Tausendertrennzeichen.

### Syntax

FEST(Zahl; Dezimalstellen; KeineTausendertrennzeichen)

Zahl ist die Zahl, die formatiert werden soll.

Dezimalstellen ist die Anzahl der Dezimalstellen, die angezeigt werden sollen.

KeineTausendertrennzeichen (optional) bestimmt, ob das Tausendertrennzeichen verwendet wird. Wenn der Parameter ungleich 0 ist, wird das Tausendertrennzeichen nicht angezeigt. Wenn der Parameter gleich 0 oder nicht vorhanden ist, werden die Tausendertrennzeichen entsprechend Ihren aktuelle lokale Einstellungen angezeigt.

### Beispiel

=FEST(1234567,89;3) ergibt 1.234.567,890 als Zeichenkette.

=FEST(1234567,89;3;1) ergibt 1234567,890 als Zeichenkette.

## FINDEN

Gibt die Position einer Textzeichenkette in einer anderen Zeichenkette zurück. Sie können auch festlegen, wo die Suche beginnen soll. Bei dem Suchbegriff kann es sich um eine Zahl oder eine beliebige Zeichenkette handeln. Die Groß- und Kleinschreibung ist hierbei zu beachten.

### Syntax

FINDEN("TextFinden"; "Text"; Position)

TextFinden bezieht sich auf Text, der gefunden werden soll.

Text ist der Text, wo die Suche stattfindet.

Position (optional) ist die Position im Text, wo die Suche beginnt.

### Beispiel

=FINDEN(76;998877665544) ergibt 6.

## GLÄTTEN

Entfernt Leerstellen aus einer Zeichenkette und lässt nur einzelne Leerzeichen zwischen Worten stehen.

### Syntax

GLÄTTEN("Text")

Text bezieht sich auf den Text, in dem Leerstellen entfernt werden sollen.

### Beispiel

=GLÄTTEN(" Hallo Welt ") ergibt Hallo Welt ohne führende und abschließende Leerzeichen und mit nur einem Leerzeichen zwischen den Wörtern.

## GROSS

Die im Textfeld Text eingegebene Buchstabenfolge wird komplett in Großbuchstaben umgewandelt.

### Syntax

GROSS("Text")

Text bezieht sich auf in Großbuchstaben umzuwandelnde Kleinbuchstaben.

### Beispiel

=GROSS("Guten Morgen") ergibt GUTEN MORGEN.

## GROSS2

Wandelt alle Wortanfänge einer Textzeichenkette in Großbuchstaben um.

### Syntax

GROSS2("Text")

Text bezieht sich auf Text, der umgewandelt werden soll.

### Beispiel

=GROSS2("libre office") ergibt Libre Office.

## IDENTISCH

Vergleicht zwei Textzeichenketten und ergibt WAHR, wenn sie identisch sind. Diese Funktion berücksichtigt die Groß- und Kleinschreibung.

### Syntax

IDENTISCH("Text1"; "Text2")

Text1 bezieht sich auf den ersten Text, der verglichen werden soll.

Text2 ist der zweite Text, der verglichen werden soll.

### Beispiel

=IDENTISCH("microsystems";"Microsystems") ergibt FALSCH.

## JIS

Die Funktion JIS wandelt ASCII- und Katakana-Zeichen halber Breite in normale Breite um. Ergibt eine Zeichenkette.

Siehe https://wiki.documentfoundation.org/Calc/Features/JIS_and_ASC_functions für eine Umrechnungstabelle.

### Syntax

JIS("Text")

Text ist der Text, der Zeichen enthält, die umgewandelt werden sollen.

Siehe auch ASC-Funktion.

## KLEIN

Die im Textfeld „Text“ eingegebene Buchstabenfolge wird komplett in Kleinbuchstaben umgewandelt.

### Syntax

KLEIN("Text")

Text bezieht sich auf Text, der umgewandelt werden soll.

### Beispiel

=KLEIN("Sonne") ergibt sonne.

## LINKS

Ergibt das erste Zeichen beziehungsweise die ersten Zeichen eines Textes.

### Syntax

LINKS("Text"; Zahl)

Text ist der Text, dessen am Anfang stehende Wortsegmente bestimmt werden sollen.

Anzahl (optional) gibt die Anzahl der Zeichen für den Anfangstext an. Ist dieser Parameter nicht definiert, dann wird ein Zeichen zurückgegeben.

### Beispiel

=LINKS("ausgabe";3) ergibt „aus“.

## LINKSB

Ergibt das erste Zeichen eines DBCS-Textes.

### Syntax

LINKSB("Text"; Anzahl_Bytes)

Text ist der Text, dessen am Anfang stehendes Wortsegment bestimmt werden soll.

Anzahl_Bytes (optional) gibt die Anzahl an Zeichen an, die LINKSB zurückgeben soll. Ist dieser Parameter nicht definiert, wird ein Zeichen zurückgegeben.

### Beispiele

LINKSB("中国";1) ergibt " " (1 Byte ist nur ein halbes DBCS-Zeichen, deshalb wird ersatzweise ein Leerzeichen zurückgegeben).

LINKSB("中国";2) ergibt "中" (2 Bytes bilden ein komplettes DBCS-Zeichen).

LINKSB("中国";3) ergibt "中 " (3 Bytes bilden ein-einhalb DBCS-Zeichen; als zweites Zeichen wird deshalb ersatzweise ein Leerzeichen zurückgegeben).

LINKSB("中国";4) ergibt "中国" (4 Bytes bilden zwei komplette DBCS-Zeichen).

LINKSB("Büro";3) ergibt "Bür" (3 nicht-DBCS-Zeichen, jedes mit der Länge 1 Byte).

## LÄNGE

Ergibt die Länge einer Zeichenkette. Leerzeichen werden mitgezählt.

### Syntax

LÄNGE("Text")

Text ist der Text, dessen Länge bestimmt werden soll.

### Beispiel

=LÄNGE("Guten Tag") ergibt 9.

=LÄNGE(12345,67) ergibt 8.

## LÄNGEB

Ergibt die Anzahl der Bytes für Double-Byte-Zeichensatz-Sprachen (DBCS), die zur Darstellung der Zeichen in einer Zeichenkette verwendet werden.

### Syntax

LÄNGEB("Text")

Text ist der Text, dessen Länge bestimmt werden soll.

### Beispiele

LÄNGEB("中") ergibt 2 (1 DBCS-Zeichen, bestehend aus 2 Bytes).

LÄNGEB("中国") ergibt 4 (2 DBCS-Zeichen, bestehend aus je 2 Bytes).

LÄNGEB("Office") ergibt 6 (6 nicht-DBCS-Zeichen, bestehend aus je 1 Byte).

=LÄNGEB("Guten Tag") ergibt 9.

=LÄNGEB(12345,67) ergibt 8.

## RECHTS

Ergibt das letzte Zeichen beziehungsweise die letzten Zeichen eines Textes.

### Syntax

RECHTS("Text"; Zahl)

Text ist der Text, dessen rechter Teil bestimmt werden soll.

Zahl (optional) gibt die Anzahl von Zeichen im rechten Teil des Textes an.

### Beispiel

=RECHTS("Sonne";2) ergibt ne.

## RECHTSB

Ergibt das letzte oder die letzten Zeichen eines Textes mit Double-Bytes-Zeichensätzen (DBCS).

### Syntax

RECHTSB("Text"; Zahl_Bytes)

Text ist der Text, dessen rechter Teil bestimmt werden soll.

Anzahl_Bytes (optional) gibt die Anzahl der auf Bytes basierenden Zeichen an, die Sie mit RECHTSB abfragen möchten.

### Beispiele

RECHTSB("中国";1) ergibt " " (1 Byte ist nur ein halbes DBCS-Zeichen, deshalb wird ersatzweise ein Leerzeichen zurückgegeben).

RECHTSB("中国";2) ergibt "国" (2 Bytes bilden ein komplettes DBCS-Zeichen).

RECHTSB("中国";3) ergibt " 国" (3 Bytes bilden ein-einhalb DBCS-Zeichen; ein Leerzeichen wird ersatzweise für das erste halbe Zeichen zurückgegeben).

RECHTSB("中国";4) ergibt "中国" (4 Bytes bilden zwei komplette DBCS-Zeichen).

RECHTSB("Büro";3) ergibt "üro" (3 nicht-DBCS-Zeichen, jedes mit der Länge 1 Byte).

## RÖMISCH

Konvertiert eine arabische in eine römische Zahl. Der Wert muss im Bereich 0 bis 3999 liegen. Als Modus kann eine Ganzzahl von 0 bis 4 angegeben werden.

### Syntax

RÖMISCH(Zahl; Modus)

Zahl ist die Zahl, die in eine römische Zahl umgewandelt werden soll.

Modus (optional) Gibt den Grad der Vereinfachung an. Je höher der Wert, desto mehr wird die römische Zahl vereinfacht.

### Beispiel

=RÖMISCH(999) ergibt CMXCIX

=RÖMISCH(999;0) ergibt CMXCIX

=RÖMISCH (999;1) ergibt LMVLIV

=RÖMISCH(999;2) ergibt XMIX

=RÖMISCH(999;3) ergibt VMIV

=RÖMISCH(999;4) ergibt IM

## SUCHEN

Ergibt die Position eines Textsegments innerhalb einer Zeichenkette. Bei Belieben können Sie auch den Anfang für die Suche festlegen. Bei dem Suchbegriff kann es sich um eine Zahl oder eine beliebige Zeichenkette handeln. Die Groß- und Kleinschreibung spielt hier keine Rolle.

Die Suche unterstützt auch reguläre Ausdrücke. Sie können zum Beispiel "all.*" eingeben, um die erste Stelle von "all", gefolgt von irgendeinem Zeichen, zu finden. Falls Sie nach Text suchen, der auch ein regulärer Ausdruck ist, müssen Sie jedem Zeichen ein \-Zeichen voranstellen. Sie können die automatische Auswertung regulärer Ausdrücke in LibreOffice - EinstellungenExtras - Optionen...
- LibreOffice Calc - Berechnen ein- und ausschalten.

### Syntax

SUCHEN("TextFinden"; "Text"; Position)

TextFinden ist der Text, nach dem gesucht werden soll.

Text ist der Text, wo die Suche stattfindet.

Position (optional) ist die Position im Text, wo die Suche beginnen soll.

### Beispiel

=SUCHEN(54;998877665544) ergibt 10.

## SÄUBERN

Aus der Zeichenkette werden alle nicht druckbaren Zeichen entfernt.

### Syntax

SÄUBERN("Text")

Text bezieht sich auf Text, aus dem alle nicht druckbaren Zeichen entfernt werden sollen.

## T

Diese Funktion ergibt den Zieltext oder eine leere Zeichenkette, wenn das Ziel kein Text ist.

### Syntax

T(Wert)

Wenn Wert eine Zeichenkette ist oder sich auf eine Zeichenkette bezieht, ergibt T die Zeichenkette; anderenfalls ergibt T eine leere Zeichenkette.

### Beispiel

=T(12345) ergibt eine leere Zeichenkette.

=T("12345") ergibt die Zeichenkette 12345.

## TEIL

Ergibt eine Zeichenkette des Textes. Die Parameter geben die Ausgangsposition und die Zeichenanzahl an.

### Syntax

TEIL("Text"; Start; Zahl)

Text ist der Text, der Zeichen enthält, die extrahiert werden sollen.

Anfang ist die Position des ersten Zeichens im Text, der extrahiert werden soll.

Zahl gibt die Anzahl von Zeichen im betreffenden Teil des Textes an.

### Beispiel

=TEIL("office";2;2) ergibt ff.

## TEILB

Ergibt eine Zeichenkette des DBCS-Textes. Die Parameter geben die Ausgangsposition und die Zeichenanzahl an.

### Syntax

TEILB("Text"; Start; Zahl_Bytes)

Text ist der Text, der Zeichen enthält, die extrahiert werden sollen.

Start ist die Position des ersten Zeichens im Text, der extrahiert werden soll.

Anzahl_Bytes legt die Anzahl der Zeichen in Bytes fest, die TEILB vom Text in Bytes zurückgeben soll.

### Beispiele

TEILB("中国";1;0) ergibt "" (0 Bytes entsprechen immer einer leeren Zeichenkette).

TEILB("中国";1;1) ergibt " " (1 Byte ist lediglich ein halbes DBCS-Zeichen, deshalb wird ersatzweise ein Leerzeichen zurückgegeben).

TEILB("中国";1;2) ergibt "中" (2 Bytes bilden ein komplettes DBCS-Zeichen).

TEILB("中国";1;3) ergibt "中 " (3 Bytes bilden ein-einhalb DBCS-Zeichen; als zweites Zeichen wird deshalb ersatzweise ein Leerzeichen zurückgegeben).

TEILB("中国";1;4) ergibt "中国" (4 Bytes bilden zwei komplette DBCS-Zeichen).

TEILB("中国";2;1) ergibt " " (die 2. Byteposition ist nicht am Anfang eines Zeichens einer DBCS-Zeichenkette; deshalb wird ersatzweise ein Leerzeichen zurückgegeben).

TEILB("中国";2;2) ergibt " " (die 2. Byteposition ist nicht am Anfang eines Zeichens einer DBCS-Zeichenkette; die 2 Bytes, die zurückgegeben werden sollen, bilden stattdessen die zweite Hälfte des ersten Zeichens und die erste Hälfte des zweiten Zeichens in der Zeichenkette; deshalb werden ersatzweise zwei Leerzeichen zurückgegeben).

TEILB("中国";2;3) ergibt " 国" (die 2. Byteposition ist nicht am Anfang eines Zeichens einer DBCS-Zeichenkette; deshalb wird ersatzweise ein Leerzeichen für die 2. Byteposition zurückgegeben).

TEILB("中国";3;1) ergibt " " (die 3. Byteposition am Anfang eines Zeichens einer DBCS-Zeichenkette, aber 1 Byte ist lediglich ein halbes DBCS-Zeichen, deshalb wird ersatzweise ein Leerzeichen zurückgegeben).

TEILB("中国";3;2) ergibt "国" (die 3. Byteposition ist am Anfang eines Zeichens einer DBCS-Zeichenkette und 2 Bytes bilden ein DBCS-Zeichen).

TEILB("Büro";2;3) ergibt "üro" (die 2. Byteposition ist am Anfang eines Zeichens einer nicht-DBCS-Zeichenkette und 3 Bytes einer nicht-DBCS-Zeichenkette bilden 3 Zeichen).

## TEXT

Konvertiert eine Zahl gemäß einer Formatangabe in Text.

### Syntax

TEXT(Zahl; Format)

Zahl ist die Zahl, die umgewandelt wird.

Format ist der Text, der das Format beschreibt. Verwenden Sie die für die im Zellenformat festgelegte Sprache üblichen Dezimal- und Tausenderseparatoren.

### Beispiel

=TEXT(12,34567;"###,##") ergibt den Text 12,35

=TEXT(12,34567;"000,00") ergibt den Text 012,35

## UNICODE

Ergibt den Code des ersten Unicode-Zeichens einer Zeichenkette.

### Syntax

UNICODE("Text")

### Beispiel

=UNICODE("©") ergibt die Unicodezahl 169 für das Copyrightzeichen.

Vergleichen Sie auch die Funktion UNIZEICHEN().

## UNIZEICHEN

Wandelt eine Codenummer in ein Unicode-Zeichen oder -Buchstaben um.

### Syntax

UNIZEICHEN(Zahl)

### Beispiel

=UNIZEICHEN(169) ergibt das Copyrightzeichen ©.

Vergleichen Sie auch die Funktion UNICODE().

## VERKETTEN

Verbindet mehrere Textzeichenketten zu einer Zeichenkette.

### Syntax

VERKETTEN("Text1"; ...; "Text30")

Text 1; Text 2; ... stellt bis zu 30 Textpassagen dar, die in einer Zeichenkette zusammengefasst werden sollen.

### Beispiel

=VERKETTEN("Guten ";"Morgen ";"Frau ";"Müller") ergibt "Guten Morgen Frau Müller".

## WECHSELN

Tauscht in einer Zeichenkette einen alten gegen einen neuen Text aus.

### Syntax

WECHSELN("Text"; "Suchtext"; "NeuerText"; GefundeneTextstelle)

Text ist der Text, in dem Textsegmente ausgetauscht werden sollen.

Suchtext ist das Textsegment, das ersetzt werden soll (mehrere Male).

NeuerText ist der Text, der das Textsegment ersetzen soll.

GefundeneTextstelle (optional) zeigt an, welche gefundene Textstelle des Suchtextes ersetzt werden soll. Wenn dieser Parameter nicht vorhanden ist, wird der Suchtext durchgängig ersetzt.

### Beispiel

=WECHSELN("123123123";"3";"abc") ergibt 12abc12abc12abc.

=WECHSELN("123123123";"3";"abc";2) ergibt 12312abc123.

## WERT

Konvertiert eine Textzeichenkette in eine Zahl.

### Syntax

WERT("Text")

Text ist der Text, der in eine Zahl umgewandelt werden soll.

### Beispiel

=WERT("4321") ergibt 4321.

## WIEDERHOLEN

Wiederholt eine Zeichenkette so oft, wie mit Anzahl angegeben.

### Syntax

WIEDERHOLEN("Text"; Zahl)

Text ist der Text, der wiederholt werden soll.

Zahl ist die Anzahl von Wiederholungen.

Das Ergebnis darf maximal 255 Zeichen lang werden.

### Beispiel

=WIEDERHOLEN("Guten Morgen";2) ergibt Guten MorgenGuten Morgen.

## ZEICHEN

Konvertiert eine Zahl gemäß der aktuellen Codetabelle in einen Buchstaben oder ein Zeichen. Bei der Zahl kann es sich um eine zwei- oder dreistellige Ganzzahl handeln.

Codes größer als 127 hängen von ihrer eingestellten System-Zeichencodierung ab (beispielsweise iso-8859-1, iso-8859-2, Windows-1262, Windows-1250) und sind daher nicht portabel.

### Syntax

ZEICHEN(Zahl)

Zahl ist eine Zahl zwischen 1 und 255, die den Codewert für das Zeichen darstellt.

### Beispiel

=ZEICHEN(100) ergibt das Zeichen d.

="abc" &ZEICHEN(10) & "def" fügt einen Zeilenumbruch in den Text ein.

Verwandte Themen

Funktionen nach Kategorie