Módulo
Conteúdo
Índice 🔎︎

# Funções financeiras - Parte 1

Esta categoria contém as funções financeiras do LibreOffice Calc.

## AMORDEGRC

Devolve a depreciação em linha reta para cada período contabilístico. Ao contrário de AMORLINC, aqui é utilizado um coeficiente de depreciação independente da vida depreciável.

### Sintaxe

AMORDEGRC(custo; data_aquisição; primeiro_período; valor_residual; período; taxa; base)

custo é o custo do ativo.

data_aquisição é a data em que o ativo foi comprado.

primeiro_período é a data do final do primeiro período.

valor_residual é o valor de recuperação no final da vida do ativo.

período é o período de depreciação do ativo.

taxa é a taxa de depreciação.

base (opcional) é base de cálculo e indica o método de cálculo do ano.

base | Cálculo
0 or missing | Método norte americano (NASD), 12 meses de 30 dias cada
1 | Número exato de dias nos meses, número exato de dias no ano
2 | Número exato de dias no mês, o ano tem 360 dias
3 | Número exato de dias no mês, o ano tem 365 dias
4 | Método europeu, 12 meses de 30 dias cada

## AMORLINC

Devolve a depreciação para cada período contabilístico. Se o ativo for adquirido durante o período de liquidação, será considerada uma quantidade proporcional de depreciação.

### Sintaxe

AMORLINC(custo; data_aquisição; primeiro_período; valor_residual; período; taxa; base)

custo é o custo do ativo.

data_aquisição é a data em que o ativo foi comprado.

primeiro_período é a data do final do primeiro período.

valor_residual é o valor de recuperação no final da vida do ativo.

período é o período de depreciação do ativo.

taxa é a taxa de depreciação.

base (opcional) é base de cálculo e indica o método de cálculo do ano.

base | Cálculo
0 or missing | Método norte americano (NASD), 12 meses de 30 dias cada
1 | Número exato de dias nos meses, número exato de dias no ano
2 | Número exato de dias no mês, o ano tem 360 dias
3 | Número exato de dias no mês, o ano tem 365 dias
4 | Método europeu, 12 meses de 30 dias cada

## AMORTD

Devolve a depreciação de um ativo utilizando o método da soma dos dígitos.

Utilize esta função para calcular a depreciação para um período em relação ao período total de depreciação de um ativo. A depreciação ao método da soma dos dígitos reduz a quantidade da depreciação de período a período por uma quantia fixa.

### Sintaxe

AMORTD(custo; valor_residual; vida; período)

custo é o custo inicial do ativo.

valor_residual é o valor do ativo após a depreciação.

vida_útil é o número de períodos em que o ativo é depreciado.

período é o período de depreciação do ativo e tem de utilizar as mesmas unidades de vida_útil.

### Exemplo

Um sistema de vídeo que custe inicialmente 50000 unidades monetárias deve ser depreciado durante 5 anos. O valor residual é de 10000 unidades monetárias. Pretende-se calcular a depreciação do primeiro ano.

=AMORTD(50000;10000;5;1)=13 333,33. A depreciação no primeiro ano é de 13 333,33 unidades monetárias.

Para obter um resumo das taxas de depreciação por período, deve definir uma tabela de depreciação. Se inserir as várias fórmulas de depreciação disponíveis no LibreOffice Calc, umas ao lado de outras, será possível ver qual a fórmula de depreciação mais apropriada. Introduza a seguinte tabela:

| A | B | C | D | E
1 | custo | valor_residual | vida_útil | período | Deprec. AMORTD
2 | 50 000 unidades monetárias | 10 000 unidades monetárias | 5 | 1 | 13 333,33 unidades monetárias
3 |  |  |  | 2 | 10 666,67 unidades monetárias
4 |  |  |  | 3 | 8000 unidades monetárias
5 |  |  |  | 4 | 5333,33 unidades monetárias
6 |  |  |  | 5 | 2666,67 unidades monetárias
7 |  |  |  | 6 | 0,00 unidades monetárias
8 |  |  |  | 7 |
9 |  |  |  | 8 |
10 |  |  |  | 9 |
11 |  |  |  | 10 |
12 |  |  |  |  |
13 | >0 |  |  | Total | 40 000 unidades monetárias

A fórmula na célula E2 é:

=AMORTD($A$2;$B$2;$C$2;D2)

Esta fórmula é duplicada na coluna E até E11 (selecione E2 e arraste para baixo com o rato).

A célula E13 contém a fórmula utilizada na verificação do total das quantias de depreciação. Utiliza a função SOMA.SE, uma vez que os valores negativos do intervalo E8:E11 não devem ser considerados. A condição >0 está incluída na célula A13. A fórmula em E13 é:

=SOMA.SE(E2:E11;A13)

Agora é possível ver a depreciação para um período de 10 anos ou com um valor residual de 1 unidade monetária, ou inserir um custo inicial diferente, e assim sucessivamente.

## BD

Devolve a depreciação de um ativo relativa a um período especificado utilizando o método das quotas degressivas fixas.

Esta forma de depreciação é utilizada para obter um valor de depreciação mais elevado no início da depreciação (em detrimento da depreciação linear). O valor de depreciação é reduzido em cada período de depreciação pela depreciação já deduzida do custo inicial.

### Sintaxe

BD(custo; valor_residual; vida; período; mês)

custo é o custo inicial do ativo.

valor_residual é o valor de um ativo no final da depreciação.

vida_útil é o número de períodos em que o ativo é depreciado.

período é o período de depreciação do ativo e tem de utilizar as mesmas unidades de vida_útil.

mês (opcional) é o número de meses do primeiro ano de depreciação. Se não for definida uma entrada, serão utilizado 12 meses.

### Exemplo

Um sistema informático com um custo inicial de 25 000 unidades monetárias deve ser depreciado ao longo de um período de três anos. O valor residual é 1000 unidades monetárias. Um período corresponde a 30 dias.

=BD(25000;1000;36;1;6) = 1075,00

A depreciação do sistema informático é de 1075,00 unidades monetárias.

## BDD

Devolve a depreciação de um bem para um determinado período, utilizando o método de redução dupla do saldo ou qualquer outro método especificado.

Utilize esta forma de depreciação para obter um valor de depreciação inicial mais alto, em detrimento da depreciação linear. O valor de depreciação diminui em cada período e é normalmente utilizado em ativos cuja perda de valor é superior nos primeiros anos de vida útil (por exemplo, veículos, computadores). Tenha em conta que o valor contabilístico nunca atinge zero com este tipo de cálculo.

### Sintaxe

BDD(custo; valor_residual; vida_útil; período; fator)

custo é o custo inicial do ativo.

valor_residual é o valor de um ativo no fim da sua vida útil.

vida_útil é o número de períodos em que o ativo é depreciado.

período é o período de depreciação do ativo e tem de utilizar as mesmas unidades de vida_útil.

fator (opcional) é o índice de redução do saldo. Se não for introduzir um valor, o fator padrão é 2.

### Exemplo

Um sistema informático com um custo inicial de 75 000 unidades monetárias será depreciado mensalmente durante 5 anos. O valor residual do ativo deverá ser 1 unidade monetária. O fator é 2.

=BDD(75000;1;60;12;2) = 1721,81. Assim, a depreciação de desvalorização dupla no décimo segundo mês após a aquisição é de 1721,81 unidades monetárias.

## DESC

Devolve a taxa de desconto de um título.

### Sintaxe

DESC(liquidação; vencimento; preço; reembolso; base)

liquidação é a data de liquidação do título.

vencimento é a data de vencimento (maturidade) do título.

preço é o preço do título por 100 unidades do valor nominal.

reembolsoé o valor de reembolso do título por 100 unidades de valor nominal.

base (opcional) é base de cálculo e indica o método de cálculo do ano.

base | Cálculo
0 or missing | Método norte americano (NASD), 12 meses de 30 dias cada
1 | Número exato de dias nos meses, número exato de dias no ano
2 | Número exato de dias no mês, o ano tem 360 dias
3 | Número exato de dias no mês, o ano tem 365 dias
4 | Método europeu, 12 meses de 30 dias cada

### Exemplo

Um título foi comprado a 2001-01-25. A data de vencimento é 2001-11-15. O preço (de compra) é 97 e o valor de reembolso é 100. Utilizando a base de cálculo diária (base 3), qual será o valor de desconto?

=DESC("2001-01-25";"2001-11-15";97;100;3) devolve aproximadamente 0,0372 ou 3,72 por cento.

## DURAÇÃO_ADD

Devolve a duração anual de Macaulay de um título com pagamentos periódicos.

As funções cujo nome terminem com _ADD ou _EXCEL2003 devolvem o mesmo resultado que as funções correspondentes do Microsoft Excel 2003 que não possuem o sufixo. Utilize as funções sem o sufixo para obter os resultados baseados em padrões internacionais.

### Sintaxe

DURAÇÃO_ADD(liquidação; vencimento; cupão; lucro; frequência; base)

liquidação é a data de liquidação do título.

vencimento é a data de vencimento (maturidade) do título.

cupão é a taxa de juro anual do título.

lucro é o lucro anual do título.

frequência é o número de pagamentos de cupões por ano. Para pagamentos anuais, frequência = 1; para semestrais, frequência = 2; para trimestrais, frequência = 4.

base (opcional) é base de cálculo e indica o método de cálculo do ano.

base | Cálculo
0 or missing | Método norte americano (NASD), 12 meses de 30 dias cada
1 | Número exato de dias nos meses, número exato de dias no ano
2 | Número exato de dias no mês, o ano tem 360 dias
3 | Número exato de dias no mês, o ano tem 365 dias
4 | Método europeu, 12 meses de 30 dias cada

### Exemplo

Um título foi adquirido a 2001-01-01. A data de vencimento é 2006-01-01. A taxa de juro de cupão é 8%. O lucro é 9%. Os juros são pagos semestralmente (a frequência é 2). Utilizando a base de cálculo diária (base 3), qual será a duração?

=DURAÇÃO_ADD("2001-01-01";"2006-01-01";0,08;0,09;2;3)

## EFETIVA

Devolve a taxa de juro anual efetiva, dada a taxa de juro nominal anual e o número de períodos compostos por ano.

O juro nominal corresponde ao juro que deve ser pago no final de um período de cálculo. O juro efetivo aumenta consoante o número de pagamentos feitos. Por outras palavras, o juro é pago frequentemente a prestações (por exemplo, mensalmente ou trimestralmente) antes do fim do período de cálculo.

### Sintaxe

EFETIVA(taxa_nominal; períodos)

taxa_nominal é a taxa de juro nominal.

períodos é o número total de períodos do ano.

### Exemplo

Se a taxa de juro nominal anual for 9,75% e forem definidos quatro períodos de cálculo de juros, qual é a taxa de juro real (taxa efetiva)?

=EFETIVA(9,75%;4) = 10,11%. A taxa efetiva anual é 10,11%.

## EFETIVA_ADD

Devolve a taxa de juro anual efetiva, dada a taxa de juro nominal anual e o número de períodos compostos.

As funções cujo nome terminem com _ADD ou _EXCEL2003 devolvem o mesmo resultado que as funções correspondentes do Microsoft Excel 2003 que não possuem o sufixo. Utilize as funções sem o sufixo para obter os resultados baseados em padrões internacionais.

### Sintaxe

EFETIVA_ADD(taxa_nominal; núm_por_ano)

taxa_nominal é a taxa de juro nominal.

núm_por_ano é o número de períodos do ano.

### Exemplo

Qual é a taxa de juro anual efetiva de uma taxa nominal de 5,25% com pagamento trimestral?

=EFETIVA_ADD(0,0525;4) devolve 0,053543 ou 5,3543%.

## JUROSACUM

Devolve os juros acumulados de um título que paga juros periódicos.

### Sintaxe

JUROSACUM(emissão; primeiro_juro; liquidação; taxa; valor_nominal; frequência; base)

emissão (obrigatório) é a data de emissão do título.

primeiro_juro (obrigatório) é a data do primeiro juro do título.

liquidação (obrigatório) é a data de liquidação do título.

taxa (obrigatório) é a taxa de juro anual do título.

valor_nominal (opcional) é o valor nominal do título.

frequência é o número de pagamentos de cupões por ano. Para pagamentos anuais, frequência = 1; para semestrais, frequência = 2; para trimestrais, frequência = 4.

base (opcional) é base de cálculo e indica o método de cálculo do ano.

base | Cálculo
0 or missing | Método norte americano (NASD), 12 meses de 30 dias cada
1 | Número exato de dias nos meses, número exato de dias no ano
2 | Número exato de dias no mês, o ano tem 360 dias
3 | Número exato de dias no mês, o ano tem 365 dias
4 | Método europeu, 12 meses de 30 dias cada

### Exemplo

Um título foi emitido a 2001-02-28. O primeiro pagamento de juros foi definido para 2001-08-31. A data de liquidação é 2001-05-01. A taxa é 0,1 ou 10% e o valor nominal é 1000 unidades monetárias. Os juros são pagos semestralmente (a frequência é 2). A base é o método dos EUA (0). Qual o valor de juros acumulados?

=JUROSACUM("2001-02-28";"2001-08-31";"2001-05-01";0,1;1000;2;0) devolve 16,94444.

## JUROSACUMV

Devolve os juros acumulada de um título que paga juros no vencimento.

### Sintaxe

JUROSACUMV(emissão; liquidação; taxa; valor_nominal; base)

emissão (obrigatório) é a data de emissão do título.

liquidação (obrigatório) é a data de liquidação do título.

taxa (obrigatório) é a taxa de juro anual do título.

valor_nominal (opcional) é o valor nominal do título.

base (opcional) é base de cálculo e indica o método de cálculo do ano.

base | Cálculo
0 or missing | Método norte americano (NASD), 12 meses de 30 dias cada
1 | Número exato de dias nos meses, número exato de dias no ano
2 | Número exato de dias no mês, o ano tem 360 dias
3 | Número exato de dias no mês, o ano tem 365 dias
4 | Método europeu, 12 meses de 30 dias cada

### Exemplo

Um título foi emitido em 2001-04-01. A data de vencimento foi definida para 2001-06-15. A taxa é 0,1 ou 10% e o valor nominal é 1000 unidades monetárias. A base do cálculo diário/anual é diária (3). Qual será o valor de juros acumulados?

=JUROSACUMV("2001-04-01";"2001-06-15";0,1;1000;3) devolve 20,54795.

## RECEBER

Devolve a quantia recebida no vencimento de um título totalmente investido.

### Sintaxe

RECEBER(liquidação; vencimento; investimento; desconto; base)

liquidação é a data de liquidação do título.

vencimento é a data de vencimento (maturidade) do título.

investimento é a quantia investida no título.

desconto é a taxa de desconto do título.

base (opcional) é base de cálculo e indica o método de cálculo do ano.

base | Cálculo
0 or missing | Método norte americano (NASD), 12 meses de 30 dias cada
1 | Número exato de dias nos meses, número exato de dias no ano
2 | Número exato de dias no mês, o ano tem 360 dias
3 | Número exato de dias no mês, o ano tem 365 dias
4 | Método europeu, 12 meses de 30 dias cada

### Exemplo

Para um título com o valor de 1000 unidades monetárias cuja data de liquidação é 1999-02-15 e a data de vencimento é 1999-05-15 com uma taxa de desconto de 5,75 por cento e base real/360 = 2.

A quantia recebida na data de vencimento é calculada da seguinte forma:

=RECEBER("1999-02-15";"1999-05-15";1000;0,0575;2) devolve 1014,420266.

## TIR

Devolve a taxa de rentabilidade interna para uma série de fluxos monetários. Os valores representam os fluxo monetários regulares e tem que existir, pelo menos, um valor negativo (pagamentos) e um valor positivo (recebimentos).

Se os pagamentos ocorrerem em intervalos irregulares, utilize a função XTIR.

### Sintaxe

TIR(Valores; Estimativa)

valores é uma matriz ou uma referência às células, que contêm os números cuja taxa interna de rendibilidade pretende calcular.

Estimativa (opcional) é o valor estimado da TIR. É utilizado um método iterativo para calcular a taxa interna de devolução. Se apenas for possível disponibilizar alguns valores, deverá disponibilizar uma estimativa inicial para ativar a iteração.

### Exemplo

Pressupondo que o conteúdo das células é A1=-10000, A2=3500, A3=7600 e A4=1000, a fórmula =TIR(A1:A4) devolve 11,33%.

Devido ao método iterativo usado, é possível que TIR falhe e devolva o Erro 523, com "Erro: o cálculo não converge" na barra de estado. Nesse caso, utilize outro valor para a estimativa.

## VA

Devolve o valor atual de um investimento resultante de uma série de pagamentos futuros.

Utilize esta função para calcular a quantia de dinheiro necessária para investimento a uma taxa fixa, por forma a receber uma quantia específica, uma anuidade, ao longo de um número especificado de períodos. É igualmente possível determinar a quantia de dinheiro que deve restar depois do fim do período. Especifique ainda se a quantia deve ser paga no início ou no fim de cada período.

Introduza estes valores em forma de números, expressões ou referências. Se, por exemplo, o juro for pago anualmente a 8%, mas pretender utilizar o mês como período, insira 8%/12 em taxa e o LibreOffice Calc efetuará automaticamente o cálculo do fator correto.

### Sintaxe

VA(taxa; nper; pgto; vf; tipo)

taxa é a taxa de juro por período.

nper é o número total de períodos de pagamento do investimento.

pgto é o pagamento efectuado em cada período.

vf (opcional) é o valor futuro ou o saldo em dinheiro que pretende obter depois do último pagamento.

tipo (opcional) é o número 0 ou 1 e indica as datas de vencimento dos pagamentos. Tipo = 1 significa que o limite é no início de um período e Tipo = 0 (padrão) significa que o limite é no fim de um período.

Nas funções do LibreOffice Calc, pode excluir parâmetros marcados como "opcionais" apenas quando não são seguidos por mais parâmetros. Por exemplo, numa função com 4 parâmetros, em que os dois últimos parâmetros são marcados como "opcionais", pode excluir o parâmetro 4 ou os parâmetros 3 e 4, mas não apenas o parâmetro 3.

### Exemplo

Qual é o valor atual de um investimento se forem pagas mensalmente 500 unidades monetárias a uma taxa de juro anual for 8%? O período de pagamento são 48 meses e devem permanecer no final do período de pagamento 20 000 unidades monetárias.

=VA(8%/12;48;500;20000) = -35 019,37 unidades monetárias. Nas condições indicadas, tem de depositar 35 019,37 unidades monetárias hoje, se quiser receber 500 unidades monetárias, por mês, durante 48 meses e ainda ficar com 20 000 unidades monetárias . A correlação cruzada demonstra que 48 x 500 unidades monetárias + 20 000 unidades monetárias são o equivalente a 44 000 unidades monetárias. A diferença entre esta quantidade e as 35 000 unidades monetárias representa o juro pago.

Se introduzir, na fórmula, referências em vez de valores, será possível calcular diversos cenários "Se-Então". Nota: as referências a constantes devem ser definidas como referências absolutas. Existem exemplos deste tipo de aplicação nas funções de depreciação.

## É.PGTO

Devolve o juro que um investimento rende durante um determinado período.

### Sintaxe

É.PGTO(taxa; período; nper; va)

taxa é a taxa de juro do investimento.

período é o período em que pretende calcular o juro e tem de estar entre 1 e nper.

nper é o número total de períodos de pagamento.

va é o valor atual do investimento. No caso de um empréstimo, va corresponde ao valor do empréstimo.

### Exemplo

Para um crédito de 120 000 unidades monetárias com um prazo de dois anos e prestações mensais a uma taxa de juro anual de 12%, qual o valor de juros após 1,5 anos?

=É.PGTO(1%;18;24;120000) = -300. O juro mensal após 1,5 anos é de 300 unidades monetárias.

Funções financeiras - Parte 2

Funções financeiras - Parte 3

Funções por categoria