Επιλογή στοιχείου(-ων) πίνακα : [] at

### 1.42.12 Επιλογή στοιχείου(-ων) πίνακα : `[] at`

Θυμηθείτε ότι ένας πίνακας είναι μια λίστα από λίστες του ίδιου μεγέθους.
Είσοδος :

`A:=[[3,4,5],[1,2,6]]`

Έξοδος :

`[[3,4,5],[1,2,6]]`

Η ενθηματική συνάρτηση `at` ή ο συμβολισμός δεικτών `[..]` χρησιμοποιείται για να έχουμε πρόσβαση σε ένα στοιχείο ή σε μια γραμμή ή σε μια στήλη ενός πίνακα:

- Για να επιλέξετε ένα στοιχείο , γράψτε τον πίνακα, και μετά γράψτε μέσα σε αγκύλες τον δείκτη της γραμμής του στοιχείου, ένα κόμμα, και τον δείκτη της στήλης του στοιχείου. Στον τρόπο λειτουργίας `Xcas` ο πρώτος δείκτης είναι 0, ενώ στους άλλους τρόπους λειτουργίας ο πρώτος δείκτης είναι 1.
  Είσοδος :
  `[[3,4,5],[1,2,6]][0,1]`
  ή
  `A[0,1]`
  ή
  `A[0][1]`
  ή
  `at(A,[0,1])`
  Έξοδος :
  `4`
- Για να επιλέξετε μια γραμμή του πίνακα `A`, γράψτε τον πίνακα, και μετά γράψτε μέσα σε αγκύλες τον δείκτη της γραμμής.
  Είσοδος :
  `[[3,4,5],[1,2,6]][0]`
  ή
  `A[0]`
  ή
  `at(A,0)`
  Έξοδος :
  `[3,4,5]`
- Για να επιλέξετε μέρος μιας γραμμής βάλτε δύο ορίσματα μέσα στις αγκύλες : τον δείκτη της γραμμής και ένα διάστημα δεικτών που αντιστοιχεί στις επιλεγμένες στήλες.
  Είσοδος :
  `A[1,0..2]`
  Έξοδος :
  `[1,2,6]`
  Είσοδος :
  `A[1,1..2]`
  Έξοδος :
  `[2,6]`
- Για να επιλέξετε μια στήλη του πίνακα `A`, πρώτα αναστρέψτε τον `A` ( `tran(A)`) και μετά επιλέξτε την γραμμή όπως παραπάνω.
  Είσοδος :
  `tran(A)[1]`
  ή
  `at(tran(A),1)`
  Έξοδος :
  `[4,2]`
- Για να επιλέξετε μέρος μιας στήλης του πίνακα `A` σαν λίστα, βάλτε δύο ορίσματα μέσα στις αγκύλες : ένα διάστημα δεικτών που αντιστοιχεί στις επιλεγμένες γραμμές και τον δείκτη της στήλης.
  Είσοδος :
  `A[0..0,1]`
  Έξοδος :
  `[4]`

  Αυτό μπορεί να χρησιμοποιηθεί για να επιλέξετε μια ολόκληρη στήλη, ορίζοντας ένα διάστημα δεικτών που αντιστοιχεί σε όλες τις γραμμές.
  Είσοδος :

  `A[0..1,1]`

  Έξοδος :

  `[4,2]`
- Για να επιλέξετε έναν υποπίνακα ενός πίνακα, βάλτε μέσα σε αγκύλες δύο διαστήματα : ένα διάστημα για τις επιλεγμένες γραμμές και ένα διάστημα για τις επιλεγμένες στήλες .
  Για τον πίνακα `A` :
  `A:=[[3,4,5],[1,2,6]]`
  Είσοδος :
  `A[0..1,1..2]`
  Έξοδος :
  `[[4,5],[2,6]]`
  Είσοδος :
  `A[0..1,1..1]`
  Έξοδος :
  `[[4],[2]]`
  Σχόλιο Εάν το δεύτερο διάστημα παραλείπεται, ο υποπίνακας φτιάχνεται με τις διαδοχικές γραμμές που αντιστοιχούν στο πρώτο διάστημα.
  Είσοδος :
  `A[1..1]`
  Έξοδος :
  `[[1,2,6]]`

Μπορείτε επίσης να κάνετε ανάθεση τιμής σε ένα στοιχείο ενός πίνακα χρησιμοποιώντας τον συμβολισμό των δεικτών. Εάν κάνετε ανάθεση τιμής με `:=` δημιουργείται ένα νέο αντίγραφο του πίνακα και το στοιχείο τροποποιείται, ενώ εάν κάνετε ανάθεση τιμής με `=<`, ο πίνακας τροποποιείται στη θέση του στοιχείου.