Moduł
Spis treści
Indeks 🔎︎

# Funkcje tekstowe

Niniejsza sekcja zawiera opisy funkcji tekstowych.

Aby wykonać tę operację...

Wstaw - Funkcja - Kategoria Tekst

## REGEX

Matches and extracts or optionally replaces text using regular expressions.

## WEBSERVICE

Pobiera zawartość internetową z URI.

## FILTERXML

Zastosuj wyrażenie XPath do dokumentu XML.

## ENCODEURL

Zwraca ciąg znaków zakodowany w standardzie URL.

## ARABSKIE

Oblicza wartość liczby zapisanej cyframi rzymskimi. Liczba musi być z przedziału pomiędzy 0 a 3999.

### Składnia

ARABSKIE("Tekst")

Tekst oznacza tekst reprezentujący liczbę zapisaną cyframi rzymskimi.

### Przykład

=ARABSKIE("MXIV") zwraca wartość 1014

=ARABSKIE("MMII") zwraca wartość 2002

## ASC

Funkcja ASC konwertuje znaki ASCII i katakana o pełnej szerokości do znaków ASCII lub katakana o połowie szerokości. Zwraca ciąg tekstowy.

Zobacz http://wiki.documentfoundation.org/Calc/Features/JIS_and_ASC_functions dla tabeli konwersji.

### Składnia

ASC("tekst")

Tekst to wartość tekstowa, która zawiera znaki do konwersji.

Zobacz również: Funkcja JIS.

## BAT.TEKST

Zamienia liczbę na tekst tajski łącznie z nazwami waluty tajlandzkiej.

### Składnia

BAT.TEKST(Liczba)

Liczba to dowolna liczba. Wartość "Baht" jest dołączana do części całkowitej liczby, a "Satang" do części ułamkowej.

### Przykład

=BAT.TEKST(12,65) zwraca ciąg tekstowy zapisany w znakach alfabetu tajskiego, który oznacza "12 batów i 65 satangów".

## DŁ

Zwraca długość ciągu wraz ze spacjami.

### Składnia

DŁ("tekst")

Tekst to wartość tekstowa, dla której należy określić znak.

### Przykład

=DŁ("Dzień dobry") zwraca wartość 11.

=DŁ(12345,67) zwraca wartość 8.

## DŁ.B

Dla dwubajtowych zestawów znaków języków (DBCS), zwracana jest liczba bajtów użytych do reprezentacji znaków w ciągu tekstowym.

### Składnia

DŁ.B("Tekst")

Tekst to wartość tekstowa, dla której należy określić znak.

### Przykład

DŁ.B("中") zwraca 2 (1 znak DBCS składający się z 2 bajtów).

DŁ.B("中国") zwraca 4 (2 znaki DBCS każdy składający się z 2 bajtów).

DŁ.B("office") zwraca 6 (6 znaków nie DBCS każdy składający się z 1 bajtu)

=DŁ.B("Dzień dobry") zwraca wartość 11.

=DŁ.B(12345,67) zwraca wartość 8.

## FRAGMENT.TEKSTU

Zwraca fragment podanego ciągu znaków. Parametry określają pozycję początkową i liczbę znaków.

### Składnia

FRAGMENT.TEKSTU("tekst"; liczba_początkowa; liczba)

Tekst jest ciągiem zawierającym znaki, które należy pobrać.

Start to pozycja pierwszego znaku w tekście do pobrania.

Liczba określa liczbę znaków części tekstu.

### Przykład

=FRAGMENT.TEKSTU("office";2;2) zwraca wartość ff.

## FRAGMENT.TEKSTU.B

Zwraca fragment podanego ciągu znaków. Parametry określają pozycję początkową i liczbę znaków.

### Składnia

FRAGMENT.TEKSTU.B("Tekst"; Liczba_początkowa; Liczba_bajtów)

Tekst jest ciągiem zawierającym znaki, które należy pobrać.

Liczba_początkowa to pozycja pierwszego znaku w tekście do pobrania.

Liczba_bajtów określa liczbę znaków, którą FRAGMENT.TEKSTU.B zwróci z tekstu, w bajtach.

### Przykład

FRAGMENT.TEKSTU.B("中国";1;0) zwraca "" (0 bajtów jest zawsze pustym ciągiem).

FRAGMENT.TEKSTU.B("中国";1;1) zwraca " " (1 bajt jest połową znaku DBCS i wynikiem jest znak spacji).

FRAGMENT.TEKSTU.B("中国";1;2) zwraca "中" (2 bajty stanowią jeden kompletny znak DBCS).

FRAGMENT.TEKSTU.B("中国";1;3) zwraca "中 " (3 bajty stanowią jeden znak DBCS i połowę następnego, ostatni bajt jest zwracany jako znak spacji).

FRAGMENT.TEKSTU.B("中国";1;4) zwraca "中国" (4 bajty stanowią dwa kompletne znaki DBCS).

FRAGMENT.TEKSTU.B("中国";2;1) zwraca " " (pozycja bajtu 2 nie jest początkiem znaku w ciągu DBCS, 1 znak spacji jest zwracany).

FRAGMENT.TEKSTU.B("中国";2;2) zwraca " " (pozycja bajtu 2 punktów do ostatniej połowy pierwszego znaku w ciągu DBCS, 2 bajty stanowią ostatnią połowę pierwszego znaku i pierwszą połowę drugiego znaku w ciągu, 2 znaki spacji są zwracane).

FRAGMENT.TEKSTU.B("中国";2;3) zwraca " 国" (pozycja bajtu 2 nie jest początkiem znaku w ciągu DBCS, zwracany jest znak spacji dla pozycji bajtu 2).

FRAGMENT.TEKSTU.B("中国";3;1) " " (pozycja bajtu 3 nie jest początkiem znaku w ciągu DBCS, ale 1 bajt jest tylko połową znaku DBCS i zwracany jest znak spacji)

FRAGMENT.TEKSTU.B("中国";3;2) zwraca "国" (pozycja bajtu 3 jest początkiem znaku w ciągu DBCS i 2 bajty stanowią jeden znak DBCS).

FRAGMENT.TEKSTU.B("office";2;3) zwraca "ffi" (pozycja bajtu 2 jest początkiem znaku w ciągu nie DBCS i 3 bajty ciągu nie DBCS stanowią 3 znaki).

## JIS

Funkcja JIS konwertuje znaki ASCII i katakana o połowie szerokości do znaków o pełnej szerokości. Zwraca ciąg tekstowy.

Zobacz http://wiki.documentfoundation.org/Calc/Features/JIS_and_ASC_functions dla tabeli konwersji.

### Składnia

JIS("tekst")

Tekst to wartość tekstowa, która zawiera znaki do konwersji.

Zobacz również: Funkcja ASC.

## KOD

Zwraca kod numeryczny pierwszego znaku łańcucha znakowego.

### Składnia

KOD("Tekst")

Tekst to wartość tekstowa, dla której należy znaleźć kod pierwszego znaku.

Kody zawierające więcej niż 127 znaków mogą być zależne od sposobu mapowania znaków w systemie (np. iso-8859-1, iso-8859-2, Windows-1252 czy Windows-1250), w związku z czym nie zawsze można ich używać na różnych platformach.

### Przykład

=KOD("Hieronymus") zwraca wartość 72, =KOD("hieroglyphic") zwraca wartość 104.

Kod numeryczny nie musi odpowiadać tabeli ASCII, lecz tabeli znaków aktualnie używanej.

## KWOTA

Przekształca liczbę na wartość w formacie walutowym, zaokrąglając ją do określonej liczby miejsc po przecinku. W polu Wartość należy wprowadzić liczbę, która ma być przekształcona na format walutowy. Opcjonalnie w polu Dziesiętne można podać liczbę miejsc po przecinku. Jeśli nie została określona żadna wartość, wszystkie liczby w formacie walutowym będą wyświetlane z dwoma miejscami po przecinku.

Format waluty definiuje się w ustawieniach systemowych.

### Składnia

KWOTA(wartość; dziesiętne)

Wartość jest liczbą, odwołaniem do komórki zawierającej liczbę lub formułą zwracającą liczbę.

Dziesiętne to parametr opcjonalny, który określa liczbę miejsc dziesiętnych.

### Przykład

=KWOTA(255) zwraca wartość 255,00 zł.

=KWOTA(367,456;2) zwraca wartość 367,46 zł. Należy użyć separatora dziesiętnego, który jest zgodny z bieżącymi ustawieniami regionalnymi.

## LEWY

Zwraca początkowe znaki w ciągu tekstowym.

### Składnia

LEWY("tekst"; liczba)

Tekst to wartość tekstowa, dla której należy określić początkowe słowa cząstkowe.

Liczba (parametr opcjonalny) oznacza liczbę znaków w początkowej części tekstu. Jeśli ten parametr nie został zdefiniowany, zwracany jest jeden znak.

### Przykład

=LEWY("wyjście";3) zwraca wartość “wyj”.

## LEWYB

Zwraca początkowe znaki tekstu DBCS.

### Składnia

LEWYB("Tekst"; Liczba_bajtów)

Tekst to wartość tekstowa, dla której należy określić początkowe słowa cząstkowe.

Liczba_bajtów (opcjonalny) oznacza liczbę znaków, którą LEWYB ma wyodrębnić na podstawie bajtów. Jeśli ten parametr nie został zdefiniowany, zwracany jest jeden znak.

### Przykład

LEWYB("中国";1) zwraca " " (1 bajt jest tylko połową znaku DBCS i zwracany jest znak spacji).

LEWYB("中国";2) zwraca "中" (2 bajty stanowią jeden kompletny znak DBCS).

LEWYB("中国";3) zwraca "中 " (3 bajty stanowią jeden znak DBCS i połowę następnego, ostatni znak jest zwracany jako znak spacji).

LEWYB("中国";4) zwraca "中国" (4 bajty stanowią dwa kompletne znaki DBCS).

LEWYB("office";3) zwraca "off" (3 znaki nie DBCS każdy składający się z 1 bajtu)

## LITERY.MAŁE

Przekształca wszystkie wielkie litery ciągu tekstowego na małe.

### Składnia

LITERY.MAŁE("tekst")

Tekst oznacza ciąg, który należy przekształcić.

### Przykład

=LITERY.MAŁE("Słońce") zwraca wartość słońce.

## LITERY.WIELKIE

Zamienia litery ciągu określonego w polu Tekst na wielkie.

### Składnia

LITERY.WIELKIE("tekst")

Tekst oznacza ciąg zawierający małe litery, które mają zostać zamienione na wielkie.

### Przykład

=LITERY.WIELKIE("Dzień dobry") zwraca wartość DZIEŃ DOBRY.

## M.DZIESIĘTNE

Przekształca tekst składający się ze znaków systemu liczbowego o podanej podstawie na liczbę naturalną. Podstawa musi być liczbą w zakresie od 2 do 36. Spacje i tabulatory są ignorowane. Pole Tekst nie rozróżnia wielkości liter.

Jeśli podstawą systemu liczbowego jest 16, znaki x, X, 0x i 0X umieszczone na początku liczby, a także znaki h i H na końcu liczby są pomijane. Jeśli podstawą systemu jest 2, znaki b lub B na końcu liczby są pomijane. Inne znaki nie należące do danego systemu liczbowego powodują błąd.

### Składnia

M.DZIESIĘTNE("tekst"; podstawa)

Tekst to wartość tekstowa do konwersji. W celu odróżnienia liczby szesnastkowej takiej jak A1 od odwołania do komórki A1 liczbę należy umieścić w cudzysłowie, na przykład "A1" lub "FACE".

Podstawa oznacza podstawę systemu liczbowego. Może to być dowolna liczba całkowita z zakresu od 2 do 36.

### Przykład

=M.DZIESIĘTNE("17";10) zwraca wartość 17.

=M.DZIESIĘTNE("FACE";16) zwraca wartość 64206.

=M.DZIESIĘTNE("0101";2) zwraca wartość 5.

## OCZYŚĆ

Funkcja usuwa z łańcucha wszystkie znaki niedrukowalne.

### Składnia

OCZYŚĆ("tekst")

Tekst oznacza wartość tekstową, z której zostaną usunięte wszystkie znaki niedrukowalne.

## PODSTAW

Podstawia nowy tekst w miejsce starego we wskazanym ciągu znaków.

### Składnia

PODSTAW("tekst"; "szukany_tekst"; "nowy_tekst"; wystąpienie)

Tekst jest tekstem, w którym segmenty zostaną zastąpione.

Szukany_tekst to segment tekstu, który ma być zastąpiony (określoną liczbę razy).

Nowy_tekst jest tekstem, który ma zastąpić segment.

Wystąpienie (parametr opcjonalny) wskazuje na numer wystąpienia wyszukiwanego tekstu, które ma być zamienione. Przy braku tego parametru zamienione zostaną wszystkie wystąpienia.

### Przykład

=PODSTAW("123123123";"3";"abc") zwraca 12abc12abc12abc.

=PODSTAW("123123123";"3";"abc";2) zwraca wartość 12abc12abc12abc.

## PODSTAWA

Zamienia liczbę naturalną o podanej podstawie na tekst w określonym systemie liczbowym. Używane są cyfry 0-9 i litery A-Z.

### Składnia

PODSTAWA(liczba; podstawa; [minimalna_długość])

Liczba to dodatnia liczba całkowita do konwersji.

Podstawa oznacza podstawę systemu liczbowego. Może to być dowolna liczba całkowita z zakresu od 2 do 36.

Minimalna_długość (parametr opcjonalny) oznacza minimalną długość utworzonej sekwencji znaków. Jeśli długość tekstu jest mniejsza niż określona długość minimalna, zostanie on uzupełniony zerami z lewej strony.

### Przykład

=PODSTAWA(17;10;4) zwraca wartość 0017 w systemie dziesiętnym.

=PODSTAWA(17;2) zwraca wartość 10001 w systemie dwójkowym.

=PODSTAWA(255;16;4) zwraca wartość 00FF w systemie szesnastkowym.

## PORÓWNAJ

Porównuje dwa ciągi tekstowe i zwraca wartość PRAWDA, jeśli są identyczne. Funkcja rozróżnia wielkość liter.

### Składnia

PORÓWNAJ("tekst_1";"tekst_2")

Tekst_1 oznacza pierwszy tekst do porównania.

Tekst_2 to druga porównywana wartość tekstowa.

### Przykład

=PORÓWNAJ(" microsystems";" Microsystems") zwraca wartość FAŁSZ.

## POWT

Powtarza łańcuch znakowy określoną ilość razy.

### Składnia

POWT("tekst"; ilość)

Tekst to wartość tekstowa, która ma być powtarzana.

Liczba oznacza liczbę powtórzeń.

Wynik może mieć maksymalnie 255 znaków.

### Przykład

=POWT("Dzień dobry";2) zwraca wartość Dzień dobryDzień dobry.

## PRAWY

Zwraca ostatnie znaki w ciągu tekstowym.

### Składnia

PRAWY("tekst"; liczba)

Tekst jest tekstem, dla którego należy określić część po prawej stronie.

Liczba (parametr opcjonalny) określa liczbę znaków części tekstu po prawej stronie.

### Przykład

=PRAWY("Słońce";2) zwraca wartość ce.

## PRAWY.B

Zwraca ostatni znak lub znaki tekstu z dwubajtowych zestawów znaków (DBCS).

### Składnia

PRAWY.B("Tekst"; Liczba_bajtów)

Tekst jest tekstem, dla którego należy określić część po prawej stronie.

Liczba_bajtów (opcjonalny) oznacza liczbę znaków, którą PRAWY.B ma wyodrębnić na podstawie bajtów.

### Przykład

PRAWY.B("中国";1) zwraca " " (1 bajt jest tylko połową znaku DBCS i zwracany jest znak spacji).

PRAWY.B("中国";2) zwraca "国" (2 bajty stanowią jeden kompletny znak DBCS).

PRAWY.B("中国";3) zwraca " 国" (3 bajty stanowią połowę jednego znaku DBCS i jeden cały znak DBCS, spacja zwracana jest dla pierwszej połowy).

PRAWY.B("中国";4) zwraca "中国" (4 bajty stanowią dwa kompletne znaki DBCS).

PRAWY.B("office";3) zwraca "ice" (3 znaki nie DBCS każdy składający się z 1 bajtu).

## RZYMSKIE

Zamienia liczbę arabską na rzymską. Liczba musi być z przedziału pomiędzy 0 a 3999, natomiast tryb może być liczbą całkowitą w zakresie od 0 do 4.

### Składnia

RZYMSKIE(liczba, tryb)

Liczba to wartość liczbowa, która ma być zamieniona na liczbę rzymską.

Tryb (parametr opcjonalny) oznacza stopień uproszczenia. Im wyższa wartość, tym bardziej zostanie uproszczona liczba rzymska.

### Przykład

=RZYMSKIE(999) zwraca wartość CMXCIX

=RZYMSKIE(999;0) zwraca wartość CMXCIX

=RZYMSKIE(999;1) zwraca wartość LMVLIV

=RZYMSKIE(999;2) zwraca wartość XMIX

=RZYMSKIE(999;3) zwraca wartość VMIV

=RZYMSKIE(999;4) zwraca wartość IM

## SZUKAJ.TEKST

Returns the position of a text segment within a character string. You can set the start of the search as an option. The search text can be a number or any sequence of characters. The search is not case-sensitive. If the text is not found, returns error 519 (#VALUE).

The search supports regular expressions. You can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must precede every character with a "\" character. You can switch the automatic evaluation of regular expression on and off in LibreOffice - PreferencesTools - Options - LibreOffice Calc - Calculate.

### Składnia

SZUKAJ.TEKST("znajdź_tekst"; "tekst"; pozycja)

Znajdź_tekst oznacza szukany tekst.

Tekst jest tekstem, w którym będzie prowadzone wyszukiwanie.

Pozycja (parametr opcjonalny) oznacza pozycję w tekście, od której rozpocznie się wyszukiwanie.

### Przykład

=SZUKAJ.TEKST(54;998877665544) zwraca wartość 10.

## T

Funkcja zwraca tekst docelowy lub tekst pusty, jeżeli ciąg docelowy nie jest sformatowany jako tekst.

### Składnia

T(wartość)

Wartość jest wartością, którą należy przekształcić. Jako parametru można także użyć odwołania. Jeśli komórka odwołania zawiera liczbę lub formułę zwracającą wynik numeryczny, wynikiem tej funkcji będzie ciąg pusty.

### Przykład

=T(12345) zwraca pusty ciąg.

=T("12345") zwraca wartość tekstową 12345.

## TEKST

Zamienia liczbę na tekst w podanym formacie.

### Składnia

TEKST(liczba; format)

Liczba to wartość liczbowa do konwersji.

Format to wartość tekstowa, która definiuje format. Przecinek dziesiętny i separator tysięcy muszą być zgodne z formatem komórki dla danego języka.

### Przykład

=TEKST(12,34567;"###.##") zwraca wartość tekstową 12,35

=TEKST(12,34567;"000,00") zwraca wartość tekstową 012,35

See also Number format codes: custom format codes defined by the user.

## UNICHAR

Konwertuje kod liczbowy na znak lub literę Unicode.

### Składnia

UNICHAR(numer)

### Przykład

=UNICHAR(169) zwraca znak praw autorskich ©.

Zobacz także funkcję UNICODE ()

## UNICODE

Zwraca kod liczbowy pierwszego znaku Unicode w ciągu tekstowym.

### Składnia

UNICODE("Text")

### Przykład

=UNICODE("©") zwraca numer kodu Unicode (169) dla znaku praw autorskich.

Zobacz także funkcję UNICHAR().

## USUŃ.ZBĘDNE.ODSTĘPY

Usuwa spacje na początku ciągu lub wyrównuje zawartość komórki do lewej.

### Składnia

USUŃ.ZBĘDNE.ODSTĘPY("tekst")

Tekst oznacza tekst, z którego mają być usunięte spacje.

### Przykład

=USUŃ.ZBĘDNE.ODSTĘPY(" wita świecie ") zwraca "witaj świecie" z pojedynczą spacją między wyrazami i bez spacji początkowej oraz końcowej.

## WARTOŚĆ

Przekształca ciąg znakowy na wyrażenie numeryczne.

### Składnia

WARTOŚĆ("tekst")

Tekst jest ciągiem, który należy przekształcić na liczbę.

### Przykład

=WARTOŚĆ("4321") zwraca 4321.

## Z.WIELKIEJ.LITERY

Zamienia pierwszą literę na wielką w każdym wyrazie w tekście.

### Składnia

Z.WIELKIEJ.LITERY("tekst")

Tekst oznacza ciąg, który należy przekształcić.

### Przykład

=Z.WIELKIEJ.LITERY("open office") zwraca wartość Open Office.

## ZAOKR.DO.TEKST

Formatuje wyświetlanie liczby, uwzględniając ustaloną liczbę miejsc po przecinku i wyświetlanie separatora tysięcy.

### Składnia

ZAOKR.DO.TEKST(liczba; dziesiętne; bez_separatorów_tysięcy)

Liczba oznacza wartość liczbową do sformatowania.

Dziesiętne określa liczbę wyświetlanych miejsc dziesiętnych.

Bez_separatorów_tysięcy (parametr opcjonalny) określa, czy mają być używane separatory tysięcy. Jeśli parametr jest inny niż 0, separator tysięcy zostanie pominięty. Jeśli parametr jest równy 0 lub nie został podany, separatory tysięcy będą wyświetlane zgodne z bieżącymi ustawieniami regionalnymi.

### Przykład

=ZAOKR.DO.TEKST(1234567,89;3) zwraca 1 234 567,890 w postaci ciągu tekstowego.

=ZAOKR.DO.TEKST(1234567,89;3;1) zwraca wartość 1234567,890 w postaci ciągu tekstowego.

## ZASTĄP

Zamienia część łańcucha tekstowego innym łańcuchem tekstowym. Ta funkcja może być użyta zarówno do znaków jak i liczb (które są automatycznie konwertowane na tekst). Wynik działania tej funkcji zawsze jest tekstem. Jeśli masz zamiar dokonywać obliczeń z użyciem liczb, które zostały zamienione na tekst musisz przeprowadzić ponownie konwersję na liczbę przy użyciu funkcji WARTOŚĆ.

Jeżeli nie chcesz, by tekst zawierający liczby był interpretowany jako liczba i automatycznie konwertowany na tekst, musisz zawrzeć go w cudzysłów.

### Składnia

ZASTĄP("tekst"; pozycja; długość; "nowy tekst")

Tekst jest to łańcuch znakowy, którego część chcesz zamienić.

Pozycja oznacza pozycję w tekście, od której rozpocznie się zastępowanie.

Długość to liczba znaków w wartości Tekst, którą należy zastąpić.

Nowy_tekst oznacza tekst, który ma zastąpić wartość Tekst.

### Przykład

=ZASTĄP("1234567";1;1;"444") zwraca wartość "444234567". Jeden znak w pozycji 1 jest zastępowany przez całe wyrażenie Nowy_tekst.

## ZNAJDŹ

Poszukuje ciągu tekstowego w innym ciągu. Funkcja pozwala także zdefiniować początek wyszukiwania. Wyszukiwany ciąg może być liczbą lub dowolnym ciągiem znakowym. Funkcja rozróżnia wielkość liter.

### Składnia

ZNAJDŹ("znajdź_tekst";"tekst";pozycja)

Znajdź_tekst oznacza szukany tekst.

Tekst jest tekstem, w którym będzie prowadzone wyszukiwanie.

Pozycja (parametr opcjonalny) oznacza pozycję w tekście, od której rozpocznie się wyszukiwanie.

### Przykład

=ZNAJDŹ(76;998877665544) zwraca wartość 6.

## ZNAK

Zamienia liczbę na znak zgodnie z tabelą kodową. Liczba może być dwucyfrową lub trzycyfrową liczbą całkowitą.

Kody zawierające więcej niż 127 znaków mogą być zależne od sposobu mapowania znaków w systemie (np. iso-8859-1, iso-8859-2, Windows-1252 czy Windows-1250), w związku z czym nie zawsze można ich używać na różnych platformach.

### Składnia

ZNAK(liczba)

Liczba to wartość liczbowa z zakresu od 1 do 255, która odpowiada wartości kodu danego znaku.

### Przykład

=ZNAK(100) zwraca znak d.

="abc" & ZNAK(10) & "def" wstawia do ciągu tekstowego znak nowej linii.

## ZŁĄCZ.TEKSTY

Łączy wiele łańcuchów znakowych w jeden.

### Składnia

ZŁĄCZ.TEKSTY("Tekst 1";...;"Tekst 30")

Tekst_1; Tekst_2; ... oznacza do 30 fragmentów tekstu, które mają być połączone w jeden łańcuch.

### Przykład

=ZŁĄCZ.TEKSTY("Dzień";"dobry";"panie";"Kowalski") zwraca: Dzień dobry panie Kowalski.

Tematy pokrewne

Funkcje według kategorii