Modulo
Contenuto
Indice 🔎︎

# Funzioni foglio elettronico

In questa sezione vengono descritte le funzioni della categoria Foglio elettronico, corredate di esempio.

Per accedere a questo comando...

Inserisci - Funzione - Categoria Foglio elettronico

## ERRORE.TIPO

Restituisce un numero che rappresenta uno specifico tipo di errore, oppure il valore di errore #N/D, se non è presente alcun errore.

## AREE

Restituisce il numero delle singole aree appartenenti a un'area multipla. Un'area può essere costituita da celle contigue o da una singola cella.

La funzione prevede un singolo argomento. Se dichiarate più aree, dovete racchiuderle tra parentesi addizionali. Aree multiple possono essere inserite utilizzando come divisore il punto e virgola (;) e questo viene automaticamente convertito nell'operatore tilde (~). La tilde è utilizzata per unire aree.

### Sintassi

AREE(Riferimento)

Riferimento è il riferimento a una cella o a un intervallo di celle.

### Esempio

=AREE((A1:B3; F2; G1)) restituisce 3, poiché qui vengono conteggiate tre celle e/o aree. Dopo la registrazione, questo viene convertito in =AREE((A1:B3~F2~G1)).

=AREE(Tutte) restituisce 1 se avete precedentemente definito un'area chiamata Tutte, selezionando Dati - Definisci area.

## CERCA

Restituisce il contenuto di una cella da un'area formata da una riga o una colonna. Come opzione, il valore assegnato (dallo stesso indice) è restituito in una colonna o riga diversa. Al contrario delle funzioni CERCA.VERT e CERCA.ORIZZ, il vettore di ricerca e dei risultati possono essere in posizioni diverse; non devono neppure essere adiacenti. Inoltre, il vettore di ricerca per CERCA deve essere ordinato, altrimenti la ricerca non restituirà un risultato utilizzabile.

Se CERCA non può trovare il criterio di ricerca, corrisponde al valore più grande nel vettore di ricerca, il quale è inferiore o uguale al criterio di ricerca.

La ricerca supporta le espressioni regolari. Per esempio, potete digitare "tutto.*" per trovare la prima occorrenza di "tutto" seguita da un carattere qualunque. Per ricercare un testo che è anche un'espressione regolare, dovete far precedere ogni carattere da "\". La valutazione automatica delle espressioni regolari può essere attivata e disattivata in LibreOffice - PreferenzeStrumenti - Opzioni - LibreOffice Calc - Calcola.

### Sintassi

CERCA(Criterio di ricerca; Vettore; Risultato)

Criterio di ricerca è il valore in base al quale viene eseguita la ricerca e può essere digitato direttamente oppure come riferimento.

Vettore è l'area di una sola riga o una sola colonna all'interno della quale deve essere eseguita la ricerca.

Risultato è un'altra area a singola riga o singola colonna da cui viene ricavato il risultato della funzione. Il risultato è la cella del risultato con lo stesso indice dell'istanza trovata nel vettore di ricerca.

Gestione di celle vuote

### Esempio

=CERCA(A1; D1:D100;F1:F100) ricerca la cella corrispondente nell'area D1:D100 per il numero indicato in A1. Per l'istanza trovata, viene quindi determinato l'indice, ad esempio, la dodicesima cella nell'area. Il contenuto della dodicesima cella viene poi restituito come valore della funzione (in Risultato).

## CERCA.ORIZZ

Ricerca orizzontale con riferimento alle celle sottostanti l'area selezionata. Questa funzione controlla se nella prima riga di una matrice è presente un certo valore, quindi restituisce il valore in una riga della matrice, indicata nel parametro Indice, nella stessa colonna.

La ricerca supporta le espressioni regolari. Per esempio, potete digitare "tutto.*" per trovare la prima occorrenza di "tutto" seguita da un carattere qualunque. Per ricercare un testo che è anche un'espressione regolare, dovete far precedere ogni carattere da "\". La valutazione automatica delle espressioni regolari può essere attivata e disattivata in LibreOffice - PreferenzeStrumenti - Opzioni - LibreOffice Calc - Calcola.

### Sintassi

CERCA.ORIZZ(Criterio di ricerca; Matrice; Indice; Ordinato)

Vedere anche:CERCA.VERT (colonne e righe sono invertite)

Gestione di celle vuote

## CERCA.VERT

Ricerca verticale con riferimento alle celle adiacenti a destra. Questa funzione controlla se nella prima colonna di una matrice è contenuto un valore determinato. La funzione restituisce il valore nella stessa riga della colonna indicata dall'Indice. Se il parametro Ordinato è omesso o impostato a VERO o uno, si presume che i dati siano ordinati in maniera crescente. In questo caso, se non viene trovato l'esatto Criterio di ricerca, sarà restituito l'ultimo valore più piccolo rispetto al criterio. Se Ordinato è impostato a FALSO o zero, deve essere trovata l'esatta corrispondenza; in caso contrario verrà restituito l'avviso Errore: valore non disponibile. I dati, dunque, se aventi valore zero, non devono essere ordinati in maniera crescente.

La ricerca supporta le espressioni regolari. Per esempio, potete digitare "tutto.*" per trovare la prima occorrenza di "tutto" seguita da un carattere qualunque. Per ricercare un testo che è anche un'espressione regolare, dovete far precedere ogni carattere da "\". La valutazione automatica delle espressioni regolari può essere attivata e disattivata in LibreOffice - PreferenzeStrumenti - Opzioni - LibreOffice Calc - Calcola.

### Sintassi

=CERCA.VERT(Criterio di ricerca; Matrice; Indice; Ordinato)

Criterio di ricerca è il valore che deve essere cercato nella prima colonna della matrice.

Matrice è il riferimento, e deve comprendere almeno due colonne.

Indice è il numero della colonna nella matrice che contiene il valore da restituire. La prima colonna contiene il numero 1.

Ordinato è un parametro opzionale che indica se la prima colonna nella matrice è ordinata in modo crescente. Digitate qui il valore logico FALSO, se la prima colonna non è ordinata in modo crescente. Le colonne ordinate possono essere sfogliate molto più velocemente. Inoltre la funzione restituisce sempre un valore, anche se non viene trovato l'esatto valore ricercato (è sufficiente che sia presente tra il valore massimo e il valore minimo dell'elenco in cui avviene l'ordinamento) Negli elenchi non ordinati deve essere trovato l'esatto valore ricercato. In caso contrario, viene visualizzato il messaggio: Errore: valore non disponibile.

Gestione di celle vuote

### Esempio

Supponiamo che vogliate inserire il numero di un piatto incluso nel menu di un ristorante nella cella A1 e desiderate che nella cella accanto (B1) sia visualizzato il nome per esteso. L'assegnazione Numero a Nome è presente nella matrice D1:E100. D1 contiene 100, E1 contiene il nome Zuppa di verdure e così via, per 100 voci del menu. I numeri nella colonna D sono elencati in ordine crescente; pertanto, il parametro opzionale Ordinato non è necessario.

Inserite in B1 la seguente formula:

=CERCA.VERT(A1;D1:E100;2)

Quando digitate un numero in A1, in B1 viene visualizzato il relativo testo presente nella seconda colonna del riferimento D1:E100. Se digitate un numero inesistente, viene visualizzato il testo con il numero successivo più piccolo. Se non è questo ciò che desiderate, inserite Falso come ultimo parametro della formula, in modo da visualizzare un messaggio di errore quando viene digitato un numero inesistente.

## COLLEGAMENTO

Se si fa clic su una cella che contiene la funzione COLLEGAMENTO, viene aperto il collegamento ipertestuale.

Se utilizzate il parametro opzionale Testo della cella, la formula individua l'URL e visualizza il testo.

Per aprire con la tastiera una cella con collegamento, selezionate la cella, premete F2 per accedere al modo Modifica, spostate il cursore davanti al collegamento, premete Maiusc+F10 e scegliete Apri collegamento.

### Sintassi

COLLEGAMENTO ("URL") o COLLEGAMENTO ("URL"; "Testo della cella")

URL specifica la destinazione del collegamento. Il parametro opzionale Testo della cella indica il testo che viene visualizzato nella cella e il risultato della funzione. Se il parametro Testo della cella non viene specificato, nella cella e nel risultato della funzione viene visualizzato l'URL.

Viene restituito il numero 0 per le celle vuote e gli elementi di matrici.

### Esempio

=COLLEGAMENTO("http://www.esempio.org") mostra il testo "http://www.esempio.org" nella cella ed esegue il collegamento ipertestuale http://www.esempio.org se vi fate clic sopra.

=COLLEGAMENTO("http://www.esempio.org";"Fate clic qui") mostra il testo "Fate clic qui" nella cella ed esegue il collegamento ipertestuale http://www.esempio.org se vi fate clic sopra.

=COLLEGAMENTO("http://www.esempio.org";12345) mostra il numero 12345 ed esegue il collegamento ipertestuale http://www.esempio.org se vi fate clic sopra.

=COLLEGAMENTO($B4) dove la cella B4 contiene http://www.esempio.org. La funzione aggiunge http://www.esempio.org all'URL del collegamento ipertestuale e restituisce lo stesso testo che sarà usato come risultato della formula.

=COLLEGAMENTO("http://www.";"Fate clic su") & "esempio.org" mostra il testo "Fate clic su esempio.org" nella cella ed esegue il collegamento ipertestuale http://www.esempio.org se vi fate clic sopra.

=COLLEGAMENTO("#Foglio1.A1";"Vai all'inizio") mostra il testo Vai all'inizio e passa alla cella Foglio1.A1 in questo documento.

=COLLEGAMENTO("file:///C:/writer.odt#Specifica";"Vai al segnalibro di Writer") mostra il testo "Vai al segnalibro di Writer", carica il testo documento e passa al segnalibro "Specifica".

## COLONNE

Restituisce il numero di colonne in un riferimento.

### Sintassi

COLONNE(Matrice)

Matrice è il riferimento a un'area di celle di cui deve essere trovato il numero totale di colonne. L'argomento può essere anche una cella singola.

### Esempio

=COLONNE(B5) restituisce 1, poiché una cella racchiude una sola colonna.

=COLONNE(A1:C5) restituisce 3, poiché il riferimento riguarda 3 colonne.

=COLONNE(Lepre) restituisce 2 se Lepre rappresenta l'area indicata (C1:D3).

## CONFRONTA

Restituisce la posizione relativa di un elemento di una matrice che corrisponde a un valore specificato. La funzione restituisce la posizione del valore trovato nella matrice di ricerca sotto forma di numero.

### Sintassi

CONFRONTA(Criterio di ricerca; Matrice; Tipo)

Criterio di ricerca è il valore da ricercare nella matrice a singola riga o a singola colonna.

Matrice è il riferimento in cui viene eseguita la ricerca. La matrice di ricerca può essere una singola riga, una singola colonna oppure una parte di queste ultime.

Tipo può accettare i valori 1, 0 oppure -1. Se questo parametro opzionale è 1 oppure manca, si presuppone che la prima colonna della matrice di ricerca venga ordinata in modo crescente. Se tipo è -1, si presuppone che la colonna venga ordinata in modo decrescente. Corrisponde alla stessa funzione presente in Microsoft Excel.

Se il Tipo è = 0 la ricerca deve dare come risultato una corrispondenza esatta. Se il valore viene trovato più volte, la funzione restituisce la prima posizione trovata. Solo se Tipo = 0 è permessa la ricerca con un'espressione regolare (se abilitata nelle opzioni di calcolo) o con caratteri jolly (se abilitata nelle opzioni di calcolo).

Se Tipo = 1, oppure se manca il terzo parametro, verrà restituito l'ultimo valore minore o uguale al criterio di ricerca. Ciò vale anche nel caso in cui la matrice di ricerca non sia ordinata. Se Tipo = -1 viene restituito il primo valore maggiore o uguale.

La ricerca supporta le espressioni regolari. Per esempio, potete digitare "tutto.*" per trovare la prima occorrenza di "tutto" seguita da un carattere qualunque. Per ricercare un testo che è anche un'espressione regolare, dovete far precedere ogni carattere da "\". La valutazione automatica delle espressioni regolari può essere attivata e disattivata in LibreOffice - PreferenzeStrumenti - Opzioni - LibreOffice Calc - Calcola.

### Esempio

=CONFRONTA(200; D1:D100) ricerca il valore 200 nell'area D1:D100, ordinato in base alla colonna D. Quando trova questo valore, il sistema restituisce il numero della riga in cui lo ha trovato. Se durante la ricerca viene trovato un valore più alto, il risultato è il numero della riga precedente.

## DDE

Restituisce il risultato di un collegamento DDE. Se il contenuto dell'area o della sezione collegata cambia, varia anche il valore restituito dalla formula. Per visualizzare i collegamenti aggiornati, è necessario ricaricare il foglio elettronico oppure scegliere Modifica - Collegamenti. Non è consentito utilizzare collegamenti tra piattaforme diverse, ad esempio da un'installazione di LibreOffice in esecuzione su un sistema Windows verso un documento creato su un computer Linux.

### Sintassi

DDE("Server"; "File"; "Area"; Modo)

Server è il nome di un'applicazione di tipo server. Le applicazioni di LibreOffice hanno il nome server "soffice".

File è il nome del file con un percorso completo.

Area è l'intervallo di celle da cui devono essere reperiti i dati.

Modo è un parametro opzionale che gestisce la conversione dei dati del server DDE in numeri.

Modo | Effetto
0 oppure omesso | Formato numerico dallo stile di cella "Predefinito"
1 | I dati vengono sempre interpretati con il formato standard per l'inglese americano
2 | I dati vengono importati come testo e non avviene alcuna trasformazione in numeri

### Esempio

=DDE("soffice";"c:\office\documento\dati1.ods";"Foglio1.A1") consente di leggere il contenuto della cella A1 nel Foglio1 del documento dati1.ods di LibreOffice Calc.

=DDE("soffice"; "c:\office\documento\motto.ods"; "Motto del giorno") fornisce il motto del giorno come contenuto della cella che contiene questa formula. È necessario inserire per prima cosa il motto in una cella nel documento motto.ods, questa cella deve essere la prima riga della sezione indicata Motto del giorno (in LibreOffice Writer sotto Inserisci - Sezione) Quando il motto del giorno viene modificato nel documento di LibreOffice Writer e viene nuovamente salvato, questo diventa nuovamente disponibile in tutte le celle di LibreOffice Calc nelle quali è definito questo collegamento DDE.

## ERRORE.TIPO

Questa funzione restituisce il numero di un codice di errore verificatosi in un'altra cella. Questa funzione può essere usata, ad esempio, per generare un messaggio testuale di errore basato su tale numero.

Se si verifica un errore, la funzione restituisce un valore logico o numerico.

Facendo clic sulla cella contenente l'errore, la barra di stato mostra il codice di errore predefinito da LibreOffice.

### Sintassi

ERRORE.TIPO(Riferimento)

Riferimento è un riferimento a una cella in cui viene indicato un errore.

### Esempio

Se nella cella A1 viene visualizzato Err:518, la funzione =ERRORE.TIPO(A1) restituisce 518.

## FOGLI

Restituisce il numero di fogli di un riferimento. Se non è stato digitato alcun parametro, verrà restituito il numero dei fogli del documento.

### Sintassi

FOGLI(Riferimento)

Riferimento è il riferimento a un foglio o un'area. Questo parametro è facoltativo.

### Esempio

=FOGLI(Foglio1.A1:Foglio3.G12) restituisce 3 se Foglio1, Foglio2 e Foglio3 esistono in questa successione.

## FOGLIO

Determina il numero di foglio di un riferimento o di una stringa contenente il nome del foglio. Se non si indica alcun parametro, il risultato è il numero del foglio elettronico nel quale è presente la formula.

### Sintassi

FOGLIO(Riferimento)

Riferimento è il riferimento opzionale a una cella, un'area o una stringa di caratteri del nome di un foglio.

### Esempio

=FOGLIO(Foglio2.A1) restituisce 2 se Foglio2 è il secondo foglio nel documento.

## GETPIVOTDATA

La funzione GETPIVOTDATA restituisce un valore ricavato da una tabella pivot. Il valore è ottenuto utilizzando i nomi dei campi e degli oggetti, in modo da non alterarsi al variare della struttura della tabella pivot.

### Sintassi

Possono essere utilizzate due differenti sintassi:

GETPIVOTDATA(Campo di dati; tabella pivot; [ Campo 1; Oggetto 1; ... ])

GETPIVOTDATA(tabella pivot; Vincoli)

La seconda sintassi funziona solo se vengono passati esattamente due parametri, il primo dei quali è una cella o un riferimento a un'area di celle. La prima sintassi funziona in tutti gli altri casi. La creazione guidata funzione mostra la prima sintassi.

### Sintassi

Campo di dati è una stringa che seleziona uno dei campi dati della tabella pivot. La stringa può consistere nel nome della colonna sorgente o il nome del campo dati come mostrato nella tabella (ad esempio "Somma - Vendite").

Tabella pivot è un riferimento a una cella o un'area di celle posizionate in una tabella pivot o contenente una tabella pivot. Se l'area di celle selezionata contiene più tabelle pivot, sarà utilizzata l'ultima tabella creata.

Se nessuna coppia campo n / oggetto n è specificata, sarà restituito il totale generale, altrimenti ogni coppia aggiungerà un vincolo che il risultato dovrà soddisfare.Campo n è il nome di un campo della tabella pivot. Oggetto n è il nome di un oggetto di quel campo.

Se la tabella pivot contiene solo un singolo valore che soddisfa tutti i vincoli oppure un subtotale che riassuma tutti i valori che corrispondono, sarà restituito quel risultato. Se nessun risultato è corrispondente o ne esistono più di uno senza un subtotale comune a tutti, sarà restituito un errore. Queste condizioni si applicano a risultati inclusi nella tabella pivot.

Se i dati di partenza contengono voci nascoste secondo le impostazioni della tabella pivot, queste sono ignorate. L'ordine delle coppie campo/oggetto non è significativo. Non c'è distinzione tra maiuscole e minuscole nei nomi dei campi e degli oggetti.

Se non viene fornito alcun vincolo per un campo pagina, il valore selezionato del campo viene utilizzato implicitamente. Se invece viene fornito un vincolo, questo deve accordarsi con il valore selezionato del campo altrimenti verrà riportato un errore. I campi pagina sono campi nella parte in alto a sinistra di una tabella pivot, popolati usando l'area "Campi pagina" della finestra di dialogo Layout della tabella pivot. Da ciascun campo pagina, è possibile selezionare un oggetto (valore), che sarà l'unico oggetto incluso nel calcolo.

I valori subtotali dalla tabella pivot sono utilizzati solo nel caso in cui utilizzino la funzione "auto" (eccetto quando specificato nel vincolo, vedere Seconda sintassi).

### Sintassi

Tabella pivot ha il medesimo significato che possiede nella prima sintassi.

Vincoli è un elenco di elementi separato da spazi. Gli elementi possono essere racchiusi in virgolette (singole). Tutta la stringa deve essere racchiusa in virgolette doppie, a meno che non si stia facendo riferimento a una stringa contenuta in un'altra cella.

Una delle voci può essere il nome del campo dati. Il nome del campo dati può essere tralasciato se la tabella pivot contiene solo un campo dati, altrimenti va specificato.

Ciascun elemento specifica un vincolo nella forma Campo[Oggetto] (attenzione ai caratteri [ e ]), oppure solo Oggetto se l'oggetto è unico entro tutti i campi che sono utilizzati nella tabella pivot.

Un nome di funzione può essere aggiunto nella forma campo[oggetto;funzione]. In questo modo verranno selezionati solo i valori che utilizzano quella funzione. I nomi di funzione possibili sono somma, conta, media, max, min, prodotto, conta.numeri, dev.st, dev.st.pop, var e var.pop, senza distinzione tra maiuscole e minuscole.

## INDICE

INDICE restituisce il contenuto di un'area secondaria, specificato mediante un numero di riga e colonna oppure un nome di area opzionale. A seconda del contesto, INDICE restituisce un riferimento o del contenuto.

### Sintassi

INDICE(Riferimento; Riga; Colonna; Area)

Riferimento è un riferimento a celle, che può essere inserito in modo diretto oppure mediante il nome di un'area. Se il riferimento include più aree, è necessario racchiudere il riferimento o il nome dell'area tra parentesi.

Riga (opzionale) è il numero della riga all'interno dell'area indicata nel riferimento di cui si desidera venga restituito il valore. In caso di valore zero (nessuna riga specifica), sono restituite tutte le righe cui si fa riferimento.

Colonna (opzionale) è il numero della colonna all'interno dell'area indicata nel riferimento di cui si desidera venga restituito il valore. In caso di valore zero (nessuna colonna specifica), sono restituite tutte le colonne cui si fa riferimento.

Area (opzionale) è l'indice dell'area secondaria, se riferito a più aree.

### Esempio

=INDICE(Prezzi;4;1) restituisce il valore tratto dalla cella all'intersezione tra la riga 4 e la colonna 1 dell'area del database che avete denominato Prezzi selezionando Dati - Definisci.

=INDICE(Somma;4;1) restituisce il valore presente nella riga 4 e nella colonna 1 dell'area che avete denominato Somma selezionando Foglio - Aree con nome ed espressioni - Definisci.

=INDICE(A1:B6;1) restituisce il riferimento alla prima riga di A1:B6.

=INDICE(A1:B6;0;1) restituisce il riferimento alla prima colonna di A1:B6.

=INDICE((Multipla);4;1) restituisce il valore all'intersezione tra la riga 4 e la colonna 1 dell'area che avete denominato Multipla selezionando Foglio - Aree con nome ed espressioni - Definisci. L'area multipla può essere formata da più aree rettangolari, ognuna delle quali può avere una riga 4 e una colonna 1. Per consultare il secondo blocco di quest'area multipla, specificate 2 come ultimo parametro (Area).

=INDICE(A1:B6;1;1) restituisce il valore nella cella superiore sinistra dell'area A1:B6.

=INDICE((multi);0;0;2) restituisce il riferimento alla seconda area di un insieme di aree.

## INDIRETTO

Restituisce il contenuto di una cella indicata quale riferimento in forma testuale. Questa funzione è anche in grado di restituire un'area a partire da un'opportuna sequenza di caratteri.

Per interoperabilità le funzioni INDIRIZZO e INDIRETTO supportano un parametro facoltativo per specificare se dovrà essere utilizzata la notazione indirizzo R1C1 invece della solita notazione A1.

In INDIRIZZO, il parametro viene inserito come quarto parametro, spostando il nome facoltativo del foglio elettronico in quinta posizione.

In INDIRETTO, il parametro viene aggiunto come secondo parametro.

In entrambe le funzioni, se l'argomento inserito ha valore pari a 0, viene utilizzata la notazione R1C1. Se l'argomento non viene indicato oppure ha valore diverso da 0, viene utilizzata la notazione A1.

In caso di notazione R1C1 notation, la funzione INDIRIZZO restituisce stringhe indirizzo usando il punto esclamativo come carattere di separazione nel nome del foglio elettronico, e INDIRETTO attende il punto esclamativo come carattere di separazione nel nome del foglio elettronico. Entrambe le funzioni utilizzano ancora il punto '.' come carattere di separazione nel nome del foglio elettronico con la notazione A1.

Quando aprite documenti dal formato ODF 1.0/1.1, le funzioni INDIRIZZO che mostrano un nome del foglio elettronico come il quarto parametro verrà spostato e diventerà il quinto parametro. Verrà inserito un nuovo quarto parametro con valore pari a 1.

Nel memorizzare un documento nel formato ODF 1.0/1.1, se le funzioni INDIRIZZO prevedono un quarto parametro, questo verrà rimosso.

Non salvate un foglio di lavoro nel precedente formato ODF 1.0/1.1 se il nuovo quarto parametro della funzione INDIRIZZO è stato utilizzato con valore pari a 0.

La funzione INDIRETTO viene salvata senza conversione nel formato ODF 1.0/1.1. Se era presente il secondo parametro, una versione precedente di Calc restituirà un errore per quella funzione.

### Sintassi

INDIRETTO(Riferimento; A1)

Riferimento rappresenta un riferimento a una cella o un'area (in forma di testo) di cui si desidera venga restituito il contenuto.

A1 (facoltativo) - se impostato a 0, viene utilizzata la notazione scientifica R1C1. Se questo parametro è assente o impostato su un valore diverso da 0, viene utilizzata la notazione scientifica A1.

Se aprite un foglio elettronico Excel che utilizza indirizzi indiretti calcolati da funzioni stringa, gli indirizzi non vengono tradotti automaticamente. Ad esempio, l'indirizzo Excel in INDIRETTO("[nome_file]nome_foglio!"&B1) non viene convertito nell'indirizzo Calc in INDIRETTO("nome_file#nome_foglio."&B1).

### Esempio

=INDIRETTO(A1) restituisce 100 se in A1 è presente il riferimento C108, mentre nella cella C108 è presente il valore 100.

=SOMMA(INDIRETTO("A1:" & INDIRIZZO(1; 3))) somma le celle nell'area A1 fino alla cella, il cui indirizzo viene definito tramite la riga 1 e la colonna 3. Quindi viene sommata l'area A1:C1.

## INDIRIZZO

Restituisce un indirizzo di cella (riferimento) in formato testo, in base ai numeri di riga e colonna specificati. Potete stabilire se l'indirizzo deve essere interpretato come indirizzo assoluto (ad esempio, $A$1), relativo (come A1) o in formato misto (A$1 o $A1). Potete inoltre specificare il nome del foglio.

Per interoperabilità le funzioni INDIRIZZO e INDIRETTO supportano un parametro facoltativo per specificare se dovrà essere utilizzata la notazione indirizzo R1C1 invece della solita notazione A1.

In INDIRIZZO, il parametro viene inserito come quarto parametro, spostando il nome facoltativo del foglio elettronico in quinta posizione.

In INDIRETTO, il parametro viene aggiunto come secondo parametro.

In entrambe le funzioni, se l'argomento inserito ha valore pari a 0, viene utilizzata la notazione R1C1. Se l'argomento non viene indicato oppure ha valore diverso da 0, viene utilizzata la notazione A1.

In caso di notazione R1C1 notation, la funzione INDIRIZZO restituisce stringhe indirizzo usando il punto esclamativo come carattere di separazione nel nome del foglio elettronico, e INDIRETTO attende il punto esclamativo come carattere di separazione nel nome del foglio elettronico. Entrambe le funzioni utilizzano ancora il punto '.' come carattere di separazione nel nome del foglio elettronico con la notazione A1.

Quando aprite documenti dal formato ODF 1.0/1.1, le funzioni INDIRIZZO che mostrano un nome del foglio elettronico come il quarto parametro verrà spostato e diventerà il quinto parametro. Verrà inserito un nuovo quarto parametro con valore pari a 1.

Nel memorizzare un documento nel formato ODF 1.0/1.1, se le funzioni INDIRIZZO prevedono un quarto parametro, questo verrà rimosso.

Non salvate un foglio di lavoro nel precedente formato ODF 1.0/1.1 se il nuovo quarto parametro della funzione INDIRIZZO è stato utilizzato con valore pari a 0.

La funzione INDIRETTO viene salvata senza conversione nel formato ODF 1.0/1.1. Se era presente il secondo parametro, una versione precedente di Calc restituirà un errore per quella funzione.

### Sintassi

INDIRIZZO(Riga; Colonna; Ass(oluto); A1; "Foglio")

Riga rappresenta il numero di riga per la cella di riferimento

Colonna rappresenta il numero di colonna per la cella di riferimento (il numero, non la lettera)

Ass(oluto) determina il tipo di riferimento:

1: assoluto ($A$1)

2: tipo riferimento riga è assoluto; riferimento colonna è relativo (A$1)

3: riga relativo; colonna assoluto ($A1)

4; relativo (A1)

A1 (facoltativo) - se impostato a 0, viene utilizzata la notazione scientifica R1C1. Se questo parametro è assente o impostato su un valore diverso da 0, viene utilizzata la notazione scientifica A1.

Foglio rappresenta il nome del foglio. Deve essere racchiuso tra virgolette.

### Esempio:

INDIRIZZO(1; 1; 2; "Foglio2") restituisce quanto segue: Foglio2.A$1

Se la formula precedente si trova nella cella B2 del foglio corrente e la cella A1 nel foglio 2 contiene il valore -6, potete fare indirettamente riferimento alla relativa cella con una funzione in B2, digitando la formula =ASS(INDIRETTO(B2)). Il risultato è il valore assoluto del riferimento specificato in B2, che in questo caso è 6.

## RIF.COLONNA

Restituisce il numero di colonna di un riferimento. Se il riferimento è una cella, viene restituito il numero di colonna della cella; se si tratta di un intervallo di celle, vengono restituiti i numeri di colonna corrispondenti in una matrice a riga singola a condizione che la formula sia stata inserita come formula di matrice. Se la funzione RIF.COLONNA avente quale parametro un riferimento a un'area non viene usata in una formula di matrice, viene restituito solo il numero di colonna della prima cella.

### Sintassi

RIF.COLONNA(Riferimento)

Riferimento è il riferimento a una cella, o a un intervallo di celle, il cui primo numero di colonna deve essere rilevato.

Se non è indicato alcun riferimento, viene rilevato il numero colonna della cella nella quale è digitata la formula. LibreOffice Calc è in grado d'impostare automaticamente il riferimento alla cella corrente.

### Esempio

=RIF.COLONNA(A1) restituisce 1. La colonna A è la prima colonna della tabella.

=RIF.COLONNA(C3:E3) restituisce 3. Poiché la colonna C è la terza colonna della tabella.

=RIF.COLONNA(D3:G10) restituisce 4, poiché la colonna D è la quarta colonna della tabella e la funzione RIF.COLONNA non viene utilizzata come formula di matrice (in questo caso viene sempre preso come risultato il primo valore della matrice).

{=RIF.COLONNA(B2:B7)} e RIF.COLONNA(B2:B7) restituiscono entrambe 2, poiché il riferimento contiene solo la colonna B come seconda colonna della tabella. Poiché nelle aree con una sola colonna è presente un solo numero di colonna, non ha alcuna rilevanza se la formula viene utilizzata o meno come formula di matrice.

=RIF.COLONNA() restituisce 3 se la formula è stata digitata nella colonna C.

{=RIF.COLONNA(lepre)} restituisce la matrice a riga singola (3, 4), se "lepre" rappresenta l'area indicata (C1:D3).

## RIF.RIGA

Restituisce il numero di riga di un riferimento. Se il riferimento è una cella, restituisce il numero di riga della cella. Se il riferimento è un'area di celle, restituisce i numeri di riga corrispondenti in una matrice a una sola colonna, a condizione che la formula sia inserita come formula di matrice. Se la funzione RIF.RIGA avente quale parametro un riferimento a un'area non viene usata in una formula di matrice, viene restituito solo il numero di riga della prima cella.

### Sintassi

RIF.RIGA(Riferimento)

Riferimento è una cella, un'area di celle o il nome di un'area.

Se non è indicato alcun riferimento, viene rilevato il numero riga della cella in cui è stata digitata la formula. LibreOffice Calc è in grado d'impostare automaticamente il riferimento nella cella corrente.

### Esempio

=RIF.RIGA(B3) restituisce 3, poiché il riferimento indica la terza riga della tabella.

{=RIF.RIGA(D5:D8)} restituisce la matrice a colonna singola (5, 6, 7, 8), poiché il riferimento indicato contiene le righe da 5 a 8.

=RIF.RIGA(D5:D8) restituisce 5, poiché la funzione RIF.RIGA non viene usata come formula di matrice e quindi viene restituito solo il numero della prima riga del riferimento.

{=RIF.RIGA(A1:E1)} e =RIF.RIGA(A1:E1) restituiscono entrambe 1, poiché il riferimento contiene solo la riga 1 come la prima colonna della tabella. Poiché nelle aree a riga singola è presente solo un numero di riga, non ha alcuna rilevanza se la formula viene utilizzata o no come formula di matrice.

=RIF.RIGA() restituisce 3, se la formula è stata digitata nella riga 3.

{=RIF.RIGA(lepre)} restituisce la matrice a colonna singola (1, 2, 3), se "lepre" rappresenta l'area indicata (C1:D3).

## RIGHE

Restituisce il numero di righe in un riferimento o in una matrice.

### Sintassi

RIGHE(Matrice)

Matrice è il riferimento o l'indicazione di area di cui deve essere determinato il numero di righe.

### Esempio

=Righe(B5) restituisce 1, poiché una cella racchiude una sola riga.

=RIGHE(A10:B12) restituisce 3.

=RIGHE(Lepre) restituisce 3, se "Lepre" è l'area indicata (C1:D3).

## SCARTO

Restituisce il valore di una cella che è spostata rispetto al punto di partenza.

### Sintassi

SCARTO(Riferimento; Righe; Colonne; Altezza; Larghezza)

Riferimento è la cella a partire dalla quale la funzione rileva il nuovo riferimento.

Righe è il numero delle righe in base a cui il riferimento viene corretto in alto (valore negativo) oppure in basso. Usate 0 per rimanere nella stessa riga.

Colonne è il numero delle colonne in base a cui il riferimento viene corretto alla sinistra (valore negativo) oppure alla destra. Usate 0 per rimanere nella stessa colonna.

Altezza è l'altezza verticale opzionale per un'area che inizia con il nuovo riferimento di posizione.

Larghezza è la larghezza orizzontale opzionale per un'area che inizia con il nuovo riferimento.

Gli argomenti righe e colonne non devono condurre a un inizio di riga o colonna pari a zero o negativo.

Gli argomenti altezza e larghezza non devono condurre a un conteggio di righe o colonne pari a zero o negativo.

Nelle funzioni di LibreOffice Calc, i parametri contrassegnati come "opzionali" possono essere tralasciati solo quando non sono seguiti da altri parametri. Ad esempio, in una funzione con quattro parametri in cui gli ultimi due sono contrassegnati come "opzionali", potete tralasciare il parametro 4 oppure i parametri 3 e 4, ma non il solo parametro 3.

### Esempio

=SCARTO(A1; 2; 2) restituisce il valore nella cella C3 (A1 spostato di due righe e due colonne verso destra in basso). Se in C3 è presente il valore 100, questa funzione ha come risultato il valore 100.

=SCARTO(B2:C3;1;1) restituisce un riferimento a B2:C3 spostato in basso di una riga e a destra di una colonna (C3:D4).

=SCARTO(B2:C3;-1;-1) restituisce un riferimento a B2:C3 spostato di una riga e una colonna alla sinistra (A1:B2).

=SCARTO(B2:C3;0;0;3;4) restituisce un riferimento a B2:C3 ridimensionato a 3 righe e 4 colonne (B2:E4).

=SCARTO(B2:C3;1;0;3;4) restituisce un riferimento a B2:C3 spostato in basso di una riga e ridimensionato in tre righe e quattro colonne (B3:E5).

=SOMMA(SCARTO(A1;2;2;5;6)) definisce la somma dell'intervallo che inizia con la cella C3 ed è alta 5 righe e larga 6 colonne (intervallo=C3:H7).

Se si include la larghezza o l'altezza, la funzione SCARTO restituisce un intervallo e deve essere quindi inserita come formula di matrice. Se non è presente né altezza né larghezza, viene restituito un riferimento di cella.

## SCEGLI

Restituisce un valore determinato da un indice da un elenco contenente un massimo di 30 argomenti.

### Sintassi

SCEGLI(Indice; Valore 1; ...;Valore 30)

Indice come riferimento o numero tra 1 e 30 indica il valore da estrarre dall'elenco.

Valore 1, Valore 2, ..., Valore 30 è l'elenco dei valori che vengono digitati come riferimento di una cella oppure come valore proprio.

### Esempio

=SCEGLI(A1; B1; B2; B3; "Oggi"; "Ieri"; "Domani"), ad esempio, restituisce per A1 = 2 il contenuto della cella B2, per A1 = 4 il testo "Oggi".

## STILE

Applica uno stile alla cella che contiene la formula. Dopo un periodo di tempo stabilito può essere applicato un altro stile. Questa funzione restituisce sempre il valore 0, consentendovi di aggiungerla a un'altra funzione senza modificarne il valore. Insieme con la funzione ATTUALE potete applicare un colore a un cella in base al valore. Per esempio: =...+STILE(SE(ATTUALE()>3;"red";"green")) applica lo stile "rosso" alla cella se il valore è maggiore di 3, in caso contrario viene applicato lo stile "verde". Entrambi i formati di cella "rosso" e "verde" devono essere definiti prima.

### Sintassi

STILE("Stile"; Tempo; "Stile2")

Stile è il nome dello stile di formato assegnato alla cella. I nomi degli stili di formato devono essere inseriti tra virgolette.

Tempo è l'intervallo di tempo opzionale espresso in secondi. Se manca questo parametro, lo stile non viene cambiato dopo un dato periodo di tempo.

Stile2 è il nome opzionale per un stile di formato assegnato alla cella al trascorrere di un determinato intervallo di tempo. Se manca questo parametro, il sistema utilizza lo stile "Predefinito".

Nelle funzioni di LibreOffice Calc, i parametri contrassegnati come "opzionali" possono essere tralasciati solo quando non sono seguiti da altri parametri. Ad esempio, in una funzione con quattro parametri in cui gli ultimi due sono contrassegnati come "opzionali", potete tralasciare il parametro 4 oppure i parametri 3 e 4, ma non il solo parametro 3.

### Esempio

=STILE("Invisibile"; 60; "Predefinito") consente di formattare la cella per 60 secondi dopo che il documento è stato nuovamente calcolato o caricato utilizzando il formato Invisibile, dopo di che alla cella viene assegnato il formato Predefinito. Entrambi i formati di cella devono essere definiti in precedenza.

Poiché STILE() restituisce un valore numerico pari a zero, questo valore viene allegato a una stringa. Ciò può essere evitato utilizzando T(), come nel seguente esempio.

="Testo"&T(STILE("mioStile"))

Vedere anche ATTUALE() per un altro esempio.

Argomenti correlati

Funzioni per categoria