Conteúdo
Índice 🔎︎

# Funções matemáticas

Esta categoria contém as funções matemáticas do Calc. Para abrir o Assistente de funções, escolha Inserir - Função.

## Função AGREGAR

Esta função devolve o resultado agregado de um intervalo. A função AGREGAR permite-lhe ignorar linhas ocultas e valores de erro, bem como agregar outras funções, tais como aquelas que são listadas abaixo.

## SUBTRAIR

Subtrai um conjunto de números e dá o resultado sem eliminar pequenos erros de arredondamento.

### COR

Devolve um valor numérico calculado por uma combinação de três cores (vermelho, verde e azul) e o canal alfa, no sistema de cores RGBA. O resultado está dependente do sistema de cores utilizado no seu computador.

## Função SOMA.SE.S

Devolve a soma dos valores das células de um intervalo que cumpram os vários critérios nos vários intervalos.

## ABS

Devolve o valor absoluto de um número.

### Sintaxe

ABS(número)

número é o número cujo valor absoluto será calculado. O valor absoluto de um número é o valor do mesmo sem o sinal +/-.

### Exemplo

=ABS(-56) devolve 56.

=ABS(12) devolve 12.

=ABS(0) devolve 0.

## ACOS

Devolve o cosseno trigonométrico inverso de um número.

### Sintaxe

ACOS(número)

Esta função devolve o cosseno trigonométrico inverso de um número, que é o ângulo (em radianos) cujo cosseno é número. O ângulo obtido encontra-se entre 0 e PI.

Para obter o ângulo em graus, utilize a função GRAUS.

### Exemplo

=ACOS(-1) devolve 3,14159265358979 (radianos PI)

=GRAUS(ACOS(0,5)) devolve 60. O cosseno de 60 graus é 0,5.

## ACOSH

Devolve o cosseno hiperbólico inverso de um número.

### Sintaxe

ACOSH(número)

Esta função devolve o cosseno hiperbólico inverso de número, que corresponde ao número cujo cosseno hiperbólico é número.

O número tem de ser maior ou igual a 1.

### Exemplo

=ACOSH(1) devolve 0.

=ACOSH(COSH(4)) devolve 4.

## ACOT

Devolve a cotangente inversa (a arco cotangente) do número indicado.

### Sintaxe

ACOT(número)

Esta função devolve a cotangente trigonométrica inversa de número, que é o ângulo (em radianos) cuja cotangente é número. O ângulo obtido encontra-se entre 0 e PI.

Para obter o ângulo em graus, utilize a função GRAUS.

### Exemplo

=ACOT(1) devolve 0,785398163397448 (radianos PI/4).

=GRAUS(ACOT(1)) devolve 45. A tangente de 45 graus é 1.

## ACOTH

Devolve a cotangente hiperbólica inversa de um número.

### Sintaxe

ACOTH(número)

Esta função devolve a cotangente hiperbólica inversa de número, que corresponde ao número cuja cotangente hiperbólica é número.

Ocorre um erro se número estiver entre -1 e 1 inclusive.

### Exemplo

=ACOTH(1,1) devolve a cotangente hiperbólica inversa de 1,1, que é aproximadamente 1,52226.

## ALEATÓRIO

Devolve um número aleatório entre 0 e 1.

### Sintaxe

ALEATÓRIO()

Esta função produz um novo número aleatório sempre que o Calc efetue novos cálculos. Para efetuar os cálculos manualmente, prima F9.

Para gerar números aleatórios que nunca voltam a ser calculados, copie as células que contenham =ALEATÓRIO() e utilize Editar - Colar especial (com as opções Colar tudo e Fórmulas desmarcadas e a opção Números marcada).

### Exemplo

=ALEATÓRIO() devolve um número aleatório entre 0 e 1.

## ALEATÓRIOENTRE

Devolve um número inteiro aleatório num intervalo especificado.

### Sintaxe

ALEATÓRIOENTRE (inferior; superior)

Devolve um número inteiro aleatório situado entre os números inteiros inferior e superior (ambos inclusos).

Esta função produz um novo número aleatório sempre que o Calc efetue novos cálculos. Para efetuar os cálculos manualmente, prima F9.

Para gerar números aleatórios que nunca voltam a ser calculados, copie as células que contenham esta função e utilize Editar - Colar especial (com as opções Colar tudo e Fórmulas desmarcadas e a opção Números marcada).

### Exemplo

=ALEATÓRIOENTRE(20;30) devolve um número inteiro entre 20 e 30.

## ARRED

Arredonda um número para um determinado número de casas decimais.

### Sintaxe

ARRED(número; núm_digitos)

Devolve número arredondado para núm_dígitos casas decimais. Se núm_dígitos for omitido ou zero, a função arredonda para o número inteiro mais próximo. Se núm_dígitos for negativo, a função arredonda para o 10, 100, 1000, etc. mais próximo.

Esta função arredonda para o número mais próximo. Consulte ARRED.PARA.BAIXO e ARRED.PARA.CIMA para obter alternativas.

### Exemplo

=ARRED(2,348;2) devolve 2,35

=ARRED(-32,4834;3) devolve -32,483. Altere o formato da célula para ver todas as casas decimais.

=ARRED(2,348;0) devolve 2.

=ARRED(2,5) devolve 3.

=ARRED(987,65;-2) devolve 1000.

## ARRED.DEFEITO

Arredonda um número até ao múltiplo de Significância mais próximo.

### Sintaxe

ARRED.DEFEITO(número; significância; modo)

número é o número que será arredondado para baixo.

significância é o número para o qual se pretende fazer o arredondamento.

modo é um valor opcional. Se indicado e diferente de zero e se número e significância forem negativos, o arredondamento baseia-se no valor absoluto de número, isto é, os números negativos serão arredondados aproximando-se de zero. Se modo não for indicado ou se for igual a zero, os números negativos serão arredondados afastando-se de zero.

Se exportar a folha de cálculo para o formato do Microsoft Excel, a função ARRED.DEFEITO será exportada como ARRED.DEFEITO.MAT que existe desde o Excel 2013. Se quiser utilizar a folha de cálculo em versões anteriores do Excel, deve utilizar a função ARRED.DEFEITO.PRECISO que existe desde o Excel 2010 ou ARRED.DEFEITO.XCL que será exportada como a função ARRED.DEFEITO que é compatível com todas as versões do Excel. Tenha em atenção de que a função ARRED.DEFEITO.XCL efetua o arredondamento a aproximar-se de zero.

### Exemplo

=ARRED.DEFEITO( -11;-2) devolve -12

=ARRED.DEFEITO( -11;-2;0) devolve -12

=ARRED.DEFEITO( -11;-2;1) devolve -10

## ARRED.DEFEITO.PRECISO

Devolve um número arredondado, por defeito, para o número inteiro mais próximo ou para o múltiplo de significância mais próximo, independentemente do sinal do número.

Esta função está disponível desde o LibreOffice 4.3

### Sintaxe

ARRED.DEFEITO.PRECISO(número; significância)

número é o número que será arredondado para baixo.

significância (opcional) é o número para o qual se pretende fazer o arredondamento.

### Exemplo

=ARRED.DEFEITO.PRECISO( -11;-2) devolve -12

## ARRED.EXCESSO

Arredonda um número até ao múltiplo de significância mais próximo.

### Sintaxe

ARRED.EXCESSO(número; significância; modo)

número é o número que será arredondado para cima.

significância é o número para o múltiplo do qual o valor será arredondado para cima.

modo é um valor opcional. Se indicado e diferente de zero, e se número e significância forem negativos, o arredondamento baseia-se no valor absoluto de número, isto é, os números negativos serão arredondados para valores distantes de zero. Se modo não for indicado ou for igual a zero, os números negativos serão arredondados aproximando-se de zero.

Se exportar a folha de cálculo para o formato do Microsoft Excel, a função ARRED.EXCESSO será exportada como ARRED.EXCESSO.MAT que existe desde o Excel 2013. Se quiser utilizar a folha de cálculo me versões anteriores do Excel, deve utilizar a função ARRED.EXCESSO.PRECISO que existe desde o Excel 2010 ou ARRED.XCL que será exportada como a função ARRED.EXCESSO que é compatível com todas as versões do Excel. Tenha em atenção de que a função ARRED.XCL efetua o arredondamento a afastar-se de zero.

### Exemplo

=ARRED.EXCESSO(-11;-2) devolve -10

=ARRED.EXCESSO(-11;-2;0) devolve -10

=ARRED.EXCESSO(-11;-2;1) devolve -12

## ARRED.EXCESSO.ISO

Devolve um número arredondado para o número inteiro mais próximo ou para o múltiplo de significância mais próximo, independentemente do sinal do número.

### Sintaxe

ARRED.EXCESSO.ISO(número; significância)

número (obrigatório) é o número que se pretende arredondar.

significância (opcional) é o número para o qual se pretende fazer o arredondamento.

### Exemplo

=ARRED.EXCESSO.ISO(-11;-2) devolve -10

## ARRED.EXCESSO.MAT

Arredonda um número por excesso até ao múltiplo de significância mais próximo.

### Sintaxe

ARRED.EXCESSO.MAT(número; significância; modo)

número é o número que será arredondado para cima.

significância é o número para o múltiplo do qual o valor será arredondado para cima.

modo é um valor opcional. Se indicado e diferente de zero e se número e significância forem negativos, o arredondamento baseia-se no valor absoluto de número, isto é, os números negativos serão arredondados afastando-se de zero. Se modo não for indicado ou se for igual a zero, os números negativos serão arredondados aproximando-se de zero.

Esta função existe para a interoperabilidade com o Microsoft Excel 2013 ou mais recente.

### Exemplo

=ARRED.EXCESSO.MAT(-10;-3) devolve -9

=ARRED.EXCESSO.MAT(-10;-3;0) devolve -9

=ARRED.EXCESSO.MAT(-10;-3;1) devolve -12

## ARRED.EXCESSO.PRECISO

Devolve um número arredondado para o número inteiro mais próximo ou para o múltiplo de significância mais próximo, independentemente do sinal do número.

Esta função está disponível desde o LibreOffice 4.3

### Sintaxe

ARRED.EXCESSO.PRECISO(número; significância)

número (obrigatório) é o número que se pretende arredondar.

significância (opcional) é o número para o qual se pretende fazer o arredondamento.

### Exemplo

=ARRED.EXCESSO.PRECISO(-11;-2) devolve -10

## ARRED.PARA.BAIXO

Arredonda um número por defeito, em direção a zero, para uma determinada precisão.

### Sintaxe

ARRED.PARA.BAIXO(número; núm_digitos)

Devolve um número arredondado por defeito (em direção a zero) para núm_dígitos casas decimais. Se núm_dígitos for omitido ou zero, a função arredonda por defeito para um número inteiro. Se núm_dígitos for negativo, a função arredonda por defeito para o 10, 100, 1000, etc. seguinte.

Esta função arredonda em direção a zero. Consulte ARRED.PARA.CIMA e ARRED para obter alternativas.

### Exemplo

=ARRED.PARA.BAIXO(1,234;2) devolve 1,23.

=ARRED.PARA.BAIXO(45,67;0) devolve 45.

=ARRED.PARA.BAIXO(-45,67) devolve -45.

=ARRED.PARA.BAIXO(987,65;-2) devolve 900.

## ARRED.PARA.CIMA

Arredonda um número por excesso, afastado de zero, para uma determinada precisão.

### Sintaxe

ARRED.PARA.CIMA(número; núm_digitos)

Devolve número arredondado por excesso (afastado de zero) para núm_digitos casas decimais. Se núm_digitos for omitido ou zero, a função arredonda por excesso para um número inteiro. Se núm_digitos for negativo, a função arredonda por excesso para o 10, 100, 1000, etc. seguinte.

Esta função arredonda afastando de zero. Consulte ARRED.PARA.BAIXO e ARRED para obter alternativas.

### Exemplo

=ARRED.PARA.CIMA(1,1111;2) devolve 1,12.

=ARRED.PARA.CIMA(1,2345;1) devolve 1,3.

=ARRED.PARA.CIMA(45,67;0) devolve 46.

=ARRED.PARA.CIMA(-45,67) devolve -46.

=ARRED.PARA.CIMA(987,65;-2) devolve 1000.

## ARRED.XCL

Arredonda um número por excesso para o múltiplo de significância mais próximo.

Esta função está disponível desde o LibreOffice 5.0

### Sintaxe

ARRED.XCL(número; significância)

número é o número que será arredondado por excesso.

significância é o múltiplo para o qual se deseja fazer o arredondamento.

Esta função existe para a interoperabilidade com o Microsoft Excel 2017 ou anteriores.

### Exemplo

=ARRED.XCL(1;3) devolve 3

=ARRED.XCL(7;4) devolve 8

=ARRED.XCL(-10;-3) devolve -12

## ASEN

Devolve o seno trigonométrico inverso de um número.

### Sintaxe

ASEN(número)

Esta função devolve o seno trigonométrico inverso de número, que é o ângulo (em radianos) cujo seno é número. O ângulo devolvido encontra-se entre -PI/2 e +PI/2.

Para obter o ângulo em graus, utilize a função GRAUS.

### Exemplo

=ASEN(0) devolve 0.

=ASEN(1) devolve 1,5707963267949 (radianos PI/2).

=GRAUS(ASEN(0,5)) devolve 30. O seno de 30 graus é 0,5.

## ASENH

Devolve o seno hiperbólico inverso de um número.

### Sintaxe

ASENH(número)

Esta função devolve o seno hiperbólico inverso de número, que é o número cujo seno hiperbólico é número.

### Exemplo

=ASENH(-90) devolve aproximadamente -5,1929877.

=ASENH(SENH(4)) devolve 4.

## ATAN

Devolve a tangente trigonométrica inversa de um número.

### Sintaxe

ATAN(número)

Esta função devolve a tangente trigonométrica inversa de número, que é o ângulo (em radianos) cuja tangente é número. O ângulo devolvido encontra-se entre -PI/2 e PI/2.

Para obter o ângulo em graus, utilize a função GRAUS.

### Exemplo

=ATAN(1) devolve 0,785398163397448 (PI/4 radianos).

=GRAUS(ATAN(1)) devolve 45. A tangente de 45 graus é 1.

## ATAN2

Retorna o ângulo (em radianos) entre o eixo X e a linha da origem do ponto (número_X|número_Y).

Esta função é parte integrante da norma Open Document Format for Office Applications (OpenDocument), versão 1.2 (ISO/IEC 26300:2-2015).

### Sintaxe

ATAN2(número_x; número_y)

número_x é o valor da coordenada x.

número_y é o valor da coordenada y.

Normalmente, as linguagens de programação a a função ATAN2() possuem a ordem oposta de argumentos.

ATAN2 devolve o ângulo (em radianos) entre o eixo X e a linha da origem do ponto (número_X|número_Y)

### Exemplo

=ATAN2(-5;9) devolve 2,07789 radianos.

Para obter o ângulo em graus, aplique a função GRAUS ao resultado.

=GRAUS(ATAN2(12.3;12.3)) devolve 45. A tangente de 45 graus é 1.

LibreOffice resulta em 0 para ATAN2(0;0).

A função pode ser utilizada para converter coordenadas cartesianas em polares.

=GRAUS(ATAN2(-8;5)) devolve φ = 147,99 graus

## ATANH

Devolve a tangente hiperbólica inversa de um número.

### Sintaxe

ATANH(número)

Esta função devolve a tangente hiperbólica inversa de número, que corresponde ao número cuja tangente hiperbólica é número.

O número tem de obedecer à condição -1 < número < 1.

### Exemplo

=ATANH(0) devolve 0.

## COMBIN

Devolve o número de combinações de elementos, sem repetição.

### Sintaxe

COMBIN(número_1; número_2)

número_1 é o número de itens no conjunto.

número_2 é o número de itens a escolher no conjunto.

COMBIN devolve o número de combinações para um conjunto de itens, sem repetição. Por exemplo, se existirem 3 itens A, B e C num conjunto, pode escolher 2 itens em 3 formas diferentes, nomeadamente AB, AC e BC.

COMBIN aplica a fórmula: número_1!/(número_2!*(número_1-número_2)!)

### Exemplo

=COMBIN(3;2) devolve 3.

## COMBINA

Devolve o número de combinações de um subconjunto de itens, com repetição.

### Sintaxe

COMBINA(número_1;número_2)

número_1 é o número de itens no conjunto.

número_2 é o número de itens a escolher do conjunto.

A função COMBINA devolve o número de combinações para um conjunto de itens, com repetição. Por exemplo, se existirem 3 itens A, B e C num conjunto, pode escolher 2 itens em 6 formas diferentes, nomeadamente AA, AB, AC, BB, BC e CC.

COMBINA aplica a fórmula: (número_1+número_2-1)!/(número_2!(número_1-1)!)

### Exemplo

=COMBINA(3;2) devolve 6.

## CONVERTER_OOO

Converte um valor de uma unidade de medida para outra unidade de medida. Os fatores de conversão são indicados numa lista na configuração.

Em determinado momento, a lista de fatores de conversão incluía as antigas moedas europeias e o euro (ver exemplos abaixo). Sugerimos a utilização da nova função EUROCONVERT para efetuar a conversão destas moedas.

### Sintaxe

CONVERTER_OOO(valor;"texto";"texto")

### Exemplo

=CONVERTER_OOO(100;"ATS";"EUR") devolve o valor em Euros de 100 xelins austríacos.

=CONVERTER_OOO(100;"EUR";"DEM") converte 100 Euros em Marcos alemães.

## COS

Devolve o cosseno do ângulo especificado (em radianos).

### Sintaxe

COS(número)

Devolve o cosseno (trigonométrico) de número, o ângulo em radianos.

Para devolver o cosseno de um ângulo em graus, utilize a função RADIANOS.

### Exemplo

=COS(PI()*2) devolve 1, o cosseno de 2*PI radianos.

=COS(RADIANOS(60)) devolve 0,5, o cosseno de 60 graus.

## COSEC

Devolve a cossecante de um ângulo (em radianos). A cossecante de um ângulo é o inverso do seno do ângulo

Esta função está disponível desde o LibreOffice 3.5

### Sintaxe

COSEC(ângulo)

Devolve a cossecante (trigonométrica) de um número, o ângulo em radianos.

Para devolver a cossecante de um ângulo em graus, utilize a função RADIANOS.

### Exemplo

=COSEC(PI()/4) devolve, aproximadamente 1,4142135624 que é o inverso do seno de PI/4 radianos.

=COSEC(RADIANOS(30)) devolve 2 que é a cossecante de 30 graus.

## COSECH

Devolve a cossecante hiperbólica de um ângulo hiperbólico.

Esta função está disponível desde o LibreOffice 3.5

### Sintaxe

COSECH(ângulo)

Devolve a cossecante hiperbólica de um ângulo hiperbólico.

### Exemplo

=CSECCH(1) devolve, aproximadamente 0.8509181282 que é a cossecante hiperbólica de 1.

## COSH

Devolve o cosseno hiperbólico de um número.

### Sintaxe

COSH(número)

Devolve o cosseno hiperbólico de um número.

### Exemplo

=COSH(0) devolve 1, o cosseno hiperbólico de 0.

## COT

Devolve a cotangente do ângulo especificado (em radianos).

### Sintaxe

COT(número)

Devolve a cotangente (trigonométrica) de número, o ângulo em radianos.

Para obter a cotangente de um ângulo em graus, utilize a função RADIANOS.

A cotangente de um ângulo é equivalente a 1 dividido pela tangente desse ângulo.

### Exemplos:

=COT(PI()/4) devolve 1, a cotangente dos radianos PI/4.

=COT(RADIANOS(45)) devolve 1, a cotangente de 45 graus.

## COTH

Devolve a cotangente hiperbólica de um número (ângulo).

### Sintaxe

COTH(número)

Devolve a cotangente hiperbólica de um número.

### Exemplo

=COTH(1) devolve a cotangente hiperbólica de 1, que é aproximadamente 1,3130.

## EUROCONVERT

Esta função converte valores de moedas europeias para euros e vice-versa.

### Sintaxe

EUROCONVERT(valor; "da_moeda"; "para_moeda", precisão_completa, precisão_triangulação)

valor é a quantidade monetária a converter.

da_moeda e para_moeda são às unidades monetárias a converter de e para, respetivamente. Estas unidades monetárias têm de ser texto, a abreviatura oficial da moeda (por exemplo, "EUR"). As taxas de câmbio (mostradas por euro) foram definidas pela Comissão Europeia.

precisão_completa é opcional. Se omisso ou 0 ou FALSO, o resultado é arredondado para as casas decimais de para_moeda. Se VERDADEIRO, o resultado não é arredondado.

precisão_triangulação é opcional. Se indicada e >=3, o resultado intermédio da conversão triangular é arredondado para essa precisão. Se omisso, o resultado não é arredondado. Adicionalmente, se a moeda de destino for "EUR", a precisão_triangulação é utilizada como se fosse necessária triangulação e fosse aplicada a conversão de EUR para EUR.

### Exemplos

=EUROCONVERT(100;"ATS";"EUR") converte 100 Xelins austríacos em Euros.

=EUROCONVERT(100;"EUR";"DEM") converte 100 Euros em Marcos alemães.

## EXP

Devolve 'e' elevado à potência de um número. A constante 'e' possui um valor aproximado de 2,71828182845904.

### Sintaxe

EXP(número)

número é a potência à qual 'e' será elevado.

### Exemplo

=EXP(1) devolve 2,71828182845904, a constante matemática e para precisão do Calc.

## FATORIAL

Calcula o fatorial de um número.

### Sintaxe

FATORIAL(número)

Devolve número!, o fatorial de número, calculado como 1*2*3*4* ... * número.

=FATORIAL(0) devolve 1 por definição.

O fatorial de um número negativo resulta no erro de "argumento inválido".

### Exemplo

=FATORIAL(3) devolve 6.

=FATORIAL(0) devolve 1.

## GRAUS

Converte radianos em graus.

### Sintaxe

GRAUS(número)

número é o ângulo, em radianos, a ser convertido para graus.

### Exemplo

=GRAUS(PI()) devolve 180 graus.

## INT

Arredonda um número para o número inteiro mais próximo.

### Sintaxe

INT(número)

Devolve úmero arredondado por defeito para o número inteiro mais próximo.

Os números negativos são arredondados por defeito para o número inteiro inferior.

### Exemplo

=INT(5,7) devolve 5.

=INT(-1,3) devolve -2.

## LN

Devolve o logaritmo natural com base na constante e de um número. A constante e possui um valor de aproximadamente 2,71828182845904.

### Sintaxe

LN(número)

número é o valor cujo logaritmo natural será calculado.

### Exemplo

=LN(3) devolve o logaritmo natural de 3 (aproximadamente 1,0986).

=LN(EXP(321)) devolve 321.

## LOG

Devolve o logaritmo de um número para a base especificada.

### Sintaxe

LOG(número; base)

número é o valor cujo logaritmo será calculado.

base (opcional) é a base para o cálculo do logaritmo. Se omissa, assume a base 10.

### Exemplo

=LOG(10;3) devolve o logaritmo para a base 3 de 10 (aproximadamente 2,0959).

=LOG(7^4;7) devolve 4.

## LOG10

Devolve o logaritmo de base 10 de um número.

### Sintaxe

LOG10(número)

Devolve o logaritmo base 10 de um número.

### Exemplo

=LOG10(5) devolve o logaritmo de base 10 de 5 (aproximadamente 0,69897).

## MARRED

Devolve um número arredondado até ao múltiplo de outro número mais próximo.

### Sintaxe

MARRED (número; múltiplo)

Devolve número arredondado para o múltiplo mais próximo de múltiplo.

Uma implementação alternativa seria Múltiplo * ARRED(número/múltiplo).

### Exemplo

=MARRED(15,5;3) devolve 15, uma vez que 15,5 está mais próximo de 15 (= 3*5) do que de 18 (= 3*6).

=MARRED(1,4;0,5) devolve 1,5 (= 0,5*3).

## MCD_EXCEL2003

O resultado é o máximo divisor comum de uma lista de números.

As funções cujo nome terminem com _ADD ou _EXCEL2003 devolvem o mesmo resultado que as funções correspondentes do Microsoft Excel 2003 que não possuem o sufixo. Utilize as funções sem o sufixo para obter os resultados baseados em padrões internacionais.

### Sintaxe

MDC_EXCEL_2003(número(s))

número(s) é uma lista de um máximo de 30 números.

### Exemplo

=MDC_EXCEL2003(5;15;25) devolve 5.

## MDC

Devolve o maior divisor comum de dois ou mais números inteiros.

O máximo divisor comum é o maior número inteiro positivo que dividirá, sem resto, cada um dos números inteiros especificados.

### Sintaxe

MDC(núm_inteiro1; núm_inteiro2; ...; núm_inteiro30)

núm_inteiro1 a núm_inteiro30 são o máximo de 30 números inteiros cujo máximo divisor comum será calculado.

### Exemplo

=MDC(16;32;24) devolve o resultado 8, uma vez que 8 corresponde ao maior número que pode dividir 16, 24 e 32 sem um resto.

=MDC(B1:B3) em que as células B1, B2 e B3 incluem 9, 12 e 9 devolve 3.

## MMC

Devolve o mínimo múltiplo comum de um ou mais números inteiros.

### Sintaxe

MMC(núm_inteiro1; núm_inteiro2; ...; núm_inteiro30)

núm_inteiro1 a núm_inteiro30 são um máximo de 30 números inteiros, cujo mínimo múltiplo comum será calculado.

### Exemplo

Se introduzir os números 512;1024 e 2000 nas caixas de texto NúmeroInteiro 1;2 e 3, é obtido 128000 como resultado.

## MMC_EXCEL2003

O resultado é o mínimo divisor comum de uma lista de números.

As funções cujo nome terminem com _ADD ou _EXCEL2003 devolvem o mesmo resultado que as funções correspondentes do Microsoft Excel 2003 que não possuem o sufixo. Utilize as funções sem o sufixo para obter os resultados baseados em padrões internacionais.

### Sintaxe

MMC_EXCEL2003(número(s)

número(s) é uma lista de até 30 números.

### Exemplo

=MMC_EXCEL2003(5;15;25) devolve 75.

## PAR

Arredonda um número positivo por excesso até ao número inteiro par seguinte e um número negativo por defeito até ao número inteiro par seguinte.

### Sintaxe

PAR(número)

Devolve número, arredondado por excesso para o número inteiro par seguinte, afastado de zero.

### Exemplo

=PAR(2.3) devolve 4.

=PAR(2) devolve 2.

=PAR(0) devolve 0.

=PAR(-0,5) devolve -2.

## PI

Devolve 3,14159265358979, o valor da constante matemática PI com 14 casas decimais.

### Sintaxe

PI()

### Exemplo

=PI() devolve 3,14159265358979.

## POLINOMIAL

Devolve o fatorial da soma dos argumentos dividido pelo produto dos fatoriais dos argumentos.

### Sintaxe

POLINOMIAL(número(s))

número(s) é uma lista de até 30 números.

### Exemplo

=POLINOMIAL(F11:H11) devolve 1260 se o intervalo F11 a H11 incluir os valores 2, 3 e 4. Corresponde à fórmula =(2+3+4)! / (2!*3!*4!)

## POTÊNCIA

Devolve o número elevado a outro número.

### Sintaxe

POTÊNCIA(base; potência)

Devolve a base elevada à potência do expoente.

O mesmo resultado pode ser obtido utilizando o operador de exponenciação ^:

Base^Expoente

### Exemplo

=POTÊNCIA(4;3) devolve 64, que é 4 elevado a 3.

=4^3 também devolve 4 elevado a 3.

## PRODUTO

Multiplica todos os números atribuídos como argumentos e devolve o produto.

### Sintaxe

PRODUTO(número1; número2; ...; número30)

número1 a número30 são de 1 até 30 argumentos numéricos cujo produto deve ser calculado.

PRODUTO devolve número1 * número2 * número3 * ...

### Exemplo

=PRODUTO(2;3;4) devolve 24.

## QUOCIENTE

Devolve a parte inteira de uma operação de divisão.

### Sintaxe

QUOCIENTE(numerador; denominador)

Devolve a parte inteira de numerador dividida por denominador.

QUOCIENTE é equivalente a INT(numerador/denominador) para numeradores e denominadores com o mesmo sinal, exceto que pode reportar erros com códigos de erro diferentes. Geralmente, é equivalente a INT(numerador/denominador)/SINAL(numerador/denominador))*SINAL(numerador/denominador).

### Exemplo

=QUOCIENTE(11;3) devolve 3. O resto de 2 é perdido.

## RADIANOS

Converte graus em radianos.

### Sintaxe

RADIANOS(número)

número é o ângulo em graus a ser convertido em radianos.

### Exemplo

=RADIANOS(90) devolve 1,570796326794, que corresponde a PI/2 para precisão do Calc.

## RAIZPI

Devolve a raiz quadrada de (PI vezes um número).

### Sintaxe

RAIZPI (número)

Devolve a raiz quadrada positiva de (PI multiplicado por número).

Isto é equivalente a RAIZQ(PI()*Número).

### Exemplo

=RAIZPI(2) devolve a raiz quadrada de (2PI), aproximadamente 2,506628.

## RAIZQ

Devolve a raiz quadrada positiva de um número.

### Sintaxe

RAIZQ(número)

Devolve a raiz quadrada positiva de número.

O número tem de ser positivo.

### Exemplo

=RAIZQ(16) devolve 4.

=RAIZQ(-16) devolve um erro de argumento inválido.

## RESTO

Devolve o resto quando um número inteiro é dividido por outro.

### Sintaxe

RESTO(dividendo; divisor)

Para argumentos de número inteiro esta função devolve dividendo módulo divisor, que corresponde ao resto quando o dividendo é dividido pelo divisor.

Esta função é implementada como Dividendo - Divisor * INT(Dividendo/Divisor), pelo que esta fórmula devolve o resultado se os argumentos não forem números inteiros.

### Exemplo

=RESTO(22;3) devolve 1, o resto quando 22 é divido por 3.

=RESTO(11,25;2,5) devolve 1,25.

## SEC

Devolve a secante de um ângulo (em radianos). A secante de um ângulo é o inverso do cosseno desse ângulo

Esta função está disponível desde o LibreOffice 3.5

### Sintaxe

SEC(ângulo)

Devolve a secante de um ângulo expresso em radianos.

Para devolver a secante de um ângulo em graus, utilize a função RADIANOS.

### Exemplo

=SEC(PI()/4) devolve aproximadamente 1,4142135624, que é o inverso do cosseno de PI/4 radianos.

=SEC(RADIANOS(60)) devolve 2, que é a secante de 60 graus.

## SECH

Devolve a secante hiperbólica de um ângulo hiperbólico.

Esta função está disponível desde o LibreOffice 3.5

### Sintaxe

SECH(ângulo)

Devolve a secante hiperbólica de um ângulo hiperbólico.

### Exemplo

=SECH(0) devolve 1, que é a secante hiperbólica de 0.

## SEN

Devolve o seno do ângulo especificado (em radianos).

### Sintaxe

SEN(número)

Devolve o seno (trigonométrico) de número, o ângulo nos radianos.

Para devolver o seno de um ângulo em graus, utilize a função RADIANOS.

### Exemplo

=SEN(PI()/2) devolve 1, o seno dos radianos PI/2.

=SEN(RADIANOS(30)) devolve 0,5, o seno de 30 graus.

## SENH

Devolve o seno hiperbólico de um número.

### Sintaxe

SENH(número)

Devolve o seno hiperbólico de número.

### Exemplo

=SENH(0) devolve 0, o seno hiperbólico de 0.

## SINAL

Devolve o sinal de um número. Devolve 1 se o número for positivo, -1 se for negativo e 0 se for zero.

### Sintaxe

SINAL(número)

número é o número cujo sinal será determinado.

### Exemplo

=SINAL(3.4) devolve 1.

=SINAL(-4.5) devolve -1.

## SOMA

Adiciona todos os números de uma série de células.

### Sintaxe

SOMA(número1; número2; ...; número30)

número 1 a número 30 são um máximo de 30 argumentos, cuja soma será calculada.

### Exemplo

Se introduzir os números 2; 3 e 4 nas caixas de texto Número 1; 2 e 3, será devolvido 9 como resultado.

=SOMA(A1;A3;B5) calcula a soma das três células. =SOMA (A1:E10) calcula a soma de todas as células no intervalo de células A1 a E10.

As condições associadas por E podem ser utilizadas com a função SOMA() da seguinte forma:

Exemplo: introduziu faturas numa tabela. A coluna A contém o valor da data da fatura, e a coluna B contém os montantes. Pretende encontrar uma fórmula que possa utilizar para obter o total de todos os montantes para um mês específico, por ex. apenas o montante correspondente ao período entre >=2008-01-01 e <2008-02-01. O intervalo com os valores das datas abrange A1:A40, o intervalo que contém os montantes que serão calculados é B1:B40. C1 contém a data de início, 2008-01-01, das faturas a serem incluídas e C2 a data, 2008-02-01, que já não será incluída.

Introduza a seguinte fórmula como fórmula de matriz:

=SOMA((A1:A40>=C1)*(A1:A40<C2)*B1:B40)

Para inserir esta fórmula como uma fórmula de matriz, tem de premir as teclas Shift+ComandoCtrl+ Enter em vez de premir apenas a tecla Enter para fechar a fórmula. A fórmula será então mostrada entre chavetas na barra de fórmulas.

{=SOMA((A1:A40>=C1)*(A1:A40<C2)*B1:B40)}

A fórmula é baseada no facto do resultado de uma comparação corresponder a 1, se o critério for obedecido e a 0 se não for obedecido. Os resultados da comparação individual serão tratados como uma matriz e utilizados na multiplicação de matrizes e, no final, os valores individuais serão somados para que seja obtida a matriz de resultados.

## SOMA.SE

Adiciona as células especificadas por determinados critérios. Esta função é utilizada para explorar um intervalo ao procurar um dado valor.

A procura permite a utilização de expressões regulares. Pode introduzir "all.*", por exemplo, para localizar a primeira localização de "all" seguida de quaisquer caracteres. Se quiser procurar texto que também é uma expressão regular, necessita de anteceder cada carácter com "\2. Pode ativar e desativar a avaliação automática de expressões regulares em LibreOffice - PreferênciasFerramentas - Opções - LibreOffice Calc - Calcular.

### Sintaxe

SOMA.SE(intervalo; critérios; intervalo_soma)

intervalo é o intervalo ao qual serão aplicados os critérios.

critérios é a célula na qual é mostrado o critério de procura ou o próprio critério de procura. Se os critérios forem registados na fórmula, terão de ser delimitados por aspas.

intervalo_soma é o intervalo a partir do qual os valores são somados. Se este parâmetro não tiver sido indicado, são somados os valores localizados no Intervalo.

A fórmula SOMA.SE aceita o operador de concatenação de referências (~) no parâmetro critérios e apenas se o parâmetro adicional intervalo_soma não for indicado.

### Exemplo

Para só somar os números negativos: =SOMA.SE(A1:A10;"<0")

=SOMA.SE(A1:A10;">0";B1:10) apenas soma os valores do intervalo B1:B10 se os valores no intervalo A1:A10 forem >0.

Consulte CONTAR.SE() para obter mais alguns exemplos de sintaxe que podem ser utilizados com SOMA.SE().

## SOMARQUAD

Se quiser calcular a soma das raízes quadradas dos números (total das raízes quadradas dos argumentos), insira os números nos campos de texto.

### Sintaxe

SOMARQUAD(número1; número2; ...; número30)

número1 a número30 são de 1 até 30 argumentos numéricos, cujas raízes quadradas serão somadas.

### Exemplo

Se introduzir os números 2; 3 e 4 nas caixas de texto Número 1; 2 e 3, será devolvido 29 como resultado.

## SOMASÉRIE

Devolve a soma de uma série polinomial.

SOMASÉRIE(x;n;m;coeficientes) = coeficiente_1*x^n + coeficiente_2*x^(n+m) + coeficiente_3*x^(n+2m) +...+ coeficiente_i*x^(n+(i-1)m)

### Sintaxe

SOMASÉRIE(x;n;m;coeficientes)

x é a variável independente da série de potências.

n é a potência inicial

m é o incremento para aumentar n

coeficientes é o conjunto de coeficientes pelo qual cada potência sucessiva de x será multiplicada. Para cada coeficiente, a soma é aumentada por uma secção.

## SUBTOTAL

Calcula o subtotal. Se um intervalo já contiver subtotal, os mesmos não serão utilizados para cálculos posteriores. Utilize esta função com os Filtros automáticos para considerar apenas os registos filtrados.

### Sintaxe

SUBTOTAL(função; intervalo)

função é um número que representa uma das seguintes funções:

Índice de funções (inclui valores ocultos) | Índice de funções (ignora valores ocultos) | Função
1 | 101 | MÉDIA
2 | 102 | CONTAR
3 | 103 | CONTAR.VAL
4 | 104 | MÁXIMO
5 | 105 | MÍNIMO
6 | 106 | PRODUTO
7 | 107 | DESVPAD
8 | 108 | DESVPADP
9 | 109 | SOMA
10 | 110 | VAR
11 | 111 | VARP

Usa números de 1-11 para incluir linhas ocultas manualmente ou 101-111 para as excluir; as células filtradas são sempre excluídas.

intervalo é o intervalo cujas células estão incluídas.

### Exemplo

Você tem uma tabela no intervalo de células A1:B6, que contém uma lista de materiais para 10 estudantes. A linha 2 (Caneta) foi ocultada manualmente. Você quer ver a soma dos valores mostrados; ou seja, só o subtotal das linhas filtradas. Nesse caso a fórmula seria:

| A | B
1 | ITEM | QUANTIDADE
2 | Caneta | 10
3 | Lápis | 10
4 | Caderno | 10
5 | Borracha | 10
6 | Afia | 10

=SUBTOTAL(9;B2:B6) devolve 50.

=SUBTOTAL(109;B2:B6) devolve 40.

## TAN

Devolve a tangente do ângulo especificado (em radianos).

### Sintaxe

TAN(número)

Devolve a tangente (trigonométrica) de número, o ângulo em radianos.

Para devolver a tangente de um ângulo em graus, utilize a função RADIANOS.

### Exemplo

=TAN(PI()/4) devolve 1, a tangente dos radianos PI/4.

=TAN(RADIANOS(45)) devolve 1, a tangente de 45 graus.

## TANH

Devolve a tangente hiperbólica de um número.

### Sintaxe

TANH(número)

Devolve a tangente hiperbólica de número.

### Exemplo

=TANH(0) devolve 0, a tangente hiperbólica de 0.

## TRUNCAR

Trunca um número removendo casas decimais.

### Sintaxe

TRUNCAR(número; núm_digitos)

Devolve número com um máximo de núm_dígitos casas decimais. As casas decimais excedentes serão removidas, independentemente do sinal.

TRUNCAR(número; 0) comporta-se como INT(número) para números positivos, mas arredonda em direção a zero para números negativos.

As casas decimais visíveis do resultado são especificadas em LibreOffice - PreferênciasFerramentas - Opções - LibreOffice Calc - Calcular.

### Exemplo

=TRUNCAR(1,239;2) devolve 1,23. O 9 desaparece.

=TRUNCAR(-1,234999;3) devolve -1,234. Todos os noves desaparecem.

## ÍMPAR

Arredonda um número positivo até ao número inteiro ímpar mais próximo e um número negativo até ao número inteiro ímpar mais próximo.

### Sintaxe

ÍMPAR(número)

Devolve número arredondado por excesso para o número ímpar seguinte, afastado de zero.

### Exemplo

=ÍMPAR(1.2) devolve 3.

=ÍMPAR(1) devolve 1.

=ÍMPAR(0) devolve 1.

=ÍMPAR(-3,1) devolve -5.

Tópicos relacionados

Funções por categoria