ডায়ালগ সম্পাদকে কন্ট্রোলের জন্য প্রোগ্রামিং উদাহরণ

Contents
Index 🔎︎

# Programming Examples for Controls in the Dialog Editor

নিম্নোক্ত উদাহরণসমূহ "Dialog1" নামের একটি নতুন ডায়ালগ এর জন্য। ডায়ালগ তৈরি করতে এবং নিম্নোক্ত কন্ট্রোল: "CheckBox1" নামের একটি পরীক্ষণবাক্স, "Label1" নামের একটি মোড়ক ক্ষেত্র, "CommandButton1" নামের একটি বোতাম এবং "ListBox1" নামের একটি তালিকা বাক্স যোগ করতে ডায়ালগ সম্পাদকের টুলবক্স বারের টুল ব্যবহার করুন ।

একটি বস্তু চলকে কন্ট্রোল সংযোজন করার সময় বড় হাতের এবং ছোট হাতের অক্ষর সম্পর্কে সতর্ক থাকতে হবে।

### লোড হচ্ছে এমন ডায়ালগের জন্য গ্লোবাল ফাংশন

    Function LoadDialog(Libname as String, DialogName as String, Optional oLibContainer)
    Dim oLib as Object
    Dim oLibDialog as Object
    Dim oRuntimeDialog as Object
        If IsMissing(oLibContainer) Then
            oLibContainer = DialogLibraries
        End If
        oLibContainer.LoadLibrary(LibName)
        oLib = oLibContainer.GetByName(Libname)
        oLibDialog = oLib.GetByName(DialogName)
        oRuntimeDialog = CreateUnoDialog(oLibDialog)
        LoadDialog() = oRuntimeDialog
    End Function

### একটি ডায়ালগ প্রদর্শিত হচ্ছে

    rem global definition of variables
    Dim oDialog1 AS Object
    Sub StartDialog1
        BasicLibraries.LoadLibrary("Tools")
        oDialog1 = LoadDialog("Standard", "Dialog1")
        oDialog1.Execute()
    End Sub

### প্রোগ্রামের কন্ট্রোলের বৈশিষ্ট্যাবলী পড়ুন অথবা সম্পাদনা করুন

    Sub Sample1
        BasicLibraries.LoadLibrary("Tools")
        oDialog1 = LoadDialog("Standard", "Dialog1")
        REM get dialog model
        oDialog1Model = oDialog1.Model
        REM display text of Label1
        oLabel1 = oDialog1.GetControl("Label1")
        MsgBox oLabel1.Text
        REM set new text for control Label1
        oLabel1.Text = "New Files"
        REM, কন্ট্রোল CheckBox1 এর জন্য মডেলের বৈশিষ্ট্যাবলী প্রদর্শন করে
        oCheckBox1Model = oDialog1Model.CheckBox1
        MsgBox oCheckBox1Model.Dbg_Properties
        REM দ্বারা কন্ট্রোল মডেলের CheckBox1 এর জন্য নতুন অবস্থা নির্ধারিত হয়
        oCheckBox1Model.State = 1
        REM display model properties for control CommandButton1
        oCMD1Model = oDialog1Model.CommandButton1
        MsgBox oCMD1Model.Dbg_Properties
        REM, কন্ট্রোল CommonButton1 এর জন্য বৈশিষ্ট্যাবলী প্রদর্শন করে
        oCMD1 = oDialog1.GetControl("CommandButton1")
        MsgBox oCMD1.Dbg_Properties
        REM ডায়ালগ কার্যকর করে
        oDialog1.Execute()
    End Sub

### ListBox এ একটি ভুক্তি যোগ করুন

    Sub AddEntry
        BasicLibraries.LoadLibrary("Tools")
        oDialog1 = LoadDialog("Standard", "Dialog1")
        REM, ListBox এ একটি নতুন ভুক্তি যোগ করে
        oDialog1Model = oDialog1.Model
        oListBox = oDialog1.GetControl("ListBox1")
        Dim iCount as integer
        iCount = oListbox.ItemCount
        oListbox.additem("New Item" & iCount,0)
    End Sub

### ListBox হতে একটি ভুক্তি অপসারণ করুন

    Sub RemoveEntry
        BasicLibraries.LoadLibrary("Tools")
        oDialog1 = LoadDialog("Standard", "Dialog1")
        REM, ListBox থেকে প্রথম ভুক্তিটি অপসারণ করে
        oDialog1Model = oDialog1.Model
        oListBox = oDialog1.GetControl("ListBox1")
        oListbox.removeitems(0,1)
    End Sub

সংশ্লিষ্ট প্রসঙ্গ

ডায়ালগ সম্পাদকে বিদ্যমান কন্ট্রোলের বৈশিষ্ট্যাবলী পরিবর্তন করা হচ্ছে

বেসিক ডায়ালগ তৈরি করা হচ্ছে

ডায়ালগ সম্পাদকে কন্ট্রোল তৈরি করা হচ্ছে

প্রোগ্রাম কোডের সাথে একটি ডায়ালগ খোলা হচ্ছে