Contenido
Índice 🔎︎

# función SUMAR.SI.CONJUNTO

Devuelve la suma de los valores de las celdas en un intervalo que cumple múltiples criterios en varios intervalos.

Esta función está disponible desde la versión 4.0 de LibreOffice.

#### Sintaxis

SUMIFS(Func_Range; Range1; Criterion1[; Range2; Criterion2][; … ; [Range127; Criterion127]])

Func_Range – required argument. It is a range of cells, a name of a named range or a label of a column or a row containing values for calculating the sum.

Range1 – required argument. It is a range of cells, a name of a named range, or a label of a column or a row, to which the corresponding criterion is to be applied.

Criterion1 – required argument. A string expression representing a logical condition or a cell reference to such string expression. The expression can contain text, numbers, regular expressions or wildcards (if enabled in calculation options).

Intervalo2: opcional. Intervalo2 y todos los argumentos siguientes tienen el mismo significado que Intervalo1.

Criterio2(opcional). Criterio2 y todos los argumentos siguientes tienen el mismo significado que Criterio1.

La búsqueda admite los caracteres comodín y las expresiones regulares. Cuando se activan estas últimas, podrá introducir «des.*», por ejemplo, para encontrar la primera ocurrencia del prefijo «des-» seguida por cualesquier caracteres. Si desea buscar un texto que es en sí mismo una expresión regular, puede bien anteponer a todos los caracteres una «\», o bien rodear el texto con \Q...\E. Puede activar o desactivar el procesamiento automático de los comodines y las expresiones regulares si se dirige a LibreOffice ▸ PreferenciasHerramientas ▸ Opciones ▸ LibreOffice Calc ▸ Calcular.

Al utilizar funciones en las que uno o más argumentos son cadenas de criterios de búsqueda que representan una expresión regular, en primer lugar se intentará convertir los criterios de la cadena en números. Por ejemplo, «.0» se convertirá en 0.0 y así sucesivamente. Si el intento es fructuoso, la correspondencia no será por expresión regular, sino numérica. No obstante, si se cambia a una configuración regional en la cual el separador decimal no es el punto, pasará a valer la expresión regular. Para forzar la evaluación de la expresión regular en lugar de una expresión numérica, utilice una expresión que no pueda confundirse con un número, como por ejemplo «.\0» o «(?i).0».

Func_Range and Range1, Range2... must have the same size, otherwise the function returns err:502 - Invalid argument.

The logical relation between criteria can be defined as logical AND (conjunction). In other words, if and only if all given criteria are met, a value from the corresponding cell of the given Func_Range is taken into calculation.

La función puede tener hasta 255 argumentos, lo que significa que es posible especificar hasta 127 intervalos de criterios y sus criterios correspondientes.

Si una celda contiene VERDADERO se tratará como 1; si contiene FALSO, como 0 (cero).

Esta función forma parte del estándar Open Document Format for Office Applications (OpenDocument), versión 1.2 (ISO/IEC 26300:2-2015).

#### Ejemplo

Tenga en cuenta la tabla siguiente

| A | B | C
1 | Nombre de producto | Ventas | Ingresos
2 | lápiz | 20 | 65
3 | pluma | 35 | 85
4 | cuaderno | 20 | 190
5 | libro | 17 | 180
6 | estuche | no | no

En todos los ejemplos siguientes, los intervalos utilizados para el cálculo incluyen la fila n.º 6, pero se ignorará debido a que contiene texto.

#### Uso simple

=SUMAR.SI.CONJUNTO(B2:B6;B2:B6;">=20")

Calcula la suma de los valores del intervalo B2:B6 que son mayores o iguales que 20. Devuelve 75 porque la quinta fila no cumple con el criterio.

=SUMAR.SI.CONJUNTO(C2:C6;B2:B6;">=20";C2:C6;">70")

Calcula la suma de los valores en el intervalo C2:C6 que son mayores que 70 y que se corresponden con las celdas del intervalo B2:B6 con valores mayores o iguales que 20. Devuelve 275 porque las filas segunda y quinta no cumplen con por lo menos un criterio.

#### Uso de expresiones regulares y funciones anidadas

=SUMAR.SI.CONJUNTO(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Calcula la suma de los valores en el intervalo C2:C6 que se corresponden con todos los valores del intervalo B2:B6, exceptuando su mínimo y su máximo. Devuelve 255 porque las filas tercera y quinta no cumplen con por lo menos un criterio.

=SUMAR.SI.CONJUNTO(C2:C6;A2:A6;"pan.*";B2:B6;"<"&MAX(B2:B6))

Calcula la suma de los valores del intervalo C2:C6 que se corresponden con todas las celdas del intervalo A2:A6 que comienzan por «pan» y con todas las celdas del intervalo B2:B6 excepto su máximo. Devuelve 65 porque solo la segunda fila cumple con todos los criterios.

#### Referencia a una celda como criterio

Si se necesita cambiar un criterio fácilmente, puede especificarlo en ena celda separada y usar una referencia a esa celda en la condición de la función SUMAR.SI.CONJUNTO. Por ejemplo, la función anterios puede reescribirse así:

=SUMAR.SI.CONJUNTO(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

Si E2 = pen, la función devuelve 65 porque el link a la celda se sustituye por su contenido.

Temas relacionados

SUMA, SUMAR.SI

CONTAR.SI.CONJUNTO, MINIFS, MAXIFS, PROMEDIO.SI.CONJUNTO, SUMAR.SI.CONJUNTO

Lista de expresiones regulares