Съдържание
Индекс 🔎︎

# Оператор MkDir

Създава нова директория върху носител на данни.

## Синтаксис:

    MkDir Text As String

## Параметри:

Text: низов израз, задаващ името и пътя на създаваната директория. Може да бъде във вид на URL.

Ако пътят не е определен, директорията се създава в текущата директория.

## Кодове за грешка:

5 Невалидно извикване на процедура

76 Пътят не е намерен

## Пример:

    Sub ExampleFileIO
    ' Пример за функциите за управление на файлове
    Const sFile1 As String = "file://c|/autoexec.bat"
    Const sDir1 As String = "file://c|/Temp"
    Const sSubDir1 As String ="Test"
    Const sFile2 As String = "Copied.tmp"
    Const sFile3 As String = "Renamed.tmp"
    Dim sFile As String
        sFile = sDir1 + "/" + sSubDir1
        ChDir( sDir1 )
        If Dir(sSubDir1, 16) = "" Then ' Съществува ли директорията?
            MkDir sSubDir1
            MsgBox sFile, 0, "Създаване на директория"
        End If
        sFile = sFile + "/" + sFile2
        FileCopy sFile1 , sFile
        MsgBox fSysURL(CurDir()), 0, "Текуща директория"
        MsgBox sFile & Chr(13) & FileDateTime(sFile), 0, "Час на създаване"
        MsgBox sFile & Chr(13) & FileLen(sFile), 0, "Дължина на файла"
        MsgBox sFile & Chr(13) & GetAttr(sFile), 0, "Атрибути на файла"
        Name sFile As sDir1 + "/" + sSubDir1 + "/" + sFile3
        ' Преименуване в същата директория
        sFile = sDir1 + "/" + sSubDir1 + "/" + sFile3
        SetAttr(sFile, 0) 'Изтриваме всички атрибути
        MsgBox sFile & Chr(13) & GetAttr(sFile), 0, "Нови атрибути на файла"
        Kill sFile
        RmDir sDir1 + "/" + sSubDir1
    End Sub

    ' Преобразува системен път в URL
    Function fSysURL( fSysFp As String ) As String
    Dim iPos As String
        iPos = 1
        iPos = Instr(iPos,fSysFp, getPathSeparator())
        Do While iPos > 0
            Mid( fSysFp, iPos , 1,"/")
            iPos = Instr(iPos+1,fSysFp, getPathSeparator())
        Loop
        ' Двоеточие в DOS
        iPos = Instr(1,fSysFp,":")
        If iPos > 0 Then Mid( fSysFp, iPos , 1,"|")
        fSysURL = "file://" & fSysFp
    End Function