Module
Contents
Index 🔎︎

# Tömbfüggvények

Ez a kategória az adattömbökön, illetve mátrixokon ható függvényeket tartalmazza.

## Mi az a tömb?

A tömb értékeket tartalmazó cellák kapcsolt tartománya a munkalapon. Egy négyzet alakú, 3 sort és 3 oszlopot tartalmazó tartomány egy 3x3-as tömb:

| A | B | C
1 | 7 | 31 | 33
2 | 95 | 17 | 2
3 | 5 | 10 | 50

A legkisebb lehetséges tömb az 1x2-es vagy a 2x1-es, amely két szomszédos cellát tartalmaz.

## Mi az a tömbképlet?

Az olyan képleteket, amelyekben a cellatartományban található egyéni értékek kerülnek kiértékelésre, tömbképleteknek nevezik. A különbség a tömbképletek, illetve a többi képlet között, hogy a tömbképletek egyidejűleg több értéket kezelnek, míg a többi képlet csak egyet.

A tömbképlet nem csupán több érték feldolgozására képes, hanem eredményül is több értéket képes adni. A tömbképlet eredménye maga is tömb.

A fenti tömbben található egyedi cellák tartalmának tízszeresére növeléséhez nem szükséges minden egyes cellára, illetve értékre képletet alkalmaznia. Ehelyett egyszerűen használjon egy tömbképletet. Jelöljön ki egy 3 x 3 cellából álló tartományt a táblázat valamely másik részén, írja be a =10*A1:C3 képletet, majd erősítse meg a bejegyzést a CommandCtrl
+Shift+Enter billentyűk segítségével. Az eredmény egy olyan 3 x 3 méretű tömb, amelyben a cellatartomány (A1:C3) egyedi értékei meg lesznek szorozva tízzel.

A szorzáson kívül a hivatkozási tartományon (tömbön) más operátorokat is használhat. A LibreOffice Calc programban összeadhat (+), kivonhat (-), szorozhat (*), oszthat (/), használhat hatványozást (^), összefűzést (&), illetve összehasonlításokat végezhet (=, <>, <, >, <=, >=). Az operátorok használhatók a cellatartomány minden egyedi értékére. Ebben az esetben – ha tömbképlet került megadásra – az eredmény maga is tömbként kerül visszaadásra.

A tömbképletben levő összehasonlító operátorok az üres cellákat ugyanúgy kezelik, mint a normál képletek, azaz vagy nullaként, vagy üres karakterláncként. Ha például az A1 és A2 cellák üresek, akkor az {=A1:A2=""} és az {=A1:A2=0} tömbképletek eredményül egyaránt IGAZ értéket adnak egy 1 oszlopos és 2 soros cellatömbben.

### Mikor érdemes használni tömbképleteket?

Tömbképleteket akkor érdemes használni, ha számításokat eltérő értékekkel kell megismételnie. Ha később a számítási módszer módosítása mellett dönt, akkor csupán a tömbképletet szükséges frissítenie. Tömbképlet felvételéhez jelölje ki a teljes tömbtartományt, majd módosítsa a tömbképletet a kívánt módon.

A tömbképletek ezen kívül tárterület-kímélő megoldást nyújtanak azon esetekre, amikor több értéket szükséges kiszámítani, hiszen nem rendelkeznek különösebb memóriaigénnyel. Ezen kívül a tömbök az összetett számítási műveletek végzése során létfontosságú eszköznek bizonyulnak, mivel segítségükkel a számítások során több cellatartományt is felhasználhat. A LibreOffice különböző matematikai műveleteket tartalmaz a tömbökkel végzett munkához, például az MSZORZAT függvényt két tömb összeszorzására vagy a SZORZATÖSSZEG függvényt két tömb skaláris szorzatának kiszámítására.

## Tömbképletek használata a LibreOffice Calc programban

Olyan „szokásos” képletet is létrehozhat, amelyben a hivatkozási tartomány (például paraméterek) tömbképletet jelöl. Ilyenkor az eredmények a hivatkozási tartomány, illetve a képletet tartalmazó sorok vagy oszlopok metszetéből kerülnek kiszámításra. Ha nem létezik metszet, illetve ha a metszettartomány több sorból vagy oszlopból áll, akkor az #ÉRTÉK! hibaüzenet jelenik meg. Az alapelvet a következő példa szemlélteti:

### Tömbképletek létrehozása

Ha tömbképletet a Függvénytündér segítségével hoz létre, akkor az Adattömb jelölőnégyzetet minden egyes alkalommal meg kell jelölnie ahhoz, hogy az eredmények tömbformátumban kerüljenek visszaadásra. Ellenkező esetben csak a tömb bal felső cellájában található érték kerül kiszámításra, illetve visszaadásra.

Ha a tömbképletet közvetlenül a cellában adja meg, akkor az Enter billentyű helyett a Shift+CommandCtrl
+Enter billentyűkombinációt kell használnia. Kizárólag ebben az esetben válhat a képlet tömbképletté.

A tömbhivatkozások kapcsos zárójelben jelennek meg a LibreOffice Calc programban. A kapcsos zárójelek kézi beírásával tömbképletek nem hozhatók létre.

Az eredménytömb cellái rendszerint módosítás elleni védelmet élveznek. Ennek ellenére a tömbképletet szerkesztheti, illetve másolhatja a tömb teljes cellatartományának kijelölésével.

### Helyi tömbkonstansok használata képletekben

A Calc támogatja a helyi mátrixokat/tömbkonstansokat a képletekben. Egy helyi tömb „{” és „}” jel közé van zárva. Az elemek mindegyike lehet szám (beleértve a negatív számokat is), logikai konstans (IGAZ, HAMIS) vagy karakterlánc. A nem konstans kifejezések nem használhatók. Megadhatók egy vagy több sorból, illetve egy vagy több oszlopból álló tömbök. Minden sornak, valamint minden oszlopnak is azonos számú elemből kell állnia.

Az oszlopelválasztó (a sorban lévő elemek elválasztója) és a sorelválasztó nyelv- és területfüggő. Azonban ebben a súgóban a ';' pontosvessző és a '|' cső jel jelzi az oszlop- és sorelválasztókat. Például angol területi beállításoknál a ',' vessző az oszlopelválasztó, és a ';' pontosvessző a sorelválasztó.

You can view and change the row and column separator in LibreOffice - PreferencesTools - Options
- Calc - Formula - Separators.

A tömbök nem ágyazhatók egymásba.

Példák:

={1;2;3}

Három számot (1, 2 és 3) tartalmazó sorral rendelkező tömb

A fenti tömbkonstans megadásához válasszon ki három cellát egy sorban, írja be az ={1;2;3} képletet kapcsos zárójelek és pontosvesszők használatával, majd nyomja meg a CommandCtrl
+Shift+Enter billentyűkombinációt.

={1;2;3|4;5;6}

Két sort és soronként három értéket tartalmazó tömb

={0;1;2|HAMIS;IGAZ;"kettő"}

Kevert adattípusú tömb

=SIN({1;2;3})

Mátrixképletként megadva három szinuszszámítás értékét adja vissza az 1, 2 és 3 argumentumra.

### Tömbképletek szerkesztése

1. Válassza ki a tömbképletet tartalmazó cellatartományt vagy tömböt. A teljes tömb kijelöléséhez mozgassa a kurzort a tömbtartományon belülre, majd nyomja meg a CommandCtrl
   +/ billentyűkombinációt, ahol / a numerikus billentyűzeten található osztásjel.

2. Nyomja meg az F2 billentyűt, vagy helyezze a kurzort a beviteli sorba. Mindkét művelet segítségével szerkesztheti a képletet.

3. Módosítás után nyomja meg a CommandCtrl
   +Shift+Enter billentyűket.

Lehetősége nyílik a tömbök önálló részeinek formázására is. Például, módosíthatja a betűtípus színét. Jelöljön ki egy cellatartományt, majd módosítsa a kívánt attribútumokat.

### Tömbhivatkozások másolása

1. Válassza ki a tömbhivatkozást tartalmazó cellatartományt vagy tömböt.

2. Nyomja meg az F2 billentyűt, vagy helyezze a kurzort a beviteli sorba.

3. A CommandCtrl
   +C megnyomásával másolja a képletet az adatbevitel sorba.

4. Válassza ki azt a cellatartományt, ahova a tömbhivatkozást be akarja szúrni, majd nyomja meg az F2 billentyűt, vagy helyezze a kurzort a beviteli sorba.

5. A CommandCtrl
   +V megnyomásával illessze be a képletet a kijelölt területre, majd erősítse meg a CommandCtrl
   +Shift+Enter megnyomásával. A kijelölt tartomány most már tartalmazza a tömbképletet.

### Tömbhivatkozás beállítása

Ha a kimeneti tömböt szeretné szerkeszteni, végezze el az alábbi műveleteket:

1. Válassza ki a tömbhivatkozást tartalmazó cellatartományt vagy tömböt.

2. A kijelölés alatt jobbra láthat egy kis ikont. Ezzel, valamint az egérrel, kicsinyítheti vagy nagyíthatja a tartományt.

A tömbtartomány beállításakor a tömbképlet nem kerül automatikusan beállításra. Csak azt a tartományt módosítja, amelyben az eredmények megjelenítésre kerülnek.

A CommandCtrl
billentyű lenyomva tartásával a megadott tartományban másolatot készíthet a tömbképletről.

### Feltételes tömbszámítások

A feltételes tömbszámítás egy olyan tömb- vagy mátrixképlet, amely egy HA() vagy VÁLASZT() függvényt tartalmaz. A képlet feltételargumentuma egy területhivatkozás vagy egy mátrixeredmény.

A következő példában a {=HA(A1:A3>0;"igen";"nem")} képlet >0 vizsgálata az A1:A3 tartomány minden cellájára lesz alkalmazva, és az eredmény a megfelelő cellába lesz másolva.

| A | B (képlet) | B (eredmény)
1 | 1 | {=HA(A1:A3>0;"igen";"nem")} | igen
2 | 0 | {=HA(A1:A3>0;"igen";"nem")} | nem
3 | 1 | {=HA(A1:A3>0;"igen";"nem")} | igen

A következő függvényekkel elfogadtatható tömbérték is: ELŐREJELZÉS, F.PRÓBA, INVERZ.MÁTRIX, KORREL, KOVAR, MDETERM, MEREDEKSÉG, METSZ, MÓDUSZ, MSZORZAT, PEARSON, RNÉGYZET, STHIBAYX, SZORZATÖSSZEG, SZUMX2BŐLY2, SZUMX2MEGY2, SZUMXBŐLY2, T.PRÓBA, VALÓSZÍNŰSÉG. Ha területhivatkozásokat használ argumentumként a fenti függvények egyikének meghívásakor, akkor a függvények tömbfüggvényekként működnek. A következő táblázat példát mutat a kényszerített tömbkezelésre:

| A | B (képlet) | B (eredmény) | C (kényszerített tömbképlet) | C (eredmény)
1 | 1 | =A1:A2+1 | 2 | =SZORZATÖSSZEG(A1:A2+1) | 5
2 | 2 | =A1:A2+1 | 3 | =SZORZATÖSSZEG(A1:A2+1) | 5
3 |  | =A1:A2+1 | #ÉRTÉK! | =SZORZATÖSSZEG(A1:A2+1) | 5

## GYAKORISÁG

Egydimenziós tömb gyakorisági eloszlását jelzi. A függvény megszámolja, hogy az adatok tömbben levő értékek közül hány esik az osztályok által meghatározott értéktartományokba.

### Szintaxis

GYAKORISÁG(adatok; osztályok)

Az adatok a megszámlálni kívánt értékeket tartalmazó tömb, illetve az értékek halmazára mutató hivatkozás.

Az osztályok az osztályok határait jelentő értékek tömbje.

A tömbfunkciókról általános információkat talál az oldal tetején.

### Példa

A következő táblázatban a rendezés nélküli mérési értékeket az A oszlop tartalmazza. A B oszlop az osztályokra megadott felső korlátot tartalmazza, amelyekbe az A oszlopban található adatokat osztani kívánja. A B1 cellában megadott korlát szerint a GYAKORISÁG függvény az 5-nél kisebb vagy azzal egyenlő mért értékek számát adja eredményül. Mivel a B2 cellában megadott korlát 10, a GYAKORISÁG függvény második eredményül az olyan mért értékek számát adja, amelyek 5-nél nagyobbak, illetve 10-nél kisebbek vagy azzal egyenlőek. A B6 cellában megadott „>25” szöveg csak referenciaként szolgál.

| A | B | C
1 | 12 | 5 | 1
2 | 8 | 10 | 3
3 | 24 | 15 | 2
4 | 11 | 20 | 3
5 | 5 | 25 | 1
6 | 20 | >25 | 1
7 | 16 |  |
8 | 9 |  |
9 | 7 |  |
10 | 16 |  |
11 | 33 |  |

Jelöljön ki egy oszloptartományt, amelyben megadásra kerülnek az értékek osztálykorlátoknak megfelelő gyakoriságai. Legalább egy, a felső osztálykorlátnál nagyobb mezőt ki kell választania. Jelen esetben jelölje ki a C1:C6 tartományt. Hívja meg a Függvénytündér GYAKORISÁG függvényét. Jelölje ki az adatok mérési tartományát az (A1:A11) tartományban, majd egy oszlopot az osztályok számára, amelyben megadta az osztálykorlátokat (B1:B6). Jelölje ki a tömb jelölőnégyzetet, majd kattintson az OK gombra. Az eredetileg kijelölt C1:C6 tartományban megjelennek a gyakorisági értékek.

More explanations on top of this page.

## INVERZ.MÁTRIX

Kiszámítja egy mátrix inverzét.

### Szintaxis

INVERZ.MÁTRIX(mátrix)

A mátrix az invertálni kívánt négyzet alakú mátrix.

More explanations on top of this page.

### Példa

Jelöljön ki egy négyzet alakú tartományt, majd válassza az INVERZ.MÁTRIX függvényt. Jelölje ki a kimeneti tömböt, jelölje ki a Tömb mezőt, majd kattintson az OK gombra.

## LIN.ILL

Az adathalmazra legjobban illeszkedő egyenes statisztikáit tartalmazó táblázatot ad vissza.

### Szintaxis

LIN.ILL(y_adatok; x_adatok; egyenes_típusa; statisztika)

Az y_adatok egy sor- vagy oszloptartomány, amely megadja az y koordinátákat az adatpontok halmazában.

Az x_adatok az x koordinátákat megadó sor- vagy oszloptartomány. Ha az x_adatok nincs megadva, akkor az alapértelmezett 1, 2, 3, ..., n értékeket kapja. Ha több változóhalmaz van, akkor az x_adatok tartomány is lehet, a megfelelő több sorral vagy oszloppal.

A LIN.ILL egy y = a + bx egyenletű egyenest keres, amely a legjobban illeszkedik az adatokra. Lineáris regressziót használ (a „legkisebb négyzetek” módszerrel). Több változóhalmaz esetén az egyenes képlete y = a + b1x1 + b2x2 ... + bnxn lesz.

Ha az egyenes_típusa értéke HAMIS, akkor az egyenes átmegy az origón (az a konstans nulla, y=bx). Ha nincs megadva, akkor az egyenes_típusa értéke IGAZ (az egyenes nem megy át az origón).

Ha a statisztika nincs megadva vagy HAMIS, akkor csak a statisztikai táblázat felső sora kerül visszaadásra. Ha IGAZ, akkor a teljes tábla visszaadásra kerül.

A LIN.ILL egy statisztikatáblázatot (tömböt) ad vissza és tömbképletként kell megadni (például a CommandCtrl
+Shift+Enter használatával, az Enter helyett).

In the LibreOffice Calc functions, parameters marked as "optional" can be left out only when no parameter follows. For example, in a function with four parameters, where the last two parameters are marked as "optional", you can leave out parameter 4 or parameters 3 and 4, but you cannot leave out parameter 3 alone.

More explanations on top of this page.

### Példa

A függvény eredményül tömböt ad vissza, és a többi tömbfüggvényhez hasonlóan kerül kezelésre. Jelöljön ki egy tömböt a válaszok számára, majd ezt követően jelölje ki a függvényt. Jelölje ki az y_adatokat. Ha kívánja, megadhat más paramétereket is. Jelölje ki az Adattömb elemet, majd kattintson az OK gombra.

A rendszer által eredményül adott eredmények (statisztika = 0 esetén) minden esetben megadják legalább a regressziós egyenes meredekségét, illetve az egyenes és az Y tengely metszéspontját. Ha a statisztika értéke 0-tól eltérő, akkor más eredmények is megjelenítésre kerülnek.

### Más LIN.ILL-eredmények:

Nézze meg az alábbi példákat:

| A | B | C | D | E | F | G
1 | x1 | x2 | y |  | LIN.ILL érték |  |
2 | 4 | 7 | 100 |  | 4,17 | -3,48 | 82,33
3 | 5 | 9 | 105 |  | 5,46 | 10,96 | 9,35
4 | 6 | 11 | 104 |  | 0,87 | 5,06 | #HIÁNYZIK
5 | 7 | 12 | 108 |  | 13,21 | 4 | #HIÁNYZIK
6 | 8 | 15 | 111 |  | 675,45 | 102,26 | #HIÁNYZIK
7 | 9 | 17 | 120 |  |  |  |
8 | 10 | 19 | 133 |  |  |  |

Az A oszlop számos X1 értéket, a B oszlop számos X2 értéket, a C oszlop pedig az Y értékeket tartalmazza. Az értékeket már ezt megelőzően beírta a táblázatba. A táblázatban sikeresen beállította az E2:G6 tartományt, és aktiválta a Függvénytündér funkciót. Ahhoz, hogy a LIN.ILL függvény működjön, be kell jelölnie a Függvénytündér párbeszédablakban található Adattömb jelölőnégyzetet. Ezt követően a táblázatban jelölje ki az alábbi értékeket (vagy írja be őket a billentyűzet segítségével):

y_adatok: C2:C8

x_adatok: A2:B8

Az egyenes_típusa és a statisztika beállítása egyaránt 1.

Amint az OK gombra kattint, a LibreOffice Calc kitölti a fenti példát a LIN.ILL értékekkel, a példában bemutatott módon.

A Képlet eszköztárban megjelenő képlet a LIN.ILL tömb {=LIN.ILL(C2:C8;A2:B8;1;1)} egyes celláinak felel meg.

Ez jelöli a kiszámított LIN.ILL értékeket:

E2 és F2: Az y=b+m*x regressziós egyenes m meredeksége az x1 és x2 értékre számítva. Az értékek fordított sorrendben vannak megadva, vagyis az x2 értékre vonatkozó meredekség az E2 cellában, az x1 értékre vonatkozó meredekség pedig az F2 cellában.

G2: Az y tengely b tengelymetszete.

E3 és F3: A meredekségérték standard hibája.

G3: A tengelymetszet standard hibája.

E4: RNÉGYZET

F4: Az Y értékre számított regressziós együttható standard hibája.

E5: A szórásnégyzet-elemzésből számított F értéke.

F5: A szórásnégyzet-analízisből számított szabadsági fokok.

E6: Az Y értékek és a négyzetes középérték különbségének négyzetösszege.

F6: A becsült Y értékek és a megadott Y értékek különbségének négyzetösszege.

More explanations on top of this page.

## LOG.ILL

E függvény a beírt adatokra igazított exponenciális regressziós görbét számítja ki (y=b*m^x).

### Szintaxis

LOG.ILL(y_adatok; x_adatok; függvénytípus; statisztika)

Az y_adatok az y adattömböt jelöli.

Az x_adatok (opcionális) az x adattömböt jelöli.

A függvénytípus argumentum opcionális. Ha a függvénytípus = 0, akkor az y = m^x formátumú függvények kerülnek kiszámításra. Ellenkező esetben az y = b*m^x függvények kerülnek kiszámításra.

A statisztika opcionális paraméter. Ha a statisztika=0, akkor csak a regressziós együttható kerül kiszámításra.

In the LibreOffice Calc functions, parameters marked as "optional" can be left out only when no parameter follows. For example, in a function with four parameters, where the last two parameters are marked as "optional", you can leave out parameter 4 or parameters 3 and 4, but you cannot leave out parameter 3 alone.

More explanations on top of this page.

### Példa

Lásd LIN.ILL függvény. Ugyanakkor a négyzetösszegek nem lesznek visszaadva.

## MDETERM

Kiszámítja egy mátrix determinánsát. Ez a függvény az eredményt az aktuális cellában adja vissza, nem szükséges az eredmények számára egy tartományt meghatározni.

### Szintaxis

MDETERM(mátrix)

A mátrix négyzet alakú mátrix, amelyben a determináns definiálva van.

A tömbfüggvényekről általános információkat talál az oldal tetején.

More explanations on top of this page.

## MMÁTRIX

A megadott nagyságú egységmátrixot adja eredményül. Az egységmátrix egy négyzetes tömb, amelyben az átló elemei 1-et, a többi elem pedig 0-át tartalmaz.

### Szintaxis

MMÁTRIX(méret)

A méret az egységmátrix méretét jelöli.

A tömbfunkciókról általános információkat talál az oldal tetején.

### Példa

Válasszon ki egy négyzetes cellatartományt a munkalapon. Legyen ez például az A1:E5.

A tartomány kijelölésének megszüntetése nélkül jelölje ki az MMÁTRIX függvényt. Jelölje be az Adattömb jelölőnégyzetet. Adja meg az egységmátrix kívánt méretét (ez esetben 5-öt), majd kattintson az OK gombra.

A =MMÁTRIX(5) képletet a kijelölt tartomány utolsó cellájában is megadhatja. Ezt követően nyomja meg a Shift+Command+Enter Shift+Ctrl+Enter
billentyűket.

Most már az A1:E5 tartományban egy egységmátrixot láthat.

More explanations on top of this page.

## MSZORZAT

Két mátrix szorzatát számítja ki. Az első mátrix (mátrix 1) oszlopainak számának meg kell egyeznie a második mátrix (mátrix 2) sorainak számával. A négyzetes mátrixnak megegyező számú oszlopa és sora van.

### Szintaxis

MSZORZAT(mátrix; mátrix)

Az első mátrix a mátrixszorzásban résztvevő első mátrixot jelöli.

A második mátrix az azonos számú sorból álló második mátrixot jelöli.

More explanations on top of this page.

### Példa

Jelöljön ki egy négyzet alakú tartományt. Válassza az MSZORZAT függvényt. Jelölje ki az első Tömböt, majd jelölje ki a második Tömböt. A Függvénytündér segítségével jelölje be az Adattömb jelölőnégyzetet. Kattintson az OK gombra. A kimeneti mátrix megjelenik az első tartományban.

## NÖV

Exponenciális trend pontjait számítja ki egy tömbben.

### Szintaxis

NÖV(y_adatok; x_adatok; új_x_adatok; függvénytípus)

Az y_adatok az y adattömböt jelöli.

Az x_adatok (opcionális) az x adattömböt jelöli.

Az új_x_adatok (opcionális) azon x adattömböt jelöli, amelyben az értékek újraszámításra kerülnek.

A függvénytípus argumentum opcionális. Ha a függvénytípus = 0, akkor y = m^x formátumú függvények lesznek kiszámítva. Ellenkező esetben y = b*m^x formátumú függvények lesznek kiszámítva.

In the LibreOffice Calc functions, parameters marked as "optional" can be left out only when no parameter follows. For example, in a function with four parameters, where the last two parameters are marked as "optional", you can leave out parameter 4 or parameters 3 and 4, but you cannot leave out parameter 3 alone.

More explanations on top of this page.

### Példa

A függvény eredményül tömböt ad vissza, és a többi tömbfüggvényhez hasonlóan kerül kezelésre. Jelölje ki azon tartományt, amelyben a válaszokat meg kívánja jeleníteni, majd jelölje ki a függvényt. Jelölje ki az y_adatokat, és ha szükséges, adja meg a többi paramétert. Jelölje be az Adattömb jelölőnégyzetet, majd kattintson az OK gombra.

## SZORZATÖSSZEG

Összeszorozza az adott tömbök megfelelő elemeit, és eredményül a szorzatok összegét adja.

### Szintaxis

SZORZATÖSSZEG(adattömb_1; adattömb_2; ...adattömb_30)

Az adattömb_1, adattömb_2, ...adattömb_30 az összeszorzandó elemeket tartalmazó tömbök.

Az argumentumlistában legalább egy tömbnek szerepelnie kell. Ha csak egy tömb van megadva, akkor az összes tömbelem össze lesz adva.

### Példa

| A | B | C | D
1 | 2 | 3 | 4 | 5
2 | 6 | 7 | 8 | 9
3 | 10 | 11 | 12 | 13

A =SZORZATÖSSZEG(A1:B3;C1:D3) a 397 értéket adja vissza.

Számítás: A1*C1 + B1*D1 + A2*C2 + B2*D2 + A3*C3 + B3*D3

A SZORZATÖSSZEG függvénnyel két vektor skaláris szorzatát számíthatja ki.

A SZORZATÖSSZEG egy számot ad vissza, nincs szükség rá, hogy a függvényt tömbfüggvényként használja.

More explanations on top of this page.

## SZUMX2BŐLY2

Két mátrix megfelelő elemei négyzetének különbségösszegét számítja ki.

### Szintaxis

SZUMX2BŐLY2(x_adattömb; y_adattömb)

Az x_adattömb az első tömb, amelynek az elemeit négyzetre kívánja emelni, majd összeadni.

Az y_adattömb a második tömb, amelynek elemeit négyzetre kívánja emelni, majd összeadni. A függvény az x_adattömb és az y_adattömb négyzetösszegeinek különbségét adja vissza.

More explanations on top of this page.

## SZUMX2MEGY2

Két mátrix megfelelő elemeinek négyzetösszegét számítja ki.

### Szintaxis

SZUMX2MEGY2(x_adattömb; y_adattömb)

Az x_adattömb az első tömb, amelynek az elemeit négyzetre kívánja emelni, majd összeadni.

Az y_adattömb a második tömb, amelynek az elemeit négyzetre kívánja emelni, majd összeadni. A függvény az x_adattömb és az y_adattömb négyzetösszegeinek összegét adja vissza.

More explanations on top of this page.

## SZUMXBŐLY2

Két mátrix megfelelő elemei négyzetének különbségeit adja össze.

### Szintaxis

SZUMXBŐLY2(x_adattömb; y_adattömb)

Az x_adattömb az első tömb, amelynek elemeiből az y_adattömb megfelelő elemeit ki kell vonni, majd az eredményt négyzetre emelni.

Az y_adattömb a második tömb, amelynek elemeit az x_adattömb megfelelő elemeiből ki kell vonni, majd az eredményt négyzetre emelni. A függvény a különbségek négyzeteinek összegét adja vissza.

More explanations on top of this page.

## TRANSZPONÁLÁS

Egy tömb sorait és oszlopait cseréli fel.

### Szintaxis

TRANSZPONÁLÁS(mátrix)

A mátrix a táblázatban található transzponálni kívánt mátrix.

A tömbfüggvényekről általános információkat talál az oldal tetején.

### Példa

A táblázatban jelölje ki azon tartományt, amelyben a transzponált mátrix megjelenhet. Ha az eredeti mátrix n sorból és m oszlopból áll, akkor a kijelölt tartománynak legalább m sorból, illetve n oszlopból kell állnia. Ezt követően adja meg közvetlenül a képletet, jelölje ki az eredeti területét, és nyomja meg a Shift+Command+EnterShift+Ctrl+Enter
billentyűket. Illetve, ha a Függvénytündért használja, jelölje be az Adattömb jelölőnégyzetet. A kijelölt céltartományban megjelenik a transzponált mátrix, amely automatikusan védett a módosítások ellen.

| A | B | C | D
1 | 2 | 3 | 4 | 5
2 | 6 | 7 | 8 | 9

The above table is 2 rows, 4 columns. In order to transpose it, you must select 4 rows, 2 columns. Assuming you want to transpose the above table to the range A7:B10 (4 rows, 2 columns) you must select the entire range and then enter the following:

TRANSPOSE(A1:D2)

Then make sure to enter it as matrix formula with Shift+Command+EnterShift+Ctrl+Enter
. The result will be as follows:

| A | B
7 | 2 | 6
8 | 3 | 7
9 | 4 | 8
10 | 5 | 9

## TREND

Egy lineáris trendnek megfelelő értékeket számít ki.

### Szintaxis

TREND(y_adatok; x_adatok; új_x_adatok; egyenes_típusa)

Az y_adatok az y adattömböt jelöli.

Az x_adatok (opcionális) az x adattömböt jelöli.

Az új_x_adatok (opcionális) azon X adatok tömbje, amelyek az értékek újraszámítása során kerülnek felhasználásra.

Az egyenes_típusa argumentum opcionális. Ha az egyenes_típusa = 0, akkor az origón áthaladó egyenesek lesznek kiszámítva. Ellenkező esetben az eltolt egyenesek is ki lesznek számítva. Az alapértelmezett esetben az egyenes_típusa <> 0.

In the LibreOffice Calc functions, parameters marked as "optional" can be left out only when no parameter follows. For example, in a function with four parameters, where the last two parameters are marked as "optional", you can leave out parameter 4 or parameters 3 and 4, but you cannot leave out parameter 3 alone.

More explanations on top of this page.

### Példa

Jelöljön ki egy táblázattartományt, amelyen belül a trendadatokat meg kívánja jeleníteni. Jelölje ki a függvényt. Adja meg a kimeneti adatokat, vagy jelölje ki azokat az egér segítségével. Jelölje meg a Tömb mezőt, és kattintson az OK gombra. Megjelenítésre kerülnek a kimeneti adatok alapján számított trendadatok.

Kapcsolódó témakörök

Függvények kategória szerint