Módulo
Contenido
Índice 🔎︎

# Funciones matriciales

Esta categoría contiene las funciones matriciales.

## ¿Qué es una matriz?

Una matriz es un intervalo de celdas enlazado de una hoja de cálculo, cuyas celdas contienen valores. Un intervalo cuadrado de 3 filas y 3 columnas es una matriz de 3 × 3:

| A | B | C
1 | 7 | 31 | 33
2 | 95 | 17 | 2
3 | 5 | 10 | 50

La mínima matriz posible son dos celdas adyacentes, 1 x 2 o 2 x 1.

## ¿Qué es una fórmula matricial?

Se denomina fórmula matricial la que permite evaluar los valores individuales de un intervalo de celdas. La diferencia entre una fórmula matricial y otro tipo de fórmula es que aquella no emplea un único valor, sino varios valores simultáneamente.

Una fórmula matricial no solo puede procesar varios valores, sino también devolver varios resultados. El resultado de una fórmula matricial también es una matriz.

To multiply the values in the individual cells by 10 in the above array, you do not need to apply a formula to each individual cell or value. Instead you just need to use a single array formula. Select a range of 3 x 3 cells on another part of the spreadsheet, enter the formula =10*A1:C3 and confirm this entry using the key combination CommandCtrl + Shift + Enter. The result is a 3 x 3 array in which the individual values in the cell range (A1:C3) are multiplied by a factor of 10.

Se pueden utilizar otros operadores, aparte de la multiplicación, en el intervalo (matriz) de referencia. LibreOffice Calc permite sumar (+), restar (-), multiplicar (*), dividir (/), elevar a potencias (^), concatenar (&) y comparar (=, <>, <, >, <=, >=). Los operadores se pueden utilizar en cada uno de los valores individuales del intervalo de celdas; devuelven el resultado en forma de matriz, si la fórmula se ha escrito como fórmula matricial.

Los operadores de comparación de una fórmula matricial tratan las celdas vacías de la misma manera que en una fórmula normal, es decir, como un cero o como una cadena vacía. Por ejemplo, si las celdas A1 y A2 están vacías, las fórmulas matriciales {=A1:A2=""} y {=A1:A2=0} devolverán una matriz de una columna y dos líneas que contendrá el valor VERDADERO.

### ¿Cuándo se deben utilizar fórmulas matriciales?

Utilice fórmulas matriciales si debe repetir los mismos cálculos con valores distintos. Si más adelante decide cambiar el método de cálculo, solo deberá modificar la fórmula matricial. Para añadir una fórmula matricial, seleccione toda la matriz y realice los cambios necesarios en la fórmula matricial.

Las fórmulas matriciales también permiten ahorrar espacio cuando se deben calcular muchos valores, ya que utilizan una cantidad reducida de memoria. Asimismo, las matrices son una herramienta fundamental para llevar a cabo cálculos complejos, ya que permiten incluir varios intervalos de celdas en los cálculos. LibreOffice dispone de diversas funciones matemáticas para matrices, como la función MMULT para multiplicar dos matrices o SUMA.PRODUCTO para calcular el producto escalar de dos matrices.

## Usar fórmulas matriciales en LibreOffice Calc

También se puede crear una fórmula «normal» cuyo intervalo de referencia, como los parámetros, indique una fórmula matricial. El resultado se obtiene a partir de la intersección del intervalo de referencia y de las filas o columnas en las que se encuentra la fórmula. Si no hay intersección o si el intervalo de la intersección abarca varias filas o columnas se mostrará un mensaje de error #¡VALOR! En el ejemplo siguiente se ilustra este concepto:

### Crear fórmulas matriciales

Para crear una fórmula matricial mediante el Asistente de funciones, deberá seleccionar la casilla de verificación Matriz para que los resultados se devuelvan en una matriz. En caso contrario, solo se devolverá el valor correspondiente a la celda superior izquierda de la matriz.

If you enter the array formula directly into the cell, you must use the key combination Shift + CommandCtrl + Enter instead of the Enter key. Only then does the formula become an array formula.

Las fórmulas matriciales se muestran en LibreOffice Calc entre llaves. No es posible crear fórmulas matriciales escribiendo las llaves manualmente.

Las celdas de una matriz de resultados están automáticamente protegidas contra modificaciones. No obstante, puede editar o copiar la fórmula matricial si selecciona todo el intervalo de celdas de la matriz.

### Usar constantes de matrices insertadas en fórmulas

Calc permite insertar constantes matriciales en las fórmulas. Las matrices insertadas en una fórmula aparecen entre llaves: { }. Cada uno de sus elementos puede ser un número (incluidos los negativos), una constante lógica (VERDADERO, FALSO), o bien, una cadena de caracteres. No se permiten expresiones no constantes. Las matrices pueden introducirse con más de una fila y más de una columnas. Todas las filas y todas las columnas deben tener la misma cantidad de elementos.

El separador de columnas (que separa elementos en una fila) y el separador de filas dependen de la región y el idioma. Mas en esta ayuda, se utilizarán el punto y coma (;) y la barra vertical (|) para indicar los separadores de columnas y filas, respectivamente. Por ejemplo, en inglés se utiliza la coma (,) como separador de columnas y el punto y coma (;) como separador de filas.

Es posible ver y modificar el separador de filas y columnas en LibreOffice ▸ PreferenciasHerramientas ▸ Opciones ▸ Calc ▸ Fórmula ▸ Separadores.

No se pueden anidar las matrices.

Ejemplo:

={1;2;3}

Una matriz de una fila que consiste de tres números: 1, 2 y 3.

To enter this array constant, you select three cells in a row, then you type the formula ={1;2;3} using the curly braces and the semicolons, then press CommandCtrl + Shift + Enter.

={1;2;3|4;5;6}

Un matriz con dos filas y tres valores en cada fila.

={0;1;2|FALSE;TRUE;"dos"}

Un matriz con datos mixtos.

=SIN({1;2;3})

Introducida como fórmula matricial, devuelve el resultado de tres cálculos SEN con los argumentos 1, 2 y 3.

### Editar fórmulas matriciales

1. Select the cell range or array containing the array formula. To select the whole array, position the cell cursor inside the array range, then press CommandCtrl + /, where / is the Division key on the numeric keypad.

2. Either press F2 or position the cursor in the input line. Both of these actions let you edit the formula.

3. After you have made changes, press CommandCtrl + Shift + Enter.

Se pueden formatear las distintas partes de una matriz. Se puede, por ejemplo, cambiar el color del tipo de letra. Seleccione un área de celdas y cambie el atributo que desee.

### Copiar fórmulas matriciales

1. Seleccione el intervalo de celdas o la matriz que contenga la fórmula matricial.

2. Either press F2 or position the cursor in the input line.

3. Copy the formula into the input line by pressing CommandCtrl + C.

4. Select a range of cells where you want to insert the array formula and either press F2 or position the cursor in the input line.

5. Paste the formula by pressing CommandCtrl + V in the selected space and confirm it by pressing CommandCtrl + Shift + Enter. The selected range now contains the array formula.

### Ajustar un intervalo matricial

Para editar la matriz de salida, siga este procedimiento:

1. Seleccione el intervalo de celdas o la matriz que contenga la fórmula matricial.

2. Bajo la selección, a la derecha, verá un pequeño icono que permite ampliar o reducir el intervalo utilizando el ratón.

Cuando el usuario ajusta el intervalo de la matriz, la fórmula no se ajusta automáticamente. Solo se modifica el intervalo en el que aparece el resultado.

By holding down the CommandCtrl key, you can create a copy of the array formula in the given range.

### Cálculos de matriz condicional

Un cálculo de matriz condicional es una fórmula matricial que incluye una función SI() o ELEGIR(). El argumento de condición de la fórmula es una referencia de área o un resultado de matriz.

En el ejemplo siguiente, la prueba >0 de la fórmula {=SI(A1:A3>0;"sí";"no")} se aplica a cada celda del área A1:A3 y el resultado se copia en la celda correspondiente.

| A | B (fórmula) | B (resultado)
1 | 1 | {=SI(A1:A3>0;"sí";"no")} | sí
2 | 0 | {=SI(A1:A3>0;"sí";"no")} | no
3 | 1 | {=SI(A1:A3>0;"sí";"no")} | sí

Las funciones siguientes permiten la gestión de matrices forzada: COEF.DE.CORREL, COVAR, PRONOSTICO, PRUEBA.F, INTERSECCION.EJE, MDETERM, MINVERSA, MMULT, MODA, PEARSON, PROBABILIDAD, COEFICIENTE.R2, PENDIENTE, ERROR.TIPICO.XY, SUMA.PRODUCTO, SUMAX2MENOSY2, SUMAX2MASY2, SUMAXMENOSY2 y PRUEBA.T. Si usa referencias de áreas como argumentos al utilizar una de estas funciones, las funciones actúan como funciones matriciales. En la tabla siguiente se muestra un ejemplo de gestión de matrices forzada:

| A | B (fórmula) | B (resultado) | C (fórmula matricial forzada) | C (resultado)
1 | 1 | =A1:A2+1 | 2 | =SUMA.PRODUCTO(A1:A2+1) | 5
2 | 2 | =A1:A2+1 | 3 | =SUMA.PRODUCTO(A1:A2+1) | 5
3 |  | =A1:A2+1 | #¡VALOR! | =SUMA.PRODUCTO(A1:A2+1) | 5

## CRECIMIENTO

Calcula los puntos de una tendencia exponencial en una matriz.

### Sintaxis

CRECIMIENTO(DatosY; DatosX; NuevosDatosX; TipodeFunción)

DatosY representa la matriz de datos Y.

DatosX (opcional) representa la matriz de datos X.

NuevosDatosX (opcional) representa la matriz de datosX, en los cuales se recalculan.

FunctionType (optional). If FunctionType = 0, functions in the form y = m^x will be calculated. Otherwise, y = b*m^x functions will be calculated.

En las funciones de LibreOffice Calc, los parámetros marcados como «opcionales» pueden omitirse siempre y cuando no haya ningún parámetro inmediatamente después. Por ejemplo, en una función de cuatro parámetros cuyos dos últimos están marcados como «opcionales», puede omitirse el parámetro 4 o los parámetros 3 y 4; sin embargo, no se puede omitir solamente el parámetro 3.

Encontrará más información al principio de la página.

### Ejemplo

This function returns an array and is handled in the same way as the other array functions. Select a range where you want the answers to appear and select the function. Select DataY. Enter any other parameters, mark Array and click OK.

## ESTIMACION.LINEAL

Devuelve una tabla de estadísticas para una línea recta que mejor se ajusta a un conjunto de datos.

### Sintaxis

ESTIMACION.LINEAL(Datos_Y; Datos_X; tipo_lineal; estadísticas)

Datos_Y es un intervalo que comprende una sola fila o columna y que especifica las coordenadas de Y en un conjunto de puntos de datos.

Datos_X corresponde a un rango de una fila o columna que especifica las coordenadas X. Si se omite Datos_X, los valores predeterminados son 1, 2, 3, ..., n. Si existe mas de un grupo de variables Datos_X puede ser un rango correspondiente a multiples filas o columnas.

ESTIMACION.LINEAL encuentra la recta y = a + bx que mejor se ajusta a los datos mediante una regresión lineal (el método «mínimos cuadrados»). Con más de un grupo de variables la recta asume la forma y = a + b1x1 + b2x2 … + bnxn.

Si el parámetro tipo_lineal es FALSO, la recta encontrada es forzada a pasar por el origen, dado que la constante «a» será cero (y = bx). Si se omite, tipo_lineal se predetermina a VERDADERO (la recta no necesariamente pasará por el origen).

Si se omite estadísticas o es FALSO, solamente se devuelve la fila superior de la tabla de estadísticas. Si este parámetro es VERDADERO, se devuelve la tabla entera.

LINEST returns a table (array) of statistics as below and must be entered as an array formula (for example by using CommandCtrl + Shift + Return rather than just Return).

En las funciones de LibreOffice Calc, los parámetros marcados como «opcionales» pueden omitirse siempre y cuando no haya ningún parámetro inmediatamente después. Por ejemplo, en una función de cuatro parámetros cuyos dos últimos están marcados como «opcionales», puede omitirse el parámetro 4 o los parámetros 3 y 4; sin embargo, no se puede omitir solamente el parámetro 3.

Encontrará más información al principio de la página.

### Ejemplo

Esta función devuelve una matriz y se manipula de la misma manera que otras funciones matriciales. Seleccione un intervalo donde quiera que aparezca la respuesta y seleccione la función. Seleccione datos_Y. Si lo desea, añada otros parámetros. Active la casilla Matriz y pulse en Aceptar.

Los resultados devueltos por el sistema (si Estadística = 0), mostraran, al menos, la pendiente de la línea de regresión y su intersección con el eje Y. Si Estadística no es igual a 0, se mostrarán otros resultados.

### Otros resultados de ESTIMACION.LINEAL:

Examine los ejemplos siguientes:

| A | B | C | D | E | F | G
1 | x1 | x2 | y |  | Valor de ESTIMACION.LINEAL |  |
2 | 4 | 7 | 100 |  | 4,17 | -3,48 | 82,33
3 | 5 | 9 | 105 |  | 5,46 | 10,96 | 9,35
4 | 6 | 11 | 104 |  | 0,87 | 5,06 | #ND
5 | 7 | 12 | 108 |  | 13,21 | 4 | #ND
6 | 8 | 15 | 111 |  | 675,45 | 102,26 | #ND
7 | 9 | 17 | 120 |  |  |  |
8 | 10 | 19 | 133 |  |  |  |

La columna A contiene diversos valores de X1, la columna B diversos valores de X2 y la columna C, los valores Y. Estos valores ya están en la hoja de cálculo. Ha configurado el intervalo E2:G6 en la hoja de cálculo y ha abierto el Asistente de funciones. Para que la función ESTIMACION.LINEAL funcione, deberá seleccionar la casilla de verificación Matriz en el Asistente de funciones. A continuación seleccione los siguientes valores en la hoja de cálculo (o escríbalos con el teclado):

Datos_Y están en C2:C8

Datos_X están en A2:B8

tipo_lineal y estadística están fijadas a 1.

Cuando pulse en Aceptar, LibreOffice Calc rellenará el ejemplo anterior con los valores de ESTIMACION.LINEAL, como se muestra en el ejemplo.

The formula in the Formula bar corresponds to each cell of the LINEST array {=LINEST(C2:C8;A2:B8;1;1)}.

Los valores calculados por ESTIMACION.LINEAL se representan así:

E2 Y F2: La Pendiente m de la línea de regresión y=b+m*x para los valores x1 y x2. Los valores se dan en orden inverso; es decir, la pendiente de x2 en E2 y la pendiente de x1 en F2.

G2: Intersección de b con el eje y.

E3 y F3: El error estándar del valor de la pendiente.

G3: El error estándar de la intersección

E4: COEFICIENTE.R2

F4: El error estándar de la regresión calculada para el valor Y.

E5: El valor F del análisis de varianza.

F5: Los grados de libertad del análisis de varianza.

E6: La suma de la desviación cuadrada de los valores Y estimados de su media lineal.

F6: La suma de la desviación cuadrada de los valores Y estimados de los valores Y especificados.

Encontrará más información al principio de la página.

## ESTIMACION.LOGARITMICA

Esta función calcula el ajuste de los datos introducidos como curva de regresión exponencial (y=b*m^x).

### Sintaxis

ESTIMACION.LOGARITMICA(DatosY; DatosX; TipoDeFunción; Estadísticas)

DatosY representa la matriz de datos Y.

DatosX (opcional) representa la matriz de datos X.

TipodeFunción (opcional). Si Tipo_de_Función = 0, se calcularán las funciones de la forma y = m^x . De lo contrario, se calcularán las funciones y = b*m^x.

Estadística (opcional). Si Estadística=0, sólo se calcula el coeficiente de regresión.

En las funciones de LibreOffice Calc, los parámetros marcados como «opcionales» pueden omitirse siempre y cuando no haya ningún parámetro inmediatamente después. Por ejemplo, en una función de cuatro parámetros cuyos dos últimos están marcados como «opcionales», puede omitirse el parámetro 4 o los parámetros 3 y 4; sin embargo, no se puede omitir solamente el parámetro 3.

Encontrará más información al principio de la página.

### Ejemplo

Consulte ESTIMACION.LINEAL. Con todo, no se devolverá ninguna suma cuadrada.

## FRECUENCIA

Indicates the frequency distribution in a one-column-array. The function counts the number of values in the Data array that are within the values given by the Classes array.

### Sintaxis

FRECUENCIA(Datos; Clases)

Datos representa la referencia de los valores que se debe contar.

Clases representa la matriz que contiene los valores de límite.

Al principio de esta página se incluye información general sobre las funciones matriciales.

### Ejemplo

En la tabla siguiente, la columna A muestra valores de medida sin ordenar. La columna B contiene el límite superior que introdujo para las clases cuyos datos quiere dividir en la columna A. Según el límite que haya especificado en B1, la función FRECUENCIA devuelve el número de valores medidos menores que o iguales a 5. Como el límite de B2 es 10, la función FRECUENCIA devuelve el segundo resultado como el número de valores medidos mayores que 5 y menores que o iguales a 10. El texto que introdujo en B6, «>25», se utiliza solo como una referencia.

| A | B | C
1 | 12 | 5 | 1
2 | 8 | 10 | 3
3 | 24 | 15 | 2
4 | 11 | 20 | 3
5 | 5 | 25 | 1
6 | 20 | >25 | 1
7 | 16 |  |
8 | 9 |  |
9 | 7 |  |
10 | 16 |  |
11 | 33 |  |

Seleccione un intervalo de una sola columna donde introducir la frecuencia según los límites de la clase. Debe seleccionar un campo más que el campo superior de la clase. En este ejemplo, seleccione el intervalo C1:C6. Active la función FRECUENCIA mediante el Asistente de funciones. Seleccione el intervalo Datos en (A1:A11) y, a continuación, el intervalo Clases en el que haya introducido los límites de la clase (B1:B6). Active la casilla Matriz y pulse en Aceptar. Aparecerá el conteo de la frecuencia en el intervalo C1:C6.

Encontrará más información al principio de la página.

## MDETERM

Devuelve el determinante de una matriz. Esta función devuelve un valor en la celda actual; no es necesario definir un área de resultados.

### Sintaxis

MDETERM(Matriz)

Matriz representa una matriz cuadrada cuyo determinante se debe calcular.

Al principio de esta página se incluye información general sobre el uso de las funciones matriciales.

Encontrará más información al principio de la página.

## MINVERSA

Devuelve la matriz inversa.

### Sintaxis

MINVERSA(Matriz)

Matriz representa la matriz cuadrada que se debe invertir.

Encontrará más información al principio de la página.

### Ejemplo

Seleccione un área cuadrada y a continuación MINVERSA. Seleccione la matriz de salida y el campo Matriz; a continuación, haga clic en Aceptar.

## MMULT

Calcula la matriz producto de dos matrices. El número de columnas de la matriz 1 debe coincidir con el número de filas de la matriz 2. La matriz cuadrada tiene el mismo número de filas y de columnas.

### Sintaxis

MMULT(Matriz; Matriz)

La primera Matriz representa la primera matriz del producto.

La segunda Matriz representa la segunda matriz del producto, con el mismo número de filas.

Encontrará más información al principio de la página.

### Ejemplo

Seleccione un intervalo cuadrado. Elija la función MMULT. Seleccione la primera Matriz y, a continuación, la segunda Matriz. Marque la casilla de verificación Matriz en el Asistente para funciones. Pulse en Aceptar. La matriz de salida aparecerá en el intervalo seleccionado.

## MUNITARIA

Devuelve una matriz cuadrada unitaria de un tamaño determinado. La matriz unitaria es una matriz cuadrada en la que los elementos de la diagonal son iguales a 1 y el resto de los elementos iguales a 0.

### Sintaxis

MUNITARIA(Dimensión)

Dimensión hace referencia al tamaño de la matriz unitaria.

Al principio de esta página se incluye información general sobre las funciones matriciales.

### Ejemplo

Seleccione un área cuadrada de la hoja de cálculo, por ejemplo, de A1 a E5.

Sin deseleccionar el intervalo, seleccione la función MUNITARIA. Active la casilla Matriz. Digite las dimensiones que deba tener la unidad matricial, en este caso 5, y pulse en Aceptar.

You can also enter the =MUNIT(5) formula in the last cell of the selected range (E5), and press Shift + Command + EnterShift + Ctrl + Enter.

Se insertará una matriz unitaria en el área A1:E5.

Encontrará más información al principio de la página.

## SUMA.PRODUCTO

Multiplica los elementos correspondientes en las matrices especificadas, y calcula la suma de dichos productos.

### Sintaxis

SUMPRODUCT(Array1; Array2; ...; Array30)

Array1, Array2; ...; Array30 represent arrays whose corresponding elements are to be multiplied.

La lista de argumentos debe contener una matriz como mínimo. Si solo se proporciona una matriz, se suman todos los elementos de la matriz.

### Ejemplo

| A | B | C | D
1 | 2 | 3 | 4 | 5
2 | 6 | 7 | 8 | 9
3 | 10 | 11 | 12 | 13

=SUMA.PRODUCTO(A1:B3;C1:D3) devuelve 397.

Cálculo: A1*C1 + B1*D1 + A2*C2 + B2*D2 + A3*C3 + B3*D3

Puede utilizar la función SUMPRODUCT para calcular el producto escalar de dos vectores.

SUMA.PRODUCTO devuelve un único número; no es necesario introducir la función como una función matricial.

Encontrará más información al principio de la página.

## SUMAX2MASY2

Calcula la suma de los cuadrados de los valores correspondientes en dos matrices.

### Sintaxis

SUMAX2MASY2(MatrizX; MatrizY)

MatrizX representa la primera matriz cuyos elementos deben sumarse y elevarse al cuadrado.

MatrizY representa la segunda matriz, cuyos elementos deben sumarse y elevarse al cuadrado.

Encontrará más información al principio de la página.

## SUMAX2MENOSY2

Calcula la suma de la diferencia de los cuadrados de los valores correspondientes en dos matrices.

### Sintaxis

SUMX2MENOSY2(MatrizX; MatrizY)

MatrizX representa la primera matriz cuyos elementos deben sumarse y elevarse al cuadrado.

MatrizY representa la segunda matriz cuyos elementos deben restarse y elevarse al cuadrado.

Encontrará más información al principio de la página.

## SUMAXMENOSY2

Suma los cuadrados de la varianza entre los valores correspondientes en dos matrices.

### Sintaxis

SUMAXMENOSY2(MatrizX; MatrizY)

MatrizX representa la primera matriz cuyos elementos deben restarse y elevarse al cuadrado.

MatrizY representa la segunda matriz cuyos elementos deben restarse y elevarse al cuadrado.

Encontrará más información al principio de la página.

## TENDENCIA

Devuelve valores siguiendo una tendencia lineal.

### Sintaxis

TENDENCIA(DatosY; DatosX; NuevosDatosX; TipodeLínea)

DatosY representa la matriz de datos Y.

DatosX (opcional) representa la matriz de datos X.

NuevosDatosX (opcional) representa las matriz de los datos X, los cuales son usados para recalcular los valores.

LinearType (optional). If LinearType = 0, then lines will be calculated through the zero point. Otherwise, offset lines will also be calculated. The default is LinearType <> 0.

En las funciones de LibreOffice Calc, los parámetros marcados como «opcionales» pueden omitirse siempre y cuando no haya ningún parámetro inmediatamente después. Por ejemplo, en una función de cuatro parámetros cuyos dos últimos están marcados como «opcionales», puede omitirse el parámetro 4 o los parámetros 3 y 4; sin embargo, no se puede omitir solamente el parámetro 3.

Encontrará más información al principio de la página.

### Ejemplo

Select a spreadsheet range in which the trend data will appear. Select the function. Enter the output data or select it with the mouse. Mark the Array field, click OK. The trend data calculated from the output data is displayed.

## TRANSPONER

Transpone las filas y las columnas de una matriz.

### Sintaxis

TRANSPONER(Matriz)

Matriz representa la matriz de la hoja de cálculo que se debe transponer.

Al principio de esta página se incluye información general sobre el uso de las funciones matriciales.

### Ejemplo

In the spreadsheet, select the range in which the transposed array can appear. If the original array has n rows and m columns, your selected range must have at least m rows and n columns. Then enter the formula directly, select the original array and press Shift + Command + EnterShift + Ctrl + Enter. Or, if you are using the Function Wizard, mark the Array check box. The transposed array appears in the selected target range and is protected automatically against changes.

| A | B | C | D
1 | 2 | 3 | 4 | 5
2 | 6 | 7 | 8 | 9

La tabla anterior posee dos filas y cuatro columnas. Para transponerla, debe seleccionar cuatro filas y dos columnas. Suponiendo que quiere transponer la tabla anterior en el intervalo A7:B10 (cuatro filas y dos columnas), debe seleccionar todo el intervalo y, a continuación, escribir lo siguiente:

TRANSPONER(A1:D2)

Then make sure to enter it as matrix formula with Shift + Command + EnterShift + Ctrl + Enter. The result will be as follows:

| A | B
7 | 2 | 6
8 | 3 | 7
9 | 4 | 8
10 | 5 | 9

Temas relacionados

Funciones por categoría