Contenuto
Indice 🔎︎

# Categoria Matematica

In questa sezione sono descritte le funzioni della categoria Matematica di Calc. Per aprire la Creazione guidata funzione, scegliete Inserisci - Funzione.

## AGGREGA

La funzione restituisce un risultato aggregato dei calcoli all'interno dell'intervallo. Si possono usare diverse funzioni aggregate, come elencate di seguito. La funzione AGGREGA permette di omettere righe, errori, SUBTOTALE e altri risultati della funzione AGGREGA all'interno del calcolo.

## SOTTRAI.RAW

Sottrae un gruppo di numeri e restituisce il risultato senza eliminare i piccoli errori di arrotondamento.

### COLORE

Restituisce un valore numerico calcolato da una combinazione di tre colori (rosso, verde e blu) e il canale alfa, nel sistema dei colori RGBA. Il risultato dipende dal sistema dei colori utilizzato dal vostro computer.

## SOMMA.PIÙ.SE

Restituisce la somma dei valori delle celle in un intervallo che soddisfa più criteri in intervalli multipli.

## ARROTONDA.ECCESSO.XCL

Arrotonda lontano da zero il numero al multiplo più prossimo a peso.

La funzione è disponibile da LibreOffice 5.0

#### Sintassi

ARROTONDA.ECCESSO.XCL(Numero; Peso)

Numero è il numero che deve essere arrotondato.

Peso è il multiplo per il quale deve essere arrotondato il valore.

Questa funzione esiste per garantire l'interoperabilità con Microsoft Excel 2007 o versioni precedenti.

#### Esempio

=ARROTONDA.ECCESSO.XCL(1;3) restituisce 3

=ARROTONDA.ECCESSO.XCL(7;4) restituisce 8

=ARROTONDA.ECCESSO.XCL(-10;-3) restituisce -12

## ARROTONDA.DIFETTO.PRECISO

Arrotonda per difetto un numero al multiplo più prossimo a peso, a prescindere dal segno del peso

La funzione è disponibile da LibreOffice 4.3

#### Sintassi

ARROTONDA.DIFETTO.PRECISO(Numero; Peso)

Numero è il numero che deve essere arrotondato per difetto.

Peso è il multiplo per il quale deve essere arrotondato per difetto il numero.

Se il foglio elettronico è esportato in Microsoft Excel, la funzione ARROTONDA.DIFETTO viene esportata come equivalente di ARROTONDA.DIFETTO.MAT, che esiste fin da Excel 2013. Se pensate di dover usare il foglio elettronico con versioni precedenti di Excel, usate ARROTONDA.DIFETTO.PRECISO, che esiste fin da Excel 2010, oppure ARROTONDA.DIFETTO.XCL che viene esportata come funzione ARROTONDA.DIFETTO compatibile con tutte le versioni di Excel. È da notare che ARROTONDA.DIFETTO.XCL arrotonda verso lo zero.

#### Esempio

=ARROTONDA.DIFETTO.PRECISO(-11;-2) restituisce -12

## ARROTONDA.ECCESSO.MAT

Arrotonda per eccesso il numero al multiplo più prossimo a Peso.

#### Sintassi

ARROTONDA.ECCESSO.MAT(Numero; Peso; Modo)

Numero è il numero che deve essere arrotondato per eccesso.

Peso è il multiplo per il quale deve essere arrotondato per eccesso il valore.

Modo è un valore opzionale. Se il valore Modo è fornito e non è uguale a zero, e il Numero e il Peso sono negativi, allora l'arrotondamento viene eseguito in base al valore assoluto di Numero, ossia i numeri negativi sono arrotondati lontano da zero. Se il valore Modo è uguale a zero o non è fornito, i numeri negativi sono arrotondati verso lo zero.

Questa funzione esiste per garantire l'interoperabilità con Microsoft Excel 2013 o versioni successive.

#### Esempio

=ARROTONDA.ECCESSO.MAT(-10;-3) restituisce -9

=ARROTONDA.ECCESSO.MAT(-10;-3;0) restituisce -9

=ARROTONDA.ECCESSO.MAT(-10;-3;1) restituisce -12

## ARROT.ECCESS.PRECISO

Arrotonda per eccesso il numero al multiplo più prossimo a peso, a prescindere dal segno del peso

La funzione è disponibile da LibreOffice 4.3

#### Sintassi

ARROT.ECCESS.PRECISO(Numero; Peso)

Numero (richiesto) è il numero che deve essere arrotondato per eccesso.

Peso (opzionale) è il multiplo per il quale deve essere arrotondato per eccesso il valore.

#### Esempio

=ARROT.ECCESS.PRECISO(-11;-2) restituisce -10

## ISO.ARROTONDA.ECCESSO

Arrotonda per eccesso il numero al multiplo più prossimo a peso, a prescindere dal segno del peso

#### Sintassi

ISO.ARROTONDA.ECCESSO(Numero; Peso)

Numero (richiesto) è il numero che deve essere arrotondato per eccesso.

Peso (opzionale) è il multiplo per il quale deve essere arrotondato per eccesso il valore.

#### Esempio

=ISO.ARROTONDA.ECCESSO(-11;-2) restituisce -10

## ARROTONDA.ECCESSO

Arrotonda per eccesso il numero al multiplo più prossimo a peso.

#### Sintassi

ARROTONDA.ECCESSO(Numero; Peso; Modo)

Numero è il numero che deve essere arrotondato per eccesso.

Peso è il multiplo per il quale deve essere arrotondato per eccesso il valore.

Modo è un valore opzionale. Se il valore Modo è fornito e non è uguale a zero, e il Numero e il Peso sono negativi, allora l'arrotondamento viene eseguito in base al valore assoluto di Numero, ossia i numeri negativi sono arrotondati lontano da zero. Se il valore Modo è uguale a zero o non è fornito, i numeri negativi sono arrotondati verso lo zero.

Se il foglio elettronico è esportato in Microsoft Excel, la funzione ARROTONDA.ECCESSO viene esportata come equivalente di ARROTONDA.ECCESSO.MAT, che esiste fin da Excel 2013. Se pensate di dover usare il foglio elettronico con versioni precedenti di Excel, usate ARROT.ECCESS.PRECISO, che esiste fin da Excel 2010, oppure ARROTONDA.ECCESSO.XCL che viene esportata come funzione ARROTONDA.ECCESSO compatibile con tutte le versioni di Excel. È da notare che ARROTONDA.ECCESSO.XCL arrotonda sempre lontano da zero.

#### Esempio

=ARROTONDA.ECCESSO(-11;-2) restituisce -10

=ARROTONDA.ECCESSO(-11;-2;0) restituisce -10

=ARROTONDA.ECCESSO(-11;-2;1) restituisce -12

## ARROTONDA

Arrotonda un numero a un determinato numero di decimali.

#### Sintassi

ARROTONDA(Numero; numero_decimali)

Restituisce Numero arrotondato al numero decimali. Se il numero decimali è omesso o è pari a zero, la funzione arrotonda al numero intero più vicino. Se il numero decimali è negativo, la funzione arrotonda alla decina, centinaia, migliaia, ecc. più vicina.

La funzione arrotonda al numero più vicino. Si vedano anche le alternative ARROTONDA.PER.DIF e ARROTONDA.PER.ECC.

#### Esempio

=ARROTONDA(2.348;2) restituisce 2.35

=ARROTONDA(-32.4834;3) restituisce -32.483. Cambiate il formato delle celle per visualizzare tutti i decimali.

=ARROTONDA(2.348;0) restituisce 2.

=ARROTONDA(2,5) restituisce 3.

=ARROTONDA(987,65;-2) restituisce 1000.

## ARROTONDA.DIFETTO

Arrotonda un numero per difetto al multiplo più prossimo al peso specificato.

#### Sintassi

ARROTONDA.DIFETTO(Numero; Peso; Modo)

Numero è il numero che deve essere arrotondato per difetto.

Peso è il multiplo per il quale deve essere arrotondato per difetto il numero.

Modo è un valore opzionale. Se il valore Modo è fornito e non è uguale a zero, e il Numero e il Peso sono negativi, allora l'arrotondamento viene eseguito in base al valore assoluto di Numero, ossia i numeri negativi sono arrotondati verso lo zero. Se il valore Modo è uguale a zero o non è fornito, i numeri negativi sono arrotondati lontani da zero.

Se il foglio elettronico è esportato in Microsoft Excel, la funzione ARROTONDA.DIFETTO viene esportata come equivalente di ARROTONDA.DIFETTO.MAT, che esiste fin da Excel 2013. Se pensate di dover usare il foglio elettronico con versioni precedenti di Excel, usate ARROTONDA.DIFETTO.PRECISO, che esiste fin da Excel 2010, oppure ARROTONDA.DIFETTO.XCL che viene esportata come funzione ARROTONDA.DIFETTO compatibile con tutte le versioni di Excel. È da notare che ARROTONDA.DIFETTO.XCL arrotonda verso lo zero.

#### Esempio

=ARROTONDA.DIFETTO(-11;-2) restituisce -12

=ARROTONDA.DIFETTO( -11; -2; 0) restituisce -12

=ARROTONDA.DIFETTO(-11;-2;1) restituisce -10

## INT

Arrotonda un numero per difetto all'intero più vicino.

#### Sintassi

INT(Numero)

Restituisce Numero arrotondato per difetto all'intero più vicino.

I numeri negativi sono arrotondati per difetto all'intero inferiore.

#### Esempio

=INT(5,7) restituisce 5.

=INT(-1,3) restituisce -2.

## ARROTONDA.PER.DIF

Arrotonda un numero per difetto verso lo zero con una certa precisione.

#### Sintassi

ARROTONDA.PER.DIF(Numero; numero_decimali)

Restituisce il Numero arrotondato per difetto (verso lo zero) al numero decimali. Se il numero decimali è omesso o è zero, la funzione arrotonda per difetto verso un intero. Se il numero decimali è negativo, la funzione arrotonda per difetto a 10, 100, 1000, ecc.

Questa funzione arrotonda verso lo zero. Si vedano anche le alternative ARROTONDA.PER.ECC e ARROTONDA.

#### Esempio

=ARROTONDA.PER.DIF(1,234;2) restituisce 1,23.

=ARROTONDA.PER.DIF(45,67; 0) restituisce 45.

=ARROTONDA.PER.DIF(-45,67) restituisce -45.

=ARROTONDA.PER.DIF(987,65; -2) restituisce 900.

## ARROTONDA.PER.ECC

Arrotonda un numero per eccesso, allontanandosi da zero, con una certa precisione.

#### Sintassi

ARROTONDA.PER.ECC(Numero; numero_decimali)

Restituisce Numero arrotondato per eccesso (partendo da zero) a un determinato numero decimali. Se il numero decimali è omessa o è pari a zero, la funzione arrotonda per eccesso a un numero intero. Se il numero decimali è negativo, la funzione arrotonda per eccesso alla decina, centinaia, migliaia, ecc., successiva.

Questa funzione arrotonda allontanandosi dallo zero. Si vedano anche le alternative ARROTONDA.PER.DIF e ARROTONDA.

#### Esempio

=ARROTONDA.PER.ECC(1,1111;2) restituisce 1,12.

=ARROTONDA.PER.ECC(1,2345; 1) restituisce 1,3.

=ARROTONDA.PER.ECC(45,67;0) restituisce 46.

=ARROTONDA.PER.ECC(-45,67) restituisce -46.

=ARROTONDA.PER.ECC(987,65;-2) restituisce 1000.

## PARI

Arrotonda un numero positivo al più vicino intero pari superiore e un numero negativo al più vicino intero pari inferiore.

#### Sintassi

PARI(Numero)

Restituisce Numero arrotondato per eccesso al pari intero successivo, partendo da zero.

#### Esempio

=PARI(2,3) restituisce 4.

=PARI(2) restituisce 2.

=PARI(0) restituisce 0.

=PARI(-0.5) restituisce -2.

## DISPARI

Arrotonda un numero positivo al più vicino intero pari superiore e un numero negativo al più vicino intero pari inferiore.

#### Sintassi

DISPARI(Numero)

Restituisce Numero arrotondato per eccesso al dispari intero successivo, partendo da zero.

#### Esempio

=DISPARI(1,2) restituisce 3.

=DISPARI(1) restituisce 1.

=DISPARI(0) restituisce 1.

=DISPARI(-3,1) restituisce -5.

## SUBTOTALE

Calcola i subtotali. Se un'area contiene già dei subtotali, questi ultimi non verranno utilizzati per ulteriori calcoli. Utilizzata con un Filtro automatico, questa funzione permette di considerare solo i record filtrati.

#### Sintassi

SUBTOTALE(Funzione; Area)

Funzione è un numero che rappresenta una delle seguenti funzioni:

Indice di funzione (include i valori nascosti) | Indice funzioni (ignora i valori nascosti) | Funzione
1 | 101 | MEDIA
2 | 102 | CONTA.NUMERI
3 | 103 | CONTA.VALORI
4 | 104 | MAX
5 | 105 | MIN
6 | 106 | PRODOTTO
7 | 107 | DEV.ST
8 | 108 | DEV.ST.POP
9 | 109 | SOMMA
10 | 110 | VAR
11 | 111 | VAR.POP

Usate i numeri 1-11 per includere manualmente le righe nascoste o i numeri 101-111 per escluderle; le celle fuori non filtrate sono sempre escluse.

Area è l'intervallo in cui le celle vengono conteggiate.

#### Esempio

Si consideri una tabella nell'area di celle A1:B6 contenente un elenco di materiale per dieci studenti. La riga 2 (penna) viene nascosta manualmente. Volete vedere la somma delle cifre che sono visualizzate; ossia, solo il subtotale per le righe filtrate. In questo caso la formula corretta sarebbe:

| A | B
1 | ELEMENTO | QUANTITÀ
2 | Penna | 10
3 | Matita | 10
4 | Taccuino | 10
5 | Gomma | 10
6 | Temperamatite | 10

=SUBTOTALE(9;B2:B6) restituisce 50.

=SUBTOTALE(109;B2:B6) restituisce 40.

## RADIANTI

Converte gradi in radianti.

#### Sintassi

RADIANTI(Numero)

Numero è l'angolo in gradi da convertire in radianti.

#### Esempio

=RADIANTI(90) restituisce 1,5707963267949, ossia pi greco mezzi con l'accuratezza di Calc.

## GRADI

Converte i radianti in gradi.

#### Sintassi

GRADI(Numero)

Numero è l'angolo espresso in radianti da convertire in gradi.

#### Esempio

= GRADI(PI.GRECO()) restituisce 180 gradi.

## CONVERTI_OOO

Converte un valore da un'unità di misura a un'altra unità di misura. I fattori di conversione sono assegnati in un elenco nella configurazione.

L'elenco dei fattori di conversione comprende sia le vecchie valute europee sia l'Euro (vedere esempi sotto). Per convertire queste valute, suggeriamo di utilizzare la nuova funzione EUROCONVERT.

#### Sintassi

CONVERTI_OOO(valore;"testo";"testo")

#### Esempio

=CONVERTI_OOO(100;"ATS";"EUR") restituisce il valore in Euro di 100 Scellini austriaci.

=CONVERTI_OOO(100;"EUR";"DEM") converte 100 Euro in Marchi tedeschi.

## EUROCONVERT

Esegue la conversione da una delle valute europee precedentemente adottate alla valuta euro e viceversa.

#### Sintassi

EUROCONVERT(Valore; "Da_valuta"; "A_valuta", precisione, precisione triangolazione)

Valore è il totale della valuta da convertire.

Da valuta e A valuta sono le unità di valuta da convertire reciprocamente. Devono essere espresse in testo nell'abbreviazione ufficiale della valuta (ad esempio, "EUR"). I tassi (indicati per l'Euro) sono stati impostati dalla Commissione Europea.

Precisione è facoltativo. Se omesso o Falso, il risultato è arrotondato in base ai decimali della valuta A. Se Precisione è Vero, il risultato non viene arrotondato.

Precisione triangolazione è facoltativo. Se è dato Precisione triangolazione ed è >=3, il risultato intermedio di una conversione triangolare (valuta1,EUR,valuta2) è arrotondato a tale precisione. Se Precisione triangolazione è omesso, il risultato intermedio non viene arrotondato. Anche se la valuta A è "EUR", Precisione triangolazione viene usato come se la triangolazione fosse necessaria e la conversione da EUR a EUR fosse applicata.

### Esempi

=EUROCONVERT(100;"ATS";"EUR") converte 100 Scellini austriaci in Euro.

=EUROCONVERT(100;"EUR";"DEM") converte 100 Euro in Marchi tedeschi.

## MCD_EXCEL2003

Il risultato è il massimo comune divisore di un elenco di numeri.

Le funzioni i cui nomi terminano per _ADD o _EXCEL2003 restituiscono lo stesso risultato delle funzioni di Microsoft Excel 2003 corrispondenti, senza suffisso. Utilizzate le funzioni senza suffisso per ottenere risultati in linea con gli standard internazionali.

#### Sintassi

MCD_EXCEL2003(Numero/i)

Numero(i) è un elenco fino a 30 numeri.

#### Esempio

=MCD_EXCEL2003(5;15;25) restituisce 5.

## MCM_EXCEL2003

Il risultato è il minimo comune multiplo di un elenco di numeri.

Le funzioni i cui nomi terminano per _ADD o _EXCEL2003 restituiscono lo stesso risultato delle funzioni di Microsoft Excel 2003 corrispondenti, senza suffisso. Utilizzate le funzioni senza suffisso per ottenere risultati in linea con gli standard internazionali.

#### Sintassi

MCM_EXCEL2003(Numero/i)

Numero(i) è un elenco fino a 30 numeri.

#### Esempio

=MCM_EXCEL2003(5;15;25) restituisce 75.

## SOMMA.Q

Per calcolare la somma dei quadrati dei numeri (il totale dei quadrati degli argomenti), inseritene i valori nei campi di testo.

#### Sintassi

SOMMA.Q(Numero 1; Numero 2; ...; Numero 30)

Numero 1 fino a 30 sono gli argomenti (massimo 30) per i quali deve essere calcolata la somma dei quadrati.

#### Esempio

Se digitate 2; 3 e 4 nelle caselle di testo Numero 1; 2 e 3, il risultato visualizzato sarà 29.

## PI.GRECO

Restituisce 3,14159265358979, il valore della costante matematica PI con 14 posizioni decimali.

#### Sintassi

PI.GRECO()

#### Esempio

=PI.GRECO() restituisce 3,14159265358979.

## COS

Restituisce il coseno di un determinato angolo espresso in radianti.

#### Sintassi

COS(Numero)

Restituisce il coseno (trigonometrico) di Numero, l'angolo espresso in radianti.

Utilizzate la funzione RADIANTI per restituire il coseno di un angolo espresso in gradi.

#### Esempio

COS(PI.GRECO()*2) restituisce 1, il coseno di 2*pi greco radianti.

=COS(RADIANTI(60)) restituisce 0,5, il coseno di 60 gradi.

## COSH

Restituisce il coseno iperbolico di un numero.

#### Sintassi

COSH(Numero)

Restituisce il coseno iperbolico di un numero.

#### Esempio

=COSH(0) restituisce 1, il coseno iperbolico di 0.

## MULTINOMIALE

Restituisce il fattoriale della somma degli argomenti diviso il prodotto dei fattoriali degli argomenti.

#### Sintassi

MULTINOMIALE(Numero/i)

Numero(i) è un elenco fino a 30 numeri.

#### Esempio

=MULTINOMIALE(F11:H11) restituisce 1260, se nell'intervallo di celle compreso tra F11 e H11 sono presenti i valori 2, 3 e 4. Ciò corrisponde alla formula =(2+3+4)! / (2!*3!*4!)

## FATTORIALE

Restituisce il fattoriale di un numero.

#### Sintassi

FATTORIALE(Numero)

Restituisce Numero!, il fattoriale di Numero, calcolato come 1*2*3*4* ... * Numero.

=FATTORIALE(0) restituisce 1 per definizione.

Il fattoriale di un numero negativo restituisce un errore del tipo "argomento non valido".

#### Esempio

=FATTORIALE(3) restituisce 6.

=FATTORIALE(0) restituisce 1.

## LOG

Restituisce il logaritmo di un numero nella base specificata.

#### Sintassi

LOG(Numero; Base)

Numero è il valore per il quale deve essere calcolato il logaritmo.

Base (facoltativa) è la base per il calcolo del logaritmo. Se omessa, viene presunta la base 10.

#### Esempio

=LOG(10;3) restituisce il logaritmo in base 3 di 10 (approssimativamente 2,0959).

=LOG(7^4;7) restituisce 4.

## LOG10

Restituisce il logaritmo in base 10 di un numero.

#### Sintassi

LOG10(Numero)

Restituisce il logaritmo in base 10 del Numero.

#### Esempio

LOG10(5) restituisce il logaritmo in base 10 di 5 (approssimativamente 0,69897).

## LN

Restituisce il logaritmo naturale basato sulla costante e di un numero. La costante ha un valore approssimativo di 2,71828182845904.

#### Sintassi

LN(Numero)

Numero è il valore per il quale deve essere calcolato il logaritmo naturale.

#### Esempio

=LN(3) restituisce il logaritmo naturale di 3 (approssimativamente 1,0986).

=LN(EXP(321)) restituisce 321.

## MCD

Restituisce il massimo comune divisore di due o più numeri interi.

Il massimo comune divisore è il più grande intero positivo che dividerà, senza resto, ciascuno degli interi specificati.

#### Sintassi

MCD(Numero intero 1; Numero intero 2; ...; Numero intero 30)

Numero intero 1 fino a 30 sono 30 numeri interi per i quali deve essere calcolato il massimo comune divisore.

#### Esempio

=MCD(16;32;24) restituisce il risultato 8, poiché 8 è il numero più grande che può dividere 16, 24 e 32 senza resto.

=MCD(B1:B3) in cui le celle B1, B2, B3 contengono 9, 12, 9 rispettivamente, restituisce 3.

## MCM

Restituisce il minimo comune multiplo di due o più numeri interi.

#### Sintassi

MCM(Numero intero 1; Numero intero 2; ...; Numero intero 30)

Numero intero 1 fino a 30 sono 30 numeri interi per i quali deve essere calcolato il minimo comune multiplo.

#### Esempio

Se digitate 512;1024 e 2000 nei campi di testo Intero 1, 2 e 3, il risultato visualizzato sarà 128.000.

## COMBINAZIONE

Restituisce il numero di permutazioni per elementi senza ripetizione.

#### Sintassi

COMBINAZIONE(Numero 1; Numero 2)

Numero 1 è il numero di oggetti nell'insieme.

Numero 2 è il numero degli oggetti da scegliere dall'insieme.

COMBINAZIONE restituisce il numero di modi in cui si possono scegliere questi elementi. Ad esempio, se ci sono tre elementi A, B e C in un insieme, se ne possono scegliere 2 in tre modi differenti, ossia AB, AC e BC.

COMBINAZIONE implementa la formula: Numero 1!/(Numero 2!*(Numero 1- Numero 2)!)

#### Esempio

=COMBINAZIONE(3;2) restituisce 3.

## COMBINAZIONE.VALORI

Restituisce il numero di permutazioni per un sottoinsieme di elementi che includono le ripetizioni.

#### Sintassi

COMBINAZIONE.VALORI(Numero 1; Numero 2)

Numero 1 è il numero di oggetti nell'insieme.

Numero 2 è il numero degli oggetti da scegliere dall'insieme.

COMBINAZIONE.VALORI restituisce il numero di modi in cui si possono scegliere questi elementi, dove l'ordine di scelta non è importante e la ripetizione degli elementi è consentita. Ad esempio, se in un insieme ci sono 3 elementi A, B e C, se ne possono scegliere due in sei modi differenti, ossia AA, AB, AC, BB, BC e CC.

COMBINAZIONE.VALORI implementa la formula:(Numero 1+Numero 2-1)! / (Numero 1!(Numero 1-1)!)

#### Esempio

=COMBINAZIONE.VALORI(3;2) restituisce 6.

## PRODOTTO

Restituisce il prodotto di tutti i numeri indicati come argomenti.

#### Sintassi

PRODOTTO(Numero 1; Numero 2; ...; Numero 30)

Numero1 a 30 sono i 30 argomenti, come massimo, tra cui il prodotto deve essere calcolato.

PRODOTTO restituisce numero1 * numero2 * numero3 * ...

#### Esempio

=PRODOTTO(2;3;4) restituisce 24.

## RESTO

Restituisce il resto quando un numero intero viene diviso per un altro.

#### Sintassi

RESTO(Dividendo; Divisore)

Per gli argomenti interi, questa funzione restituisce Dividendo modulo Divisore, ovvero il resto della divisione del Dividendo per il Divisore.

Questa funzione viene implementata come Dividendo - Divisore * INT(Dividendo / Divisore), e la formula fornisce un risultato quando gli argomenti non sono interi.

#### Esempio

=RESTO(22;3) restituisce 1, il resto della divisione di 22 per 3.

=RESTO(11,25;2,5) restituisce 1,25.

## SEGNO

Restituisce il segno di un numero. Restituisce 1 se il numero è positivo, -1 se è negativo e 0 se è zero.

#### Sintassi

SEGNO(Numero)

Numero è il numero per il quale deve essere definito il segno.

#### Esempio

=SEGNO(3,4) restituisce 1.

=SEGNO(-4,5) restituisce -1.

## SEN

Restituisce il seno di un determinato angolo espresso in radianti.

#### Sintassi

SEN(Numero)

Restituisce il seno (trigonometrico) del Numero, l'angolo in radianti.

Utilizzate la funzione RADIANTI per restituire il seno di un angolo espresso in gradi.

#### Esempio

=SEN(PI.GRECO()/2) restituisce 1, il seno di PI.GRECO/2 radianti.

=SEN(RADIANTI(30)) restituisce 0,5, il seno di 30 gradi.

## SENH

Restituisce il seno iperbolico di un numero.

#### Sintassi

SENH(Numero)

Restituisce il seno iperbolico del Numero.

#### Esempio

=SENH(0) restituisce 0, il seno iperbolico di 0.

## ARCSENH

Restituisce il seno iperbolico inverso di un numero.

#### Sintassi

ARCSENH(Numero)

Questa funzione restituisce il seno iperbolico inverso di Numero, ovvero il numero il cui seno iperbolico è Numero.

#### Esempio

=ARCSENH(-90) restituisce approssimativamente -5,1929877.

=ARCSENH(SENH(4)) restituisce 4.

## ASS

Restituisce il valore assoluto di un numero.

#### Sintassi

ASS(Numero)

Numero è il numero di cui viene calcolato il valore assoluto. Il valore assoluto di un numero è il suo valore senza il segno positivo o negativo (+/-).

#### Esempio

=ASS(-56) restituisce 56.

=ASS(12) restituisce 12.

=ASS(0) restituisce 0.

## ARCTAN.2

Restituisce l'angolo (in radianti) tra l'asse x e una linea che collega l'origine al punto (NumeroX|NumeroY).

Questa funzione appartiene all'Open Document Format for Office Applications (OpenDocument), versione standard 1.2 (ISO/IEC 26300:2-2015).

#### Sintassi

ARCTAN.2(numero X; numero Y)

NumeroX è il valore della coordinata x.

Numero Y è il valore della coordinata y.

I linguaggi di programmazione presentano solitamente l'ordine opposto degli argomenti per la funzione ARCTAN.2().

ARCTAN.2 restituisce l'angolo (in radianti) tra l'asse x e una linea che va dall'origine al punto (NumeroX|NumeroY).

#### Esempio

=ARCTAN.2(-5;9) restituisce 2,07789 radianti.

Per ottenere l'angolo in gradi applicare la funzione GRADI al risultato.

=GRADI(ARCTAN.2(12,3;12,3)) restituisce 45. La tangente di 45 gradi è 1.

LibreOffice restituisce 0 per ARCTAN.2(0;0).

Potete utilizzare questa funzione per convertire le coordinate cartesiane in coordinate polari.

=GRADI(ACTAN.2(-8;5)) restituisce φ = 147,9 gradi

## EXP

Restituisce l'esponente a base e del numero indicato. La costante ha un valore approssimativo di 2,71828182845904.

#### Sintassi

EXP(Numero)

Numero è l'esponente applicato alla base e.

#### Esempio

=EXP(1) restituisce 2,71828182845904, la costante matematica e con l'accuratezza di Calc.

## ARCCOSH

Restituisce l'inversa del coseno iperbolico di un numero.

#### Sintassi

ARCCOSH(Numero)

Questa funzione restituisce il coseno iperbolico inverso di Numero, ovvero il numero il cui coseno iperbolico è Numero.

Il Numero deve essere maggiore o uguale a 1.

#### Esempio

=ARCCOSH(1) restituisce 0.

=ARCCOSH(COSH(4)) restituisce 4.

## ARCCOS

Restituisce l'inversa del coseno trigonometrico di un numero.

#### Sintassi

ARCCOS(Numero)

Questa funzione restituisce il coseno trigonometrico inverso di Numero, ovvero l'angolo (in radianti) il cui coseno è Numero. L'angolo restituito è tra 0 e PI.GRECO.

Utilizzate la funzione GRADI per restituire l'angolo in gradi.

#### Esempio

=ARCCOS(-1) restituisce 3,14159265358979 (pi greco radianti)

=GRADI(ARCCOS(0,5)) restituisce 60. Il coseno di 60 gradi è 0,5.

## ARCSEN

Restituisce l'inversa del seno trigonometrico di un numero.

#### Sintassi

ARCSEN(Numero)

Questa funzione restituisce il seno trigonometrico inverso di Numero, ovvero il numero il cui seno trigonometrico è Numero. L'angolo restituito (in radianti) è tra -PI.GRECO/2 e +PI.GRECO/2.

Utilizzate la funzione GRADI per restituire l'angolo in gradi.

#### Esempio

=ARCSEN(0) restituisce 0.

=ARCSEN(1) restituisce 1,5707963267949 (pi greco mezzi radianti).

=GRADI(ARCSEN(0.5)) restituisce 30. Il seno di 30 gradi è 0,5.

## ARCCOTH

Restituisce l'inversa della cotangente iperbolica di un numero dato.

#### Sintassi

ARCCOTH(Numero)

Questa funzione restituisce la cotangente iperbolica inversa del Numero, ossia la cifra la cui cotangente iperbolica è Numero.

Se il Numero è compreso tra -1 e 1 (inclusi) si verificherà un errore.

#### Esempio

=ARCCOTH(1,1) restituisce la cotangente iperbolica inversa di 1,1, approssimativamente 1,52226.

## ARCTANH

Restituisce l'inversa della tangente iperbolica di un numero.

#### Sintassi

ARCTANH(Numero)

Questa funzione restituisce la tangente iperbolica inversa di Numero, ossia il numero la cui tangente iperbolica è Numero.

Il numero deve rispettare la condizione -1 < numero < 1.

#### Esempio

=ARCTANH(0) restituisce 0.

## ARCTAN

Restituisce l'inversa della tangente trigonometrica di un numero.

#### Sintassi

ARCTAN(Numero)

Questa funzione restituisce la tangente trigonometrica inversa di Numero, ovvero l'angolo (in radianti) la cui tangente trigonometrica è Numero. L'angolo restituito è tra -PI.GRECO/2 e +PI.GRECO/2.

Utilizzate la funzione GRADI per restituire l'angolo in gradi.

#### Esempio

=ARCTAN(1) restituisce 0.785398163397448 (PI.GRECO/4 radianti).

=GRADI(ARCTAN(1)) restituisce 45. La tangente di 45 gradi è 1.

## COSEC

Restituisce la cosecante dell'angolo dato (in radianti). La cosecante di un angolo è il reciproco del seno dell'angolo.

La funzione è disponibile da LibreOffice 3.5

#### Sintassi

COSEC(Angolo)

Restituisce la cosecante (trigonometrica) di Angolo, l'angolo in radianti.

Utilizzate la funzione RADIANTI per restituire la cosecante di un angolo espresso in gradi.

#### Esempio

=COSEC(PI.GRECO()/4) restituisce circa 1.4142135624, il reciproco del seno di PI.GRECO()/4 radianti.

=COSEC(RADIANTI(30)) restituisce 2, la cosecante di 30 gradi.

## COSECH

Restituisce la cosecante iperbolica di un numero.

La funzione è disponibile da LibreOffice 3.5

#### Sintassi

COSECH(Angolo)

Restituisce la cosecante iperbolica di Angolo.

#### Esempio

=COSECH(1) restituisce circa 0.8509181282, la cosecante iperbolica di 1.

## COT

Restituisce la cotangente di un determinato angolo espresso in radianti.

#### Sintassi

COT(Numero)

Restituisce la cotangente trigonometrica di un numero, l'angolo espresso in radianti.

Utilizzate la funzione RADIANTI per restituire la cotangente di un angolo espressa in gradi.

La cotangente di un angolo è equivalente a 1 diviso la tangente di quell'angolo.

### Esempi:

=COT(PI.GRECO()/4) restituisce 1, la cotangente di pi greco quarti radianti.

=COT(RADIANTI(45)) restituisce 1, la cotangente di 45 gradi.

## ARCCOT

Restituisce la cotangente inversa (l'arcocotangente) di un numero.

#### Sintassi

ARCCOT(Numero)

Questa funzione restituisce la cotangente trigonometrica inversa di Numero, ovvero l'angolo (in radianti) la cui cotangente è Numero. L'angolo restituito è tra 0 e PI.GRECO.

Utilizzate la funzione GRADI per restituire l'angolo in gradi.

#### Esempio

=ARCCOT(1) restituisce 0,785398163397448 (pi greco quarti radianti).

=GRADI(ARCCOT(1)) restituisce 45. La tangente di 45 gradi è 1.

## COTH

Restituisce la cotangente iperbolica di un numero dato (angolo).

#### Sintassi

COTH(Numero)

Restituisce la cotangente iperbolica di Numero.

#### Esempio

=COTH(1) restituisce la cotangente iperbolica di 1, circa 1.3130.

## QUOZIENTE

Restituisce la parte intera di una divisione.

#### Sintassi

QUOZIENTE(Numeratore; Denominatore)

Restituisce la parte intera del Numeratore diviso dal Denominatore.

QUOZIENTE equivale a INT(numeratore/denominatore) per il numeratore e il denominatore dello stesso segno, ad eccezione del fatto che potrebbe segnalare errori con codici di errore diversi. Più in generale, equivale a INT(numeratore/denominatore/SEGNO(numeratore/denominatore))*SEGNO(numeratore/denominatore).

#### Esempio

=QUOZIENTE(11;3) restituisce 3. Il resto di 2 è perso.

## RADQ.PI.GRECO

Restituisce la radice quadrata di un numero moltiplicato per pi greco.

#### Sintassi

RADQ.PI.GRECO(Numero)

Restituisce la radice quadrata positiva di (PI.GRECO moltiplicato per il numero).

Questo è l'equivalente di RADQ(PI.GRECO()*Numero).

#### Esempio

=RADQ.PI.GRECO(2) restituisce la radice quadrata di 2*pi greco, approssimativamente 2,506628.

## RADQ

Restituisce la radice quadrata positiva di un numero.

#### Sintassi

RADQ(Numero)

Restituisce la radice quadrata positiva di Numero.

Il numero deve essere positivo.

#### Esempio

=RADQ(16) restituisce 4.

=RADQ(-16) restituisce un errore del tipo argomento non valido.

## SEC

Restituisce la secante dell'angolo dato (in radianti). La secante di un angolo è il reciproco del coseno di quell'angolo.

La funzione è disponibile da LibreOffice 3.5

#### Sintassi

SEC(Angolo)

Restituisce la secante (trigonometrica) dell'Angolo, in radianti.

Utilizzate la funzione RADIANTI per restituire la secante di un angolo espresso in gradi.

#### Esempio

=SEC(PI.GRECO()/4) restituisce circa 1.4142135624, il reciproco del coseno di PI.GRECO()/4 radianti.

=SEC(RADIANTI(60)) restituisce 2, la secante di 60 gradi.

## SECH

Restituisce la secante iperbolica di un numero.

La funzione è disponibile da LibreOffice 3.5

#### Sintassi

SECH(Angolo)

Restituisce la secante iperbolica dell'Angolo.

#### Esempio

=SECH(0) restituisce 1, la secante iperbolica di 0.

## SOMMA

Restituisce la somma di tutti i numeri in un'area di celle.

#### Sintassi

SOMMA(Numero 1; Numero 2; ...; Numero 30)

Numero 1 fino a Numero 30 sono gli argomenti (massimo 30), o le celle o gli intervalli, per i quali deve essere calcolata la somma.

SOMMA ignora qualsiasi testo o cella vuota all'interno di un intervallo o una matrice. Se pensate di aver ottenuto risultati errati della funzione SOMMA, cercate del testo all'interno dell'intervallo di dati. Usate la funzionalità evidenziazione valori per evidenziare il contenuto di testo, all'interno dell'intervallo, che potrebbe rappresentare un numero.

#### Esempio

Se digitate 2; 3 e 4 nei campi di testo Numero 1, 2 e 3, il risultato visualizzato sarà 9.

SOMMA(A1;A3;B5) calcola la somma delle tre celle. =SOMMA(A1:E10) calcola la somma di tutte le celle nell'area di celle da A1 fino a E10.

Le condizioni collegate con E possono essere usate insieme alla funzione SOMMA() nel modo seguente:

Ipotesi di esempio: avete raccolto le vostre fatture in una tabella. La colonna A riporta le date delle fatture, mentre nella colonna B sono visualizzati gli importi. Cercate ora una formula che consenta di sommare solo gli importi relativi a un mese specifico, ad esempio solo gli importi relativi al periodo dal 1/1/2008 al 1/2/2008. L'area comprendente le date è A1:A40, l'area con gli importi da sommare è B1:B40. In C1 è inserita la data iniziale delle fatture da calcolare, 1/1/2008, e in C2 la data che non deve più essere presa in considerazione, 1/2/2008.

Digitate ora la seguente formula come formula di matrice:

=SOMMA((A1:A40>=C1)*(A1:A40<C2)*B1:B40)

Per digitare la formula come formula di matrice dovete premere la combinazione di tasti Maiusc+Comando+ Ctrl+ Invio, invece di chiudere la formula semplicemente con il tasto Invio. A questo punto la formula viene visualizzata nella barra Formula racchiusa tra parentesi graffe.

{=SOMMA((A1:A40>=C1)*(A1:A40<C2)*B1:B40)}

La formula si basa sul fatto che il risultato di un confronto è 1 se il criterio viene soddisfatto, mentre è 0 in caso contrario. I singoli risultati del confronto vengono trattati come matrice e utilizzati in moltiplicazioni di matrice. Alla fine, i singoli valori vengono sommati per ottenere la matrice dei risultati.

## TAN

Restituisce la tangente di un determinato angolo espresso in radianti.

#### Sintassi

TAN(Numero)

Restituisce la tangente (trigonometrica) di Numero, l'angolo in radianti.

Utilizzate la funzione RADIANTI per restituire la tangente di un angolo espressa in gradi.

#### Esempio

=TAN(PI.GRECO()/4) restituisce 1, la tangente di pi greco quarti radianti.

=TAN(RADIANTI(45)) restituisce 1, la tangente di 45 gradi.

## TANH

Restituisce la tangente iperbolica di un numero.

#### Sintassi

TANH(Numero)

Restituisce la tangente iperbolica di Numero.

#### Esempio

=TANH(0) restituisce 0, la tangente iperbolica di 0.

## ARROTONDA.MULTIPLO

Restituisce un numero arrotondato al più vicino multiplo di un altro numero.

#### Sintassi

ARROTONDA.MULTIPLO(Numero; Multiplo)

Restituisce il Numero arrotondato al più vicino multiplo di Multiplo.

Un'implementazione alternativa potrebbe essere Multiplo * ARROTONDA(Numero/Multiplo).

#### Esempio

=ARROTONDA.MULTIPLO(15,5;3) restituisce 15, poiché 15,5 è più vicino a 15 (= 3*5) che a 18 (= 3*6).

=ARROTONDA.MULTIPLO(1,4;0,5) restituisce 1,5 (= 0,5*3).

## CASUALE

Restituisce un numero casuale compreso tra 0 e 1.

#### Sintassi

CASUALE()

Questa funzione genera un nuovo numero casuale ogni volta che Calc ripete il calcolo. Per forzare Calc a ripetere il calcolo manualmente premete F9.

Per generare numeri casuali che non vengono ricalcolati, copiate le celle che contengono =CASUALE(), e utilizzate Modifica - Incolla speciale (selezionando Numeri ma non selezionando Incolla tutto e Formule).

#### Esempio

=CASUALE() restituisce un numero casuale tra 0 e 1.

## POTENZA

Restituisce un numero elevato a potenza.

#### Sintassi

POTENZA(Base; Esponente)

Restituisce la base elevata alla potenza espressa dall'esponente.

Lo stesso risultato può essere ottenuto utilizzando l'operatore esponenziale ^:

Base^Esponente

#### Esempio

=POTENZA(4;3) restituisce 64, ovvero 4 elevato alla terza.

=4^3 restituisce anche 4 con potenza 3.

## CASUALE.TRA

Restituisce un numero intero casuale in un intervallo specificato.

#### Sintassi

CASUALE.TRA(Minore; Maggiore)

Restituisce un numero intero casuale tra l'intero inferiore e quello superiore (entrambi inclusi).

Questa funzione genera un nuovo numero casuale ogni volta che Calc ripete il calcolo. Per forzare Calc a ripetere il calcolo manualmente premete F9.

Per generare numeri casuali che non vengono ricalcolati, copiate le celle contenenti questa funzione, e utilizzate Modifica - Incolla speciale (con le opzioni Incolla tutto e Formule disattivate e quella Numeri attivata).

#### Esempio

=CASUALE.TRA(20;30) restituisce un numero intero tra 20 e 30.

## SOMMA.SE

Somma gli argomenti specificati secondo il criterio dato. Questa funzione viene usata per scorrere un intervallo quando si cerca un determinato valore.

La ricerca supporta caratteri jolly o espressioni regolari. Attivando le espressioni regolari potete, per esempio, digitare "all.*", per trovare la prima posizione di "all" seguita da qualsiasi altro carattere. Se volete ricercare un testo che è anch'esso un'espressione regolare, dovete far precedere qualsiasi carattere da un carattere "\" character, oppure racchiudere il testo all'interno \Q...\E. Potete attivare o disattivare la stima automatica dei caratteri jolly o delle espressioni regolari in LibreOffice - PreferenzeStrumenti - Opzioni - LibreOffice Calc - Calcola.

Quando utilizzate funzioni in cui uno o più argomenti sono stringhe di criteri di ricerca che rappresentano un'espressione regolare, il primo tentativo è convertire i criteri della stringa in numeri. Per esempio, ".0" sarà convertito in 0.0 e via discorrendo. Se coincide, la corrispondenza non sarà una corrispondenza di espressione regolare ma una corrispondenza numerica. Tuttavia, quando si passa a un'impostazione regionale in cui il separatore decimale non è il punto, tale passaggio fa funzionare la conversione in espressione regolare. Per forzare la stima dell'espressione regolare, anziché di quella numerica, utilizzate delle espressioni che non possano essere confuse con una numerica, tipo ".[0]", ".\0" oppure "(?i).0".

#### Sintassi

SOMMA.SE(Area; Criteri; Intervallo somma)

Area è l'intervallo di celle dove applicare i criteri.

Criteri è la cella nella quale è indicato o riportato il criterio di ricerca. Se il criterio è scritto nella formula, deve essere indicato tra virgolette.

Intervallo somma è l'area dalla quale vengono sommati i valori. Se questo parametro non viene indicato, vengono sommati i valori trovati in Area.

SOMMA.SE supporta l'operatore di concatenazione del riferimento (~) solo nel parametro Criteri, e solo se il parametro opzionale "Intervallo somma" non è presente.

#### Esempio

Per sommare solo i numeri negativi: =SOMMA.SE(A1:A10;"<0")

=SOMMA.SE(A1:A10;">0";B1:B10) somma i valori compresi nell'area B1:B10 solo se i valori corrispondenti compresi nell'area A1:A10 sono >0.

Vedete CONTA.SE() per alcuni altri esempi di sintassi che possono essere utilizzati con SOMMA.SE().

## SOMMA.SERIE

Somma i primi termini di una serie di potenze.

SOMMA.SERIE(x;n;m;coefficienti) = coefficiente_1*x^n + coefficiente_2*x^(n+m) + coefficiente_3*x^(n+2m) +...+ coefficiente_i*x^(n+(i-1)m)

#### Sintassi

SOMMA.SERIE(X; N; M; Coefficienti)

X: il valore da immettere per la serie di potenze.

N esprime la potenza iniziale

M è l'incremento da aggiungere a N

Coefficienti è una serie di coefficienti. Per ciascun coefficiente la somma della serie è estesa di una sezione.

## TRONCA

Tronca un numero rimuovendo le cifre dopo la virgola.

#### Sintassi

TRONCA(Numero; Numero)

Restituisce Numero con al massimo un determinato numero di decimali. I decimali in eccesso sono semplicemente rimossi, a prescindere dal segno.

TRONCA(Numero; 0) si comporta come INT(Numero) per i numeri positivi, ma arrotonda verso lo zero per i numeri negativi.

Le posizioni decimali visibili del risultato sono specificate inLibreOffice - PreferenzeStrumenti - Opzioni - LibreOffice Calc - Calcola.

#### Esempio

=TRONCA(1,239;2) restituisce 1,23. Il 9 viene eliminato.

=TRONCA(-1,234999;3) restituisce -1,234. Tutti i 9 vengono scartati.

Argomenti correlati

Funzioni per categoria