Contingut
Índex 🔎︎

# Funcions de text

Aquesta secció conté descripcions de les funcions de text.

Per a accedir a aquesta ordre...

Insereix ▸ Funció ▸ categoria Text

## REGEX

Troba i extreu, o opcionalment reemplaça, text, fent servir expressions regulars.

### WEBSERVICE

Obté contingut web a partir d'un URI.

### FILTERXML

Aplica una expressió XPath en un document XML.

### ENCODEURL

Returns a URL-encoded string.

## T

Aquesta funció retorna el text de destinació o, si la destinació no és text, retorna una cadena de text buida.

#### Sintaxi

T(Valor)

Si Valor és una cadena de text o fa referència a una cadena de text, T retorna aquesta cadena de text; altrament, retorna una cadena de text buida.

#### Exemple

=T(12345) retorna una cadena buida.

=T("12345") retorna la cadena 12345.

## ARABIC

Calcula el valor d'una xifra romana. L'interval de valors s'ha de trobar entre 0 i 3999.

#### Sintaxi

ARABIC("Text")

Text és el text que representa una xifra romana.

#### Exemple

=ARABIC("MXIV") retorna 1014.

=ARABIC("MMII") retorna 2002.

## CONCATENA

Combina diverses cadenes de text en una sola cadena.

#### Sintaxi

CONCATENA("Text1"; ...; "Text30")

Text1; Text2; ... representen fins a 30 passatges de text que s'han de combinar en una sola cadena.

#### Exemple

=CONCATENA("Bon ";"dia ";"Sra. ";"Pla") retorna: Bon dia Sra. Pla.

## EXACTE

Compara dues cadenes de text i retorna CERT si són idèntiques. Aquesta funció distingeix entre majúscules i minúscules.

#### Sintaxi

EXACTE("Text1"; "Text2")

Text1 fa referència al primer text que s'ha de comparar.

Text2 és el segon text que s'ha de comparar.

#### Exemple

=EXACTE("microsystems";"Microsystems") retorna FALS.

## MAJUSC

Converteix la cadena indicada en el camp de text que s'ha d'escriure amb majúscules.

#### Sintaxi

MAJUSC("Text")

Text fa referència a les lletres en minúscules que voleu convertir en majúscules.

#### Exemple

=MAJUSC("Bon dia") retorna BON DIA.

## DECIMAL

Converteix text amb caràcters d'un sistema numèric en un enter positiu de la base de numeració indicada. La base de numeració s'ha de trobar en l'interval de 2 a 36. S'ignoren els espais i les tabulacions. En el camp Text no es distingeix entre majúscules i minúscules.

Si la base de numeració és 16, s'ignora una x o X o 0x o 0X al començament, i una h o H al final. Si la base de numeració és 2, s'ignora una b o B al final. Els caràcters que no pertanyen al sistema numèric generen un error.

#### Sintaxi

DECIMAL("Text"; BaseDeNumeració)

Text és el text que s'ha de convertir. Per diferenciar entre un nombre hexadecimal, com ara A1 i la referència a la cel·la A1, heu de posar el nombre entre cometes, com ara, "A1" o "FACE".

BaseDeNumeració indica la base del sistema numèric. Pot ser qualsevol nombre enter positiu entre 2 i 36.

#### Exemple

=DECIMAL("17";10) retorna 17.

=DECIMAL("FACE";16) retorna 64206.

=DECIMAL("0101";2) retorna 5.

## MINUSC

Converteix totes les majúscules d'una cadena de text en minúscules.

#### Sintaxi

MINUSC("Text")

Text es refereix al text que s'ha de convertir.

#### Exemple

=MINUSC("Sun") retorna sun.

## CARACUNI

Converteix un codi numèric en un caràcter o lletra Unicode.

#### Sintaxi

CARACUNI(nombre)

#### Exemple

=CARACUNI(169) retorna el caràcter de drets d'autor ©.

Vegeu també la funció UNICODE().

## BASE

Converteix un enter positiu en una base especificada en un text del sistema de numeració. S'utilitzen els dígits 0 a 9 i les lletres A a Z.

#### Sintaxi

BASE(Nombre; BaseDeNumeració; [LongitudMínima])

Nombre és l'enter positiu que s'ha de convertir.

BaseDeNumeració indica la base del sistema numèric. Pot ser qualsevol nombre enter positiu entre 2 i 36.

LongitudMínima (opcional) determina la longitud mínima de la seqüència de caràcters que s'ha creat. Si el text és més curt que la longitud mínima que s'ha indicat, s'afegeixen zeros a l'esquerra de la cadena.

#### Exemple

=BASE(17;10;4) retorna 0017 en el sistema decimal.

=BASE(17;2) retorna 10001 en el sistema binari.

=BASE(255;16;4) retorna 00FF en el sistema hexadecimal.

## TEXT

Converteix un nombre en text d'acord amb un format indicat.

#### Sintaxi

TEXT(Nombre; Format)

Nombre és el valor numèric que s'ha de convertir.

Format és el text que defineix el format. Utilitzeu els decimals i els separadors de milers en funció de la llengua indicada en el format de cel·la.

#### Exemple

=TEXT(12,34567;"###,##") retorna el text 12,35.

=TEXT(12,34567;"000,00") retorna el text 012,35.

Vegeu també Codis de format numèric: codis de format personalitzats definits per l'usuari.

## TEXTBAHT

Converteix un nombre en text thai, incloent-hi els noms de moneda thai.

#### Sintaxi

TEXTBAHT(Nombre)

Nombre és qualsevol nombre. S'afegeix "baht" a la part entera del nombre i "satang" a la part decimal.

#### Exemple

=TEXTBAHT(12,65) retorna una cadena en caràcters thai amb el significat de "Dotze baht i seixanta-cinc satang".

## CARAC

Converteix un nombre en un caràcter segons la taula de codi actual. El nombre pot ser un enter de dos o tres dígits.

Els codis més grans que 127 poden dependre del mapatge de caràcters del vostre sistema (per exemple, iso-8859-1, iso-8859-2, Windows-1252, Windows-1250), i per tant és possible que no siguin portàtils.

#### Sintaxi

CARAC(Nombre)

Nombre és un nombre entre 1 i 255 que representa el valor de codi del caràcter.

#### Exemple

=CARAC(100) retorna el caràcter d.

="abc" & CARAC(10) & "def" insereix un caràcter de línia nova a la cadena.

## ROMA

Converteix un nombre en un numeral romà. L'interval de valors ha d'estar comprès entre 0 i 3999; els modes poden ser enters del 0 al 4.

#### Sintaxi

ROMA(Nombre; Mode)

Nombre és el nombre que s'ha de convertir en un numeral romà.

Mode (opcional) indica el grau de simplificació. Com més alt sigui el valor, més gran és la simplificació de la xifra romana.

#### Exemple

=ROMA(999) retorna CMXCIX.

=ROMA(999;0) retorna CMXCIX.

=ROMA(999;1) retorna LMVLIV.

=ROMA(999;2) retorna XMIX.

=ROMA(999;3) retorna VMIV.

=ROMA(999;4) retorna IM.

## MONEDA

Converteix un nombre en una quantitat en el format de moneda, arrodonit a les xifres decimals que s'hagin indicat. En el camp Valor, introduïu-hi el nombre que s'ha de convertir en moneda. Opcionalment, podeu introduir el nombre de decimals en el camp Decimals. Si no s'indica cap valor, es mostraran tots els nombres en format de moneda amb dos decimals.

Heu de definir el format de la moneda en la configuració del sistema.

#### Sintaxi

MONEDA(Valor; Decimals)

Valor és un nombre, una referència a una cel·la que conté un nombre o una fórmula que retorna un nombre.

Decimals és el nombre opcional de xifres decimals.

#### Exemple

=MONEDA(255) retorna 255,00 €.

=MONEDA(367,456;2) retorna 367,46 €. Utilitzeu el separador decimal que correspongui a la configuració regional actual.

## VALOR

Converteix una cadena de text en un nombre.

#### Sintaxi

VALOR("Text")

Text és el text que s'ha de convertir en un nombre.

#### Exemple

=VALOR("4321") retorna 4321.

## RETALLA

Elimina espais d'una cadena; deixa un sol espai entre les paraules.

#### Sintaxi

RETALLA("Text")

Text fa referència al text de què s'eliminen els espais.

#### Exemple

=TRIM(" hello world ") returns hello world without leading and trailing spaces and with single space between words.

## INICIALMAJUSC

Escriu amb majúscula la primera lletra de totes les paraules d'una cadena de text.

#### Sintaxi

INICIALMAJUSC("Text")

Text es refereix al text que s'ha de convertir.

#### Exemple

=INICIALMAJUSC("open office") retorna Open Office.

## LONGB

For double-byte character set (DBCS) languages, returns the number of bytes used to represent the characters in a text string.

Aquesta funció és disponible des del LibreOffice4.2

#### Sintaxi

LONGB("Text")

Text és el text la longitud del qual s'ha de determinar.

#### Exemple

ESQUERRAB("中国";2) retorna "中" (2 bytes formen un caràcter DBCS complet).

ESQUERRAB("中国";2) retorna 4 (2 bytes formen un caràcter DBCS).

ESQUERRAB("oficina") retorna " 6 (6 caràcters no-DBCS, cadascun format per 1 byte).

=LONGB("Bon dia") retorna 7.

=LONGB(12345,67) retorna 8.

## ASC

La funció ASC converteix caràcters ASCII d'amplada completa a caràcters de mitja amplada i caràcters katakana. Retorna una cadena de text.

See https://wiki.documentfoundation.org/Calc/Features/JIS_and_ASC_functions for a conversion table.

#### Sintaxi

ASC("Text")

Text és el text que conté els caràcters que s'han de convertir.

Vegeu també la funció JIS.

## JIS

La funció JIS converteix caràcters ASCII i katakana de mitja amplada a caràcters d'amplada completa. Retorna una cadena de text.

See https://wiki.documentfoundation.org/Calc/Features/JIS_and_ASC_functions for a conversion table.

#### Sintaxi

JIS("Text")

Text és el text que conté els caràcters que s'han de convertir.

Vegeu també la funció ASC.

## SUBSTITUEIX

Reemplaça text vell per text nou en una cadena.

#### Sintaxi

SUBSTITUEIX("Text"; "TextDeCerca"; "TextNou"; Aparició)

Text és el text en el qual s'han d'intercanviar segments de text.

TextDeCerca és el segment de text que s'ha de reemplaçar (un nombre de vegades).

TextNou és el text que ha de reemplaçar el segment de text.

Aparició (opcional) indica quina aparició del text de cerca s'ha de reemplaçar. Si manca aquest paràmetre, es reemplaça el text de cerca arreu.

#### Exemple

=SUBSTITUEIX("123123123";"3";"abc") retorna 12abc12abc12abc.

=SUBSTITUEIX("123123123";"3";"abc";2) retorna 12312abc123.

## REEMPLAÇA

Reemplaça una part d'una cadena de text per una altra cadena de text. Aquesta funció es pot utilitzar per reemplaçar caràcters i nombres (que es converteixen en text automàticament). El resultat de la funció sempre es mostra en forma de text. Si voleu fer més càlculs amb un nombre que s'ha reemplaçat per text, l'haureu de tornar a convertir en un nombre mitjançant la funció VALOR.

Qualsevol text que contingui nombres s'ha de posar entre cometes perquè no s'interpreti com a nombre i es converteixi automàticament en text.

#### Sintaxi

REEMPLAÇA("Text"; Posició; Longitud; "TextNou")

Text fa referència al text del qual es reemplaçarà una part.

Posició fa referència a la posició en el text on començarà el reemplaçament.

Longitud és el nombre de caràcters de Text que s'han de reemplaçar.

TextNou fa referència al text que reemplaça Text.

#### Exemple

=REEMPLAÇA("1234567";1;1;"444") retorna "444234567". Es reemplaça un caràcter en la posició 1 pel TextNou complet.

## REPT

Repeteix una cadena de caràcters en funció del nombre de còpies indicat.

#### Sintaxi

REPT("Text"; Nombre)

Text és el text que s'ha de repetir.

Nombre és el nombre de repeticions.

El resultat pot contenir un màxim de 255 caràcters.

#### Exemple

=REPT("Bon dia";2) retorna Bon diaBon dia.

## UNICODE

Retorna el codi numèric del primer caràcter Unicode d'una cadena de text.

#### Sintaxi

UNICODE("Text")

#### Exemple

=UNICODE("©") retorna el nombre Unicode 169 corresponent al caràcter de copyright.

Vegeu també la funció CARACUNI().

## ESQUERRAB

Retorna el primer caràcter o caràcters d'un text DBCS.

Aquesta funció és disponible des del LibreOffice4.2

#### Sintaxi

ESQUERRAB("Text"; NombreBytes)

Text és el text del qual s'han de determinar les paraules parcials inicials.

NombreBytes (opcional) indica el nombre de caràcters que voleu extreure amb ESQUERRAB. Si no es defineix aquest paràmetre, es retorna un únic caràcter.

#### Exemple

ESQUERRAB("中国";1) retorna " " (1 byte només és la meitat d'un caràcter DBCS i, per tant, es retorna un espai).

ESQUERRAB("中国";2) retorna "中" (2 bytes formen un caràcter DBCS complet).

ESQUERRAB("中国";3) retorna "中 " (3 bytes formen un caràcter DBCS i mig; per tant es retorna un espai com a últim caràcter).

ESQUERRAB("中国";4) retorna "中国" (4 bytes formen dos caràcters DBCS complets).

ESQUERRAB("oficina";3) retorna "ofi" (3 caràcters no-DBCS, cadascun format per 1 byte).

## ESQUERRA

Retorna el primer caràcter o caràcters d'un text.

#### Sintaxi

ESQUERRA("Text"; Nombre)

Text és el text on s'han de determinar les paraules inicials parcials.

Nombre (opcional) indica el nombre de caràcters del text d'inici. Si no es defineix aquest paràmetre, es retorna un caràcter.

#### Exemple

=ESQUERRA("sortida";3) retorna “sor”.

## RIGHTB

Retorna l'últim caràcter o caràcters d'un text amb jocs de caràcters de byte doble (DBCS).

Aquesta funció és disponible des del LibreOffice4.2

#### Sintaxi

DRETAB("Text"; NombreBytes)

Text és el text del qual es determinarà la part dreta.

NombreBytes (opcional) indica el nombre de caràcters que voleu extreure amb DRETAB, segons els bytes.

#### Exemple

DRETAB("中国";1) retorna " " (1 byte només és la meitat d'un caràcter DBCS i, per tant, es retorna un espai).

DRETAB("中国";2) retorna "国" (2 bytes formen un caràcter DBCS complet).

DRETAB("中国";3) retorna "国 " (3 bytes formen un caràcter DBCS i mig i un caràcter DBCS complet; es retorna un espai per la primera meitat).

DRETAB("中国";4) retorna "中国" (4 bytes formen dos caràcters DBCS complets).

DRETAB("Àngel";3) retorna «gel» (3 caràcters no-DBCS, cadascun format per 1 byte).

## DRETA

Retorna l'últim caràcter o caràcters d'un text.

#### Sintaxi

DRETA("Text"; Nombre)

Text és el text del qual es determinarà la part dreta.

Nombre (opcional) és el nombre de caràcters des de la part dreta del text.

#### Exemple

=DRETA("Sun";2) retorna un.

## MIDB

Retorna la cadena de text d'un text DBCS. Els paràmetres indiquen la posició inicial i el nombre de caràcters.

Aquesta funció és disponible des del LibreOffice4.2

#### Sintaxi

MIGB("Text"; Inici; NombreBytes)

Text és el text que conté els caràcters que s'han d'extreure.

Inici és la posició del primer caràcter del text que s'ha d'extreure.

NombreBytes indica el nombre de caràcters que MIDB retornarà del text, en bytes.

#### Exemple

MIGB("中国";1;0) retorna "" (0 bytes es sempre una cadena buida).

MIGB("中国";1:1) retorna " " (1 byte és només mig caràcter DBCS i, per tant, el resultat és un caràcter d'espai).

MIGB("中国";1;2) retorna "中" (2 bytes formen un caràcter DBCS complet).

MIGB("中国";1;3) retorna "中 " (3 bytes formen un caràcter DBCS i mig; l'últim byte dóna lloc a un caràcter d'espai).

MIGB("中国";1;4) retorna "中国" (4 bytes formen dos caràcters DBCS complets).

MIGB("中国";2;1) retorna " " (el byte de la posició 2 no és al principi d'un caràcter en una cadena DBCS; es retorna 1 espai com a caràcter).

MIDB("中国";2;2) returns " " (byte position 2 points to the last half of the first character in the DBCS string; the 2 bytes asked for therefore constitutes the last half of the first character and the first half of the second character in the string; 2 space characters are therefore returned).

MIGB("中国";2;1) retorna " " (el byte de la posició 2 no és al principi d'un caràcter en una cadena DBCS; es retorna 1 espai com a caràcter).

MIDB("中国";3;1) returns " " (byte position 3 is at the beginning of a character in a DBCS string, but 1 byte is only half a DBCS character and a space character is therefore returned instead).

MIGB("中国";2;1) retorna " " (el byte de la posició 2 no és al principi d'un caràcter en una cadena DBCS; es retorna 1 espai com a caràcter).

MIGB("中国";2;1) retorna " " (el byte de la posició 2 no és al principi d'un caràcter en una cadena DBCS; es retorna 1 espai com a caràcter).

## MIG

Retorna la cadena de text d'un text. Els paràmetres indiquen la posició inicial i el nombre de caràcters.

#### Sintaxi

MIG("Text"; Inici; Nombre)

Text és el text que conté els caràcters que s'han d'extreure.

Inici és la posició del primer caràcter del text que s'ha d'extreure.

Nombre indica el nombre de caràcters que conté la part del text.

#### Exemple

=MIG("oficina";2;2) retorna fi.

## LONG

Retorna la longitud d'una cadena; hi inclou els espais.

#### Sintaxi

LONG("Text")

Text és el text la longitud del qual s'ha de determinar.

#### Exemple

=LONG("Bon dia") retorna 7.

=LONG(12345,67) retorna 8.

## CERCA

Retorna la posició d'un segment de text en una cadena de caràcters. Podeu definir l'inici de la cerca com una opció. El text de cerca pot ser un nombre o qualsevol seqüència de caràcters. En la cerca no es distingeix entre majúscules i minúscules. Si el text no es troba, es retorna l'error 519 (#VALOR).

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every character with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in LibreOffice - PreferencesTools - Options - LibreOffice Calc - Calculate.

When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".

#### Sintaxi

CERCA("TextDeCerca"; "Text"; Posició)

TextDeCerca és el text que s'ha de cercar.

Text és el text on es du a terme la cerca.

Posició (opcional) és la posició en el text on ha de començar la cerca.

#### Exemple

=CERCA(54;998877665544) retorna 10.

## TROBA

Retorna la posició d'una cadena de text en una altra cadena. També podeu definir on voleu començar la cerca. El terme de cerca pot ser un nombre o qualsevol cadena de caràcters. En la cerca es distingeix entre majúscules i minúscules.

#### Sintaxi

TROBA("TextDeCerca"; "Text"; Posició)

TextDeCerca és el text que s'ha de cercar.

Text és el text on es du a terme la cerca.

Posició (opcional) és la posició en el text des d'on comença la cerca.

#### Exemple

=TROBA(76;998877665544) retorna 6.

## CODI

Retorna un codi numèric per al primer caràcter d'una cadena de text.

#### Sintaxi

CODI("Text")

Text és el text del qual s'ha de trobar el codi del primer caràcter.

Els codis més grans que 127 poden dependre del mapatge de caràcters del vostre sistema (per exemple, iso-8859-1, iso-8859-2, Windows-1252, Windows-1250), i per tant és possible que no siguin portàtils.

#### Exemple

=CODI("Jerònim") retorna 74, =CODI("jeroglífic") retorna 106.

El codi que s'utilitza aquí no fa referència a l'ASCII, sinó a la taula de codi actual.

## FIX

Retorna un nombre com a text amb un nombre de decimals determinat i amb separadors de milers opcionals.

#### Sintaxi

FIX(Nombre; Decimals; SenseSeparadorsDeMilers)

Nombre fa referència al nombre que s'ha de formatar.

Decimals fa referència al nombre de decimals que s'han de mostrar.

SenseSeparadorsDeMilers (opcional) determina si s'ha d'utilitzar el separador de milers. Si el paràmetre és un nombre diferent de 0, se suprimeix el separador de milers. Si el paràmetre és igual a 0 o no s'indica, es mostren els separadors de milers de la vostra configuració regional actual.

#### Exemple

=FIX(1234567,89;3) retorna 1.234.567,890 com a cadena de text.

=FIX(1234567,89;3;1) retorna 1234567,890 com a cadena de text.

## NETEJA

S'eliminen de la cadena tots els caràcters no imprimibles.

#### Sintaxi

NETEJA("Text")

Text fa referència al text del qual s'han d'eliminar els caràcters no imprimibles.

Temes relacionats

Funcions per categoria