Module
Enhavo
Indekso 🔎︎

# MkDir Statement

Kreas novan dosierujon ĉe datuma konservujo.

## Sintakso:

    MkDir Text As String

## Parametroj:

Text: Ĉena esprimo kiu specifas la nomon kaj vojprefiskon de la dosierujo kreota. Ankaŭ uzeblas URL-notacio.

Se la vojprefikso ne estas trovita, la dosierujo kreiĝos en la aktuala dosierujo.

## Error codes:

5 Nevalida procedurvoko

76 Path not found

## Ekzemplo:

    Sub ExampleFileIO
    ' Example for functions of the file organization
    Const sFile1 As String = "file://c|/autoexec.bat"
    Const sDir1 As String = "file://c|/Temp"
    Const sSubDir1 as String ="Test"
    Const sFile2 as String = "Copied.tmp"
    Const sFile3 as String = "Renamed.tmp"
    Dim sFile As String
        sFile = sDir1 + "/" + sSubDir1
        ChDir( sDir1 )
        If Dir(sSubDir1,16)="" then ' Ĉu la dosierujo ekzistas ?
            MkDir sSubDir1
            MsgBox sFile,0,"Krei dosierujon"
        End If
        sFile = sFile + "/" + sFile2
        FileCopy sFile1 , sFile
        MsgBox fSysURL(CurDir()),0,"Aktuala dosierujo"
        MsgBox sFile & Chr(13) & FileDateTime( sFile ),0,"Horo de kreo"
        MsgBox sFile & Chr(13)& FileLen( sFile ),0,"Longo de dosiero"
        MsgBox sFile & Chr(13)& GetAttr( sFile ),0,"Atributoj de dosiero"
        Name sFile As sDir1 + "/" + sSubDir1 + "/" + sFile3
        ' Renomi en la sama dosierujo
        sFile = sDir1 + "/" + sSubDir1 + "/" + sFile3
        SetAttr( sFile, 0 ) 'Delete all attributes
        MsgBox sFile & Chr(13) & GetAttr( sFile ),0,"Novaj atributoj de la dosiero"
        Kill sFile
        RmDir sDir1 + "/" + sSubDir1
    End Sub

    ' Konvertas sisteman vojprefikson al URL
    Function fSysURL( fSysFp As String ) As String
    Dim iPos As String
        iPos = 1
        iPos = Instr(iPos,fSysFp, getPathSeparator())
        Do While iPos > 0
            Mid( fSysFp, iPos , 1,"/")
            iPos = Instr(iPos+1,fSysFp, getPathSeparator())
        Loop
        ' the colon with DOS
        iPos = Instr(1,fSysFp,":")
        If iPos > 0 Then Mid( fSysFp, iPos , 1,"|")
        fSysURL = "file://" & fSysFp
    End Function