Isi
Indeks 🔎︎

# Fungsi Lembar Sebar

Bagian ini berisi uraian tentang fungsi-fungsiLembar Sebar bersama dengan sebuah contoh.

Untuk mengakses fungsi ini...

Sisip - Fungsi - Kategori Lembar Sebar

## ERROR.TYPE

Mengembalikan angka yang mewakili jenis Kesalahan tertentu, atau nilai kesalahan #N/A, jika tidak ada kesalahan.

## ADDRESS

Mengembalikan alamat sel (referensi) sebagai teks, sesuai dengan nomor baris dan kolom yang ditentukan.Anda dapat menentukan apakah alamat ditafsirkan sebagai alamat absolut (misalnya, $A$1) atau sebagai alamat relatif (sebagai A1) atau dalam bentuk campuran (A$1 atau $A1). Anda juga dapat menentukan nama lembar.

Untuk interoperabilitas, fungsi ALAMAT dan SECARA TIDAK LANGSING mendukung parameter opsional untuk menentukan apakah notasi alamat R1C1 alih-alih notasi A1 biasa harus digunakan.

Dalam ALAMAT, parameter dimasukkan sebagai parameter keempat, menggeser parameter nama sheet opsional ke posisi kelima.

Dalam INDIRECT, parameter ditambahkan sebagai parameter kedua.

Di kedua fungsi, jika argumen dimasukkan dengan nilai 0, maka notasi R1C1 digunakan. Jika argumen tidak diberikan atau memiliki nilai selain 0, maka notasi A1 digunakan.

Dalam hal notasi R1C1, ADDRESS mengembalikan string alamat menggunakan tanda seru '!' sebagai pemisah nama sheet, dan INDIRECT mengharapkan tanda seru sebagai pemisah nama sheet. Kedua fungsi masih menggunakan titik '.' pemisah nama lembar dengan notasi A1.

Saat membuka dokumen dari format ODF 1.0/1.1, fungsi ADDRESS yang memperlihatkan nama sheet sebagai parameter keempat akan menggeser nama sheet itu menjadi parameter kelima. Parameter keempat yang baru dengan nilai 1 akan dimasukkan.

Saat menyimpan dokumen dalam format ODF 1.0/1.1, jika fungsi ADDRESS memiliki parameter keempat, parameter itu akan dihapus.

Jangan menyimpan lembar sebar dalam format ODF 1.0/1.1 yang lama jika parameter keempat fungsi ADDRESS baru digunakan dengan nilai 0.

Fungsi INDIRECT disimpan tanpa konversi ke format ODF 1.0/1.1. Jika parameter kedua ada, versi Calc yang lebih lama akan mengembalikan kesalahan untuk fungsi itu.

#### Sintaksis

ADDRESS(Row; Column [; Abs [; A1 [; "Sheet"]]])

Baris mewakili nomor baris untuk referensi sel

Kolom mewakili nomor kolom untuk referensi sel (angka, bukan huruf)

Abs menentukan jenis referensi:

1: absolut ($A$1)

2: jenis referensi barisnya absolut; referensi kolomnya relatif (A$1)

3: baris (relatif); kolom (absolut) ($A1)

4: relatif (A1)

A1 (pilihan) - jika set ke 0, notasi R1C1 digunakan. Jika parameter ini tidak ada atau ditetapkan ke nilai lain dari 0, notasi A1 digunakan.

Lembarmewakili nama lembar. Itu harus ditempatkan dalam tanda kutip ganda.

### Contoh:

=ADDRESS(1;1;2;;"Sheet2") mengembalikan yang berikut: Sheet2.A$1

Jika rumus di atas adalah dalam sel B2 dari sheet saat ini, dan sel A1 di sheet 2 berisi nilai-6, Anda dapat merujuk secara tidak langsung ke sel yang direferensikan menggunakan fungsi dalam B2 dengan memasukkan =ABS(INDIRECT(B2)). Hasilnya adalah nilai absolut dari referensi sel yang ditentukan dalam B2, yang dalam hal ini adalah 6.

## AREAS

Mengembalikan jumlah rentang individual yang termasuk dalam beberapa jarak. Jarak dapat terdiri dari sel yang berdekatan atau satu sel tunggal.

Fungsi mengharapkan satu argumen. Jika Anda menyatakan beberapa rentang, Anda harus melampirkannya ke dalam tanda kurung tambahan. Beberapa rentang dapat dimasukkan menggunakan titik koma (;) sebagai pembagi, tetapi ini akan secara otomatis dikonversi ke operator tilde (~). Tilde digunakan untuk bergabung dengan rentang.

#### Sintaksis

AREAS(Referensi)

Referensi mewakili referensi ke sel atau rentang sel.

#### Contoh

=AREAS((A1:B3;F2;G1)) mengembalikan 3, karena referensi ke tiga sel dan / atau area. Setelah entri ini dikonversi menjadi =AREAS((A1:B3~F2~G1)).

=AREAS(All)mengembalikan 1 jika Anda telah menetapkan area bernama All underData - Rentang yang Ditentukan.

## CHOOSE

Menggunakan indeks untuk mengembalikan nilai dari daftar hingga 30 nilai.

#### Sintaksis

CHOOSE(Index; Value 1 [; Value 2 [; ... [; Value 30]]])

Index adalah referensi atau angka antara 1 dan 30 yang menunjukkan nilai mana yang harus diambil dari daftar.

Value 1, Value 2, ..., Value 30 is the list of values entered as a reference to a cell or as individual values.

#### Contoh

=CHOOSE(A1;B1;B2;B3;"Hari ini";"Kemarin";"Besok"),misalnya, mengembalikan konten sel B2 untuk A1 = 2; untuk A1 = 4, fungsi mengembalikan teks "Hari ini".

## COLUMN

Mengembalikan nomor kolom referensi sel. Jika referensi adalah sel nomor kolom sel dikembalikan; jika parameternya adalah area sel, nomor kolom yang sesuai dikembalikan dalam satu baris array Jika rumus dimasukkan sebagai rumus array. Jika fungsi COLUMN dengan parameter referensi area tidak digunakan untuk rumus array, hanya nomor kolom sel pertama di dalam area yang ditentukan.

#### Sintaksis

COLUMN([Reference])

Referensi adalah referensi ke sel atau area sel yang nomor kolomnya pertama kali ditemukan.

Jika tidak ada referensi yang dimasukkan, nomor kolom sel tempat formula yang dimasukkan akan ditemukan. LibreOffice Calc secara otomatis menetapkan referensi ke sel saat ini.

#### Contoh

=COLUMN(A1) sama dengan 1. Kolom A adalah kolom pertama dalam tabel.

=COLUMN(C3:E3) sama dengan 3. Kolom C adalah kolom ketiga dalam tabel.

=COLUMN(D3:G10) mengembalikan 4 karena kolom D adalah kolom keempat dalam tabel dan fungsi COLUMN tidak digunakan sebagai rumus array. (Dalam hal ini, nilai pertama array selalu digunakan sebagai hasilnya.)

{=COLUMN(B2:B7)} dan =COLUMN(B2:B7) keduanya menghasilkan 2 karena referensi hanya berisi kolom B sebagai kolom kedua dalam tabel. Karena area satu kolom hanya memiliki satu nomor kolom, itu tidak membuat perbedaan apakah rumus digunakan atau tidak sebagai rumus array.

=COLUMN() mengembalikan 3 jika rumus dimasukkan dalam kolom C.

{=COLUMN(Rabbit)} mengembalikan array tunggal(3, 4) jika "Rabbit" adalah area bernama (C1:D3).

## COLUMNS

Mengembalikan jumlah kolom dalam referensi yang diberikan.

#### Sintaksis

COLUMNS(susunan)

Arrayadalah referensi ke rentang sel yang jumlah kolomnya dapat ditemukan. Argumennya juga bisa berupa sel tunggal.

#### Contoh

=COLUMNS(B5) mengembalikan 1 karena sel hanya berisi satu kolom.

=COLUMNS(A1:C5) sama dengan 3. Referensi terdiri dari tiga kolom.

=COLUMNS(Rabbit) mengembalikan 2 jika Rabbit adalah rentang bernama (C1:D3).

## DDE

Menghasilkan hasil tautan berbasis DDE.Jika konten dari rentang atau bagian yang diubah berubah, nilai yang dihasilkan juga akan berubah. Anda harus memuat ulang lembar sebar atau memilihSunting - Tautan untuk melihat tautan yang diperbarui. Tautan lintas platform, misalnya dari LibreOfficeinstalasi yang berjalan pada mesin Windows ke dokumen yang dibuat pada mesin Linux, tidak diperkenankan.

#### Sintaksis

DDE("Server"; "File"; "Range" [; Mode])

Peladenadalah nama aplikasi peladen. LibreOffice aplikasi memiliki nama peladen "soffice".

Berkas adalah nama lengkap berkasnya, termasuk spesifikasi jalur.

Rentang adalah wilayah yang memiliki data untuk dievaluasi.

Mode adalah parameter opsional yang mengontrol metode yang digunakan server DDE untuk mengubah datanya menjadi angka.

Nama | Efek
0 atau hilang | Format angka dari gaya sel "Bawaan"
1 | Data selalu diinterpretasikan dalam bentuk standar bagi Inggris AS
2 | Data diterima sebagai teks, tidak dikonversi sebagai angka

#### Contoh

=DDE("soffice";"c:\office\document\data1.ods";"lembar1.A1")membaca isi sel A1 di lembar1 dariLibreOffice Calc

=DDE("soffice";"c:\office\document\motto.odt";"Motto hari ini")mengembalikan moto di sel yang berisi rumus ini. Pertama, Anda harus memasukkan baris dalam dokumen motto.odt yang berisi teks motto dan mendefinisikannya sebagai baris pertama dari bagian bernama Motto hari ini (inLibreOfficePenulis di bawah Sisipkan - Bagian. Jika moto diubah (dan disimpan) di LibreOffice Dokumen penulis, moto diperbarui di semua LibreOffice Sel-sel Calc tempat tautan DDE ini didefinisikan.

## ERRORTYPE

Mengembalikan nomor yang sesuai dengan nilai kesalahan terjadi di sel yang berbeda. Dengan bantuan nomor ini, Anda dapat menghasilkan teks pesan kesalahan.

Jika sebuah galat terjadi, fungsi mengembalikan sebuah logical atau nilai numerik

Bilah Status menampilkan kode kesalahan standar dariLibreOffice jika Anda mengklik sel yang mengandung kesalahan.

#### Sintaksis

ERRORTYPE(Referensi)

Referensi berisi alamat sel tempat kesalahan terjadi.

#### Contoh

Jika sel A1 menampilkan Err: 518, fungsinya =ERRORTYPE(A1)mengembalikan nomor 518.

## GETPIVOTDATA

Fungsi GETPIVOTDATA mengembalikan nilai hasil dari tabel pivot. Nilai tersebut ditangani menggunakan nama bidang dan item, sehingga tetap valid jika tata letak tabel pivot berubah.

#### Sintaksis

Dua definisi sintaksis berbeda dapat dipakai:

GETPIVOTDATA(TargetField; pivot table[; Field 1; Item 1][; ... [Field 126; Item 126]])

atau

Bagi Tabel

Sintaks kedua diasumsikan jika tepat dua parameter diberikan, parameter yang pertama adalah referensi sel atau rentang sel. Sintaks pertama diasumsikan dalam semua kasus lainnya. Fungsi Wisaya menampilkan sintaks pertama.

### Sintaks Pertama

RuasTarget adalah string yang memilih salah satu bidang data tabel pivot. String dapat berupa nama kolom sumber, atau nama bidang data seperti yang ditunjukkan pada tabel (seperti "Jumlah - Penjualan").

tabel pivot adalah referensi ke sel atau rentang sel yang diposisikan dalam tabel pivot atau berisi tabel pivot. Jika rentang sel berisi beberapa tabel pivot, tabel yang dibuat terakhir digunakan.

Jika tidak ada pasangan Ruas n / Item n yang diberikan, total keseluruhan akan dikembalikan. Jika tidak, setiap pasangan menambahkan kendala yang harus dipenuhi hasilnya. Ruas n adalah nama bidang dari tabel pivot. Item n adalah nama item dari bidang itu.

Jika tabel pivot hanya berisi nilai hasil tunggal yang memenuhi semua kendala, atau hasil subtotal yang merangkum semua nilai yang cocok, hasil itu dikembalikan. Jika tidak ada hasil yang cocok, atau beberapa yang tanpa subtotal untuk mereka, kesalahan dikembalikan. Kondisi ini berlaku untuk hasil yang termasuk dalam tabel pivot.

Jika data sumber berisi entri yang disembunyikan oleh pengaturan tabel pivot, mereka diabaikan. Urutan pasangan Ruas/Item tidak signifikan. Nama Ruas dan item tidak peka huruf besar-kecil.

If no constraint for a filter is given, the field's selected value is implicitly used. If a constraint for a filter is given, it must match the field's selected value, or an error is returned. Filters are the fields at the top left of a pivot table, populated using the "Filters" area of the pivot table layout dialog. From each filter, an item (value) can be selected, which means only that item is included in the calculation.

Nilai subtotal dari tabel pivot hanya digunakan jika mereka menggunakan fungsi "otomatis" (kecuali ketika ditentukan dalam kendala, lihat Sintaks Kedua di bawah).

### Sintaks Kedua

Kelas mewakili susunan dari batas nilai.

Kendala adalah daftar yang dipisahkan oleh spasi. Entri dapat dikutip (kutipan tunggal). Seluruh string harus dilampirkan dalam tanda kutip (tanda kutip ganda), kecuali jika Anda mereferensikan string dari sel lain.

Salah satu entri dapat berupa nama ruas data. Nama ruas data bisa ditinggalkan jika tabel pivot hanya berisi satu bidang data, jika tidak harus ada.

Masing-masing entri lain menetapkan batasan dalam bentuk Field[Item] (dengan karakter literal [ and ]), atau hanya Item jika nama item unik dalam semua bidang yang digunakan dalam tabel pivot

Nama fungsi dapat ditambahkan dalam formulir Field[Item;Function], yang akan menyebabkan batasan hanya cocok dengan nilai subtotal yang menggunakan fungsi itu. Nama fungsi yang mungkin adalah Jumlah, Jumlah, Rata-Rata, Maks, Min, Produk, Hitungan (Angka saja), StDev (Sampel), StDevP (Populasi), Var (Sampel), dan VarP (Populasi), tidak peka huruf besar-kecil.

## HLOOKUP

Menelusuri nilai dan referensi ke sel di bawah area yang dipilih. Fungsi ini memverifikasi apakah baris pertama array mengandung nilai tertentu. Fungsi mengembalikan nilai pada deretan array, dinamai dalam Indeks, di kolom yang sama.

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every character with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in LibreOffice - PreferencesTools - Options - LibreOffice Calc - Calculate.

When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".

#### Sintaksis

HLOOKUP(Lookup; Array; Index [; SortedRangeLookup])

For an explanation on the parameters, see: VLOOKUP (columns and rows are exchanged)

Penanganan Sel Kosong

#### Contoh

Suppose we have built a small database table occupying the cell range A1:DO4 and containing basic information about 118 chemical elements. The first column contains the row headings “Element”, “Symbol”, “Atomic Number”, and “Relative Atomic Mass”. Subsequent columns contain the relevant information for each of the elements, ordered left to right by atomic number. For example, cells B1:B4 contain “Hydrogen”, “H”, “1” and “1.008”, while cells DO1:DO4 contain “Oganesson”, “Og”, “118”, and “294”.

| A | B | C | D | ... | DO
1 | Element | Hydrogen | Helium | Lithium | ... | Oganesson
2 | Symbol | H | He | Li | ... | Og
3 | Atomic Number | 1 | 2 | 3 | ... | 118
4 | Relative Atomic Mass | 1.008 | 4.0026 | 6.94 | ... | 294

=HLOOKUP("Lead"; $A$1:$DO$4; 2; 0) returns “Pb”, the symbol for lead.

=HLOOKUP("Gold"; $A$1:$DO$4; 3; 0) returns 79, the atomic number for gold.

=HLOOKUP("Carbon"; $A$1:$DO$4; 4; 0) returns 12.011, the relative atomic mass of carbon.

## HYPERLINK

Saat Anda mengklik sel yang berisi fungsi HYPERLINK, hyperlink terbuka.

Jika Anda menggunakan parameter CellText opsional, rumus menemukan URL, dan kemudian menampilkan teks atau angka.

Untuk membuka sel pranala dengan keyboard, pilih sel, tekan F2 untuk masuk ke mode Edit, gerakkan kursor di depan pranala, tekan Shift+F10, lalu pilih Buka Pranala.

#### Sintaksis

HYPERLINK("URL" [; "CellText"])

URL menentukan target tautan. Parameter CellText opsional adalah teks atau angka yang ditampilkan dalam sel dan akan dikembalikan sebagai hasilnya. Jika parameter CellText tidak ditentukan, URL ditampilkan dalam teks sel dan akan dikembalikan sebagai hasilnya.

Angka 0 dikembalikan untuk sel kosong dan elemen matriks.

#### Contoh

=HYPERLINK("http://www.example.org") displays the text "http://www.example.org" in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("http://www.example.org";"Click here") displays the text "Click here" in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("http://www.example.org";12345) displays the number 12345 and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK($B4) where cell B4 contains http://www.example.org. The function adds http://www.example.org to the URL of the hyperlink cell and returns the same text which is used as formula result.

=HYPERLINK("http://www.";"Click ") & "example.org" displays the text Click example.org in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("#Sheet1.A1";"Go to top") displays the text Go to top and jumps to cell Sheet1.A1 in this document.

=HYPERLINK("file:///C:/writer.odt#Specification";"Go to Writer bookmark") displays the text "Go to Writer bookmark", loads the specified text document and jumps to bookmark "Specification".

=HYPERLINK("file:///C:/Documents/";"Open Documents folder") displays the text "Open Documents folder" and shows the folder contents using the standard file manager in your operating system.

## INDEX

INDEX mengembalikan kisaran sub, ditentukan oleh nomor baris dan kolom, atau indeks rentang opsional. Bergantung pada konteksnya, INDEX mengembalikan referensi atau konten.

#### Sintaksis

INDEX(Reference [; Row [; Column [; Range]]])

Referensi adalah referensi, yang dimasukkan secara langsung atau dengan menentukan nama rentang. Jika referensi terdiri dari beberapa rentang, Anda harus menyertakan referensi atau nama rentang dalam tanda kurung.

Baris(pilihan) mewakili indeks baris rentang referensi, untuk mengembalikan nilai. Dalam hal nol (tidak ada baris spesifik) semua baris yang direferensikan dikembalikan.

Kolom (opsional) mewakili indeks kolom rentang referensi, yang untuknya mengembalikan nilai. Dalam hal nol (tidak ada kolom khusus) semua kolom yang direferensikan dikembalikan.

Rentang (opsional) mewakili indeks subrange jika merujuk ke beberapa rentang.

#### Contoh

=INDEX(Prices;4;1)mengembalikan nilai dari baris 4 dan kolom 1 dari rentang basis data yang ditentukan dalam Data - Tentukansebagaiharga.

=INDEX(SumX;4;1)mengembalikan nilai dari rentangSumXdi baris 4 dan kolom 1 sebagaimana didefinisikan dalamLemabar - Bernama - Rentang dan Ekspresi - Definisi.

=INDEX(A1:B6;1) mengembalikan referensi ke baris pertama A1: B6.

=INDEX(A1:B6;1) mengembalikan referensi ke baris pertama A1: B6.

= INDEX((multi);4;1) menunjukkan nilai yang terkandung dalam baris 4 dan kolom 1 dari rentang (multiple), yang Anda beri nama di bawah Sheet - Rentang nama dan Ekspresi - Define as multi . Berbagai rentang dapat terdiri dari beberapa rentang persegi panjang, masing-masing dengan baris 4 dan kolom 1. Jika sekarang Anda ingin memanggil blok kedua dari beberapa rentang ini masukkan angka 2 sebagai parameter range.

=INDEX(A1:B6;1;1)menunjukkan nilai di range kiri atas A1:B6.

=INDEX((multi);0;0;2) mengembalikan referensi ke rentang kedua dari beberapa rentang.

## INDIRECT

Mengembalikan reference ditentukan oleh string teks. Fungsi ini juga dapat digunakan untuk mengembalikan area string yang sesuai.

This function is always recalculated whenever a recalculation occurs.

Untuk interoperabilitas, fungsi ALAMAT dan SECARA TIDAK LANGSING mendukung parameter opsional untuk menentukan apakah notasi alamat R1C1 alih-alih notasi A1 biasa harus digunakan.

Dalam ALAMAT, parameter dimasukkan sebagai parameter keempat, menggeser parameter nama sheet opsional ke posisi kelima.

Dalam INDIRECT, parameter ditambahkan sebagai parameter kedua.

Di kedua fungsi, jika argumen dimasukkan dengan nilai 0, maka notasi R1C1 digunakan. Jika argumen tidak diberikan atau memiliki nilai selain 0, maka notasi A1 digunakan.

Dalam hal notasi R1C1, ADDRESS mengembalikan string alamat menggunakan tanda seru '!' sebagai pemisah nama sheet, dan INDIRECT mengharapkan tanda seru sebagai pemisah nama sheet. Kedua fungsi masih menggunakan titik '.' pemisah nama lembar dengan notasi A1.

Saat membuka dokumen dari format ODF 1.0/1.1, fungsi ADDRESS yang memperlihatkan nama sheet sebagai parameter keempat akan menggeser nama sheet itu menjadi parameter kelima. Parameter keempat yang baru dengan nilai 1 akan dimasukkan.

Saat menyimpan dokumen dalam format ODF 1.0/1.1, jika fungsi ADDRESS memiliki parameter keempat, parameter itu akan dihapus.

Jangan menyimpan lembar sebar dalam format ODF 1.0/1.1 yang lama jika parameter keempat fungsi ADDRESS baru digunakan dengan nilai 0.

Fungsi INDIRECT disimpan tanpa konversi ke format ODF 1.0/1.1. Jika parameter kedua ada, versi Calc yang lebih lama akan mengembalikan kesalahan untuk fungsi itu.

#### Sintaksis

INDIRECT(Ref [; A1])

Ref mewakili referensi ke sel atau area (dalam bentuk teks) untuk mengembalikan konten.

A1 (pilihan) - jika set ke 0, notasi R1C1 digunakan. Jika parameter ini tidak ada atau ditetapkan ke nilai lain dari 0, notasi A1 digunakan.

Jika anda membuka lembar sebar Excel yang menggunakan alamat tidak langsung yang dihitung dari fungsi string, alamat lembar tidak akan diterjemahkan secara otomatis. Misalnya, alamat Excel di INDIRECT("[filename]sheetname!"&B1) tidak dikonversi menjadi alamat Calc di INDIRECT("filename#sheetname."&B1).

#### Contoh

=INDIRECT(A1)sama dengan 100 jika A1 berisi C108 sebagai referensi dan sel C108 berisi nilai100.

=SUM(INDIRECT("a1:" & ADDRESS(1;3))) totalkan sel di area A1 hingga sel dengan alamat yang ditentukan oleh baris 1 dan kolom 3. Ini berarti area A1: C1 dijumlahkan.

## LOOKUP

Mengembalikan konten sel baik dari satu baris atau satu kolom. Secara opsional, nilai yang diberikan (dari indeks yang sama) dikembalikan dalam kolom dan baris yang berbeda. Berbeda dengan VLOOKUP and HLOOKUP, vektor hasil dan pencarian mungkin ada di posisi yang berbeda; mereka tidak harus berdekatan. Selain itu, vektor pencarian untuk LOOKUP harus diurutkan naik, jika tidak, pencarian tidak akan mengembalikan hasil yang dapat digunakan.

Jika LOOKUP tidak dapat menemukan kriteria pencarian, itu cocok dengan nilai terbesar dalam vektor pencarian yang kurang dari atau sama dengan kriteria pencarian.

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every character with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in LibreOffice - PreferencesTools - Options - LibreOffice Calc - Calculate.

When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".

#### Sintaksis

LOOKUP(Lookup; SearchVector [; ResultVector])

Lookup is the value of any type to be looked for; entered either directly or as a reference.

SearchVector adalah area baris tunggal atau kolom tunggal yang akan dicari.

ResultVector adalah satu baris atau baris tunggal kolom lain tempat hasil dari fungsi tersebut diambil. Hasilnya adalah sel vektor hasil dengan indeks yang sama dengan contoh yang ditemukan dalam vektor pencarian.

Penanganan Sel Kosong

#### Contoh

=LOOKUP(A1;D1:D100;F1:F100) mencari sel yang sesuai dalam rentang D1:D100 untuk nomor yang Anda masukkan dalam A1. Untuk contoh yang ditemukan, indeks ditentukan, misalnya, sel ke-12 dalam rentang ini. Kemudian, isi sel ke-12 dikembalikan sebagai nilai fungsi (dalam vektor hasil).

## MATCH

Mengembalikan posisi relatif suatu item dalam array yang cocok dengan nilai yang ditentukan. Fungsi mengembalikan posisi nilai yang ditemukan di lookup_array sebagai angka.

#### Sintaksis

MATCH(Search; LookupArray [; Type])

Search is the value which is to be searched for in the single-row or single-column array.

LookupArray adalah referensi yang dicari. Array pencarian dapat berupa satu baris atau kolom, atau bagian dari satu baris atau kolom.

Ketik dapat menggunakan nilai 1, 0, atau -1. Jika Type = 1 atau jika parameter opsional ini hilang, diasumsikan bahwa kolom pertama dari array pencarian diurutkan dalam urutan menaik. Jika Tipe = -1 diasumsikan bahwa kolom dalam diurutkan dalam urutan menurun. Ini sesuai dengan fungsi yang sama di Microsoft Excel.

Jika Tipe = 0, hanya pencocokan tepat yang ditemukan. Jika kriteria pencarian ditemukan lebih dari satu kali, fungsi mengembalikan indeks dari nilai yang cocok pertama. Hanya jika Tipe = 0 dapat anda mencari ekspresi reguler (jika diaktifkan dalam opsi perhitungan) atau wildcard (jika diaktifkan dalam opsi perhitungan).

Jika Tipe = 1 atau parameter ketiga tidak ada, indeks nilai terakhir yang lebih kecil atau sama dengan kriteria pencarian dikembalikan. Ini berlaku bahkan ketika array pencarian tidak diurutkan. Untuk Tipe = -1, nilai pertama yang lebih besar atau sama dikembalikan.

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every character with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in LibreOffice - PreferencesTools - Options - LibreOffice Calc - Calculate.

When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".

#### Contoh

=MATCH(200;D1:D100) mencari area D1:D100, yang diurutkan berdasarkan kolom D, untuk nilai 200. Begitu nilai ini tercapai, angka tersebut dari baris yang ditemukan dikembalikan. Jika nilai yang lebih tinggi ditemukan selama pencarian di kolom, jumlah baris sebelumnya dikembalikan.

## OFFSET

Mengembalikan nilai sel yang diimbangi dengan sejumlah baris dan kolom tertentu dari titik referensi yang diberikan.

This function is always recalculated whenever a recalculation occurs.

#### Sintaksis

OFFSET(Reference; Rows; Columns [; Height [; Width]])

Reference adalah referensi dari mana fungsi mencari referensi baru.

Rowsadalah jumlah baris di mana referensi dikoreksi ke atas (nilai negatif) atau turun. Gunakan 0 untuk tetap di baris yang sama.

Columns adalah jumlah kolom yang referensinya dikoreksi ke kiri (nilai negatif) atau ke kanan. Gunakan 0 untuk tetap di kolom yang sama

Tinggi (opsional) adalah ketinggian vertikal untuk area yang dimulai pada posisi referensi baru.

Lebar (opsional) adalah lebar horizontal untuk area yang dimulai pada posisi referensi baru.

ArgumenBaris dan Kolom tidak boleh mengarah ke nol atau negatif mulai baris atau kolom.

Argumen Tinggi dan Lebar tidak boleh mengarah ke nol atau negatif jumlah baris atau kolom.

Dalam fungsi-fungsi LibreOffice Calc, parameter yang ditandai dengan "opsional" dapat ditinggalkan apabila tidak ada parameter yang mengikuti. Sebagai contoh, [ada fungsi dengan empat parameter yang dua parameter terakhir ditandai dengan "opsional", Anda dapat meninggalkan parameter 4 atau parameter 3 dan 4, tetapi Anda tetap tidak bisa membiarkan parameter 3 sendirian.

#### Contoh

=OFFSET(A1;2;2) mengembalikan nilai dalam sel C3 (A1 digerakkan oleh dua baris dan dua kolom ke bawah). Jika C3 berisi nilai 100 fungsi ini mengembalikan nilai 100.

=OFFSET(B2:C3;1;1) mengembalikan referensi ke B2:C3 dipindahkan ke bawah dengan 1 baris dan satu kolom di sebelah kanan (C3:D4).

=OFFSET(B2:C3;-1;-1) mengembalikan referensi ke B2:C3 naik 1 baris dan satu kolom ke kiri (A1:B2).

=OFFSET(B2:C3;0;0;3;4) mengembalikan referensi ke B2:C3 yang diubah ukurannya menjadi 3 baris dan 4 kolom (B2:E4).

=OFFSET(B2:C3;1;0;3;4) mengembalikan referensi ke B2:C3 dipindahkan ke bawah dengan satu baris yang diubah ukurannya menjadi 3 baris dan 4 kolom (B3:E5 ).

=SUM(OFFSET(A1;2;2;5;6)) menentukan total area yang dimulai pada sel C3 dan memiliki ketinggian 5 baris dan lebar 6 kolom (area=C3:H7).

If Width or Height are given, the OFFSET function returns a cell range reference. If Reference is a single cell reference and both Width and Height are omitted, a single cell reference is returned.

## ROW

Mengembalikan nomor baris referensi sel. Jika referensi adalah sel, ia mengembalikan nomor baris sel. Jika referensi adalah rentang sel, ia mengembalikan nomor baris yang sesuai dalam satu kolom Array jika rumus dimasukkan sebagai rumus formula. Jika fungsi ROW dengan referensi rentang tidak digunakan dalam rumus array, hanya nomor baris sel rentang pertama yang akan dikembalikan.

#### Sintaksis

ROW([Reference])

Referensi adalah sel, area, atau nama area.

Jika Anda tidak menunjukkan referensi, nomor baris sel tempat rumus dimasukkan akan ditemukan. LibreOffice Calc secara otomatis menetapkan referensi ke sel saat ini.

#### Contoh

=ROW(B3) mengembalikan 3 karena referensi merujuk ke baris ketiga dalam tabel.

{=ROW(D5:D8)} mengembalikan array satu kolom (5, 6, 7, 8) karena referensi yang ditentukan berisi baris 5 hingga 8.

=ROW(D5:D8) mengembalikan 5 karena fungsi ROW tidak digunakan sebagai rumus array dan hanya jumlah baris pertama dari referensi yang dikembalikan.

{=ROW(A1:E1)} dan =ROW(A1: E1) keduanya menghasilkan 1 karena referensi hanya berisi baris 1 sebagai baris pertama dalam tabel. (Karena area baris tunggal hanya memiliki satu nomor baris, tidak ada bedanya apakah rumus tersebut digunakan sebagai rumus array atau tidak.)

=ROW() mengembalikan 3 jika rumus dimasukkan pada baris 3.

{=ROW(Rabbit)} mengembalikan array satu kolom (1, 2, 3) jika "Rabbit" adalah area bernama (C1:D3).

## ROWS

Mengembalikan jumlah baris dalam referensi atau array.

#### Sintaksis

ROWS(susunan)

Array adalah area referensi atau bernama yang jumlah barisnya harus ditentukan.

#### Contoh

=Rows(B5) mengembalikan 1 karena sel hanya berisi satu baris.

=ROWS(A10:B12) mengembalikan 3.

=ROWS(Rabbit) mengembalikan 3 jika "Rabbit" adalah nama daerah tersebut (C1:D3).

## SHEET

Returns the sheet number of either a reference or a string representing a sheet name. If you do not enter any parameters, the result is the sheet number of the spreadsheet containing the formula.

#### Sintaksis

SHEET([Reference])

Referensi adalah opsional dan merupakan referensi ke sel, area, atau string nama sheet.

#### Contoh

=SHEET(Sheet2.A1) returns 2 if Sheet2 is the second sheet in the spreadsheet document.

=SHEET("Sheet3") returns 3 if Sheet3 is the third sheet in the spreadsheet document.

## SHEETS

Menentukan jumlah lembar dalam referensi.Jika Anda tidak memasukkan parameter apa pun, itu mengembalikan jumlah lembar dalam dokumen saat ini.

#### Sintaksis

SHEETS([Reference])

Reference adalah referensi ke sheet atau area. Parameter ini opsional.

#### Contoh

=SHEETS(Sheet1.A1:Sheet3.G12)mengembalikan 3 jika Sheet1, Sheet2, dan Sheet3 ada dalam urutan yang ditunjukkan.

## STYLE

Menerapkan gaya ke sel yang berisi rumus. Setelah waktu yang ditentukan, gaya lain dapat diterapkan. Fungsi ini selalu mengembalikan nilai 0, memungkinkan Anda untuk menambahkannya ke fungsi lain tanpa mengubah nilainya. Bersama dengan fungsi CURRENT Anda dapat menerapkan warna ke sel tergantung pada nilainya. Misalnya: =...+STYLE(IF(CURRENT()>3;"merah";"hijau")) menerapkan gaya "merah" ke sel jika nilainya lebih besar dari 3, jika tidak gaya "hijau" diterapkan. Kedua format sel, "merah" dan "hijau" harus ditentukan sebelumnya.

#### Sintaksis

STYLE("Style" [; Time [; "Style2"]])

Style adalah nama gaya sel yang ditetapkan untuk sel. Nama gaya harus dimasukkan dalam tanda kutip.

Waktuadalah opsi rentang waktu dalam detik. jika parameter ini hilang gaya tidak akan diubah setelah sejumlah waktu telah berlalu.

gaya2 adalah nama opsional gaya sel yang ditetapkan ke sel setelah waktu tertentu berlalu. Jika parameter ini tidak ada, "Bawaan" diasumsikan.

Dalam fungsi-fungsi LibreOffice Calc, parameter yang ditandai dengan "opsional" dapat ditinggalkan apabila tidak ada parameter yang mengikuti. Sebagai contoh, [ada fungsi dengan empat parameter yang dua parameter terakhir ditandai dengan "opsional", Anda dapat meninggalkan parameter 4 atau parameter 3 dan 4, tetapi Anda tetap tidak bisa membiarkan parameter 3 sendirian.

#### Contoh

=STYLE("Invisible";60;"Default") memformat sel dalam format transparan selama 60 detik setelah dokumen dihitung ulang atau dimuat, kemudian format Bawaan ditetapkan. Kedua format sel harus ditentukan sebelumnya.

Karena STYLE () memiliki nilai pengembalian numerik nol, nilai pengembalian ini ditambahkan ke string. Ini dapat dihindari dengan menggunakan T () seperti pada contoh berikut:

="Text"&T(STYLE("myStyle"))

Lihat juga CURRENT() untuk contoh lain.

## VLOOKUP

Vertical search with reference to adjacent cells to the right. This function checks if a specific value is contained in the first column of an array. The function then returns the value in the same row of the column named by Index. If the Sorted parameter is omitted or set to TRUE or one, it is assumed that the data is sorted in ascending order. In this case, if the exact Lookup is not found, the last value that is smaller than the criterion will be returned. If Sorted is set to FALSE or zero, an exact match must be found, otherwise the error Error: Value Not Available will be the result. Thus with a value of zero the data does not need to be sorted in ascending order.

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every character with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in LibreOffice - PreferencesTools - Options - LibreOffice Calc - Calculate.

When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".

#### Sintaksis

=VLOOKUP(Lookup; Array; Index [; SortedRangeLookup])

Lookup is the value of any type looked for in the first column of the array.

Array is the reference, which is to comprise at least as many columns as the number passed in Index argument.

Index adalah jumlah kolom dalam array yang berisi nilai yang akan dikembalikan. Kolom pertama memiliki nomor 1.

SortedRangeLookup is an optional parameter that indicates whether the first column in the array contains range boundaries instead of plain values. In this mode, the lookup returns the value in the row with first column having value equal to or less than Lookup. E.g., it could contain dates when some tax value had been changed, and so the values represent starting dates of a period when a specific tax value was effective. Thus, searching for a date that is absent in the first array column, but falls between some existing boundary dates, would give the lower of them, allowing to find out the data being effective to the searched date. Enter the Boolean value FALSE or zero if the first column is not a range boundary list. When this parameter is TRUE or not given, the first column in the array must be sorted in ascending order. Sorted columns can be searched much faster and the function always returns a value, even if the search value was not matched exactly, if it is greater than the lowest value of the sorted list. In unsorted lists, the search value must be matched exactly. Otherwise the function will return #N/A with message: Error: Value Not Available.

Penanganan Sel Kosong

#### Contoh

Anda ingin memasukkan nomor piringan pada menu di sel A1, dan nama piringan tersebut segera muncul sebagai teks di sel tetangga (B1). Penugasan Number to Name terkandung dalam array D1:E100. D1 berisi 100, E1 berisi nama Vegetable Soup, dan sebagainya, untuk 100 item menu. Angka-angka dalam kolom D diurutkan dalam urutan menaik; dengan demikian, parameter Diurutkan opsional tidak diperlukan.

Masukkan rumus berikut pada B1:

=VLOOKUP(A1;D1:E100;2)

Segera setelah anda memasukkan angka dalam A1 B1 akan menampilkan teks yang sesuai yang terkandung dalam kolom referensi kedua D1:E100. Memasukkan nomor yang tidak ada akan menampilkan teks dengan nomor berikutnya di bawah. Untuk mencegah hal ini, masukkan FALSE sebagai parameter terakhir dalam rumus sehingga pesan kesalahan dihasilkan ketika nomor yang tidak ada dimasukkan.

Topik Terkait

Fungsi berdasarkan kategor