Loris Opcodes
Prev | Historical and Abandonned Opcodes | Next

## Loris Opcodes

| Note
These opcodes are an optional component of Csound5. You can check if they are installed by using the command 'csound -z' which lists all available opcodes.

The Loris family of opcodes wraps: lorisread which imports a set of bandwidth-enhanced partials from a SDIF-format data file, applying control-rate frequency, amplitude, and bandwidth scaling envelopes, and stores the modified partials in memory; lorismorph, which morphs two stored sets of bandwidth-enhanced partials and stores a new set of partials representing the morphed sound. The morph is performed by linearly interpolating the parameter envelopes (frequency, amplitude, and bandwidth, or noisiness) of the bandwidth-enhanced partials according to control-rate frequency, amplitude, and bandwidth morphing functions, and lorisplay, which renders a stored set of bandwidth-enhanced partials using the method of Bandwidth-Enhanced Additive Synthesis implemented in the Loris software, applying control-rate frequency, amplitude, and bandwidth scaling envelopes.

For more information about sound morphing and manipulation using Loris and the Reassigned Bandwidth-Enhanced Additive Model, visit the Loris web site at www.cerlsoundgroup.org/Loris.

### Examples

Example 1329. Play the partials wihtout modification

    ;
    ; Play the partials in clarinet.sdif
    ; from 0 to 3 sec with 1 ms fadetime
    ; and no frequency , amplitude, or
    ; bandwidth modification.
    ;
    instr 1
        ktime    linseg      0, p3, 3.0    ; linear time function from 0 to 3 seconds
                 lorisread   ktime, "clarinet.sdif", 1, 1, 1, 1, .001
        asig     lorisplay   1, 1, 1, 1
                 out         asig
    endin

Example 1330. Add tuning and vibrato

    ; Play the partials in clarinet.sdif
    ; from 0 to 3 sec with 1 ms fadetime
    ; adding tuning and vibrato, increasing the
    ; "breathiness" (noisiness) and overall
    ; amplitude, and adding a highpass filter.
    ;
    instr 2
        ktime    linseg      0, p3, 3.0    ; linear time function from 0 to 3 seconds

        ; compute frequency scale for tuning
        ; (original pitch was G#4)
        ifscale  =           cpspch(p4)/cpspch(8.08)

        ; make a vibrato envelope
        kvenv    linseg      0, p3/6, 0, p3/6, .02, p3/3, .02, p3/6, 0, p3/6, 0
        kvib     oscil       kvenv, 4, 1   ; table 1, sinusoid

        kbwenv   linseg      1, p3/6, 1, p3/6, 2, 2*p3/3, 2
                 lorisread   ktime, "clarinet.sdif", 1, 1, 1, 1, .001
        a1       lorisplay   1, ifscale+kvib, 2, kbwenv
        a2       atone       a1, 1000      ; highpass filter, cutoff 1000 Hz
                 out         a2
    endin

The instrument in the first example synthesizes a clarinet tone from beginning to end using partials derived from reassigned bandwidth-enhanced analysis of a three-second clarinet tone, stored in a file, `clarinet.sdif`. The instrument in Example 2 adds tuning and vibrato to the clarinet tone synthesized by instr 1, boosts its amplitde and noisiness, and applies a highpass filter to the result. The following score can be used to test both of the instruments described above.

        ; make sinusoid in table 1
        f 1 0 4096 10 1

        ; play instr 1
        ;     strt   dur
        i 1    0      3
        i 1    +      1
        i 1    +      6
        s

        ; play instr 2
        ;     strt   dur   ptch
        i 2     1     3    8.08
        i 2     3.5   1    8.04
        i 2     4     6    8.00
        i 2     4     6    8.07

        e

Example 1331. Morph partials

    ; Morph the partials in clarinet.sdif into the
    ; partials in flute.sdif over the duration of
    ; the sustained portion of the two tones (from
    ; .2 to 2.0 seconds in the clarinet, and from
    ; .5 to 2.1 seconds in the flute). The onset
    ; and decay portions in the morphed sound are
    ; specified by parameters p4 and p5, respectively.
    ; The morphing time is the time between the
    ; onset and the decay. The clarinet partials are
    ; shfited in pitch to match the pitch of the flute
    ; tone (D above middle C).
    ;
    instr 1
        ionset   =           p4
        idecay   =           p5
        itmorph  =           p3 - (ionset + idecay)
        ipshift  =           cpspch(8.02)/cpspch(8.08)

          ; clarinet time function, morph from .2 to 2.0 seconds
        ktcl     linseg      0, ionset, .2, itmorph, 2.0, idecay, 2.1
          ; flute time function, morph from .5 to 2.1 seconds
        ktfl     linseg      0, ionset, .5, itmorph, 2.1, idecay, 2.3
        kmurph   linseg      0, ionset, 0, itmorph, 1, idecay, 1
                 lorisread   ktcl, "clarinet.sdif", 1, ipshift, 2, 1, .001
                 lorisread   ktfl, "flute.sdif", 2, 1, 1, 1, .001
                 lorismorph  1, 2, 3, kmurph, kmurph, kmurph
        asig     lorisplay   3, 1, 1, 1
                 out         asig
    endin

Example 1332. More morphing

    ; Morph the partials in trombone.sdif into the
    ; partials in meow.sdif. The start and end times
    ; for the morph are specified by parameters p4
    ; and p5, respectively. The morph occurs over the
    ; second of four pitches in each of the sounds,
    ; from .75 to 1.2 seconds in the flutter-tongued
    ; trombone tone, and from 1.7 to 2.2 seconds in
    ; the cat's meow. Different morphing functions are
    ; used for the frequency and amplitude envelopes,
    ; so that the partial amplitudes make a faster
    ; transition from trombone to cat than the frequencies.
    ; (The bandwidth envelopes use the same morphing
    ; function as the amplitudes.)
    ;
    instr 2
        ionset   =           p4
        imorph   =           p5 - p4
        irelease =           p3 - p5

        kttbn    linseg      0, ionset, .75, imorph, 1.2, irelease, 2.4
        ktmeow   linseg      0, ionset, 1.7, imorph, 2.2, irelease, 3.4

        kmfreq   linseg      0, ionset, 0, .75*imorph, .25, .25*imorph, 1, irelease, 1
        kmamp    linseg      0, ionset, 0, .75*imorph, .9, .25*imorph, 1, irelease, 1

                 lorisread   kttbn, "trombone.sdif", 1, 1, 1, 1, .001
                 lorisread   ktmeow, "meow.sdif", 2, 1, 1, 1, .001
                 lorismorph  1, 2, 3, kmfreq, kmamp, kmamp
        asig     lorisplay   3, 1, 1, 1
                 out         asig
    endin

The instrument in the first morphing example performs a sound morph between a clarinet tone and a flute tone using reassigned bandwidth-enhanced partials stored in `clarinet.sdif` and `flute.sdif`.

The morph is performed over the sustain portions of the tones, 2. seconds to 2.0 seconds in the case of the clarinet tone and .5 seconds to 2.1 seconds in the case of the flute tone. The time index functions, ktcl and ktfl, align the onset and decay portions of the tones with the specified onset and decay times for the morphed sound, specified by parameters p4 and p5, respectively. The onset in the morphed sounds is purely clarinet partial data, and the decay is purely flute data. The clarinet partials are shifted in pitch to match the pitch of the flute tone (D above middle C).

The instrument in the second morphing example performs a sound morph between a flutter-tongued trombone tone and a cat's meow using reassigned bandwidth-enhanced partials stored in `trombone.sdif` and `meow.sdif`. The data in these SDIF files have been channelized and distilled to establish correspondences between partials.

The two sets of partials are imported and stored in memory locations labeled 1 and 2, respectively. Both of the original sounds have four notes, and the morph is performed over the second note in each sound (from .75 to 1.2 seconds in the flutter-tongued trombone tone, and from 1.7 to 2.2 seconds in the cat's meow). The different time index functions, kttbn and ktmeow, align those segments of the source and target partial sets with the specified morph start, morph end, and overall duration parameters. Two different morphing functions are used, so that the partial ammplitudes and bandwidth coefficients morph quickly from the trombone values to the cat's-meow values, and the frequencies make a more gradual transition. The morphed partials are stored in a memory location labeled 3 and rendered by the subsequent lorisplay instruction. They could also have been used as a source for another morph in a three-way morphing instrument. The following score can be used to test both of the instruments described above.

        ; play instr 1
        ;     strt   dur   onset   decay
        i 1    0      3     .25     .15
        i 1    +      1     .10     .10
        i 1    +      6    1.      1.
        s

        ; play instr 2
        ;     strt   dur  morph_start   morph_end
        i 2    0      4     .75           2.75

        e

### Credits

This implementation of the Loris unit generators was written by Kelly Fitz (loris@cerlsoundgroup.org).

It is patterned after a prototype implementation of the lorisplay unit generator written by Corbin Champion, and based on the method of Bandwidth-Enhanced Additive Synthesis and on the sound morphing algorithms implemented in the Loris library for sound modeling and manipulation. The opcodes were further adapted as a plugin for Csound 5 by Michael Gogins.

Prev | Up | Next
Historical and Abandonned Opcodes | Home | lorismorph