Module
Inhalte
Index 🔎︎

## Funktion ZÄHLENWENNS

Gibt die Anzahl an Zellen zurück, welche Bedingungen in mehreren Bereichen erfüllen.

### Syntax

ZÄHLENWENNS(Bereich 1; Bedingung 1 [; Bereich 2; Bedingung 2 [; ...]])

Bereich 1 (erforderlich). Ist ein Zellbereich, ein Name eines Bereichs oder eine Spalten-/Zeilenbeschriftung, welche(r) die Werte enthält, die bei erfüllter Bedingung gezählt werden sollen.

Kriterium 1 (erforderlich) - Ein Zeichenkettenausdruck, der eine logische Bedingung oder einen Bezug zu seinem solchen Zeichenkettenausdruck enthält. Der Ausdruck kann Text, Zahlen, reguläre Ausdrücke oder Platzhalter enthalten (wenn in den Berechnungsoptionen aktiviert).

Bereich 2 – optional. Für Bereich 2 und folgende gilt dasselbe wie für Bereich 1.

Bedingung 2 - optional. Bedingung 2 und folgende meinen dasselbe wie Bedingung 1.

Bereich 1, Bereich 2, ... und Bedingung 1, Bedingung 2, ... müssen die selbe Dimension umfassen, ansonsten gibt die Funktion den Fehler Err:502 - Ungültiges Argument zurück.

Die logische Beziehung zwischen Bedingungen kann als logisches UND (Konjunktion) definiert werden. In anderen Worten, wenn und nur wenn alle angegebenen Bedingungen zutreffen, wird ein Wert von der zugehörigen Zelle aus dem angegebenen Funktionsbereich in der Berechnung berücksichtigt.

Die Funktion kann bis zu 255 Argumente verarbeiten, bedeutet, dass Sie 127 Bereiche und Bedingungen angeben können.

Wenn die Zelle WAHR enthält, wird sie wie 1 behandelt, wenn FALSCH, wie 0 (Null).

Diese Funktion ist Teil des OpenDocument-Standards (Open Document Format for Office Applications) Version 1.2. (ISO/IEC 26300:2-2015)

### Beispiel

#### Betrachten Sie folgende Tabelle

| A | B | C
1 | Produktname | Absatz | Einnahmen
2 | Buntstift | 20 | 65
3 | Stift | 35 | 85
4 | Schulbuch | 20 | 190
5 | Buch | 17 | 180
6 | Buntstift-Set | nicht | nicht

In allen unten stehenden Beispielen enthält der Bereich für die Berechnung der Summe die Zeile 6, diese wird aber ignoriert, da sie Text enthält.

#### Einfache Verwendung

=ZÄHLENWENNS(B2:B6;">=20")

Zählt die Anzahl der Zeilen im Bereich B2:B6, deren Wert größer oder gleich 20 ist. Ergibt 3, da die fünfte und sechste Zeile die Bedingung nicht erfüllen.

=ZÄHLENWENNS(B2:B6;">=20";C2:C6;">70")

Zählt die Anzahl der Zeilen die gleichzeitig Werte größer als 70 im Bereich C2:C6 und Werte größer oder gleich 20 im Bereich B2:B6 enthalten. Ergibt 2, da die zweite, fünfte und sechste Zeile je mindestens eine Bedingung nicht erfüllen.

#### Verwendung mit regulären Ausdrücken und verschachtelten Funktionen

=ZÄHLENWENNS(B2:B6;"[:alpha:]*")

Zählt die Anzahl der Zeilen im Bereich B2:B6, die nur Buchstaben enthalten. Ergibt 1, da nur die sechste Zeile die Bedingung erfüllt.

=ZÄHLENWENNS(B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Zählt die Anzahl der Zeilen im Bereich B2:B6, außer der Zeilen mit Maximal- und Minimalwerten in diesem Bereich. Ergibt 2, da die dritte, fünfte und sechste Zeile je mindestens eine Bedingung nicht erfüllen.

=ZÄHLENWENNS(A2:A6;".*stift";B2:B6;"<"&MAX(B2:B6))

Zählt die Anzahl der Zeilen, deren Zellen im Bereich A2:A6 auf "stift" enden und deren Zellen im Bereich B2:B6 nicht den Maximalwert enthalten. Ergibt 1, da nur die zweite Zeile alle Bedingungen erfüllt.

#### Bezüge zu einer Zelle mit einer Bedingung

Um eine Bedingung einfach zu ändern, bietet es sich an, diese in einer separaten Zelle festzulegen und für die Bedingung der Funktion ZÄHLENWENNS einen Bezug zur Zelle anzugeben. Beispielsweise kann obige Funktion geschrieben werden als:

=ZÄHLENWENNS(A2:A6;".*"&E2;B2:B6;"<"&MAX(B2:B6))

Wenn E2 = stift ist, ergibt die Funktion 1, da der Bezug zur Zelle derem Inhalt entspricht und wie die Funktion oben funktioniert.

Verwandte Themen

ANZAHL, ZÄHLENWENN, ANZAHLLEEREZELLEN, ANZAHL2

ZÄHLENWENNS, MINWENNS, MAXWENNS, MITTELWERTWENNS, SUMMEWENNS

Liste der regulären Ausdrücke