Sisukord
Register 🔎︎

# Matemaatilised funktsioonid

This category contains the Mathematical functions for Calc. To open the Function Wizard, choose Insert - Function.

## AGGREGATE

This function returns an aggregate result of the calculations in the range. You can use different aggregate functions listed below. The Aggregate function enables you to omit hidden rows, errors, SUBTOTAL and other AGGREGATE function results in the calculation.

## RAWSUBTRACT

Subtracts a set of numbers and gives the result without eliminating small roundoff errors.

### COLOR

Return a numeric value calculated by a combination of three colors (red, green and blue) and the alpha channel, in the RGBA color system. The result depends on the color system used by your computer.

## SUMIFS

Returns the sum of the values of cells in a range that meets multiple criteria in multiple ranges.

## SUMSQ

Arvude ruutude summa leidmiseks tuleb arvud sisestada nõustaja väljadele.

#### Süntaks

SUMSQ(Number1; Number2; ...; Number30)

Number1 to 30 are up to 30 arguments the sum of whose squares is to be calculated.

#### Näide

Kui sisestada arvud 2, 3 ja 4 väljadele arv1, 2 ja 3, tagastatakse vastus 29.

## SUBTOTAL

Arvutab vahekokkuvõtteid. Kui ala sisaldab juba vahekokkuvõtteid, siis neid edasistes arvutustes ei kasutata. Seda funktsiooni kasutatakse koos automaatfiltriga, et võtta arvesse ainult filtreeritud andmeid.

#### Süntaks

SUBTOTAL(funktsioon; vahemik)

Function is a number that stands for one of the following functions:

Funktsiooni indeks (includes hidden values) | Funktsiooni indeks (ignores hidden values) | Function
1 | 101 | AVERAGE
2 | 102 | COUNT
3 | 103 | COUNTA
4 | 104 | MAX
5 | 105 | MIN
6 | 106 | PRODUCT
7 | 107 | STDEV
8 | 108 | STDEVP
9 | 109 | SUM
10 | 110 | VAR
11 | 111 | VARP

Use numbers 1-11 to include manually hidden rows or 101-111 to exclude them; filtered-out cells are always excluded.

Range is the range whose cells are included.

#### Näide

You have a table in the cell range A1:B6 containing a bill of material for 10 students. Row 2 (Pen) is manually hidden. You want to see the sum of the figures that are displayed; that is, just the subtotal for the filtered rows. In this case the correct formula would be:

| A | B
1 | ITEM | QUANTITY
2 | Pen | 10
3 | Pliiats | 10
4 | Notebook | 10
5 | Rubber | 10
6 | Sharpener | 10

=SUBTOTAL(9;B2:B6) returns 50.

=SUBTOTAL(109;B2:B6) returns 40.

## CONVERT_OOO

Converts a value from one unit of measurement to another unit of measurement. The conversion factors are given in a list in the configuration.

Varem sisaldas teisendustegurite loend ka vanemaid Euroopas kasutusel olnud rahaühikuid ja eurot (vt allpool toodud näiteid). Nende rahaühikute teisendamiseks on parem kasutada uut funktsiooni EUROCONVERT.

#### Süntaks

CONVERT_OOO(value;"text";"text")

#### Näide

=CONVERT_OOO(100;"ATS";"EUR") returns the Euro value of 100 Austrian Schillings.

=CONVERT_OOO(100;"EUR";"DEM") converts 100 Euros into German Marks.

## PRODUCT

Korrutab kõik argumendid ja tagastab korrutise.

#### Süntaks

PRODUCT(Number1; Number2; ...; Number30)

Number1 to 30 are up to 30 arguments whose product is to be calculated.

PRODUCT tagastab korrutise arv1 * arv2 * arv3 * ...

#### Näide

=PRODUCT(2;3;4) tagastab 24.

## TRUNC

Kärbib arvu komakohtade eemaldamise teel.

#### Süntaks

TRUNC(arv; kohti)

Tagastab arvu, milles jäetakse alles määratud arv kohti. Liigsed kümnendkohad lihtsalt eemaldatakse, märki ei arvestata.

TRUNC(Number; 0) behaves as INT(Number) for positive numbers, but effectively rounds towards zero for negative numbers.

The visible decimal places of the result are specified in LibreOffice - PreferencesTools - Options - LibreOffice Calc - Calculate.

#### Näide

=TRUNC(1,239; 2) tagastab 1,23. 9 läheb kaotsi.

=TRUNC(-1,234999; 3) tagastab -1,234. Kõik 9-d lähevad kaotsi.

## SUMIF

Liidab antud kriteeriumitega määratud lahtrid. Funktsiooni kasutatakse soovitud väärtuste leidmiseks vahemikus.

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every character with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in LibreOffice - PreferencesTools - Options - LibreOffice Calc - Calculate.

When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".

#### Süntaks

SUMIF(vahemik; kriteeriumid; summa_vahemik)

Range is the range to which the criteria are to be applied.

Criteria is the cell in which the search criterion is shown, or the search criterion itself. If the criteria is written into the formula, it has to be surrounded by double quotes.

SumRange is the range from which values are summed. If this parameter has not been indicated, the values found in the Range are summed.

SUMIF toetab viidete liitmise tehet (~) ainult kriteeriumite parameetris ning ainult juhul, kui mittekohustuslik summa vahemiku parameeter puudub.

#### Näide

To sum up only negative numbers: =SUMIF(A1:A10;"<0")

=SUMIF(A1:A10;">0";B1:B10) - sums values from the range B1:B10 only if the corresponding values in the range A1:A10 are >0.

Funktsiooni COUNTIF() juures on toodud teisigi süntaksinäiteid, mida saab kasutada koos funktsiooniga SUMIF().

## SERIESSUM

Liidab astmete jadade esimesed liikmed.

SERIESSUM(x;n;m;kordajad) = kordaja_1*x^n + kordaja_2*x^(n+m) + kordaja_3*x^(n+2m) +...+ kordaja_i*x^(n+(i-1)m)

#### Süntaks

SERIESSUM(x; n; m; kordajad)

X on astmete jada sisendarv.

N on esimene astendaja.

M on samm, mille võrra n-i suurendatakse.

Coefficients is a series of coefficients. For each coefficient the series sum is extended by one section.

## SUM

Liidab kokku lahtrite vahemikus olevad arvud.

#### Süntaks

SUM(Number1; Number2; ...; Number30)

Number1 to Number30 are up to 30 arguments, either cells or ranges, whose sum is to be calculated.

SUM ignores any text or empty cell within a range or array. If you suspect wrong results of the SUM function, look for text in the data ranges. Use the value highlighting feature to highlight the text contents in the range that may represent a number.

#### Näide

Kui sisestada arvud 2, 3 ja 4 väljadele arv 1, 2 ja 3, tagastatakse vastus 9.

=SUM(A1;A3;B5) calculates the sum of the three cells. =SUM (A1:E10) calculates the sum of all cells in the A1 to E10 cell range.

Funktsiooni AND sisaldavaid tingimusi saab kasutada koos funktsiooniga SUM() järgneval viisil:

Näiteülesanne: tabelisse on sisestatud arved. Veerg A sisaldab arvete kuupäevi, veerg B arvete summasid. Vaja on kirjutada valem, mille abil saaks leida teatud ajavahemikul väljastatud arvete kogusumma. Võtame näiteks perioodi, mis vastab tingimusele >=01.01.2008 ja <01.02.2008. Kuupäevaväärtused paiknevad vahemikus A1:A40, liidetavad arvud paiknevad vahemikus B1:B40. C1 sisaldab kaasatavate arvete alguskuupäeva 01.01.2008 ning C2 kuupäeva 01.02.2008, mis jäetakse esimesena välja.

Sisestame massiivi valemina järgmise valemi:

=SUM((A1:A40>=C1)*(A1:A40<C2)*B1:B40)

In order to enter this as an array formula, you must press the Shift+Command+ Ctrl+ Enter keys instead of simply pressing the Enter key to close the formula. The formula will then be shown in the Formula bar enclosed in braces.

{=SUM((A1:A40>=C1)*(A1:A40<C2)*B1:B40)}

Valem rajaneb põhimõttel, et kui tingimus on rahuldatud, on võrdluse tulemuseks 1, ja kui mitte, siis 0. Võrdluste tulemuste hulka käsitletakse massiivina ja seda kasutatakse maatrikskorrutises, mille vastuse elemendid lõpptulemuse saamiseks liidetakse.

## POWER

Returns a number raised to another number.

#### Süntaks

POWER(alus; aste)

Tagastab arvu alus astmes aste.

Sama tulemuse saamiseks võib kasutada astendusmärki ^:

arv^aste

#### Näide

=POWER(4;3) returns 64, which is 4 to the power of 3.

=4^3 tagastab arvu 4 astmes 3.

## ATAN2

Returns the angle (in radians) between the x-axis and a line from the origin to the point (NumberX|NumberY).

This function is part of the Open Document Format for Office Applications (OpenDocument) standard Version 1.2. (ISO/IEC 26300:2-2015)

#### Süntaks

ATAN2(arv x; arv y)

Arv x on x-koordinaadi väärtus.

Arv y on y-koordinaadi väärtus.

Programming languages have usually the opposite order of arguments for their atan2() function.

ATAN2 returns the angle (in radians) between the x-axis and a line from the origin to the point (NumberX|NumberY)

#### Näide

=ATAN2(-5;9) returns 2.07789 radians.

To get the angle in degrees apply the DEGREES function to the result.

=DEGREES(ATAN2(12.3;12.3)) returns 45. The tangent of 45 degrees is 1.

LibreOffice results 0 for ATAN2(0;0).

The function can be used in converting cartesian coordinates to polar coordinates.

=DEGREES(ATAN2(-8;5)) returns φ = 147.9 degrees

## MULTINOMIAL

Returns the factorial of the sum of the arguments divided by the product of the factorials of the arguments.

#### Süntaks

MULTINOMIAL(arv(ud))

Arv(ud) on loend kuni 30 arvust.

#### Näide

=MULTINOMIAL(F11:H11) returns 1260, if F11 to H11 contain the values 2, 3 and 4. This corresponds to the formula =(2+3+4)! / (2!*3!*4!)

## SEC

Returns the secant of the given angle (in radians). The secant of an angle is equivalent to 1 divided by the cosine of that angle

See funktsioon on saadaval alates LibreOffice'i versioonist 3.5

#### Süntaks

SEC(arv)

Tagastab arvu (radiaanides antud nurga) seekansi.

Et leida kraadides antud nurga seekansit, kasuta funktsiooni RADIANS.

#### Näide

=SEC(PI()/4) annab tulemuseks ligikaudu 1,4142135624, mis on pöördväärtus arvu π/4 radiaani koosinusest.

=SEC(RADIANS(60)) annab tulemuseks 2, mis on seekans 60 kraadist.

## CEILING.XCL

Rounds a number away from zero to the nearest multiple of Significance.

See funktsioon on saadaval alates LibreOffice'i versioonist 5.0

#### Süntaks

CEILING.XCL(Number; Significance)

Number is the number that is to be rounded.

Significance is the number to whose multiple the value is to be rounded.

This function exists for interoperability with Microsoft Excel 2007 or older versions.

#### Näide

=CEILING.XCL(1;3) returns 3

=CEILING.XCL(7;4) returns 8

=CEILING.XCL(-10;-3) returns -12

## FLOOR.PRECISE

Rounds a number down to the nearest multiple of Significance, regardless of sign of Significance

See funktsioon on saadaval alates LibreOffice'i versioonist 4.3

#### Süntaks

FLOOR.PRECISE(Number; Significance)

Number is the number that is to be rounded down.

Significance is the value to whose multiple the number is to be rounded down.

If the spreadsheet is exported to Microsoft Excel, the FLOOR function is exported as the equivalent FLOOR.MATH function that exists since Excel 2013. If you plan to use the spreadsheet with earlier Excel versions, use either FLOOR.PRECISE that exists since Excel 2010, or FLOOR.XCL that is exported as the FLOOR function compatible with all Excel versions. Note that FLOOR.XCL always rounds towards zero.

#### Näide

=FLOOR.PRECISE( -11;-2) returns -12

## CEILING.PRECISE

Rounds a number up to the nearest multiple of Significance, regardless of sign of Significance

See funktsioon on saadaval alates LibreOffice'i versioonist 4.3

#### Süntaks

CEILING.PRECISE(Number; Significance)

Number (required) is the number that is to be rounded up.

Significance (optional) is the number to whose multiple the value is to be rounded up.

#### Näide

=CEILING.PRECISE(-11;-2) returns -10

## ISO.CEILING

Rounds a number up to the nearest multiple of Significance, regardless of sign of Significance

#### Süntaks

ISO.CEILING(Number; Significance)

Number (required) is the number that is to be rounded up.

Significance (optional) is the number to whose multiple the value is to be rounded up.

#### Näide

=ISO.CEILING(-11;-2) returns -10

## CEILING.MATH

Rounds a number up to the nearest multiple of Significance.

#### Süntaks

CEILING.MATH(Number; Significance; Mode)

Arv on ülespoole ümardatav arv.

Significance is the number to whose multiple the value is to be rounded up.

Mode is an optional value. If the Mode value is given and not equal to zero, and if Number and Significance are negative, then rounding is done based on the absolute value of Number, i.e. negative numbers are rounded away from zero. If the Mode value is equal to zero or is not given, negative numbers are rounded towards zero.

This function exists for interoperability with Microsoft Excel 2013 or newer.

#### Näide

=CEILING.MATH(-10;-3) returns -9

=CEILING.MATH(-10;-3;0) returns -9

=CEILING.MATH(-10;-3;1) returns -12

## PI

Tagastab 3,14159265358979 ehk matemaatilise konstandi π väärtuse täpsusega 14 kohta pärast koma.

#### Süntaks

PI()

#### Näide

=PI() tagastab 3,14159265358979.

## COTH

Tagastab antud arvu (nurga) hüperboolse kootangensi.

#### Süntaks

COTH(arv)

Tagastab arvu hüperboolse kootangensi.

#### Näide

=COTH(1) returns the hyperbolic cotangent of 1, approximately 1.3130.

## ACOTH

Tagastab antud arvu areakootangensi.

#### Süntaks

ACOTH(arv)

This function returns the inverse hyperbolic cotangent of Number, that is the number whose hyperbolic cotangent is Number.

Kui arv on vahemikus -1 kuni 1 (kaasa arvatud), on tulemuseks viga.

#### Näide

=ACOTH(1.1) returns inverse hyperbolic cotangent of 1.1, approximately 1.52226.

## ACOT

Tagastab antud arvu arkuskootangensi (kootangensi pöördfunktsiooni).

#### Süntaks

ACOT(arv)

See funktsioon tagastab arvu arkuskootangensi, s.t nurga (radiaanides), mille kootangens on antud arv. Vastus on vahemikus 0 kuni π.

Tagastatud nurga teisendamiseks kraadidesse kasuta funktsiooni DEGREES.

#### Näide

=ACOT(1) returns 0.785398163397448 (PI/4 radians).

=DEGREES(ACOT(1)) tagastab 45. 45-kraadise nurga tangens on 1.

## CSC

Tagastab antud nurga (radiaanides) koosekansi. Nurga koosekans on võrdne sama nurga siinuse pöördväärtusega.

See funktsioon on saadaval alates LibreOffice'i versioonist 3.5

#### Süntaks

CSC(arv)

Tagastab arvu (radiaanides antud nurga) koosekansi.

Et leida kraadides antud nurga koosekansit, kasuta funktsiooni RADIANS.

#### Näide

=CSC(PI()/4) annab tulemuseks ligikaudu 1,4142135624, mis on pöördväärtus arvu π/4 radiaani siinusest.

=CSC(RADIANS(30)) annab tulemuseks 2, mis on koosekans 30 kraadist.

## COS

Tagastab antud nurga (radiaanides) koosinuse.

#### Süntaks

COS(arv)

Tagastab arvu (radiaanides antud nurga) koosinuse.

Et leida kraadides antud nurga koosinust, kasuta funktsiooni RADIANS.

#### Näide

=COS(PI()*2) returns 1, the cosine of 2*PI radians.

=COS(RADIANS(60)) returns 0.5, the cosine of 60 degrees.

## COT

Tagastab antud nurga (radiaanides) kootangensi.

#### Süntaks

COT(arv)

Tagastab arvu (radiaanides antud nurga) kootangensi.

Et leida kraadides antud nurga kootangensit, kasuta funktsiooni RADIANS.

Nurga kootangens on võrdne sama nurga tangensi pöördväärtusega.

### Näited:

=COT(PI()/4) returns 1, the cotangent of PI/4 radians.

=COT(RADIANS(45)) returns 1, the cotangent of 45 degrees.

## SIN

Tagastab antud nurga (radiaanides) siinuse.

#### Süntaks

SIN(arv)

Tagastab arvu (radiaanides antud nurga) siinuse.

Et leida kraadides antud nurga siinust, kasuta funktsiooni RADIANS.

#### Näide

=SIN(PI()/2) tagastab 1, siinuse PI/2 radiaanist.

=SIN(RADIANS(30)) tagastab 0,5, siinuse 30 kraadist.

## TAN

Tagastab antud nurga (radiaanides) tangensi.

#### Süntaks

TAN(arv)

Tagastab arvu (radiaanides antud nurga) tangensi.

Et leida kraadides antud nurga tangensit, kasuta funktsiooni RADIANS.

#### Näide

=TAN(PI()/4) returns 1, the tangent of PI/4 radians.

=TAN(RADIANS(45)) returns 1, the tangent of 45 degrees.

## ABS

Tagastab arvu absoluutväärtuse.

#### Süntaks

ABS(arv)

Number is the number whose absolute value is to be calculated. The absolute value of a number is its value without the +/- sign.

#### Näide

=ABS(-56) tagastab 56.

=ABS(12) tagastab 12.

=ABS(0) tagastab 0.

## ACOSH

Tagastab arvu areakoosinuse.

#### Süntaks

ACOSH(arv)

See funktsioon tagastab arvu areakoosinuse, tulemuseks on arv, mille hüperboolne koosinus on antud arv.

Arv peab olema suurem kui 1 või sellega võrdne.

#### Näide

=ACOSH(1) tagastab 0.

=ACOSH(COSH(4)) tagastab 4.

## ASINH

Tagastab arvu areasiinuse.

#### Süntaks

ASINH(arv)

See funktsioon tagastab arvu areasiinuse, tulemuseks on arv, mille hüperboolne siinus on antud arv.

#### Näide

=ASINH(-90) tagastab ligikaudse väärtuse -5,1929877.

=ASINH(SINH(4)) tagastab 4.

## ATANH

Tagastab arvu areatangensi.

#### Süntaks

ATANH(arv)

See funktsioon tagastab arvu areatangensi, tulemuseks on arv, mille hüperboolne tangens on antud arv.

Arv peab vastama tingimusele: -1 < arv < 1.

#### Näide

=ATANH(0) tagastab 0.

## ACOS

Tagastab arvu arkuskoosinuse.

#### Süntaks

ACOS(arv)

See funktsioon tagastab arvu arkuskoosinuse, s.t nurga (radiaanides), mille koosinus on antud arv. Vastus on vahemikus 0 kuni π.

Tagastatud nurga teisendamiseks kraadidesse kasuta funktsiooni DEGREES.

#### Näide

=ACOS(-1) tagastab 3,14159265358979 (π radiaani).

=DEGREES(ACOS(0,5)) tagastab 60. 60-kraadise nurga koosinus on 0,5.

## ASIN

Tagastab arvu arkussiinuse.

#### Süntaks

ASIN(arv)

See funktsioon tagastab arvu arkussiinuse, s.t nurga (radiaanides), mille siinus on antud arv. Tagastatav nurk on vahemikus -π/2 kuni +π/2.

Tagastatud nurga teisendamiseks kraadidesse kasuta funktsiooni DEGREES.

#### Näide

=ASIN(0) tagastab 0.

=ASIN(1) tagastab 1,5707963267949 (π/2 radiaani).

=DEGREES(ASIN(0,5)) tagastab 30. 30-kraadise nurga siinus on 0,5.

## ATAN

Tagastab arvu arkustangensi.

#### Süntaks

ATAN(arv)

See funktsioon tagastab arvu arkustangensi, s.t nurga (radiaanides), mille tangens on antud arv. Vastus on vahemikus -π/2 kuni π/2.

Tagastatud nurga teisendamiseks kraadidesse kasuta funktsiooni DEGREES.

#### Näide

=ATAN(1) returns 0.785398163397448 (PI/4 radians).

=DEGREES(ATAN(1)) tagastab 45. 45-kraadise nurga tangens on 1.

## EXP

Tagastab arvu e astme vastavalt argumendile. Arvu e ligikaudne väärtus on 2,71828182845904.

#### Süntaks

EXP(arv)

Arv on aste, millesse e tõstetakse.

#### Näide

=EXP(1) returns 2.71828182845904, the mathematical constant e to Calc's accuracy.

## FACT

Tagastab arvu faktoriaali.

#### Süntaks

FACT(arv)

Tagastab väärtuse arv!, see on arvu faktoriaal, mis arvutatakse valemi 1*2*3*4* ... * arv järgi.

=FACT(0) tagastab vastavalt definitsioonile 1.

Negatiivse arvu faktoriaal tagastab veateate "vigane argument".

#### Näide

=FACT(3) tagastab 6.

=FACT(0) tagastab 1.

## CSCH

Tagastab arvu hüperboolse koosekansi.

See funktsioon on saadaval alates LibreOffice'i versioonist 3.5

#### Süntaks

CSCH(arv)

Tagastab arvu hüperboolse koosekansi.

#### Näide

=CSCH(1) annab tulemuseks ligikaudu 0,8509181282, mis on arvu 1 hüperboolne koosekans.

## COSH

Tagastab arvu hüperboolse koosinuse.

#### Süntaks

COSH(arv)

Tagastab arvu hüperboolse koosinuse.

#### Näide

=COSH(0) tagastab 1, arvu 0 hüperboolse koosinuse.

## SECH

Tagastab arvu hüperboolse seekansi.

See funktsioon on saadaval alates LibreOffice'i versioonist 3.5

#### Süntaks

SECH(arv)

Tagastab arvu hüperboolse seekansi.

#### Näide

=SECH(0) annab tulemuseks 1, mis on hüperboolne seekans arvust 0.

## SINH

Tagastab arvu hüperboolse siinuse.

#### Süntaks

SINH(arv)

Tagastab arvu hüperboolse siinuse.

#### Näide

=SINH(0) tagastab 0, arvu 0 hüperboolse siinuse.

## TANH

Tagastab arvu hüperboolse tangensi.

#### Süntaks

TANH(arv)

Tagastab arvu hüperboolse tangensi.

#### Näide

=TANH(0) returns 0, the hyperbolic tangent of 0.

## SQRTPI

Tagastab arvu ja π korrutise ruutjuure.

#### Süntaks

SQRTPI(Arv)

Tagastab π ja arvu korrutise ruutjuure positiivse arvuna.

Funktsioon on analoogiline valemiga SQRT(PI()*arv).

#### Näide

=SQRTPI(2) returns the squareroot of (2PI), approximately 2.506628.

## LOG10

Tagastab arvu kümnendlogaritmi.

#### Süntaks

LOG10(arv)

Tagastab arvu kümnendlogaritmi.

#### Näide

=LOG10(5) returns the base-10 logarithm of 5 (approximately 0.69897).

## LOG

Tagastab arvu logaritmi antud alusel.

#### Süntaks

LOG(arv; alus)

Arv on väärtus, mille logaritm arvutatakse.

Base (optional) is the base for the logarithm calculation. If omitted, Base 10 is assumed.

#### Näide

=LOG(10;3) returns the logarithm to base 3 of 10 (approximately 2.0959).

=LOG(7^4;7) tagastab 4.

## SIGN

Tagastab arvu märgi. Kui arv on positiivne, tagastatakse 1, kui arv on negatiivne, tagastatakse -1 ja nulli korral tagastatakse 0.

#### Süntaks

SIGN(arv)

Number is the number whose sign is to be determined.

#### Näide

=SIGN(3,4) tagastab 1.

=SIGN(-4,5) tagastab -1.

## LN

Tagastab arvu naturaallogaritmi ehk logaritmi alusel e (2,71828182845904). Arvu e ligikaudne väärtus on 2,71828182845904.

#### Süntaks

LN(arv)

Arv on väärtus, mille naturaallogaritm arvutatakse.

#### Näide

=LN(3) returns the natural logarithm of 3 (approximately 1.0986).

=LN(EXP(321)) tagastab 321.

## SQRT

Tagastab arvu ruutjuure positiivse arvuna.

#### Süntaks

SQRT(arv)

Tagastab arvu ruutjuure positiivse arvuna.

Arv peab olema positiivne.

#### Näide

=SQRT(16) tagastab 4.

=SQRT(-16) returns an invalid argument error.

## MROUND

Tagastab arvu ümardatuna teise arvu lähima täisarvkordseni.

#### Süntaks

MROUND(arv; kordaja)

Tagastab arvu ümardatuna lähima kordaja kordseni.

Teine võimalus sama tulemuse saamiseks oleks kordaja * ROUND(arv/kordaja).

#### Näide

=MROUND(15.5;3) returns 15, as 15.5 is closer to 15 (= 3*5) than to 18 (= 3*6).

=MROUND(1.4;0.5) returns 1.5 (= 0.5*3).

## COMBINA

Tagastab elementide kordustega kombinatsioonide arvu.

#### Süntaks

COMBINA(arv1; arv2)

Arv1 on elementide koguarv hulgas.

Arv2 on hulgast valitavate elementide arv.

COMBINA tagastab hulga elementide valimise võimaluste arvu, kus valimise järjekord pole oluline ja elementide kordused on lubatud. Kui näiteks hulgas on 3 elementi A, B ja C, siis saab 2 elementi valida 6 erineval viisil: AA, AB, AC, BB, BC ja CC.

COMBINA kasutab valemit: (arv1+arv2-1)! / (arv2!(arv1-1)!)

#### Näide

=COMBINA(3;2) tagastab 6.

## COMBIN

Tagastab elementide kordusteta kombinatsioonide arvu.

#### Süntaks

COMBIN(arv1; arv2)

Arv1 on elementide koguarv hulgas.

Arv2 on hulgast valitavate elementide arv.

COMBIN tagastab hulga elementide järjestatud valimise võimaluste arvu. Kui näiteks hulgas on 3 elementi A, B ja C, saab 2 elementi valida 3 erineval viisil: AB, AC ja BC.

COMBIN kasutab valemit: arv_1!/(arv_2!*(arv_1-arv_2)!)

#### Näide

=COMBIN(3;2) tagastab 3.

## QUOTIENT

Tagastab jagamistehte tulemuse täisarvulise osa.

#### Süntaks

QUOTIENT(lugeja; nimetaja)

Tagastab lugeja ja nimetaja jagatise täisosa.

QUOTIENT is equivalent to INT(numerator/denominator) for same-sign numerator and denominator, except that it may report errors with different error codes. More generally, it is equivalent to INT(numerator/denominator/SIGN(numerator/denominator))*SIGN(numerator/denominator).

#### Näide

=QUOTIENT(11;3) returns 3. The remainder of 2 is lost.

## RAND

Tagastab juhuarvu vahemikus 0 kuni 1.

#### Süntaks

RAND()

This function produces a new random number each time Calc recalculates. To force Calc to recalculate manually press F9.

Juhuarvude genereerimiseks, mida ei taasarvutata kunagi, kopeeri funktsiooni =RAND() sisaldavad lahtrid ja kasuta käsku Redigeerimine - Aseta teisiti (kusjuures Asetatakse kõik ja Valemid on märgistamata ning Arvud on märgistatud).

#### Näide

=RAND() returns a random number between 0 and 1.

## RANDBETWEEN

Tagastab määratud vahemikus asuva juhusliku täisarvu.

#### Süntaks

RANDBETWEEN(alumine; ülemine)

Tagastab juhusliku täisarvu arvude alumine ja ülemine vahel (mõlemad kaasa arvatud).

This function produces a new random number each time Calc recalculates. To force Calc to recalculate manually press F9.

Juhuarvude genereerimiseks, mida ei taasarvutata kunagi, kopeeri funktsiooni sisaldavad lahtrid ja kasuta käsku Redigeerimine - Aseta teisiti (kusjuures Asetatakse kõik ja Valemid on märgistamata ning Arvud on märgistatud).

#### Näide

=RANDBETWEEN(20;30) returns an integer of between 20 and 30.

## MOD

Tagastab täisarvu jagamisel teise täisarvuga tekkiva jäägi.

#### Süntaks

MOD(jagatav; jagaja)

Täisarvude korral tagastab see funktsioon lihtsalt jagatava mooduli jagaja järgi ehk jagatava ja jagaja jagamistehte jäägi.

See funktsioon kasutab valemit jagatav - jagaja * INT(jagatav / jagaja), mille põhjal arvutatakse tulemus, kui argumendid pole täisarvud.

#### Näide

=MOD(22;3) returns 1, the remainder when 22 is divided by 3.

=MOD(11,25;2,5) tagastab 1,25.

## GCD

Tagastab ühe või mitme täisarvu suurima ühisteguri.

Suurim ühistegur on suurim positiivne arv, millega jaguvad ilma jäägita kõik antud täisarvud.

#### Süntaks

GCD(täisarv1; täisarv2; ...; täisarv30)

Integer1 To 30 are up to 30 integers whose greatest common divisor is to be calculated.

#### Näide

=GCD(16;32;24) gives the result 8, because 8 is the largest number that can divide 16, 24 and 32 without a remainder.

=GCD(B1:B3), kus lahtrid B1, B2, B3 sisaldavad väärtust 9, 12, 9, annab tulemuseks 3.

## LCM

Tagastab ühe või mitme täisarvu vähima ühiskordse.

#### Süntaks

LCM(täisarv1; täisarv2; ...; täisarv30)

Integer1 to 30 are up to 30 integers whose lowest common multiple is to be calculated.

#### Näide

Kui sisestada arvud 512, 1024 ja 2000 väljadele täisarv 1, 2 ja 3, tagastatakse vastus 128000.

## EUROCONVERT

Teisendab Euroopa vanad rahvusvaluutad eurodeks ja vastupidi.

#### Süntaks

EUROCONVERT(väärtus; "lähtevaluuta"; "sihtvaluuta", täielik_täpsus, trianguleeritud_täpsus)

Value is the amount of the currency to be converted.

From_currency and To_currency are the currency units to convert from and to respectively. These must be text, the official abbreviation for the currency (for example, "EUR"). The rates (shown per Euro) were set by the European Commission.

Full_precision is optional. If omitted or False, the result is rounded according to the decimals of the To currency. If Full_precision is True, the result is not rounded.

Triangulation_precision is optional. If Triangulation_precision is given and >=3, the intermediate result of a triangular conversion (currency1,EUR,currency2) is rounded to that precision. If Triangulation_precision is omitted, the intermediate result is not rounded. Also if To currency is "EUR", Triangulation_precision is used as if triangulation was needed and conversion from EUR to EUR was applied.

### Näited

=EUROCONVERT(100;"ATS";"EUR") teisendab 100 Austria šillingit eurodeks.

=EUROCONVERT(100;"EUR";"DEM") teisendab 100 eurot Saksa markadeks.

## RADIANS

Teisendab kraadid radiaanideks.

#### Süntaks

RADIANS(arv)

Arv on kraadides antud nurk, mis tuleb radiaanideks teisendada.

#### Näide

=RADIANS(90) tagastab 1,5707963267949 ehk π/2 Calcis lubatud täpsusega.

## DEGREES

Teisendab radiaanid kraadideks.

#### Süntaks

DEGREES(arv)

Arv on nurk radiaanides, mis tuleb kraadideks teisendada.

#### Näide

=DEGREES(PI()) tagastab 180 kraadi.

## GCD_EXCEL2003

The result is the greatest common divisor of a list of numbers.

The functions whose names end with _ADD or _EXCEL2003 return the same results as the corresponding Microsoft Excel 2003 functions without the suffix. Use the functions without suffix to get results based on international standards.

#### Süntaks

GCD_EXCEL2003(Number(s))

Arv(ud) on loend kuni 30 arvust.

#### Näide

=GCD_EXCEL2003(5;15;25) returns 5.

## LCM_EXCEL2003

The result is the lowest common multiple of a list of numbers.

The functions whose names end with _ADD or _EXCEL2003 return the same results as the corresponding Microsoft Excel 2003 functions without the suffix. Use the functions without suffix to get results based on international standards.

#### Süntaks

LCM_EXCEL2003(Number(s))

Arv(ud) on loend kuni 30 arvust.

#### Näide

=LCM_EXCEL2003(5;15;25) returns 75.

## ROUNDDOWN

Ümardab arvu allapoole (nulli suunas) vastavalt määratud täpsusele.

#### Süntaks

ROUNDDOWN(arv; kohti)

Tagastab arvu ümardatuna allapoole (nulli suunas) kuni antud kohtade arvuni. Kui kohti puudub või on null, ümardatakse allapoole kuni täisarvuni. Kui kohti on negatiivne, ümardab funktsioon kuni 10, 100, 1000 jne. kordseteni.

See funktsioon ümardab nulli suunas. Alternatiivide jaoks vaata funktsioone ROUNDUP ja ROUND.

#### Näide

=ROUNDDOWN(1,234;2) tagastab 1,23.

=ROUNDDOWN(45,67;0) tagastab 45.

=ROUNDDOWN(-45,67) tagastab -45.

=ROUNDDOWN(987,65;-2) tagastab 900.

## FLOOR

Ümardab arvu allapoole lähima kordaja kordseni.

#### Süntaks

FLOOR(Arv; Kordaja; Režiim)

Number is the number that is to be rounded down.

Significance is the value to whose multiple the number is to be rounded down.

Mode is an optional value. If the Mode value is given and not equal to zero, and if Number and Significance are negative, then rounding is done based on the absolute value of Number, i.e. negative numbers are rounded towards zero. If the Mode value is equal to zero or is not given, negative numbers are rounded away from zero.

If the spreadsheet is exported to Microsoft Excel, the FLOOR function is exported as the equivalent FLOOR.MATH function that exists since Excel 2013. If you plan to use the spreadsheet with earlier Excel versions, use either FLOOR.PRECISE that exists since Excel 2010, or FLOOR.XCL that is exported as the FLOOR function compatible with all Excel versions. Note that FLOOR.XCL always rounds towards zero.

#### Näide

=FLOOR( -11;-2) tagastab -12.

=FLOOR( -11;-2;0) tagastab -12.

=FLOOR( -11;-2;1) tagastab -10.

## INT

Ümardab arvu allapoole lähima täisarvuni.

#### Süntaks

INT(arv)

Tagastab arvu ümardatuna allapoole lähima täisarvuni.

Negatiivsed arvud ümardatakse allapoole (nullist eemale) järgmise täisarvuni.

#### Näide

=INT(5,7) tagastab 5.

=INT(-1,3) tagastab -2.

## ROUND

Ümardab arvu kuni antud kohtade arvuni.

#### Süntaks

ROUND(arv; kohti)

Returns Number rounded to Count decimal places. If Count is omitted or zero, the function rounds to the nearest integer. If Count is negative, the function rounds to the nearest 10, 100, 1000, etc.

See funktsioon ümardab lähima arvuni. Alternatiivsete võimaluste jaoks vaata funktsioone ROUNDDOWN ja ROUNDUP.

#### Näide

=ROUND(2,348;2) tagastab 2,35.

=ROUND(-32,4834;3) tagastab -32,483. Kõigi kümnendkohtade nägemiseks muuda lahtri vormingut.

=ROUND(2,348;0) tagastab 2.

=ROUND(2,5) tagastab 3.

=ROUND(987,65;-2) tagastab 1000.

## ROUNDUP

Ümardab arvu ülespoole (nullist eemale) vastavalt määratud täpsusele.

#### Süntaks

ROUNDUP(arv; kohti)

Tagastab arvu ümardatuna ülespoole (nullist eemale) kuni kohtade arvuni. Kui kohti puudub või on null, ümardab funktsioon ülespoole kuni täisarvuni. Kui kohti on negatiivne, ümardab funktsioon ülespoole kuni 10, 100, 1000 jne. kordseni.

See funktsioon ümardab nullist eemale. Alternatiivide jaoks vaata funktsioone ROUNDDOWN ja ROUND.

#### Näide

=ROUNDUP(1,1111;2) tagastab 1,12.

=ROUNDUP(1,2345;1) tagastab 1,3.

=ROUNDUP(45,67;0) tagastab 46.

=ROUNDUP(-45,67) tagastab -46.

=ROUNDUP(987,65;-2) tagastab 1000.

## CEILING

Ümardab arvu ülespoole lähima kordaja kordseni.

#### Süntaks

CEILING(Arv; Kordaja; Režiim)

Arv on ülespoole ümardatav arv.

Significance is the number to whose multiple the value is to be rounded up.

Mode is an optional value. If the Mode value is given and not equal to zero, and if Number and Significance are negative, then rounding is done based on the absolute value of Number, i.e. negative numbers are rounded away from zero. If the Mode value is equal to zero or is not given, negative numbers are rounded towards zero.

If the spreadsheet is exported to Microsoft Excel, the CEILING function is exported as the equivalent CEILING.MATH function that exists since Excel 2013. If you plan to use the spreadsheet with earlier Excel versions, use either CEILING.PRECISE that exists since Excel 2010, or CEILING.XCL that is exported as the CEILING function compatible with all Excel versions. Note that CEILING.XCL always rounds away from zero.

#### Näide

=CEILING(-11;-2) tagastab -10.

=CEILING(-11;-2;0) tagastab -10.

=CEILING(-11;-2;1) tagastab -12.

## EVEN

Ümardab positiivse arvu ülespoole ja negatiivse arvu allapoole lähima paarisarvuni.

#### Süntaks

EVEN(arv)

Tagastab arvu ümardatuna ülespoole (nullist eemale) lähima paarisarvulise täisarvuni.

#### Näide

=EVEN(2,3) tagastab 4.

=EVEN(2) tagastab 2.

=EVEN(0) tagastab 0.

=EVEN(-0,5) tagastab -2.

## ODD

Ümardab positiivse arvu ülespoole ja negatiivse arvu allapoole lähima paaritu arvuni.

#### Süntaks

ODD(arv)

Tagastab arvu ümardatuna ülespoole järgneva paaritu arvuni (nullist eemale).

#### Näide

=ODD(1,2) tagastab 3.

=ODD(1) tagastab 1.

=ODD(0) tagastab 1.

=ODD(-3,1) tagastab -5.

Sarnased teemad

Functions by Category