Functie AGGREGEREN

Inhoud
Index 🔎︎

# AGGREGEREN-functie

Deze functie geeft een aggregatie-resultaat van de berekeningen in het assortiment. U kunt verschillende statistische functies die hieronder staan gebruiken. Met de Aggregatie-functie kunt u verborgen rijen, fouten, SUBTOTAAL en andere statistische functie resultaten weglaten uit de berekening.

De functie AGGREGATIE wordt toegepast op verticale data-bereiken met een actief AutoFilter. Als het AutoFilter niet actief is, werkt de automatische herberekening niet voor recent verborgen rijen. De functie is niet bedoeld voor gebruik met horizontale bereiken. Toch kan de functie er wel op worden toegepast, maar met beperkingen. Zo zal de AGGREGATIE-functie toegepast op een horizontaal data-bereik het verbergen van kolommen niet herkennen. Maar de functie gaat wel correct om met fouten en resultaten van SUBTOTAAL en andere AGGREGATIE-functies die in de rij zijn opgenomen.

Deze functie is beschikbaar sinds LibreOffice 4.4

#### Syntaxis

AGGREGATIE(Functie; Optie; Ref1 [; Ref2 [; …]])

of

AGGREGATIE(Functie; Optie; Matrix [; k])

Functie - verplicht argument. Een functie-index of een verwijzing naar een cel met de waarde 1-19, overeenkomstig met de volgende tabel.

Functie-index | Toegepaste functie
1 | GEMIDDELDE
2 | AANTAL
3 | AANTALARG
4 | MAX
5 | MIN
6 | PRODUCT
7 | STDEV.S
8 | STDEV.P
9 | SOM
10 | VAR.S
11 | VAR.P
12 | MEDIAAN
13 | MODUS.ENKELV
14 | GROOTSTE
15 | KLEINSTE
16 | PERCENTIEL.INC
17 | KWARTIEL.INC
18 | PERCENTIEL.EXC
19 | KWARTIEL.EXC

Optie - verplicht argument. Een indexoptie of verwijzing naar een cel met een waarde van 0 tot 7 bepaalt wat te negeren in het bereik van de functie.

Indexoptie | Optie toegepast
0 | Negeer alleen genest SUBTOTAAL en AGGREGATIE-functies
1 | Negeer alleen verborgen rijen, genest SUBTOTAAL en AGGREGATIE-functies
2 | Negeer alleen fouten, genest SUBTOTAAL en AGGREGATIE-functies
3 | Negeer verborgen rijen, fouten, genest SUBTOTAAL en AGGREGATIE-functies
4 | Negeer niets
5 | Negeer alleen verborgen rijen
6 | Negeer alleen fouten
7 | Negeer alleen verborgen rijen en fouten

Ref1 – verplicht argument. Het eerste numerieke argument (als het bereik van een lijst van waarden binnen de functie is ingesteld) of een verwijzing naar een cel die het bevat.

Ref2, 3, ... – optioneel. Een numeriek argument of een verwijzing naar een cel (maximaal 253 argumenten), waarvoor u de totale waarde nodig heeft.

Array – verplicht argument. De matrix kan worden opgegeven door de grenzen van het bereik, de naam van het benoemde bereik of het kolomlabel.

Voor het gebruik van kolomlabels moet de functie "Kolom- en rij-labels automatisch vinden" worden ingeschakeld.

k – verplicht argument voor de volgende functies: GROOT, KLEIN, PERCENT.INC, KWARTIEL.INCL, PERCENT.EXCL, KWARTIEL.EXCL. Het is een numerieke argument, dat overeen moet komen met het tweede argument van deze functies.

#### Voorbeeld

| A | B | C
1 | KolomEen | KolomTwee | KolomDrie
2 | 34 | 11 | 12
3 | 10 | 56 | 35
4 | #DIV/0! | 5 | 3
5 | 20 | 8 | 1
6 | 0 | 8 | 9
7 | #WAARDE! | 20 | 21
8 | 5 | 7 | 8
9 | 14 | 0 | 5

=AGGREGEREN(4;2;A2:A9)
Geeft de maximum waarde terug voor het bereik van A2:A9 = 34, waar =MAX(A2:A9) de fout Err:511 teruggeeft.

=AGGREGATIE(9;5;A5:C5)
Geeft de som van de reeks A5:C5 = 29, zelfs als sommige kolommen verborgen zijn.

=AGGREGEREN(9;5;B2:B9)
Geeft de som van kolom B = 115 terug. Als er een rij verborgen is, laat de functie de waarde weg, als bijvoorbeeld de 7de rij verborgen is, geeft de functie 95 terug.

Als u de functie met een 3D-reeks moet toepassen, laat dit voorbeeld zien hoe dat moet.

=AGGREGATIE(13;3;Blad1.B2:B9:Blad3.B2:B9)
De functie geeft de modus van de waarden van de tweede kolom van bladen 1:3 (die hetzelfde gegeven hebben) = 8.

U kunt naar een cel of een bereik verwijzen, voor elk argument in de formule. Het volgende voorbeeld laat zien hoe het werkt. Daarbij laat het zien dat u kolomlabels kunt gebruiken om een matrix op te geven.

=AGGREGEREN(E3;E5;'KolomEen')
Als E3 = 13 en E5 = 5, geeft de functie de modus van de eerste kolom = 10.

Verwante onderwerpen

AVERAGE, COUNT, COUNTA, MAX, MIN, PRODUCT, STDEV.S, STDEV.P, SUM, VAR.S, VAR.P, MEDIAN, MODE.SNGL, LARGE, SMALL, PERCENTILE.INC , QUARTILE.INC, PERCENTILE.EXC, QUARTILE.EXC

Vind automatisch kolom- en rijlabels