Contenu
Index 🔎︎

# Fonctions de texte

Cette section décrit les fonctions de texte.

Pour accéder à cette commande...

Insertion - Fonction - Catégorie Texte

## REGEX

Recherche et extrait ou facultativement remplace le texte en utilisant des expressions régulières.

### SERVICEWEB

Obtenez du contenu web à partir d'une URI.

### FILTREXML

Applique une expression XPath à un document XML.

### ENCODEURL

Renvoie une chaîne encodée en URL.

## ARABE

Calcule la valeur d'un chiffre romain. La plage de valeurs doit être comprise entre 0 et 3 999.

#### Syntaxe

ARABE("Texte")

Texte est le texte représentant le nombre en chiffres romains.

#### Exemple

=ARABE("MXIV") renvoie 1014

=ARABE("MMII") renvoie 2002

## ASC

La fonction ASC convertit des caractères ASCII et katakana pleine-chasse en caractères demi-chasse. Elle renvoie une chaîne de texte.

Voir https://wiki.documentfoundation.org/Calc/Features/JIS_and_ASC_functions pour une table de conversion.

#### Syntaxe

ASC("Texte")

Texte est le texte qui contient des caractères à convertir.

Voir également la fonction JIS.

## BAHTTEXT

Convertit un numéro en texte thaï, y compris les noms de devises thaïs.

#### Syntaxe

BAHTTEXT(nombre)

nombre correspond à un nombre quelconque. "Baht" est ajouté à la partie entière du nombre et "Satang" à sa partie décimale.

#### Exemple

=BAHTTEXT(12,65) renvoie une chaîne en caractères Thaï avec la signification de "Douze Baht et soixante-cinq Satang".

## BASE

Convertit un entier positif en texte du système de numérotation vers la base spécifiée. Les chiffres 0 à 9 et les lettres A à Z sont utilisés.

#### Syntaxe

BASE(nombre; racine[;longueur_minimum])

nombre est le nombre entier positif à convertir.

racine indique la base du système de nombre. Cela peut être n'importe quel nombre entier positif entre 2 et 36.

longueur_minimum (facultatif) détermine la longueur minimum de la séquence de caractères qui a été créée. Si le texte est plus court que la longueur minimum indiquée, des zéros sont ajoutés à la gauche de la chaîne.

#### Exemple

=BASE(17;10;4) renvoie 0017 dans le système décimal.

=BASE(17;2) renvoie 10001 dans le système binaire.

=BASE(255;16;4) renvoie 00FF dans le système hexadécimal.

## CAR

Convertit un nombre en caractère en fonction du tableau de code actif. Il peut s'agir d'un nombre entier à deux ou trois chiffres.

Les codes supérieurs à 127 dépendent du mappage de caractères de votre système (par exemple iso-8859-1, iso-8859-2, Windows-1252, Windows-1250) et ne sont donc peut-être pas transférables.

#### Syntaxe

CAR(nombre)

nombre est un nombre entre 1 et 255 représentant la valeur de code du caractère.

#### Exemple

=CAR(100) renvoie le caractère d.

="abc" & CAR(10) & "def" insère un caractère de saut de ligne dans une chaîne.

## CHERCHE

Renvoie l'emplacement d'un segment de texte dans une chaîne de caractères. Vous pouvez facultativement définir le point de départ de la recherche. Le texte recherché peut être un nombre ou toute autre séquence de caractères. La recherche ne respecte pas la casse. Si le texte n'est pas trouvé, l'erreur 519 (#VALEUR) est renvoyée.

La recherche prend en charge les caractères génériques ou les expressions régulières . Lorsque les expressions régulières sont activées, vous pouvez saisir "tous. *", Par exemple pour trouver le premier emplacement de "tous" suivi de n'importe quel caractère. Si vous souhaitez rechercher un texte qui est également une expression régulière, vous devez soit précéder chaque caractère d'un caractère "\", soit placer le texte dans \Q ...\E. Vous pouvez activer ou désactiver l'évaluation automatique des caractères génériques ou des expressions régulières dans LibreOffice - PréférencesOutils - Options - LibreOffice Calc - Calculer .

Lorsque vous utilisez des fonctions où un ou plusieurs arguments sont des chaînes de critères de recherche qui représentent une expression régulière, la première tentative consiste à convertir les critères de chaîne en nombres. Par exemple, ".0" se convertira en 0.0 et ainsi de suite. En cas de succès, la correspondance ne sera pas une correspondance d'expression régulière mais une correspondance numérique. Cependant, lorsque vous passez à un environnement local où le séparateur décimal n'est pas le point, la conversion d'expression régulière fonctionne. Pour forcer l'évaluation de l'expression régulière au lieu d'une expression numérique, utilisez une expression qui ne peut pas être mal interprétée comme numérique, telle que ". [0]" ou ".\0" ou "(?I) .0".

#### Syntaxe

CHERCHE("texte_cherché";"texte"[;position])

Texte_cherché est le texte à rechercher.

Texte est le texte où la recherche va prendre place.

position (facultatif) est la position où la recherche doit commencer dans le texte.

#### Exemple

=CHERCHE(54;998877665544) renvoie 10.

## CNUM

Convertit une chaîne de texte en nombre.

#### Syntaxe

CNUM("Texte")

Texte est le texte à convertir en nombre.

#### Exemple

=CNUM("4321") renvoie 4321.

## CODE

Renvoie le numéro de code du premier caractère du texte.

#### Syntaxe

CODE("Texte")

Texte représente le texte dont vous voulez obtenir le code du premier caractère.

Les codes supérieurs à 127 dépendent du mappage de caractères de votre système (par exemple iso-8859-1, iso-8859-2, Windows-1252, Windows-1250) et ne sont donc peut-être pas transférables.

#### Exemple

=CODE("Hieronymus") renvoie 72, =CODE("hieroglyphique") renvoie 104.

Le code utilisé à ce niveau n'est pas le code ASCII, mais le code de la table de codes active.

## CONCATENER

Combine plusieurs chaînes de texte pour n'en former qu'une.

#### Syntaxe

CONCATENER(chaîne1[;chaîne2[;...[;chaîne255]]])

chaîne1[;chaîne2][;...;[chaîne255]] sont des chaînes ou références à des cellules contenant des chaînes.

#### Exemple

=CONCATENER("Bonne ";"journée ";"Mme ";"Sanou") renvoie : Bonne journée Mme Sanou.

## CTXT

Renvoie un nombre en tant que texte avec un nombre défini de décimales et des séparateurs de milliers facultatifs.

#### Syntaxe

CTXT(nombre;[décimales[;pas_de_séparateurs_de_milliers=FAUX]])

nombre est arrondi à Décimales (après le séparateur décimal) et le résultat est formaté sous forme de texte, en utilisant les paramètres spécifiques aux paramètres régionaux.

Décimales (facultatif) fait référence au nombre de décimales à afficher. Si Décimales est négatif, nombre est arrondi à ABS(Décimales) placé à gauche de la virgule décimale. Si Décimales est une fraction, elle est tronquée en ignorant en fait quel est l'entier le plus proche.

pas de séparateur de milliers (facultatif) détermine si le séparateur des milliers est utilisé. S'il est VRAI ou différent de zéro, les séparateurs de groupe sont omis de la chaîne résultante. Si le paramètre est égal à 0 ou s'il est totalement absent, les séparateurs de milliers des paramètres régionaux actuels sont affichés.

#### Exemple

=CTXT(1234567,89;3) renvoie 1 234 567,890 comme chaîne de texte.

=CTXT(123456,789;;VRAI) renvoie 123456,79 comme chaîne de texte.

=CTXT(12345,6789;-2) renvoie 12 300 comme chaîne de texte.

=CTXT(1234567,89;-3;1) renvoie 12135000 comme chaîne de texte.

=CTXT(12345,789;3/4) renvoie 12 346 comme chaîne de texte.

=CTXT(12345,789;8/5) renvoie 12 345,8 comme chaîne de texte.

## DECIMAL

Convertit du texte avec des caractères d'un système de nombre en un nombre entier positif dans la base racine donnée. La racine doit être dans la plage 2 à 36. Les espaces et les tabulations sont ignorés. Le champ Texte n'est pas sensible à la casse.

Si la racine est 16, un x ou X de début, un 0x ou 0X de début ou un h ou H de fin sont ignorés. Si la racine est 2, un b ou un B de fin est ignoré. Les caractères ne faisant pas partie du système de numération génèrent une erreur.

#### Syntaxe

DECIMAL("Texte";racine)

Texte est le texte devant être converti. Pour faire la différence entre un nombre hexadécimal, comme A1 et la référence à la cellule A1, vous devez placer le nombre entre guillemets doubles, par exemple "A1" ou "FACE".

racine indique la base du système de nombre. Cela peut être n'importe quel nombre entier positif entre 2 et 36.

#### Exemple

=DECIMAL("17";10) renvoie 17.

=DECIMAL("FACE";16) renvoie 64206.

=DECIMAL("0101";2) renvoie 5.

## DROITE

Renvoie le ou les derniers caractères d'un texte.

#### Syntaxe

DROITE("Texte"[;nombre])

Texte est le texte dont la partie droite doit être déterminée.

nombre (facultatif) est le nombre de caractères de la partie à droite du texte.

#### Exemple

=DROITE("Son";2) renvoie on.

## DROITEB

Renvoie le ou les derniers caractères d'un texte en ensembles de doubles octets de caractères (DBCS).

Cette fonction est disponible depuis la version 4.2 de LibreOffice.

#### Syntaxe

DROITEB("Texte"[;nombre_octets])

Texte est le texte dont la partie droite doit être déterminée.

nombre_octets (facultatif) indique le nombre de caractères que DROITEB doit extraire, basé en octets.

#### Exemple

DROITEB("中国";1) renvoie " " (1 octet est seulement la moitié d'un caractère DBCS et un caractère d'espace est renvoyé à la place).

DROITEB("中国";2) renvoie "国" (2 octets constituent un caractère DBCS complet).

DROITEB("中国";3) renvoie " 国" (3 octets constituent un demi caractère DBCS et un caractère DBCS complet ; un espace est renvoyé pour la première moitié).

DROITEB("中国";4) renvoie "中国" (4 octets constituent deux caractère DBCS complets).

DROITEB("bureau";3) renvoie "eau" (3 caractère non-DBCS, chacun constitué de 1 octet).

## EPURAGE

Tous les caractères non imprimables sont supprimés de la chaîne.

#### Syntaxe

EPURAGE("Texte")

Texte réfère au texte duquel doit être retiré tous caractères non imprimables.

#### Exemple

=NBCAR(EPURAGE(CAR(7) & "LibreOffice Calc" & CAR(8))) renvoie 16, montrant que la fonction EPURAGE supprime les caractères Unicode non imprimables U+0007 ("BEL") et U+0008 ("BS") au début et à la fin de l'argument de chaîne. EPURAGE ne supprime pas les espaces.

## EXACT

Compare deux chaînes de texte et renvoie la valeur VRAI si elles sont identiques. Cette fonction est sensible à la casse.

#### Syntaxe

EXACT("Texte_1"; "Texte_2")

Texte_1 réfère au premier texte à comparer.

Texte_2 est le second texte à comparer.

#### Exemple

=EXACT("microsystems";"Microsystems") renvoie FAUX.

## FRANC

Convertit un nombre en un montant dans le format monétaire, arrondi à une décimale spécifiée. Dans le champ valeur, saisissez le nombre à convertir en une monnaie. Facultativement, vous pouvez saisir un nombre de décimales dans le champ décimales. Si aucune valeur n'est spécifiée, tous les nombres au format monétaire seront affichés avec deux décimales.

Vous pouvez définir le format monétaire dans les paramètres du système.

#### Syntaxe

FRANC(valeur[;décimales])

valeur est un nombre, une référence à une cellule contenant un nombre ou une formule qui renvoie un nombre.

décimalesest le nombre facultatif de décimales.

#### Exemple

=FRANC(255) renvoie $255.00 pour la locale Anglais (USA) et la monnaie USD (dollar) ; ￥255.00 pour la locale japonaise et la monnaie JPY (yen) ; 255,00 € pour la locale allemande (Allemagne) et la monnaie EUR (euro).

=FRANC(367,456;2) renvoie 367,46F. Utilisez le séparateur décimal qui correspond au paramétrage de la locale actuel.

## GAUCHE

Renvoie le ou les premiers caractères d'un texte.

#### Syntaxe

GAUCHE("Texte"[;nombre])

Texte est le texte duquel les mots initiaux partiels doivent être déterminés.

nombre (facultatif) indique le nombre de caractères du texte de départ. Si ce paramètre n'est pas défini, un seul caractère est renvoyé.

#### Exemple

=GAUCHE("sortie";3) renvoie “sor”.

## GAUCHEB

Renvoie le premier caractère d'un texte DBCS (Double Byte Character Set).

Cette fonction est disponible depuis la version 4.2 de LibreOffice.

#### Syntaxe

GAUCHEB("Texte"[;nombre_octets])

Texte est le texte duquel les mots initiaux partiels doivent être déterminés.

nombre_octets (facultatif) indique le nombre de caractères qui doivent être extraits par GAUCHEB, basé sur les octets. Si ce paramètre n'est pas défini, un caractère est renvoyé.

#### Exemple

GAUCHEB("中国";1) renvoie " " (1 octet est seulement la moitié d'un caractère DBCS et un caractère d'espace est renvoyé à la place).

GAUCHEB("中国";2) renvoie "中" (2 octets constituent un caractère DBCS complet).

GAUCHEB("中国";3) renvoie "中 " (3 octets constituent un caractère DBCS et demi ; le dernier caractère renvoyé est alors un caractère d'espace.)

GAUCHEB("中国";4) renvoie "中国" (4 octets constituent deux caractères DBCS complets).

GAUCHEB("bureau";3) renvoie "bur" (3 caractères non-DBCS chacun consistant en 1 byte).

## JIS

La fonction JIS convertit des caractères ASCII et katakana demi-chasse en caractères pleine-chasse. Elle renvoie une chaîne de texte.

Voir https://wiki.documentfoundation.org/Calc/Features/JIS_and_ASC_functions pour une table de conversion.

#### Syntaxe

JIS("Texte")

Texte est le texte qui contient des caractères à convertir.

Voir également la fonction ASC.

## MAJUSCULE

Convertit en majuscules la chaîne indiquée dans le champ texte.

#### Syntaxe

MAJUSCULE("Texte")

Texte réfère aux lettres en minuscules à convertir en majuscules.

#### Exemple

=MAJUSCULE("Bonne journée") renvoie BONNE JOURNÉE.

## MINUSCULE

Convertit toutes les majuscules d'une chaîne de caractères en minuscules.

#### Syntaxe

MINUSCULE("Texte")

Texte réfère au texte à convertir.

#### Exemple

=MINUSCULE("Son") renvoie son.

## NBCAR

Renvoie la longueur d'une chaîne en incluant les espaces.

#### Syntaxe

NBCAR("Texte")

Texte est le texte dont vous voulez déterminer la longueur.

#### Exemple

=NBCAR("Bon après-midi") renvoie 14.

=NBCAR(12345,67) renvoie 8.

## NBCARB

Pour les langues à ensembles de caractères sur deux octets (DBCS), renvoie le nombre d'octets utilisés pour représentes les caractères dans une chaîne de texte.

Cette fonction est disponible depuis la version 4.2 de LibreOffice.

#### Syntaxe

NBCARB("Texte")

Texte est le texte dont vous voulez déterminer la longueur.

#### Exemple

NBCARB("中") renvoie 2 (1 caractère DBCS constitué de 2 octets).

NBCARB("中国") renvoie 4 (2 caractères DBCS chacun constitué de 2 octets).

GAUCHEB("bureau") renvoie 6 (6 caractère non-DBCS chacun constitué d'1 octet).

=NBCARB("Bon après-midi") renvoie 14.

=NBCARB(12345.67) renvoie 8.

## NOMPROPRE

Met la première lettre de tous les mots d'une chaîne en majuscules.

#### Syntaxe

NOMPROPRE("Texte")

Texte réfère au texte à convertir.

#### Exemple

=NOMPROPRE("the document foundation" renvoie The Document Foundation.

## REPLACE

Remplace une partie de la chaîne de texte par une chaîne de texte différente. Cette fonction sert à remplacer les caractères et les nombres, qui sont automatiquement convertis en texte. Le résultat de cette fonction s'affiche toujours en tant que texte. Si vous souhaitez effectuer d'autres calculs avec un nombre qui a été remplacé par du texte, vous devrez le reconvertir en nombre en utilisant la fonction CNUM.

Tout texte contenant des nombres doit être saisi entre guillemets, faute de quoi il est interprété comme un nombre et automatiquement converti en texte.

#### Syntaxe

REMPLACER("Texte";position;longueur;"Nouveau_texte")

Texte réfère au texte dont une partie doit être remplacée.

position réfère à la position où le remplacement va débuter dans le texte.

longueur est le nombre de caractères à remplacer dans le texte.

Nouveau_texte réfère au texte qui remplace le Texte.

#### Exemple

=REMPLACER("1234567";1;1;"444") renvoie "444234567". Un caractère à la position 1 est remplacé par le Nouveau_texte complet.

## REPT

Répète une chaîne de caractères selon le nombre de fois spécifié.

#### Syntaxe

REPT("Texte";nombre)

Texte est le texte à répéter.

nombre est le nombre à tester.

Le résultat ne doit pas dépasser 255 caractères.

#### Exemple

=REPT("Bonne journée";2) renvoie Bonne journéeBonne journée.

## ROMAIN

Convertit un nombre en chiffres romains. La plage de valeurs doit être comprise entre 0 et 3 999. Le mode peut être un nombre entier compris entre 0 et 4.

#### Syntaxe

ROMAIN(nombre{;mode])

nombre représente le nombre à convertir en chiffres romains.

mode (facultatif) spécifie le degré de simplification. Plus la valeur est élevée, plus le nombre en chiffres romains sera simplifié.

#### Exemple

=ROMAIN(999) renvoie CMXCIX

=ROMAIN(999;0) renvoie CMXCIX

=ROMAIN(999;1) renvoie LMVLIV

=ROMAIN(999;2) renvoie XMIX

=ROMAIN(999;3) renvoie VMIV

=ROMAIN(999;4) renvoie IM

## STXT

Renvoie une chaîne d'un texte. Les paramètres indiquent le point de départ et le nombre de caractères.

#### Syntaxe

STXT("Texte";début;nombre)

Texte est le texte contenant les caractères à extraire.

début est la position du premier caractère dans le texte à extraire.

nombre spécifie le nombre de caractères dans la partie de texte.

#### Exemple

=STXT("office";2;2) renvoie ff.

## STXTB

Renvoie une chaîne de texte d'un texte DBCS. Les paramètres indiquent la position de départ et le nombre de caractères.

Cette fonction est disponible depuis la version 4.2 de LibreOffice.

#### Syntaxe

STXTB("Texte";début;nombre_octets)

Texte est le texte contenant les caractères à extraire.

début est la position du premier caractère dans le texte à extraire.

nombre_octets indique le nombre de caractère que STXTB renvoie à partir du texte, en octets.

#### Exemple

STXTB("中国";1;0) renvoie "" (0 octet est toujours une chaîne vide).

STXTB("中国";1;1) renvoie " " (1 octet est seulement la moitié d'un caractère DBCS et donc le résultat est un caractère d'espace).

STXTB("中国";1;2) renvoie "中" (2 octets constituent un caractère DBCS complet).

STXTB("中国";1;3) renvoie "中 " (3 octets constituent un caractère DBCS et demi, le dernier octet résulte en un caractère d'espace).

STXTB("中国";1;4) renvoie "中国" (4 octets constituent deux caractères DBCS complets).

STXTB("中国";2;1) renvoie " " (la position 2 de l'octet n'est pas au début d'un caractère dans une chaîne DBCS ; 1 caractère d'espace est renvoyé).

STXTB("中国";2;2) renvoie " " (la position 2 de l'octet pointe la dernière moitié du premier caractère dans la chaîne DBCS ; les 2 octets demandés pour constituer la dernière moitié du premier caractère et la première moitié du deuxième caractère dans la chaîne ; 2 caractères d'espace sont donc renvoyés).

STXTB("中国";2;3) renvoie " 国" (l'octet en position 2 n'est pas au début d'un caractère dans une chaîne DBCS ; un caractère d'espace est renvoyé pour l'octet en position 2).

STXTB("中国";3;1) renvoie " " (l'octet en position 3 est au début d'un caractère dans une chaîne DBCS, mais 1 octet correspond seulement à la moitié d'un caractère DBCS et un caractère d'espace est donc renvoyé à la place).

STXTB("中国";3;2) renvoie "国" (l'octet en position 3 est au début d'un caractère dans une chaîne DBCS, et 2 octets constituent un caractère DBCS).

STXTB("bureau";2;3) renvoie "ure" (l'octet à la position 2 est au début d'un caractère dans une chaîne non-DBCS, et 3 octets d'une chaîne non-DBCS constituent 3 caractères).

## SUBSTITUE

Remplace l'ancien texte par le nouveau texte dans une chaîne.

#### Syntaxe

SUBSTITUE("texte";"texte_cherché";"nouveau_texte"[;occurrence])

Texte est le texte dans lequel le segment de texte doit être échangé.

Texte_cherché est le segment de texte qui doit être remplacé (un certain nombre de fois).

Nouveau_texte est le texte qui doit remplacer le segment de texte.

occurrence (facultatif) indique quelle occurrence du texte recherché doit être remplacée. Si ce paramètre est manquant, le texte recherché est remplacé partout.

#### Exemple

=SUBSTITUE("123123123";"3";"abc") renvoie 12abc12abc12abc.

=SUBSTITUE("123123123";"3";"abc";2) renvoie 12312abc123.

## SUPPRESPACE

Supprime les espaces d'une chaîne, les mots sont alors séparés par un seul caractère d'espacement.

#### Syntaxe

SUPRESPACE("Texte")

Texte désigne le texte dans lequel les espaces sont supprimés.

#### Exemple

=SUPRESPACE(" coucou le monde ") renvoie coucou le monde sans les espaces avant ou après et avec un seul espace entre les mots.

## T

Cette fonction renvoie le texte cible ou une chaîne vide si la cible n'est pas du texte.

#### Syntaxe

T(valeur)

Si valeur est une chaîne de texte ou réfère à une chaîne de texte, T renvoie cette chaîne de texte, sinon elle renvoie une chaîne de texte vide.

#### Exemple

=T(12345) renvoie une chaîne vide.

=T("12345") renvoie la chaîne 12345.

## TEXTE

Convertit un nombre en texte selon un format spécifié.

#### Syntaxe

TEXTE(valeur;format)

valeur est la valeur (numérique ou textuelle) à convertir.

format est le texte définissant le format. Utilisez les décimales et les séparateurs de milliers correspondant à la langue définie dans le format de cellule.

#### Exemple

=TEXTE(12,34567;"###,##") renvoie le texte 12,35

=TEXTE(12,34567;"000,00") renvoie le texte 012,35

=TEXTE("xyz";"=== @ ===") renvoie le texte === xyz ===

Voir également Codes de format de nombre : codes de format personnalisé définis par l'utilisateur.

## TROUVE

Renvoie la position d'une chaîne de texte dans une autre chaîne. Vous pouvez également définir l'endroit à partir duquel la recherche doit être lancée. Le terme recherché peut être un nombre ou une chaîne de caractères. La recherche respecte la casse.

#### Syntaxe

TROUVE("Texte_à_trouver";"Texte"[;position])

Texte_à_trouver réfère au texte à trouver.

Texte est le texte dans lequel la recherche prend place.

position (facultatif) est la position dans le texte à partir de laquelle la recherche commence.

#### Exemple

=TROUVE(76;998877665544) renvoie 6.

## UNICAR

Convertit un numéro de code en un caractère ou une lettre Unicode.

#### Syntaxe

UNICAR(nombre)

#### Exemple

=UNICAR(169) renvoie le caractère de copyright ©.

Voir également la fonction UNICODE().

## UNICODE

Renvoie le numéro de code du premier caractère Unicode d'une chaîne de texte.

#### Syntaxe

UNICODE("Texte")

#### Exemple

=UNICODE("©") renvoie le numéro Unicode 169 du caractère de copyright.

Voir également la fonction UNICAR().

Rubriques connexes

Fonctions par catégories