LibreLogo Araç Çubuğu

İçerikler
Dizin 🔎︎

# LibreLogo

LibreLogo kaplumbağa vektör grafikleriyle hesaplama (programlama ve kelime işleme), DTP ve grafik tasarımı öğretmek için hazırlanmış basit, yerelleştirilmiş, Logo benzeri bir programlama ortamıdır. Ayrıntılar için: http://www.numbertext.org/logo/librelogo.pdf.

## LibreLogo araç çubuğu

LibreLogo araç çubuğu (Görünüm - Araç Çubukları - Logo), hareket yön işaretleri, program başlat, durdur, anasayfa, ekranı temizle, yazılım düzenleyecisi/sözdizimi vurgulama/simge çevirisi ve bir girdi çubuğu (komut satırı) bileşenlerini içerir.

## Kaplumbağa hareket simgeleri

Bunlar “FORWARD 10”, “BACK 10”, “LEFT 15”, “RIGHT 15” Logo komutlarının eşdeğerleridir. Simgelerden birine tıklamak kaplumbağanın şeklinin sayfaya göre kaydırmasını konumuna da odaklar.

## Logo uygulamasını Başlat

Writer belgesinin metnini (ya da seçili metni) bir LibreLogo programı olarak çalıştırmak için "Logo programını başlat" simgesine tıklayın. Boş bir belgede örnek bir program yerleştirilecek ve çalıştırılacaktır.

Programın çalışmasını durdurmak için "Durdur" simgesine tıklayın.

## Başlangıç

Konumu ve kaplumbağa ayarlarını sıfırlamak için "Başlangıç" simgesine tıklayın.

## Ekranı temizle

Belgenin çizim nesnelerini silmek için "Ekranı temizle" simgesine tıklayın.

## Yazılım düzenleyici/Sözdizimi vurgulama/Çeviri

"Sihirli değnek" simgesi program düzenleme için 2 sayfalı yerleşim ayarlar, Writer belgesindeki kısaltmaları büyük harfe, Logo komutlarını küçük harfe dönüştürür ve genişletir. Belgenin dilini değiştirin (Araçlar - Seçenekler - Dil Ayarları - Diller - Batı) ve Logo programını seçili dile çevirmek için bu simgeye tıklayın.

## Komut satırı

Komut satırının içeriğini çalıştırmak için Enter tuşuna basın. Programı durdurmak için "Durdur" simgesini kullanın.

Komut satırını tekrarlamak için Enter tuşuna basılı tutun, örneğin, sıra takip eden komutlarda:

     FORWARD 200 LEFT 89

Komut satırını sıfırlamak için üç kere tıklayın veya önceki komutları seçmek için Ctrl-A tuşlarına basın, ve yeni komutları girin.

## Temel kaplumbağa ayarları için grafik kullanıcı arayüzü

LibreLogo'nun kaplumbağa şekli normal sabit boyutlu bir çizim nesnesidir. Fareyi ve Çizim Nesneleri Özellikleri araç çubuğundaki Döndür simgesini kullanarak konumlandırabilir ve döndürebilirsiniz. LibreLogo'nun özniteliklerinden PENSIZE, PENCOLOR ve FILLCOLOR değerlerini değiştirerek Çizgi Genişliğini, Çizgi Rengini ve Alan Rengini düzenleyebilirsiniz.

## Program düzenlemek

LibreLogo çizimleri ve programları aynı Writer belgelerini kullanırlar. LibreLogo tuvali Writer belgesinin ilk sayfasındadır. LibreLogo programlarından önce bir sayfa sonlandırması ekleyebilir ve sayfa yakınlaştırması için Logo araç çubuğundaki "sihirli değnek" simgesini ayarlayabilirsiniz, LibreLogo programlama için konforlu 2 sayfa düzeni için yakınlaştırmayı da ayarlayabilirsiniz: sol (ilk) sayfayı tuval, sağ (ikinci) sayfayı LibreLogo program düzenleyicisi için.

# LibreLogo programlama dili

LibreLogo kolayca yerelleştirilebilir Logo benzeri bir programlama dilidir ve bir çok LibreOffice topluluğu tarafından yerelleştirilmiştir. Eğitimde kullanılan basit Logo programlarının sistemine geriye dönük uyumluluğu vardır.

     TO üçgen :boyut
     REPEAT 3 [
       FORWARD :boyut
       LEFT 120
     ]
     END

     üçgen 10 üçgen 100 üçgen 200

## Logo programla dilinden farklar

- Liste üyeleri virgülle ayrılmıştır: POSITION [0, 0]

- Program blokları ve listeleri farklıdır

- - Program blokları parenteze alma işleminde boşluğa veya yeni bir satıra ihtiyac duyar: REPEAT 10 [ FORWARD 10 LEFT 36 ]

  - Liste parantezlerinden önce ve sonra boşluk olmamalı: POSITION [0, 0] doğru, POSITION [ 0, 0 ] hatalı

- 1-satır işlevi açıklamaları desteklenmez (TO ve END yeni satırlara ihtiyaç duyar).

## LibreLogo'nun diğer özellikleri

- Değişken isimlerinden önce iki nokta üst üste isteğe bağlıdır.

       TO üçgen boyutu
         REPEAT 3 [ FORWARD size LEFT 120 ]
       END

- Dizgi yazımı imla ve Python sözdizimini de destekler.

       PRINT "kelime ; özgün Logo sözdizimi
       PRINT “Rasgele metin.” ; imla, Writer
       PRINT 'Rasgele metin.' ; Python sözdizimi

- Python liste ve dizgilerini kullanmak

       PRINT “metin”[2] ; print “x”
       PRINT “metin”[1:3] ; print “et”

- Python benzeri FOR döngüsü

- Python benzeri değişken tanımlaması:

       x = 15
       PRINT x

- Ek sorgu işlevleri yoktur:

       PRINT FILLCOLOR
       p = POSITION
       PRINT p
       REPEAT 10 [ POSITION ANY POSITION p ]

- İşlev çağrılarında farklı parentezleme

       TO yıldız boyut renk
       FILLCOLOR renk
       REPEAT 5 [ LEFT 72 FORWARD boyut RIGHT 144 FORWARD boyut ]
       FILL
       END

       yıldır 100 “kırmızı”
       yıldız (100, “yeşil”)
       yıldız (100, “mavi”)

# LibreLogo komutları

## Temel sözdizimi

### Büyük/Küçük Harf Duyarlı

Komutlar, renk sabitleri büyük/küçük harfe duyarlıdır:

     PRINT “Merhaba, Dünya!”
     print “Tekrar, Merhaba, Dünya!”

Değişken isimleri büyük-küçük harf duyarlı:

     a = 5
     A = 7
     PRINT a
     PRINT A

### Program satırları

LibreLogo programının satırları LibreOffice Writer belgesindeki paragraflardır. Bir program satırı birden fazla komut içerebilir:

     PRINT “Merhaba, Dünya!” PRINT “LibreLogo”

### Yorumlar

Satır (paragraf) sonunda noktalı virgül ile ayrılan satırlar veya satır parçaları yorumdur.

     ; bazı yorumlar
     PRINT 5 * 5 ; bazı yorumlar

### Program satırlarını çoklu paragraflara böl

Satır sonunda tilda karakteri kullanarak bir program satırını paragraflara kırmak mümkündür:

     PRINT “Bu çok uzun bir ” + ~
           “uyarı iletisidir”

## Kaplumbağa hareketli

### FORWARD (fd)

     FORWARD 10 ; 10pt (1pt = 1/72 inch) ileri git
     FORWARD 10pt ; yukarı bak
     FORWARD 0.5in ; 0.5 inch (1 inch = 2.54 cm) ileri git
     FORWARD 1" ; yukarı bak
     FD 1mm
     FD 1cm

### BACK (bk)

     BACK 10 ; 10pt geri git

### LEFT (lt)

     LEFT 90 ; saat yönünün tersine 90 derece dön
     LEFT 90° ; yukarı bak
     LT 3h ; yukarı bak (saat konumu)
     LT any ; rastgele dön

### RIGHT (rt)

     RIGHT 90 ; saat yönünde 90 derece dön

### PENUP (pu)

     PENUP ; kaplumbağa çizmeden hareket eder

### PENDOWN (pd)

     PENDOWN ; kaplumbağa çizimle hareket eder

### POSITION (pos)

     POSITION [0, 0] ; sol üst köşede dön ve hareket et
     POSITION PAGESIZE ; sağ alt köşede dön ve hareket et
     POSITION [PAGESIZE[0], 0] ; sağ üst köşede dön ve hareket et
     POSITION ANY ; rastgele bir yerde dön ve hareket et

### HEADING (seth)

     HEADING 0 ; kuzeye dön
     HEADING 12h ; yukarı bak
     HEADING [0, 0] ; sol üst köşeye dön
     HEADING ANY ; rasgele bir yöne dön

## Diğer kaplumbağa komutları

### HIDETURTLE (ht)

     HIDETURTLE ; kaplumbağayı gizle (showturtle komutuna kadar)

### SHOWTURTLE (st)

     SHOWTURTLE ; kaplumbağayı göster

### HOME

     HOME; kaplumbağayı başlangıç konuma sıfırla

### CLEARSCREEN (cs)

     CLEARSCREEN ; belgenin çizim nesnelerini kaldırır

### FILL ve CLOSE

     FILL ; kapatır ve gerçek çizgi veya nokta şeklini doldurur
     CLOSE ; gerçek çizgi şeklini kapatır veya gerçek noktaları birleştirir

Örnek: bir düzenli üçgeni doldurmak:

     FORWARD 50 LEFT 120 FORWARD 50 FILL

Örnek: bir düzenli üçgen çizmek:

     FORWARD 50 LEFT 120 FORWARD 50 CLOSE

## Kalem ayarları

### PENSIZE (ps)

     PENSIZE 100 ; 100 nokta genişliğinde çizgi
     PENSIZE ANY ; PENSIZE RANDOM 10 eşiti

### PENCOLOR/PENCOLOUR (pc)

     PENCOLOR “red” ; kalem rengini kırmızı yap (renk isimleri için renk sabitlerine bakın)
     PENCOLOR [255, 255, 0] ; rengi sarı yap (RGB listesi)
     PENCOLOR 0xffff00 ; rengi sarı yap (hexa kod)
     PENCOLOR 0 ; rengi siyah yap (0x000000)
     PENCOLOR ANY ; rasgele renk
     PENCOLOR [5] ; rengi kırmızı yap (renk ayırıcıları için renk sabitlerine bakın)
     PENCOLOR “invisible” ; görünür anahat olmadan şekil çizmek için kalem rengi
     PENCOLOR “~red” ; rengi rasgele kırmızı ayarla

### PENTRANSPARENCY

     PENTRANSPARENCY 80 ; şeffaflığı gerçek kalem renginin %80'ine ayarla

### PENCAP/LINECAP

     PENCAP “none” ; ek çizgi sonu olmadan (varsayılan)
     PENCAP “round” ; yuvarlatılmış çizgi ucu
     PENCAP “square” ; kare çizgi ucu

### PENJOINT/LINEJOINT

     PENJOINT “rounded” ; yuvarlatılmış çizgi birleşmesi (varsayılan)
     PENJOINT “miter” ; keskin çizgi birleşmesi
     PENJOINT “bevel” ; eğik çizgi birleşmesi
     PENJOINT “none” ; çizgi birleşmesi olmadan

### PENSTYLE

     PENSTYLE “solid” ; düz çizgi (varsayılan)
     PENSTYLE “dotted” ; noktalı çizgi
     PENSTYLE “dashed” ; kesikli çizgi

     ; özel nokta–kesikli çizgi desenleri aşağıdaki değişkenlerle sağlanır:
     ; – takip eden nokta sayısı
     ; – noktanın uzunluğu
     ; – takip eden kesikli çizgi sayısı
     ; – kesikli çizginin uzunluğu
     ; – noktaların/kesikli çizgilerin mesafesi
     ; – tür (isteğe bağlı):
     ;   0 = dikdörtgen şeklinde noktalar (varsayılan)
     ;   2 = kare şeklinde noktalar (uzunluklar ve mesafeler kalem boyutuna bağlıdır)

     PENSTYLE [3, 1mm, 2, 4mm, 2mm, 2] ; ...––...––...––

## Doldurma ayarları

### FILLCOLOR/FILLCOLOUR (fc)

     FILLCOLOR “blue” ; mavi renkle doldur, ayrıca PENCOLOR'a da bakın
     FILLCOLOR “invisible” CIRCLE 10 ; doldurulmamış çember
     FILLCOLOR [“blue”, “red”] ; kırmızı mavi arası geçişli
     FILLCOLOR [[255, 255, 255], [255, 128, 0]] ; beyaz ve turuncu arası
     FILLCOLOR [“blue”, “red”, 1, 0, 0] ; eksensel geçiş ayarla (gerekli döndürme ve kenarlık ayarlarıyla), kullanılabilir değerler: 0-5 = doğrusal, eksensel, radyal, eliptik, kare ve dikdörtgen geçişleri
     FILLCOLOR [“red”, “blue”, 0, 90, 20] ; %20 kenarlıkla doğrusal, kaplumbağanın gerçek başlığından 90 derece döndürülmüş
     FILLCOLOR [“red”, 'blue”, 0, 90, 20, 0, 0, 200, 50] ; %200 ile %50 arası yoğunluk
     FILLCOLOR [ANY, ANY, 2, 0, 0, 50, 50] ; merkezin %50-50 yatay ve dikey konumunda rasgele renklerle radyal geçişli

### FILLTRANSPARENCY

     FILLTRANSPARENCY 80 ; gerçek doldurma renginin şeffalığını %80 yap
     FILLTRANSPARENCY [80] ; doğrusal şeffaflık geçişini %80'den %0'a ayarla
     FILLTRANSPARENCY [80, 20] ; doğrusal şeffaflık geçişini %80'den %20'ye ayarla
     FILLTRANSPARENCY [80, 20, 1, 90] ; eksensel şeffaflık geçişi dönmesini kaplumbağanın gerçek başlığından 90 dereceye ayarla
     FILLTRANSPARENCY [80, 20, 2, 0, 20, 50, 50] ; radyal şeffaflık geçişini dışta %80'den içte %20'ye, %20 kenarlık şeffaflığına ve merkezden %50-50 yatay ve dikey konuma ayarla

### FILLSTYLE

     FILLSTYLE 0 ; tarama olmadan doldur (varsayılan)
     FILLSTYLE 1 ; siyah tek taramalı (yatay)
     FILLSTYLE 2 ; siyah tek taramalı (45 derece)
     FILLSTYLE 3 ; siyah tek taramalı (-45 derece)
     FILLSTYLE 4 ; siyah tek taramalı (dikey)
     FILLSTYLE 5 ; kırmızı çapraz taramalar (45 derece)
     FILLSTYLE 6 ; kırmızı çapraz taramalar (0 derece)
     FILLSTYLE 7 ; mavi çapraz taramalar (45 derece)
     FILLSTYLE 8 ; mavi çapraz taramalar (0 derece)
     FILLSTYLE 9 ; mavi üçlü çapraz
     FILLSTYLE 10 ; siyah geniş tek tarama (45 derece)

     ; aşağıdaki değişkenlerle tanımlanan özel taramalar:
     ; – biçem (1 = tek, 2 = ikili, 3 = üçlü tarama)
     ; – renk
     ; – mesafe
     ; – açı

     FILLSTYLE [2, “green”, 3pt, 15°] ; yeşil çapraz taramalar (15 derece)

## Çizim nesneleri

### CIRCLE

     CIRCLE 100 ; bir daire şekli çiz (çap = 100pt)

### ELLIPSE

     ELLIPSE [50, 100] ; çapları 50 ve 100 olan bir elip çiz
     ELLIPSE [50, 100, 2h, 12h] ; bir eliptik dilim çiz (saatin 2 konumundan 12 konumuna)
     ELLIPSE [50, 100, 2h, 12h, 2]  ; bir eliptik dilim çiz
     ELLIPSE [50, 100, 2h, 12h, 3]  ; bir eliptik yay çiz

### SQUARE

     SQUARE 100 ; bir kare şekli çiz (boyut = 100pt)

### RECTANGLE

     RECTANGLE [50, 100] ; bir dikdörtgen şekli çiz (50×100pt)
     RECTANGLE [50, 100, 10] ; yuvarlatılmış köşeleri olan bir dikdörtgen çiz

### POINT

     POINT ; kalemin renk ve boyutu ile bir nokta çiz

CLOSE son noktaları birleştirebilir, FILL noktalarla tanımlanan şekli doldurabilir. Örneğin merkezinden başlayan bir “düz” yıldız çizmek çok kolaydır:

     PENUP
     REPEAT 5 [
       FORWARD 80
       POINT
       BACK 80
       RIGHT 36
       FORWARD 50
       POINT
       BACK 50
       RIGHT 120
     ] FILL

### LABEL

     LABEL “metin” ; kaplumbağa konumuna metin yazdır
     LABEL 'metin' ; yukarı bakın
     LABEL "metin ; yukarı bakın (sadece tek kelimeler için)

### TEXT

     CIRCLE 10 TEXT “metin” ; gerçek çizim nesnesinin metnini ayarla

## Yazı tipi ayarları

### FONTCOLOR/FONTCOLOUR

     FONTCOLOR “yeşil” ; yazı tipi rengini ayarla

### FONTFAMILY

     FONTFAMILY “Linux Libertine G” ; yazı tipini ayarla (aile)
     FONTFAMILY “Linux Libertine G:smcp=1” ; yazı tipi özelliğini de ayarla (küçük harfler)
     FONTFAMILY “Linux Libertine G:smcp=1&onum=1” ; küçük harfler + eski şekiller

### FONTSIZE

     FONTSIZE 12 ; yazı tipinin boyunu 12pt ayarla

### FONTWEIGHT

     FONTWEIGHT “bold” ; yazı tipini kalın ayarla
     FONTWEIGHT “normal” ; normal ağırlıkta ayarla

### FONTSTYLE

     FONTSTYLE “italic” ; yatık yazı ayarla
     FONTSTYLE “normal” ; normal ayarla

## PICTURE (pic)

PICTURE şunlar için kullanılır

- şekil gruplamak;

- yeni çizgi şekilleri başlatmak;

- SVG görüntülerini ve SVG/SMIL canlandırmalarını kaydetmek;

- sol kenarındaki konum uyumunu ve çizgi şekillerini muhafaza etmek.

### Şekil gruplamak

     ; PICTURE [ LibreLogo_komutları ]
     PICTURE [ FORWARD 100 CIRCLE 100 ] ; ağaç benzeri gruplama şekli

LibreOffice Writer Yardım'da da "Grup"a bakabilirsiniz.

     TO tree konum
       PENUP POSITION konum HEADING 0 PENDOWN
       PICTURE [ FORWARD 100 CIRCLE 100 ] ; ağaç benzeri gruplanmış şekil
     END

     PICTURE [ tree [230, 400] tree [300, 400] ] ; gruplandırılmış şekilde gruplandırılmış şekiller

### Yeni çizgi şekilleri başlatmak

     PICTURE ; yeni bir çizgi şekli başlat
     FORWARD 10 PICTURE FORWARD 10 ; iki çizgi şekli

### SVG resimlerini kaydetme

     PICTURE “örnek.svg” [ CIRCLE 5 ] ; kullanıcı klasörüne resmi bir SVG görüntü dosyası olarak kaydet
     PICTURE “Desktop/örnek.svg” [ FORWARD 100 CIRCLE 5 ] ; yukarıdaki gibi, bağıl bir yol ile
     PICTURE “/home/kullanıcı/örnek.svg” [ CIRCLE 5 ] ; Unix/Linux için mutlak yol
     PICTURE “C:\örnek.svg” [ CIRCLE 5 ] ; Windows için mutlak yol

### SVG/SMIL animasyonlarını kaydetme (SLEEP komutları ile çizim)

     PICTURE “animasyon.svg” [ CIRCLE 5 SLEEP 1000 CIRCLE 99 ] ; bir SVG/SMIL animasyonu kaydet (ayrıca SLEEP'e de bakın)
     PICTURE “animasyon2.svg” [ CIRCLE 5 SLEEP 1000 CIRCLE 99 SLEEP 2000 ] ; yukarıdaki gibi, ancak son nesneden sonra SLEEP kullanmak, döngü sağlayacak: 2 saniye sonra SVG animasyonu SMIL uyumlu tarayıcılarda yeniden başlar

### Sol kenardaki uyumluluk

Writer'ın sol kenarındaki konum uyumunu ve çizgi şekillerini muhafaza etmek için PICTURE kullanın:

     PICTURE [ CIRCLE 20 POSITION [-100, 100] CIRCLE 20 ]

## Döngüler

### REPEAT

     ; REPEAT sayı [ komutlar ]

     REPEAT 10 [ FORWARD 10 LEFT 45 CIRCLE 10 ] ; 10 kez tekrarla

     ; sayı isteğe bağlıdır

     REPEAT [ POSITION ANY ] ; sonsuz tekrarla

### REPCOUNT

Döngü değişkeni (FOR ve WHILE döngüleri içinde de)

     REPEAT 100 [ FORWARD REPCOUNT LEFT 90 ]

### FOR IN

Liste ögeleri için döngü:

     FOR i IN [1, 5, 7, 9, 11] [
       FORWARD i
       LEFT 90
     ]

Bir karakter dizisinin karakterleri için döngü:

     FOR i IN “metin” [
       LABEL i
       FORWARD 10
     ]

### WHILE

     WHILE TRUE [ POSITION ANY ] ; sonsuz döngü
     WHILE REPCOUNT <= 10 [ FORWARD 50 LEFT 36 ] ; REPEAT 10 gibi [ ... ]

### BREAK

Döngüyü durdur.

     REPEAT [ ; sonsuz döngü
       POSITION ANY
       IF REPCOUNT = 100 [ BREAK ]  ; REPEAT 100 [ ... ] ile aynıdır
     ]

### CONTINUE

Döngünün sonraki yinelemesine atla.

     REPEAT 100 [
       POSITION ANY
       IF REPCOUNT % 2 = 0 [ CONTINUE ]
       CIRCLE 10 ; her 2. konuma çember çiz
     ]

## Koşullar

### IF

     ; IF koşul [ doğru bloğu ]
     ; IF koşul [ doğru bloğu ] [ yanlış bloğu ]

     IF a < 10 [ PRINT “Küçük” ]
     IF a < 10 [ PRINT “Küçük” ] [ PRINT “Büyük” ]

### AND, OR, NOT

Mantıksal işleçler.

     IF a < 10 AND NOT a = 5 [ PRINT “0, 1, 2, 3, 4, 6, 7, 8 veya 9” ]
     IF a < 10 AND a != 5 [ PRINT “0, 1, 2, 3, 4, 6, 7, 8 veya 9” ] ; yukarıdaki gibi

## Alt Yordamlar

### TO, END

Yeni kelime (veya yöntem).

     TO üçgen
       REPEAT 2 [ FORWARD 100 RIGHT 120 ] FILL
     END

     REPEAT 10 [ üçgen PENUP POSITION ANY PENDOWN ]

### OUTPUT

İşlevin değerine döndür.

     TO rasgeleharf
       OUTPUT RANDOM “qwertzuiopasdfghjklyxcvbnm”
     END

     PRINT rasgeleharf + rasgeleharf + rasgeleharf ; 3-harflik rasgele karakter dizisi yazdır

### STOP

Yordamdan döndür.

     TO örnek sayı
       IF sayı < 0 [ STOP ]
       PRINT SQRT sayı ; kare kökü yazdır
     ]

     örnek 100
     örnek -1 ; çıktı ve hata olmadan
     örnek 25

## Varsayılan değişkenler

### ANY

Renklerin vb. varsayılan rastgele değeri

     PENCOLOR ANY ; rastgele kalem rengi

### TRUE

Mantıksal değer.

     WHILE TRUE [ POSITION ANY ] ; sonsuz döngü
     PRINT TRUE ; true yazdır

### FALSE

Mantıksal değer.

     WHILE NOT FALSE [ POSITION ANY ] ; sonsuz döngü
     PRINT FALSE ; yanlış yazdır

### PAGESIZE

     PRINT PAGESIZE ; nokta cinsinden sayfa boyutlarının listesini yazdırır, örn. [595.30, 841.89]

### PI/π

     PRINT PI ; 3.14159265359 yazdır

## Girdi/Çıktı

### PRINT

     PRINT “metin” ; iletişim kutusunda “metin” yazdır
     PRINT 5 + 10 ; 15 yazdır

### INPUT

     PRINT INPUT “Girdi değeri?” ; sor ve sorgu iletişim penceresi ile bir dizge yazdır
     PRINT FLOAT (INPUT “İlk sayı?”) + FLOAT (INPUT “İkinci sayı?”) ; basit hesap makinesi

## SLEEP

     SLEEP 1000 ; 1000 ms (1 sn.) bekle

## GLOBAL

Yordamlarda kullanılan evrensel değişkenleri ayarla.

     GLOBAL hakkinda
     hakkinda = “LibreLogo”

     TO ornek
       PRINT hakkinda
       GLOBAL hakkinda ; yeni bir değer eklemek istediğimizde
       hakkinda = “global (evrensel) değişken için yeni değer”
     END

     ornek
     PRINT hakkinda

## İşlevler

### RANDOM

     PRINT RANDOM 100 ; rasgele kayan sayı (0 <= x < 100)
     PRINT RANDOM “metin” ; “metin” ifadesinin rasgele bir harfi
     PRINT RANDOM [1, 2] ; listenin rasgele bir elemanı (1 veya 2)

### INT

     PRINT INT 3.8 ; 3 yazdır (3.8'in tamsayı kısmı)
     PRINT INT RANDOM 100 ; rasgele tamsayı  (0 <= x < 100)
     PRINT INT “7” ; karakter dizisini tam sayıya dönüştür

### FLOAT

     ; karakter dizisindeki parametreyi kayan sayıya dönüştür
     PRINT 2 * FLOAT “5.5” ; 11.0 yazdır

### STR

     ; sayı parametresini karakter dizisine dönüştür
     PRINT “Sonuç: ” + STR 5 ; print “Sonuç: 5”
     PRINT 10 * STR 5 ; print 5555555555

### SQRT

     PRINT SQRT 100 ; print 10, 100'ün karekökü

### SIN

     PRINT SIN 90 * PI/180 ; print 1.0 (90° radyanın sinüsü)

### COS

     PRINT COS 0 * PI/180 ; print 1.0 (0° radyanın kosinüsü)

### LOG10

     PRINT LOG10 100 ; print 2.0 (100'ün doğal logaritması)

### ROUND

     PRINT ROUND 3.8 ; print 4 (3.8'in yuvarlaması)
     PRINT ROUND RANDOM 100 ; rasgele tam sayı (0 <= x <= 100)

### ABS

     PRINT ABS -10 ; print 10, -10'un mutlak değeri

### COUNT

     PRINT COUNT “yazı” ; print 4, “yazı” metninin karakter sayısı
     PRINT COUNT [1, 2, 3] ; print 3, listenin boyutu

### SET

     ; Listeyi Python kümesine dönüştür
     PRINT SET [4, 5, 6, 6] ; print {4, 5, 6}
     PRINT SET [4, 5, 6, 6] | SET [4, 1, 9] ; print {1, 4, 5, 6, 9}, birleşim
     PRINT SET [4, 5, 6, 6] & SET [4, 1, 9] ; print {4}, kesişim
     PRINT SET ([4, 5, 6, 6]) - SET [4, 1, 9] ; print {5, 6}, fark
     PRINT SET [4, 5, 6, 6] ^ SET [4, 1, 9] ; print {1, 5, 6, 9}, simetrik fark

### RANGE

     ; Python benzeri liste oluşturma
     PRINT RANGE 10 ; print [0, 1, 2, 3, 4, 5, 6, 7, 8, 9]
     PRINT RANGE 3 10 ; print [3, 4, 5, 6, 7, 8, 9]
     PRINT RANGE 3 10 3 ; print [3, 6, 9]

     FOR i IN RANGE 10 50 10 [ ; [10, 20, 30, 40] için döngü
       FORWARD i
       LEFT 90
     ]

### LIST

     ;ayarla ve listele dönüştürmeyi kullanarak bir listenin tekrarlayan ögelerini sil
     PRINT LIST (SET [1, 3, 5, 5, 2, 1]) ; print [1, 3, 5, 2]

### TUPLE

Python'daki tüpün (değiştirilemeyen liste) karşılığı

     PRINT TUPLE [4, 5]

### SORTED

Sıralanmış bir liste ile döndürür.

     PRINT SORTED [5, 1, 3, 4] ; print [1, 3, 4, 5]

### SUB

Karakter dizilerini regex (düzenli ifade) desenleri kullanarak değiştir.

     PRINT SUB (“t”, “T”, “metin”) ; print “meTin”, “t” ile “T”'yi değiştirmek
     PRINT SUB (“(.)”, “\\1\\1”, “metin”) ; print “mmeettiinn”, her karakteri iki defa yaz

### MBUL

Tekrarlı karakter desenlerini düzenli ifade desenleriyle ara.

     IF SEARCH (“\k”, "kelime") [ PRINT “Kelimedeki bir harf.” ]

### FINDALL

Verilen düzenli ifade deseniyle eşleşen girdi dizisindeki tüm tekrarlı karakterleri bul.

     PRINT FINDALL(“\w+”, “Köpek, kedi.”) ; print [“Köpek”, “kedi”], kelime listesi.

### MIN

     PRINT MIN [1, 2, 3] ; print 1, listenin en küçük ögesi

### MAX

     PRINT MAX [1, 2, 3] ; print 3, listenin en büyük ögesi

## Renk sabitleri

     PENCOLOR “SILVER” ; isimle belirleme
     PENCOLOR [1] ; tanımlatıcı ile belirleme
     PENCOLOR “~SILVER” ; rasgele gümüş rengi

Tanımlayıcı | İsim
0 | BLACK
1 | SILVER
2 | GRAY/GREY
3 | WHITE
4 | MAROON
5 | RED
6 | PURPLE
7 | FUCHSIA/MAGENTA
8 | GREEN
9 | LIME
10 | OLIVE
11 | YELLOW
12 | NAVY
13 | BLUE
14 | TEAL
15 | AQUA
16 | PINK
17 | TOMATO
18 | ORANGE
19 | GOLD
20 | VIOLET
21 | SKYBLUE
22 | CHOCOLATE
23 | BROWN
24 | INVISIBLE