Turinys
Rodyklė 🔎︎

## AVERAGEIFS funkcija

Grąžina visų srities langelių reikšmių tenkinančių duotą sudėtinę sąlygą aritmetinį vidurkį. Funkcija AVERAGEIFS susumuoja visus rezultatus, kurie tenkina logines sąlygas ir padalija iš jų skaičiaus.

Ši funkcija galima nuo „LibreOffice“ 4.0

#### Sintaksė

AVERAGEIFS(Funkcijos sritis; 1 sritis; 1 kriterijus [ ; 2 sritis; 2 kriterijus [;...]]))

Funkcijos sritis – būtinas argumentas. Gali būti langelių sritis, srities pavadinimas, stulpelio ar eilutės žymė, kurie nurodo į langelius su reikšmės, kurių vidurkis skaičiuojamas.

1 kriterijus – būtinas argumentas, kuris gali būti eilutė išreiškianti loginę sąlygą arba langelio nuoroda į tokią eilutę. Išraiškoje gali būti tekstas, skaičiai, kita išraiška (jei įgalinta skaičiavimo parinktyse).

2 sritis – neprivaloma. 2 sritis ir visos paskesnė aprašomos taip pat, kaip ir 1 sritis.

2 kriterijus – papildomas. 2 kriterijus ir paskesni aprašomi taip pat kaip ir 1 kriterijus.

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every character with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in LibreOffice - PreferencesTools - Options - LibreOffice Calc - Calculate.

When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".

Funkcijos sritis ir 1 sritis, 2 sritis... turi būti tokio paties dydžio, kitaip funkciją grąžina „Klaida:502“ – neteisingas argumentas.

Kriterijams galima naudoti loginę operaciją AND (konjunkciją). Kitais žodžiai, jei tenkinamas tik duotas kriterijus, tai į skaičiavimą įtraukiama atitinkamo langelio duotos Funkcijos srities reikšmė.

Funkcija gali turėti iki 255 argumentų, tai reiškia, kad galite nurodyti 127 kriterijų sritis ir jų kriterijus.

Jei langelyje yra reikšmė TRUE, tai traktuojama kaip 1, o FALSE - kaip 0 (nulis).

Ši funkcija yra raštinės paketo standarto 1.2 versijos atviro dokumento formato dalis (ISO/IEC 26300:2-2015)

#### Pavyzdys

Aptarsime pateiktą lentelę

| A | B | C
1 | Produkto pavadinimas | Pardavimai | Pajamos
2 | pieštukas | 20 | 65
3 | plunksna | 35 | 85
4 | užrašinė | 20 | 190
5 | knyga | 17 | 180
6 | pieštuko veiksena | neigimas | neigimas

Žemiau pateiktuose pavyzdžiuose, skaičiavimo sritys apima #6 eilutę, kurios nepaisoma, nes joje yra tekstas.

#### Įprastas naudojimas

=AVERAGEIFS(B2:B6;B2:B6;">=20")

Apskaičiuoja srities B2:B6 reikšmių, kurios didesnės arba lygios 20, vidurkį. Grąžina 25, nes penktos eilutės reikšmė netenkina sąlygos.

=AVERAGEIFS(C2:C6;B2:B6;">=20";C2:C6;">70")

Apskaičiuoja srities C2:C6 reikšmių didesnių už 70 ir atitinkančių srities B2:B6 langelių reikšmių didesnių arba lygių 20, vidurkį. Grąžina 137,5, nes antros ir penktos eilutės reikšmės netenkina bent vienos sąlygos.

#### Reguliariojo reiškinio ir įdėtosios funkcijos naudojimas

=AVERAGEIFS(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Apskaičiuoja srities C2:C6 reikšmių, kurios atitinka visas srities B2:B6 mažiausias ir didžiausias reikšmes, vidurkį. Grąžina 127,5, nes trečia ir penkta eilutės netenkina bent vienos sąlygos.

=AVERAGEIFS(C2:C6;A2:A6;"rašiklis.*";B2:B6;"<"&MAX(B2:B6))

Apskaičiuoja srities C2:C6 reikšmių atitinkančių langelių A2:A6 reikšmių pradedant „rašiklis“ ir baigiant srities B2:B6 didžiausia reikšme, vidurkis. Grąžina 65, nes tik antra eilutė tenkina visas sąlygas.

#### Nuorodą į langelį kaip kriterijų

Jei norite lengvai pakeisti kriterijų, tai geriau jį nurodyti atskirame langelyje ir naudoti jo nuorodą kaip sąlygą funkcijoje AVERAGEIFS. Pavyzdžiui, pateiktą funkciją galima parašyti šitaip:

=AVERAGEIFS(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

Jei E2 = rašiklis, tai funkcija grąžina 65, nes turinys pakeistas į langelio nuorodą.

Susijusios temos

AVERAGE, AVERAGEA, AVEDEV, AVERAGEIF

COUNTIFS, MINIF, MAXIFS, AVERAGEIFS, SUMIF

Reguliariųjų reiškinių sąrašas