butterlp
Prev | Orchestra Opcodes and Operators | Next

## butterlp

butterlp — A low-pass Butterworth filter.

## Description

Implementation of a second-order low-pass Butterworth filter. This opcode can also be written as butlp.

## Syntax

    ares butterlp asig, kfreq [, iskip]

    ares butterlp asig, afreq [, iskip]

## Initialization

iskip (optional, default=0) -- Skip initialization if present and non-zero.

## Performance

These filters are Butterworth second-order IIR filters. They are slightly slower than the original filters in Csound, but they offer an almost flat passband and very good precision and stopband attenuation.

asig -- Input signal to be filtered.

kfreq/afreq -- Cutoff or center frequency for each of the filters.

## Examples

Here is an example of the butterlp opcode. It uses the file butterlp.csd.

Example 106. Example of the butterlp opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;RT audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o butterlp.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs = 1

    instr 1	; White noise signal

    asig rand 0.5
         outs asig, asig

    endin

    instr 2	; filtered noise

    asig rand 0.7
    alp  butterlp asig, 1000	  ;cutting frequencies above 1 KHz
         outs alp, alp

    endin

    </CsInstruments>
    <CsScore>

    i 1 0 2
    i 2 2.5 2
    e

    </CsScore>
    </CsoundSynthesizer>

## See Also

butterbp, butterbr, butterhp

## Credits

Author: Paris Smaragdis
MIT, Cambridge
1995

Existed in 3.30

Audio rate parameters introduced in version 6.02

October 2013.

Prev | Up | Next
butterhp | Home | button