Modulua
Edukiak
Aurkibidea 🔎︎

# Gelaxka hutsen kudeaketa

Softwarearen bertsio zaharragoetan, gelaxka hutsak zenbakizko 0ra bihurtzera behartzen ziren zenbait testuingurutan. Salbuespena: =A1=0 eta =A1="" TRUE (egiazko) gisa ebaluatzen diren zuzeneko konparazioa, A1 hutsik badago. Huts-ezaugarria heredatu egiten da orain erabili arte, eta, beraz, =VLOOKUP(...)=0 eta =VLOOKUP(...)="" bi funtzioak TRUE gisa ebaluatzen dira, bilaketak gelaxka hutsa itzultzen badu.

Gelaxka huts baten erreferentzia soilak 0 gisa bistaratzen jarraituko du, baina aurrerantzean ez da halabeharrez zenbakizkoa motakoa izango, eta, beraz, erreferentzia-gelaxka daukaten konparazioek ere espero bezala funtzionatuko dute.

Hurrengo adibideetan, A1 gelaxkak zenbaki bat dauka, B1 hutsik dago, eta C1 gelaxkak B1 gelaxkaren erreferentzia dauka:

A1: 1 B1: <Empty> C1: =B1 (0 bistaratzen du)

=B1=0 => TRUE

=B1="" => TRUE

=C1=0 => TRUE

=C1="" => TRUE (lehenago FALSE zen)

=ISNUMBER(B1) => FALSE

=ISNUMBER(C1) => FALSE (lehenago TRUE zen)

=ISNUMBER(VLOOKUP(1;A1:C1;2)) => FALSE (B1)

=ISNUMBER(VLOOKUP(1;A1:C1;3)) => FALSE (C1, lehenago TRUE zen)

=ISTEXT(B1) => FALSE

=ISTEXT(C1) => FALSE

=ISTEXT(VLOOKUP(1;A1:C1;2)) => FALSE (B1, lehenago TRUE zen)

=ISTEXT(VLOOKUP(1;A1:C1;3)) => FALSE (C1)

=ISBLANK(B1) => TRUE

=ISBLANK(C1) => FALSE

=ISBLANK(VLOOKUP(1;A1:C1;2)) => TRUE (B1, lehenago FALSE zen)

=ISBLANK(VLOOKUP(1;A1:C1;3)) => FALSE (C1)

Note that Microsoft Excel behaves different and always returns a number as the result of a reference to an empty cell or a formula cell with the result of an empty cell. Adibidez:

A1: <Empty>

B1: =A1 => 0 bistaratzen du, baina gelaxka huts baten erreferentzia baino ez da

=ISNUMBER(A1) => FALSE

=ISTEXT(A1) => FALSE

=A1=0 => TRUE

=A1="" => TRUE

=ISNUMBER(B1) => FALSE (Microsoft Excel: TRUE)

=ISTEXT(B1) => FALSE

=B1=0 => TRUE

=B1="" => TRUE (Microsoft Excel: FALSE)

C1: =VLOOKUP(...) gelaxka hutseko emaitzarekin => hutsa bistaratzen du (Microsoft Excel: 0 bistaratzen du)

=ISNUMBER(VLOOKUP(...)) => FALSE

=ISTEXT(VLOOKUP(...)) => FALSE

=ISNUMBER(C1) => FALSE (Microsoft Excel: TRUE)

=ISTEXT(C1) => FALSE