Modul
Obsah
Index 🔎︎

# Maticové funkce

Tato kategorie obsahuje maticové funkce.

## Co je to matice?

Matice je souvislá oblast buněk, které obsahují nějaké hodnoty. Čtvercová oblast 3 řádků a 3 sloupců je matice 3 x 3:

| A | B | C
1 | 7 | 31 | 33
2 | 95 | 17 | 2
3 | 5 | 10 | 50

Pro náš tabulkový kalkulátor je nejmenší možná matice 1 x 2 nebo 2 x 1, sestávající ze dvou přilehlých buněk.

## Co je to maticový vzorec?

Maticový vzorec říkáme takovému vzorci, ve kterém vystupují hodnoty celé oblasti buněk. Rozdíl mezi maticovým vzorcem a jinými vzorci je ten, že maticový vzorec namísto jedné hodnoty operuje s více hodnotami najednou.

Nejenže maticový vzorec zpracovává několik hodnot najednou, ale také může vícero hodnot najednou vrátit. Přesněji řečeno, výsledek maticového vzorce může být také matice.

Chcete-li vynásobit hodnoty ve všech buňkách matice číslem 10, nemusíte používat vzorec na každou buňku nebo hodnotu. Místo toho použijte jednoduchý maticový vzorec. Vyberte v jiné části sešitu oblast o velikosti 3 x 3 buňky, vložte vzorec =10*A1:C3 a potvrďte jej kombinací kláves CommandCtrl+Shift+Enter. Výsledkem je matice 3 x 3, ve které jsou jednotlivé hodnoty v oblasti buněk (A1:C3) vynásobené číslem 10.

Kromě násobení je také možné použít na danou oblast buněk (matici) i jiné operátory. V programu LibreOffice Calc můžete sčítat (+), odčítat (-), násobit (*), dělit (/), používat exponenty (^), spojovat řetězce (&) a porovnávat (=, <>, <, >, <=, >=). Tyto operátory mohou být použity na každou jedinečnou hodnotu v dané oblasti buněk a při použití v maticovém vzorci vracejí jako výsledek matici.

Porovnávací operátory ve vzorci zpracovávají prázdné buňky stejným způsobem jako normální vzorec, který existuje buď jako nula nebo jako prázdný řetězec. Například jsou-li buňky A1 a A2 prázdné, oba vzorce {=A1:A2=""} a {=A1:A2=0} vrátí jeden sloupec a 2 řádky obsahující PRAVDA.

### Kdy použít maticový vzorec?

Maticové vzorce použijte tehdy, pokud musíte pro různé sady hodnot provádět opakované výpočty. Pokud se později rozhodnete změnit způsob výpočtu, stačí změnit pouze jeden maticový vzorec. Pro úpravu maticového vzorce vyberte všechny buňky z rozsahu matice a potom už můžete provést v maticovém vzorci požadované změny.

Použití maticových vzorců je také úsporné řešení výpočtu více položek najednou, protože tyto maticové výpočty nejsou příliš paměťově náročné. Navíc se jedná o základní nástroj pro provádění složitých výpočtů, protože je možné do výpočtu zahrnout několik oblastí buněk najednou. LibreOffice má pro matice speciální funkce, jako třeba MMULT pro násobení dvou matic nebo SUMPRODUCT pro výpočet jejich skalárního součinu.

## Použití maticových vzorců v programu LibreOffice Calc

Možné je také vytvořit "normální" vzorec, ve kterém odkazovaná oblast buněk indikuje maticový vzorec. Výsledek bude získán z průniku odkazované oblasti a řádků nebo sloupců, ve kterých se vzorec nachází. Je-li tento průnik prázdný nebo pokrývá-li několik řádků či sloupců, bude zobrazena chybová zpráva #VALUE!. Pro ilustraci slouží následující příklad:

### Vytváření maticových vzorců

Pokud vytváříte maticový vzorec s použitím Průvodce funkcí, musíte pokaždé zaškrtnout pole Matice. Potom budou výsledky výpočtu vráceny jako matice; v opačném případě bude vrácena pouze hodnota buňky v levém horním rohu zvolené oblasti.

Pokud zadáte maticový vzorec přímo do buňky, musíte použít místo klávesy Enter použít kombinaci Shift+CommandCtrl+Enter. Pouze tak bude vzorec uložen jako maticový.

Maticové vzorce se v programu LibreOffice Calc zobrazují ve složených závorkách. Prostým ručním přidáním složených závorek však maticový vzorec není možné vytvořit.

Buňky v matici výsledků jsou automaticky chráněny před změnami. Maticový vzorec je ovšem možné upravit nebo zkopírovat tak, že vyberete celou oblast buněk matice.

### Použití vložených matic ve vzorcích

Calc podporuje ve vzorcích vložené matice. Vložená matice je uzavřena ve složených závorkách '{' a '}'. Prvky matice mohou být čísla (i záporná), logické konstanty (PRAVDA, NEPRAVDA) nebo řetězec. Nejsou dovoleny nekonstantové výrazy. Matici lze zadat s jedním či více sloupci a jedním či více řádky. Každý řádek musí obsahovat stejný počet prvků, každý sloupec musí obsahovat stejný počet prvků.

Oddělovač sloupců (oddělující prvky v jednom řádku) a oddělovač řádků závisí na jazyku a národním prostředí. V této nápovědě však bude jako oddělovač sloupců používán středník ';' a jako oddělovač řádků svislá čára '|'. Například v anglickém národním prostředí se jako oddělovač sloupců používá čárka ',', zatímco jako oddělovač řádků se používá středník ';'.

Oddělovač řádků a sloupců můžete zobrazit či změnit v LibreOffice - PředvolbyNástroje - Možnosti - Calc - Vzorec - Oddělovače.

Matice nemohou být vnořené.

Příklady:

={1;2;3}

Matice s jedním řádkem obsahujícím tři čísla 1, 2 a 3.

Tuto matici konstant vložíte tím, že vyberete tři buňky v řádku, poté zadáte vzorec ={1;2;3} s použitím složených závorek a středníků a poté stisknete CommandCtrl+Shift+Enter.

={1;2;3|4;5;6}

Matice se dvěma řádky a třemi hodnotami v každém řádku.

={0;1;2|NEPRAVDA;PRAVDA;"dva"}

Matice se smíšenými hodnotami.

=SIN({1;2;3})

Pokud je funkce zadána jako maticový vzorec, vrátí výsledek tří výpočtů SIN pro argumenty 1, 2 a 3.

### Úpravy maticových vzorců

1. Vyberte oblast buněk nebo matici obsahující maticový vzorec. Chcete-li vybrat celou matici, umístěte kurzor na buňku v oblasti matice a poté stiskněte CommandCtrl+/, kde / je klávesa děleno na numerické klávesnici.

2. Stiskněte klávesu F2 nebo umístěte kurzor do vstupní řádky. Oběma způsoby zahájíte úpravy vzorce.

3. Po dokončení úprav stiskněte CommandCtrl+Shift+Enter.

Možné je formátovat jednotlivé části matice. Je například možné změnit barvu písma. Vyberte oblast buněk a potom změňte libovolný atribut.

### Kopírování maticových vzorců

1. Vyberte oblast buněk nebo matici obsahující maticový vzorec.

2. Stiskněte klávesu F2 nebo umístěte kurzor do vstupního řádku.

3. Stisknutím CommandCtrl+C zkopírujte vzorec do vstupní řádky.

4. Vyberte oblast buněk, do které chcete vložit maticový vzorec, a stiskněte F2 nebo umístěte kurzor do vstupní řádky.

5. Vložte vzorec stisknutím CommandCtrl+V na zvolené místo a potvrďte jej stisknutím kombinace kláves CommandCtrl+Shift+Enter. Vybraná oblast buněk nyní obsahuje maticový vzorec.

### Úprava oblasti matice

Pokud chcete upravit výslednou matici, udělejte následující:

1. Vyberte oblast buněk nebo matici obsahující maticový vzorec.

2. V pravém dolním rohu výběru se zobrazí ikona malého čtverce, jehož přetažením je možné rozšířit nebo zmenšit oblast matice.

Když upravíte oblast matice, samotný maticový vzorec nebude automaticky upraven. Pouze totiž měníte oblast buněk, ve které se objeví výsledky.

Pokud podržíte klávesu CommandCtrl, vytvoříte v dané oblasti kopii maticového vzorce.

### Podmíněné maticové výpočty

Podmíněný maticový výpočet je maticový vzorec, v němž jsou použity funkce IF() nebo CHOOSE(). Argument podmínky je oblast buněk nebo výsledná matice.

V následujícím příkladě je podmínka >0 vzorce {=IF(A1:A3>0;"ano";"ne")} použita na každou buňku v oblasti A1:A3 a výsledek je zkopírován do příslušné buňky.

| A | B (vzorec) | B (výsledek)
1 | 1 | {=IF(A1:A3>0;"ano";"ne")} | ano
2 | 0 | {=IF(A1:A3>0;"ano";"ne")} | ne
3 | 1 | {=IF(A1:A3>0;"ano";"ne")} | ano

Následující funkce poskytují vynucené zpracování matic: CORREL, COVAR, FORECAST, FTEST, INTERCEPT, MDETERM, MINVERSE, MMULT, MODE, PEARSON, PROB, RSQ, SLOPE, STEYX, SUMPRODUCT, SUMX2MY2, SUMX2PY2, SUMXMY2, TTEST. Je-li jako argument funkce použita oblast buněk (matice), funkce se chová jako maticová. Následující tabulka poskytuje příklady vynuceného zpracování matic:

| A | B (vzorec) | B (výsledek) | C (vynucený maticový vzorec) | C (výsledek)
1 | 1 | =A1:A2+1 | 2 | =SUMPRODUCT(A1:A2+1) | 5
2 | 2 | =A1:A2+1 | 3 | =SUMPRODUCT(A1:A2+1) | 5
3 |  | =A1:A2+1 | #VALUE! | =SUMPRODUCT(A1:A2+1) | 5

## FREQUENCY

Ukazuje rozdělení četností hodnot v jednosloupcové matici. Funkce vrací počet hodnot v matici Data, která jsou v hodnotách matice Třídy.

### Syntaxe

FREQUENCY(Data; Třídy)

Data představuje odkaz na hodnoty, které se mají spočítat.

Třídy představují matici omezujících hodnot.

Všeobecný úvod do maticových funkcí naleznete na začátku této stránky.

### Příklad

Sloupec A v následující tabulce obsahuje nesetříděné hodnoty měření. Sloupec B obsahuje horní meze intervalů, do kterých chceme rozdělit údaje ze sloupce A. Funkce FREQUENCY použije hodnotu v B1 k tomu, aby vrátila počet hodnot měření, které jsou menší nebo rovny 5. Na základě hodnoty B2 zase funkce FREQUENCY vrátí počet naměřených hodnot, které jsou větší než 5, nebo menší nebo rovny 10. Text ">25" zadaný do B6 slouží pouze pro lepší názornost.

| A | B | C
1 | 12 | 5 | 1
2 | 8 | 10 | 3
3 | 24 | 15 | 2
4 | 11 | 20 | 3
5 | 5 | 25 | 1
6 | 20 | >25 | 1
7 | 16 |  |
8 | 9 |  |
9 | 7 |  |
10 | 16 |  |
11 | 33 |  |

Vyberte jednosloupcovou oblast buněk, do které chcete vložit četnosti zdrojových hodnot. Musíte vybrat o jednu buňku více, než je počet tříd, do této buňky bude vložena četnost hodnot, které překračují horní limit poslední třídy. V tomto příkladě vyberte buňky C1:C6. V Průvodci funkcí zvolte funkci FREQUENCY. Jako Data dále zadejte oblast buněk obsahujících hodnoty měření (A1:A11) a také sloupec obsahující horní meze zkoumaných intervalů jako Třídy; tedy buňky B1:B6. Zaškrtněte pole Matice a klepněte na OK. V původně označené oblasti buněk C1:C6 se zobrazí četnosti hodnot měření v příslušných intervalech.

Podrobnější vysvětlení nahoře.

## GROWTH

Vypočte body ležící na exponenciální regresní křivce.

### Syntaxe

GROWTH(DataY; DataX; NováDataX; TypFunkce)

DataY reprezentuje data Y.

DataX (volitelné) reprezentuje data X.

NováDataX (volitelné) reprezentují data X, ve kterých budou přepočítány hodnoty.

TypFunkce (nepovinné). Pokud je Typ_Funkce = 0, bude vypočítána funkce ve tvaru y = m^x. Jinak se vypočítá funkce y = b*m^x.

Pokud jsou parametry funkcí LibreOffice Calc označeny jako "nepovinné", je možné je vynechat, pokud za nimi nenásledují žádné další parametry. Např. pokud má funkce čtyři parametry a poslední dva jsou označeny jako "nepovinné", je možné vynechat parametr 4 nebo parametry 3 a 4, ale není možné vynechat samotný parametr 3.

Podrobnější vysvětlení nahoře.

### Příklad

Tato funkce vrací matici a je ovládána stejným způsobem jako ostatní maticové funkce. Vyberte oblast, kde chcete, aby se objevily odpovědi a poté zvolte funkci. Vyberte DataY. Zadejte ostatní parametry, označte Matice a klikněte na tlačítko OK.

## LINEST

Vrátí statistickou tabulku pro přímku, která je nejlepším proložením množiny dat.

### Syntaxe

LINEST(data_Y; data_X; TypLinie; statistika)

data_Y je jeden řádek nebo sloupec, který určuje souřadnice Y v sadě datových bodů.

data_X je jeden řádek nebo sloupec, který určuje souřadnice X v sadě datových bodů. Pokud je data_X vynecháno, výchozí hodnota je 1, 2, 3, ..., n. Pokud je více sad proměnných, data_X může být oblast několika řádků či sloupců.

LINEST najde přímku y = a + bx, která nejlépe odpovídá datům. Použije se při tom lineární regrese (metoda "nejmenších čtverců"). Pokud je více sad proměnných, má přímka rovnici y = a + b1x1 + b2x2 ... + bnxn.

Pokud má typLinie hodnotu NEPRAVDA, přímka musí procházet počátečním bodem (konstanta a je nula; y = bx). Pokud je parametr vynechán, má typLinie hodnotu PRAVDA (přímka nemusí procházet počátkem).

Pokud je parametr statistika vynechán nebo NEPRAVDA, bude vrácen jen horní řádek statistické tabulky. Pokud má hodnotu PRAVDA, bude vrácena celá tabulka.

LINEST vrací tabulku (matici) statistik a musí být zadána jako maticový vzorec (například pomocí klávesové zkratky CommandCtrl+Shift+Enter namísto Enter).

Pokud jsou parametry funkcí LibreOffice Calc označeny jako "nepovinné", je možné je vynechat, pokud za nimi nenásledují žádné další parametry. Např. pokud má funkce čtyři parametry a poslední dva jsou označeny jako "nepovinné", je možné vynechat parametr 4 nebo parametry 3 a 4, ale není možné vynechat samotný parametr 3.

Podrobnější vysvětlení nahoře.

### Příklad

Tato funkce vrátí matici a funguje stejným způsobem jako jiné maticové funkce. Vyberte oblast pro výsledek a poté funkci. Vyberte data_Y. Pokud chcete, můžete vybrat i další parametry. Vyberte Matice a klepněte na tlačítko OK.

Výsledek vrácený systémem (pokud statistika = 0) bude ukazovat minimálně směrnici regresní přímky a její průsečík s osou Y. Pokud se parametr nerovná 0, bude zobrazen jiný výsledek.

### Další výsledky funkce LINEST:

Následující tabulka slouží jako příklad popisu dalších výsledků:

| A | B | C | D | E | F | G
1 | x1 | x2 | y |  | Hodnota LINEST |  |
2 | 4 | 7 | 100 |  | 4,17 | -3,48 | 82,33
3 | 5 | 9 | 105 |  | 5,46 | 10,96 | 9,35
4 | 6 | 11 | 104 |  | 0,87 | 5,06 | #NA
5 | 7 | 12 | 108 |  | 13,21 | 4 | #NA
6 | 8 | 15 | 111 |  | 675,45 | 102,26 | #NA
7 | 9 | 17 | 120 |  |  |  |
8 | 10 | 19 | 133 |  |  |  |

Sloupec A obsahuje několik hodnot X1, sloupec B několik hodnot X2 a sloupec C hodnoty Y. Tyto hodnoty už byly zadány. Nyní označíte rozsah buněk E2:G6 a spustíte Průvodce funkcí. Aby funkce LINEST fungovala, je nutné zaškrtnout pole Matice v Průvodci funkcí. Nyní zadejte následující hodnoty (označte příslušné oblasti buněk myší nebo je zapište pomocí klávesnice):

data_Y je C2:C8

data_X je A2:B8

typLinie i statistika nastaveno na 1.

Jakmile klepnete na OK, LibreOffice Calc doplní výsledky funkce LINEST tak, jak je uvedeno v ukázce.

Vzorec na liště Vzorec odpovídá každé buňce v matici LINEST {=LINEST(C2:C8;A2:B8;1;1)}.

Toto jsou další hodnoty, vypočtené funkcí LINEST:

E2a F2: Směrnice m regresní přímky y=b+m*x pro hodnoty x1 a x2. Hodnoty jsou dány v opačném pořadí, tzn. směrnice pro x2 v E2 a směrnice pro x1 v F2.

G2: Průsečík s osou y (hodnota b).

E3 a F3: Standardní chyba hodnoty směrnice.

G3: Standardní chyba průsečíku s osou y.

E4: RSQ (Druhá mocnina Pearsonova korelačního koeficientu).

F4: Standardní odchylka regrese vypočtená pro hodnotu y.

E5: Hodnota F z analýzy rozptylu.

F5: Stupně volnosti získané z analýzy rozptylu.

E6: Součet čtverců odchylek předpokládaných hodnot y od jejich lineárního průměru.

F6: Součet čtverců odchylek předpokládaných hodnot y od zadaných hodnot y.

Podrobnější vysvětlení nahoře.

## LOGEST

Tato funkce vypočte korekci zadaných hodnot ve formě exponenciální regresní funkce (y=b*m^x).

### Syntaxe

LOGEST(DataY; DataX; TypFunkce; Parametr)

DataY reprezentuje data Y.

DataX (volitelné) reprezentuje data X.

TypFunkce (volitelné). Pokud je Typ_Funkce = 0, bude vypočítána funkce ve tvaru y = m^x. Jinak se vypočítá funkce y = b*m^x.

Parametr (volitelný). Pokud Parametr = 0, bude vypočten pouze regresní koeficient.

Pokud jsou parametry funkcí LibreOffice Calc označeny jako "nepovinné", je možné je vynechat, pokud za nimi nenásledují žádné další parametry. Např. pokud má funkce čtyři parametry a poslední dva jsou označeny jako "nepovinné", je možné vynechat parametr 4 nebo parametry 3 a 4, ale není možné vynechat samotný parametr 3.

Podrobnější vysvětlení nahoře.

### Příklad

Viz LINEST. V tomto případě ale nebudou vráceny žádné součty druhých mocnin.

## MDETERM

Vrátí determinant matice. Tato funkce vloží do aktuální buňky jedinou hodnotu, není třeba pro výsledky rezervovat oblast buněk.

### Syntaxe

MDETERM(Matice)

Matice představuje čtvercovou matici (oblast buněk), jejíž determinant bude vypočten.

Všeobecný úvod do používání maticových funkcí naleznete na začátku této stránky.

Podrobnější vysvětlení nahoře.

## MINVERSE

Vrátí inverzní matici.

### Syntaxe

MINVERSE(Matice)

Matice je čtvercová matice, k níž počítáme inverzní matici.

Podrobnější vysvětlení nahoře.

### Příklad

Vyberte čtvercovou oblast buněk a funkci MINVERSE. Vyberte cílovou oblast buněk, zaškrtněte pole Matice a klepněte na OK.

## MMULT

Vypočítá maticový součin dvou matic. Počet sloupců první matice se musí rovna počtu řádků druhé matice. Čtvercová matice má stejný počet řádků i sloupců.

### Syntaxe

MMULT(Matice; Matice)

Matice jako první parametr značí první činitel maticového součinu.

Matice jako druhý parametr je druhý činitel maticového součinu.

Podrobnější vysvětlení nahoře.

### Příklad

Vyberte čtvercovou oblast buněk. Vyberte funkci MMULT. Zadejte první Matici a potom druhou Matici. V Průvodci funkcí zaškrtněte pole Matice. Klepněte na tlačítko OK. Výsledná matice se objeví v oblasti buněk označené v prvním kroku.

## MUNIT

Vrátí jednotkovou čtvercovou matici dané velikosti. Jednotková matice je čtvercová matice, která má na diagonále jedničky a její ostatní prvky mají hodnotu 0.

### Syntaxe

MUNIT(Rozměry)

Rozměry určují velikost matice.

Všeobecný úvod do maticových funkcí naleznete na začátku této stránky.

### Příklad

Vyberte čtvercovou oblast buněk, například A1 až E5.

Aniž byste zrušili vybranou oblast, zvolte funkci MUNIT. Zaškrtněte pole Matice. Zadejte požadované rozměry, v tomto případě 5, a klepněte na OK.

Můžete také vložit vzorec =MUNIT(5) do poslední buňky vybrané oblasti (E5) a poté stisknout Shift+Command+EnterShift+Ctrl+Enter.

V oblasti buněk A1:E5 se zobrazí jednotková matice.

Podrobnější vysvětlení nahoře.

## SUMPRODUCT

Vynásobí odpovídající prvky v zadaných maticích a vrátí součet těchto součinů.

### Syntaxe

SUMPRODUCT(Matice1; Matice2; ...; Matice30)

Matice1, Matice2; ...; Matice30 představují matice, jejichž vzájemně si odpovídající prvky budou násobeny.

Seznam argumentů musí obsahovat alespoň jednu matici. Je-li zadána pouze jedna matice, bude vrácen součet jejích prvků.

### Příklad

| A | B | C | D
1 | 2 | 3 | 4 | 5
2 | 6 | 7 | 8 | 9
3 | 10 | 11 | 12 | 13

=SUMPRODUCT(A1:B3;C1:D3) vrátí 397.

Výpočet: A1*C1 + B1*D1 + A2*C2 + B2*D2 + A3*C3 + B3*D3

Funkci SUMPRODUCT je možné použít pro výpočet skalárního součinu dvou vektorů.

Funkce SUMPRODUCT vrací jediné číslo, není třeba ji zadávat jako maticovou funkci.

Podrobnější vysvětlení nahoře.

## SUMX2MY2

Vrací součet rozdílů druhých mocnin odpovídajících si hodnot dvou matic.

### Syntaxe

SUMX2MY2(MaticeX; MaticeY)

MaticeX reprezentuje první matici, její prvky budou umocněny na druhou a přidány.

MaticeY reprezentuje druhou matici, její prvky budou umocněny na druhou a odečteny.

Podrobnější vysvětlení nahoře.

## SUMX2PY2

Vrátí součet součtů druhých mocnin odpovídajících si hodnot dvou matic.

### Syntaxe

SUMX2PY2(MaticeX; MaticeY)

MaticeX reprezentuje první matici, její prvky budou umocněny na druhou a přidány.

MaticeY reprezentuje druhou matici, její prvky budou umocněny na druhou a odečteny.

Podrobnější vysvětlení nahoře.

## SUMXMY2

Sečte druhé mocniny rozdílů mezi odpovídajícími si hodnotami dvou matic.

### Syntaxe

SUMXMY2(MaticeX; MaticeY)

MaticeX reprezentuje první matici, její prvky budou odečteny a umocněny na druhou.

MaticeY reprezentuje druhou matici, její prvky budou odečteny a umocněny na druhou.

Podrobnější vysvětlení nahoře.

## TRANSPOSE

Transponuje řádky a sloupce zadané matice.

### Syntaxe

TRANSPOSE(Matice)

Matice označuje matici (oblast buněk), která bude transponována.

Všeobecný úvod do používání maticových funkcí naleznete na začátku této stránky.

### Příklad

Vyberte v sešitu oblast buněk, ve které se zobrazí transponovaná matice. Pokud má původní matice n řádek a m sloupců, musí mít zvolená oblast buněk alespoň n sloupců a m řádek. Potom přímo zadejte vzorec, zvolte zdrojovou matici a stiskněte Shift+Command+EnterShift+Ctrl+Enter. Pokud používáte Průvodce maticí, nezapomeňte zaškrtnout pole Matice. Transponovaná matice se objeví v cílové oblasti buněk a je automaticky chráněna před změnami.

| A | B | C | D
1 | 2 | 3 | 4 | 5
2 | 6 | 7 | 8 | 9

Výše uvedená tabulka obsahuje 2 řádky, 4 sloupce. Abyste je mohli transponovat, musíte vybrat 4 řádky, 2 sloupce. Za předpokladu, že chcete transponovat výše uvedenou tabulku do oblasti A7:B10 (4 řádky, 2 sloupce), musíte vybrat celou oblast a poté zadejte následující:

TRANSPOSE(A1:D2)

Ujistěte se, že zadáváte maticový vzorec pomocí Shift+Command+EnterShift+Ctrl+Enter. Výsledek bude následující:

| A | B
7 | 2 | 6
8 | 3 | 7
9 | 4 | 8
10 | 5 | 9

## TREND

Vypočte body ležící na regresní přímce.

### Syntaxe

TREND(DataY; DataX; NováDataX; TypLinie)

DataY reprezentuje data Y.

DataX (volitelné) reprezentuje data X.

NováDataX (volitelné) reprezentuje pole dat X, které jsou použity pro přepočítání hodnot.

TypLinie (nepovinné). Pokud je TypLinie = 0, bude vypočtená přímka procházet počátkem. V opačném případě se vypočítá také posun přímky. Výchozí TypLinie je <> 0.

Pokud jsou parametry funkcí LibreOffice Calc označeny jako "nepovinné", je možné je vynechat, pokud za nimi nenásledují žádné další parametry. Např. pokud má funkce čtyři parametry a poslední dva jsou označeny jako "nepovinné", je možné vynechat parametr 4 nebo parametry 3 a 4, ale není možné vynechat samotný parametr 3.

Podrobnější vysvětlení nahoře.

### Příklad

Vyberte oblast buněk, v níž se objeví výsledná data. Zvolte funkci. Zadejte požadované údaje (nebo vyberte příslušné buňky myší). Zaškrtněte pole Matice a klepněte na tlačítko OK. Zobrazí se data vypočtená podle regresní závislosti.

Související témata

Funkce podle kategorie