Contenuto
Indice 🔎︎

## Funzione MEDIA.SE

Restituisce la media aritmetica di tutte le celle all'interno di un intervallo che soddisfi una determinata condizione. La funzione MEDIA.SE somma tutti i risultati che corrispondono al test logico e divide per la quantità dei valori selezionati.

La funzione è disponibile da LibreOffice 4.0

### Sintassi

MEDIA.SE(Intervallo; Criterio [; intervallo_media ])

Intervallo – argomento obbligatorio. Può essere una matrice, il nome di un'area indicata, la dicitura di una colonna o di una riga che contiene numeri per l'esecuzione della media oppure numeri o testo per la condizione.

Criterio – argomento obbligatorio. È una condizione nella forma di un'espressione o un riferimento a una cella con espressione che definisce quali celle devono essere utilizzate per calcolare la media. L'espressione può contenere testo, numeri, espressioni regolari (se abilitate nelle opzioni di calcolo) o caratteri jolly (se abilitati nelle opzioni di calcolo).

intervallo_media – argomento opzionale. È un intervallo di valori per il calcolo della media.

Si noti che se non è specificato intervallo_media, Intervallo viene usato sia per il calcolo della media, sia per la ricerca in base alla condizione. Se intervallo_media viene specificato, Intervallo è utilizzato solo per il test della condizione, mentre intervallo_media è usato per il calcolo della media.
L'opzione Criterio necessita di un'espressione di stringa; in particolare, Criterio deve essere incluso tra virgolette doppie ("Criterio"). Le virgolette non sono necessarie per i nomi delle funzioni, i riferimenti di cella e le operazioni con concatenazione di stringa (&).

Questa funzione appartiene all'Open Document Format for Office Applications (OpenDocument), versione standard 1.2 (ISO/IEC 26300:2-2015).

Se all'interno di un intervallo di valori per il calcolo della media, una cella fosse vuota o contenesse del testo, la funzione AVERAGEIF ignorerebbe tale cella.
Se l'intero intervallo fosse vuoto, contenesse solo testo o tutti i valori al suo interno non soddisfassero la condizione (o qualsiasi loro combinazione), la funzione restituirebbe l'errore #DIV/0!.

### Esempio

#### Considerate la tabella seguente

| A | B | C
1 | Nome prodotto | Vendite | Ricavo
2 | matita | 20 | 65
3 | penna | 35 | 85
4 | notebook | 20 | 190
5 | libro | 17 | 180
6 | astuccio | non | non

In tutti gli esempi riportati sotto, gli intervalli per il calcolo contengono la riga #6, che viene ignorata poiché contiene testo.

In tutti i calcoli sotto riportati, l'intervallo per il calcolo della media include la riga #6, ma essa è ignorata poiché contiene del testo.

#### Uso semplice

=MEDIA.SE(B2:B6;"<35")

Calcola la media per i valori dell'intervallo B2:B6, minori di 35. Restituisce 19, perché la seconda riga non è inclusa nel calcolo.

=MEDIA.SE(B2:B6;"<"&MAX(B2:B6))

Calcola la media per i valori dello stesso intervallo minori del valore massimo dello stesso intervallo. Restituisce 19, perché il valore maggiore (la seconda riga) non è incluso nel calcolo.

=MEDIA.SE(B2:B6;">"&PICCOLO(B2:B6;1))

Calcola la media per i valori dello stesso intervallo maggiori del primo valore più piccolo dello stesso intervallo. Restituisce 25, perché il primo valore più piccolo (la quarta riga) non è incluso nel calcolo.

#### Uso di intervallo_media

=MEDIA.SE(B2:B6;"<35";C2:C6)

La funzione ricerca quali valori sono minori di 35 all'interno dell'intervallo B2:B6, e calcola la media dei valori corrispondenti dall'intervallo C2:C6. Restituisce 145, perché la seconda riga non è inclusa nel calcolo.

=MEDIA.SE(B2:B6;">"&MIN(B2:B6);C2:C6)

La funzione ricerca quali valori dall'intervallo B2:B6 sono maggiori del valore minimo all'interno dell'intervallo B2:B6, e calcola la media dei valori corrispondenti dall'intervallo C2:C6. Restituisce 113,3, perché la quarta riga (in cui è presente il valore minimo all'interno dell'intervallo B2:B6) non è inclusa nel calcolo.

=MEDIA.SE(B2:B6;"<"&GRANDE(B2:B6;2);C2:C6)

La funzione ricerca quali valori dall'intervallo B2:B6 sono minori del secondo valore maggiore all'interno dell'intervallo B2:B6, e calcola la media dei valori corrispondenti dall'intervallo C2:C6. Restituisce 180, perché solo la quarta riga è inclusa nel calcolo.

#### Uso delle espressioni regolari

=MEDIA.SE(A2:A6;"pen";B2:B6)

La funzione ricerca quali celle dall'intervallo A2:A6 contengono la parola “pen”, e calcola la media dei valori corrispondenti dall'intervallo B2:B6. Restituisce 35, perché solo la seconda riga è inclusa nel calcolo. La ricerca è eseguita nell'intervallo A2:A6, ma vengono restituiti solo i valori dall'intervallo B2:B6.

=MEDIA.SE(A2:A6;"pen.*";B2:B6)

La funzione ricerca quali celle dall'intervallo A2:A6 iniziano con “pen”, e terminano con un qualsiasi altro numero di altri caratteri, e calcola la media dei valori corrispondenti dall'intervallo B2:B6. Restituisce 27,5, perché al momento solo “pencil” soddisfa la condizione, e sia la prima sia la seconda riga sono incluse nel calcolo.

=MEDIA.SE(A2:A6;".*book.*";B2:B6)

La funzione ricerca quali celle dall'intervallo A2:A6 iniziano con “book”, e iniziano e terminano con un qualsiasi altro numero di altri caratteri, e calcola la media dei valori corrispondenti dall'intervallo B2:B6. Restituisce 18,5, perché solo la terza e la quarta riga sono incluse nel calcolo.

#### Fare riferimento a una cella come criterio

Per cambiare in modo facile un criterio, potete specificarlo in una cella separata, utilizzando un riferimento alla cella all'interno della condizione della funzione MEDIA.SE.

=MEDIA.SE(A2:A6;".*"&E2&".*";B2:B6)

La funzione ricerca quali celle dall'intervallo A2:A6 contengono una combinazione di caratteri specificati in E2, che iniziano e terminano con un qualsiasi altro numero di altri caratteri, e calcola la media dei valori corrispondenti dall'intervallo B2:B6. Se E2 = book, la funzione restituisce 18,5.

=MEDIA.SE(B2:B6;"<"&E2;C2:C6)

La funzione ricerca quali celle dall'intervallo B2:A6 sono minori del valore specificato in E2, e calcola la media dei valori corrispondenti dall'intervallo C2:C6. Se E2 = 35, la funzione restituisce 145.

Argomenti correlati

MEDIA, MEDIA.VALORI, MEDIA.DEV

CONTA.PIÙ.SE, MIN.PIÙ.SE, MAX.PIÙ.SE, MEDIA.PIÙ.SE, SOMMA.PIÙ.SE

Elenco delle espressioni regolari