Modulo
Contenuto
Indice 🔎︎

# Istruzione MkDir

Crea una nuova cartella in un supporto di dati.

## Sintassi:

    MkDir Text As String

## Parametri:

Text (Testo): stringa che specifica il nome e il percorso della cartella da creare. In alternativa, potete usare una notazione URL.

Se il percorso non è determinato, la cartella viene creata nella cartella attiva.

## Codici di errore:

5 Richiamo di procedura non valido

76 Percorso non trovato

## Esempio:

    Sub ExampleFileIO
    ' Esempio per funzioni di organizzazione file
    Const sFile1 As String = "file://c|/autoexec.bat"
    Const sDir1 As String = "file://c|/Temp"
    Const sSubDir1 As String ="Prova"
    Const sFile2 As String = "Copiato.tmp"
    Const sFile3 As String = "Rinominato.tmp"
    Dim sFile As String
        sFile = sDir1 + "/" + sSubDir1
        ChDir( sDir1 )
        If Dir(sSubDir1,16)="" Then ' La cartella esiste?
            MkDir sSubDir1
            MsgBox sFile,0,"Crea cartella"
        End If
        sFile = sFile + "/" + sFile2
        FileCopy sFile1 , sFile
        MsgBox fSysURL(CurDir()),0,"Cartella attiva"
        MsgBox sFile & Chr(13) & FileDateTime( sFile ),0,"Data e ora di creazione"
        MsgBox sFile & Chr(13)& FileLen( sFile ),0,"Lunghezza del file"
        MsgBox sFile & Chr(13)& GetAttr( sFile ),0,"Attributi del file"
        Name sFile As sDir1 + "/" + sSubDir1 + "/" + sFile3
        ' Rinomina nella stessa cartella
        sFile = sDir1 + "/" + sSubDir1 + "/" + sFile3
        SetAttr( sFile, 0 ) 'Elimina tutti gli attributi
        MsgBox sFile & Chr(13) & GetAttr( sFile ),0,"Nuovi attributi del file"
        Kill sFile
        RmDir sDir1 + "/" + sSubDir1
    End Sub

    ' Converte un percorso di sistema in URL
    Function fSysURL( fSysFp As String ) As String
    Dim iPos As String
        iPos = 1
        iPos = Instr(iPos,fSysFp, getPathSeparator())
        Do While iPos > 0
            Mid( fSysFp, iPos , 1,"/")
            iPos = Instr(iPos+1,fSysFp, getPathSeparator())
        Loop
        ' due punti con DOS
        iPos = Instr(1,fSysFp,":")
        If iPos > 0 Then Mid( fSysFp, iPos , 1,"|")
        fSysURL = "file://" & fSysFp
    End Function