Modulua
Edukiak
Aurkibidea 🔎︎

## COUNTIFS funtzioa

Barruti anitzetan irizpidea betetzen duten gelaxken kopurua ematen du.

### Sintaxia

COUNTIFS(Barrutia1; Irizpidea1 [; Barrutia2; Irizpidea2 [; ...]])

Barrutia1 (derrigorrezko argumentua). Gelaxka-barruti bat, izendatutako barruti baten izen bat, edo zutabe edo errenkada baten etiketa bat da, dagokion irizpidea zenbatzeko eta aurkitzeko erabiliko diren balioak dituena.

Irizpidea1 – derrigorrezko argumentua. Kate motako adierazpen bat, baldintza logiko bat edo kate-adierazpen horren gelaxka-erreferentzia bat ordezkatzen duena. Adierazpenak testua, zenbakiak, adierazpen erregularrak edo komodinak izan ditzake (kalkuluaren aukeretan gaituta badaude).

Barrutia2 – Aukerakoa. Barrutia2 eta hurrengoek Barrutia1 parametroaren esanahi bera dute.

Irizpidea2 – Aukerakoa. Irizpidea2 eta hurrengoek Irizpidea1 parametroaren esanahi bera dute.

Barrutia1, Barrutia2, ... eta Irizpidea1, Irizpidea2, ... parametroek tamaina bera izan behar dute, bestela funtzioak 'err:502 - Baliogabeko argumentua' errorea itzuliko du.

Irizpideen arteko erlazio logikoa AND logiko modura definitu daiteke. Alegia, emandako irizpide guztiak betetzen badira (eta soilik horrela bada), hartuko da kontuan kalkuluan emandako FuntzioBarrutia parametroari dagokion balio bat.

Funtzioak 255 argumentu arte izan ditzake; alegia, 127 irizpide-barruti eta irizpide zehaztu daitezke funtziorako.

Gelaxka batek TRUE (Egiazkoa) badu, 1 baliotzat hartzen du; FALSE (Gezurra) badu, 0 (zero) baliotzat.

Funtzio hori Open Document Format for Office Applications (OpenDocument) estandarraren 1.2 bertsioan (ISO/IEC 26300:2-2015) dago onartuta.

### Adibidea

#### Begiratu honako taula

| A | B | C
1 | Produktuaren izena | Salmentak | Diru-sarrerak
2 | arkatza | 20 | 65
3 | luma | 35 | 85
4 | koadernoa | 20 | 190
5 | liburua | 17 | 180
6 | arkatz-kutxa | ez | ez

Beheko adibide guztietan batuketa kalkulatzeko barrutiek #6 errenkada dute, baina hura ez ikusi egingo da testua duelako.

#### Erabilera sinplea

=COUNTIFS(B2:B6;">=20")

B2:B6 barrutian 20 balioaren berdina edo handiagoak diren balioak dituzten errenkaden kopuruazenbatzen du. 3 ematen du, bosgarren eta seigarren errenkadak ez dutelako irizpidea betetzen.

=COUNTIFS(B2:B6;">=20";C2:C6;">70")

Aldi berean C2:C6 barrutian 70 baino handiagoak diren balioak eta B2:B6 barrutian 20 baino handiagoak edo berdinak diren balioak dituzten errenkaden kopurua zenbatzen du. 2 ematen du, bigarren, bosgarren eta seigarren errenkadek ez dutelako betetzen gutxienez irizpide bat.

#### Adierazpen erregularrak eta habiaratutako funtzioak erabiltzea

=COUNTIFS(B2:B6;"[:alpha:]*")

B2:B6 barrutian alfabetoko ikurrak soilik dituzten errenkaden kopurua zenbatzen du. 1 ematen du, seigarren errenkadak soilik betetzen duelako irizpidea.

=COUNTIFS(B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

B2:B6 barrutiko errenkada kopurua zenbatzen du, barrutiko balio minimoa eta maximoa duten errenkadak kanpoan utzita. 2 ematen du, hirugarren, bosgarren eta seigarren errenkadek ez dutelako gutxienez irizpide bat betetzen.

=COUNTIFS(A2:A6;"pen.*";B2:B6;"<"&MAX(B2:B6))

A2:A6 barrutian "pen" katearekin hasten diren gelaxka guztiei, bai eta B2:B6 barrutiko gelaxka guztiei ere (maximoa salbu), dagozkien errenkada kopurua zenbatzen du. 1 ematen du, bigarren errenkadak soilik betetzen dituelako irizpide guztiak.

#### Irizpidetzat gelaxka baten erreferentzia erabiltzea

Irizpide bat erraz aldatu nahi baduzu, beste gelaxka batean zehaztu dezakezu eta gelaxka horren erreferentzia bat erabili COUNTIFS funtzioaren baldintzan. Adibidez, goiko funtzioa beste modu honetan idatzi daiteke:

=COUNTIFS(A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

E2 = pen bada, funtzioak 1 ematen du, gelaxkarako esteka bere edukiarekin ordezkatuko delako eta aurreko funtzioak bezala funtzionatuko duelako.

Inguruko gaiak

COUNT, COUNTIF, COUNTBLANK, COUNTA

COUNTIFS, MINIFS, MAXIFS, AVERAGEIFS, SUMIFS

Adierazpen erregularren zerrenda