Fonction REGEX

Contenu
Index 🔎︎

# REGEX

Recherche et extrait ou facultativement remplace le texte en utilisant des expressions régulières.

Cette fonction est disponible depuis LibreOffice 6.2

### Syntaxe

REGEX( Texte ; Expression [ ; [ Remplacement ] [ ; Drapeaux|Occurrence ] ] )

Texte : un texte ou une référence à une cellule auxquels l'expression régulière doit être appliquée.

Expression : un texte représentant l'expression régulière, utilisant les expressions régulières ICU. S'il n'y a pas de correspondance et si Remplacement n'est pas indiqué, #N/D est renvoyé.

Remplacement : facultatif. Le texte de remplacement et les références pour capturer les groupes. S'il n'y a pas de correspondances, le Texte est renvoyé sans modification.

Drapeaux : facultatif. "g" remplace toutes les correspondances de Expression dans Texte qui ne sont pas extraites. S'il n'y a pas de correspondances, le Texte est renvoyé sans modification.

Occurrence : facultatif. Un nombre pour indiquer quelle correspondance de Expression dans Texte doit être extraite ou remplacée. S'il n'y a pas de correspondance et si Remplacement n'est pas indiqué, #N/D est envoyé. S'il n'y a pas de correspondance et si Remplacement est indiqué, Texte est renvoyé non modifié. Si Occurrence vaut 0, Texte est renvoyé non modifié.

### Exemples

=REGEX("123456ABCDEF";"[:chiffre:]";"Z") renvoie "Z23456ABCDEF", où la première correspondance d'un chiffre est remplacée par "Z".

=REGEX("123456ABCDEF";"[:chiffre:]";"Z";"g") renvoie "ZZZZZZABCDEF", où tous les chiffres sont remplacés par "Z".

=REGEX("123456ABCDEF";"[126]";"";"g") renvoie "345ABCDEF", où chaque occurrence de "1", "2" ou "6" est remplacée par la chaîne vide et donc supprimée.

=REGEX("axbxcxd";".x";;2) renvoie "bx", la deuxième correspondance de ".x".

=REGEX("axbxcxd";"(.)x";"$1y";2) renvoie "axbycxd", la deuxième correspondance de "(.)x" (i.e. "bx") remplacée par le groupe capturé d'un caractère (c'est-à-dire "b") suivi par "y".

Rubriques connexes

Liste des expressions régulières

Expressions régulières ICU