Obsah
Rejstřík 🔎︎

# Finanční funkce – první část

Tato kategorie obsahuje matematické finanční funkce LibreOffice Calc.

## ACCRINT

Spočítá nahromaděný úrok z cenného papíru v případě pravidelných plateb.

#### Syntaxe

ACCRINT(Vydání; První úrok; Vypořádání; Sazba; [Nominál]; Frekvence [;Základ])

Vydání (vyžadováno) je datum emise cenného papíru.

První úrok (vyžadováno) je datum prvního výnosu cenného papíru.

Vypořádání (vyžadováno) je datum, ve kterém se počítají do té doby nahromaděné úroky.

Sazba (vyžadováno) je roční nominální sazba úroku (sazba úroku kuponu)

Nominál (nepovinné) je nominální hodnota cenného papíru. Není-li zadána, použije se výchozí hodnota 1000.

Doporučuje se hodnotu argumentu Nominál funkce ACCRINT vždy uvádět a neponechávat v Calcu nastavenou výchozí hodnotu. Díky tomu bude vzorec pochopitelnější a bude se snadněji udržovat.

Frekvence (vyžadováno) je počet výplat úroků za rok (1, 2 nebo 4).

Metoda (volitelné) se vybírá ze seznamu možností a určuje, jak se počítá rok.

Metoda | Výpočty
0 nebo nezadáno | Metoda US (NASD), 12 měsíců po 30 dnech
1 | Přesný počet dní v měsíci, přesný počet dní v roce.
2 | Přesný počet dní v měsíci, rok má 360 dní.
3 | Přesný počet dní v měsíci, rok má 365 dní.
4 | Evropská metoda, 12 měsíců po 30 dnech

#### Příklad

Cenný papír je vydán dne 2001-02-28. Datum prvního výnosu je nastaveno na 2001-08-31. Den vypořádání je 2001-05-01. Sazba činí 0.1 neboli 10 % a nominální hodnota je 1000 měnových jednotek. Úrok je placen jednou za půl roku (frekvence je 2). Používá se metoda US (0). Jaký úrok se nashromáždí?

=ACCRINT("2001-02-28";"2001-08-31";"2001-05-01";0,1;1000;2;0) vrátí 16,94444.

## ACCRINTM

Spočítá nahromaděný úrok z cenného papíru, u kterého se úrok splácí k datu splatnosti.

#### Syntaxe

ACCRINTM(Vydání; Vypořádání; Sazba [; Nominál [;Základ]])

Vydání (vyžadováno) je datum emise cenného papíru.

Vypořádání (vyžadováno) je datum, ve kterém se počítají do té doby nahromaděné úroky.

Sazba (vyžadováno) je roční nominální sazba úroku (sazba úroku kuponu)

Nominál (nepovinné) je nominální hodnota cenného papíru. Není-li zadána, použije se výchozí hodnota 1000.

Doporučuje se hodnotu argumentu Nominál funkce ACCRINTM vždy uvádět a neponechávat v Calcu nastavenou výchozí hodnotu. Díky tomu bude vzorec pochopitelnější a bude se snadněji udržovat.

Metoda (volitelné) se vybírá ze seznamu možností a určuje, jak se počítá rok.

Metoda | Výpočty
0 nebo nezadáno | Metoda US (NASD), 12 měsíců po 30 dnech
1 | Přesný počet dní v měsíci, přesný počet dní v roce.
2 | Přesný počet dní v měsíci, rok má 360 dní.
3 | Přesný počet dní v měsíci, rok má 365 dní.
4 | Evropská metoda, 12 měsíců po 30 dnech

#### Příklad

Cenný papír je vydán dne 2001-04-01. Datum splatnosti je nastaveno na 2001-06-15. Sazba činí 0.1 neboli 10 % a nominální hodnota je 1000 měnových jednotek. Používá se metoda denního zůstatku (3). Jaký úrok se nashromáždí?

=ACCRINTM("2001-04-01";"2001-06-15";0,1;1000;3) vrátí 20,54795.

## AMORDEGRC

Spočítá výši odpisu pro odpisové období jako degresivní amortizaci. Na rozdíl od AMORLINC se zde používá odpisový koeficient, který je nezávislý na životnosti.

#### Syntaxe

AMORDEGRC(Náklady; Datum nákupu; První období; Zůstatek; Období; Sazba [;Základ])

Náklady jsou náklady na nákup.

Datum nákupu je datum nákupu.

První období je koncové datum prvního období.

Zůstatek je zůstatková cena majetku na konci životnosti.

Období je uvažované období.

Sazba je odpisová sazba.

Metoda (volitelné) se vybírá ze seznamu možností a určuje, jak se počítá rok.

Metoda | Výpočty
0 nebo nezadáno | Metoda US (NASD), 12 měsíců po 30 dnech
1 | Přesný počet dní v měsíci, přesný počet dní v roce.
2 | Přesný počet dní v měsíci, rok má 360 dní.
3 | Přesný počet dní v měsíci, rok má 365 dní.
4 | Evropská metoda, 12 měsíců po 30 dnech

#### Příklad

Majetek byl pořízen dne 2020-02-01 za cenu 2000 měnových jednotek. Koncové datum prvního období bylo 2020-12-31. Zůstatková cena majetku na konci jeho životnosti bude 10 měnových jednotek. Odpisová sazba činí 0,1 (10 %) a rok se počítá pomocí metody US (Základ 0). Jaká bude výše odpisu za čtvrté období za předpokladu degresivní amortizace?

=AMORDEGRC(2000; "2020-02-01"; "2020-12-31"; 10; 4; 0,1; 0) vrátí výši odpisu 163 měnových jednotek.

Mějte na paměti, že Základ 2 není podporován aplikací Microsoft Excel. Pokud jej použijete a dokument exportujete do formátu XLSX, při otevření v Excelu se vrátí chyba.

## AMORLINC

Spočítá výši odpisu pro odpisové období jako lineární amortizaci. Jestliže je kapitálový prostředek zakoupen během odpisového období, použije se proporcionální výše odpisu.

#### Syntaxe

AMORLINC(Náklady; Datum nákupu; První období; Zůstatek; Období; Sazba [;Základ])

Náklady znamenají náklady na nákup.

Datum nákupu je datum nákupu.

První období je koncové datum prvního období.

Zůstatek je zůstatková cena majetku na konci životnosti.

Období je uvažované období.

Sazbaje odpisová sazba.

Metoda (volitelné) se vybírá ze seznamu možností a určuje, jak se počítá rok.

Metoda | Výpočty
0 nebo nezadáno | Metoda US (NASD), 12 měsíců po 30 dnech
1 | Přesný počet dní v měsíci, přesný počet dní v roce.
2 | Přesný počet dní v měsíci, rok má 360 dní.
3 | Přesný počet dní v měsíci, rok má 365 dní.
4 | Evropská metoda, 12 měsíců po 30 dnech

#### Příklad

Majetek byl pořízen dne 2020-02-01 za cenu 2000 měnových jednotek. Koncové datum prvního období bylo 2020-12-31. Zůstatková cena majetku na konci jeho životnosti bude 10 měnových jednotek. Odpisová sazba činí 0,1 (10 %) a rok se počítá pomocí metody US (Základ 0). Jaká bude výše odpisu za čtvrté období za předpokladu lineární amortizace?

=AMORLINC(2000; "2020-02-01"; "2020-12-31"; 10; 4; 0,1; 0) vrátí výši odpisu 200 měnových jednotek.

Mějte na paměti, že Základ 2 není podporován aplikací Microsoft Excel. Pokud jej použijete a dokument exportujete do formátu XLSX, při otevření v Excelu se vrátí chyba.

## DB

Vrátí odpisy aktiva pro zadané časové období při použití geometrické degresivní metody.

Tato metoda odepisování se používá v případě, že chcete, aby hodnota odpisu byla větší na začátku doby odepisování (na rozdíl od lineárního odpisu). Hodnota odpisu se snižuje s každým obdobím odepisování o odpis již odečtený z pořizovací hodnoty.

#### Syntaxe

DB(Cena; Zůstatek; Životnost; Období [; Měsíc])

Cena je počáteční hodnota majetku.

Zůstatek je hodnota majetku na konci odpisů.

Životnost určuje období, během kterého se majetek odepisuje.

Období je délka každého období. Délka musí být zadána ve stejných jednotkách jako doba životnosti.

Měsíc (nepovinné) značí počet měsíců pro první rok odpisů. Není-li určen, použije se výchozí hodnota 12.

#### Příklad

Počítačová sestava s počáteční cenou 25 000 měnových jednotek má životnost tři roky. Zůstatková cena má být 1000 měnových jednotek. První období odpisů trvá 6 měsíců. Jaký je geometrický degresivní odpis této sestavy ve druhém období, které trvá celý rok a začíná od konce prvního, šestiměsíčního období?

=DB(25000; 1000; 3; 2; 6) vrátí 11 037,95 měnových jednotek.

## DDB

Vrátí odpisy aktiva pro zadané časové období při použití aritmetické degresivní metody.

Použijte tuto formu odpisů, pokud požadujete vyšší počáteční hodnotu odpisu (na rozdíl od lineárního odpisování). Výše odpisů se snižuje každé období. Obvykle se používá u aktiv, u kterých krátce po koupi výrazněji klesá hodnota (například auta, počítače). Účetní hodnota při tomto typu výpočtu nikdy neklesne na nulu.

#### Syntaxe

DDB(Cena; Zůstatek; Životnost; Období [; Faktor])

Cena je počáteční hodnota majetku.

Zůstatek je hodnota majetku na konci životnosti.

Životnost je počet období (například let nebo měsíců), který určuje, jak dlouho se bude majetek používat.

Období udává období, pro které se hodnota počítá.

Faktor (nepovinné) je faktor, podle kterého se odepisování snižuje. Není-li jeho hodnota zadána, výchozí je 2.

#### Příklad

Počítačová sestava v pořizovací hodnotě 75 000 měnových jednotek má být odepisována každý měsíc po dobu pěti let. Hodnota na konci doby odepisování má být 1 měnová jednotka. Faktor je 2.

=DDB(75000;1;60;12;2) = 1,721.81 měnových jednotek. Klesající odpisy jsou tedy pro dvanáctý měsíc po nákupu rovny 1 721,81 měnovým jednotkám.

## DISC

Spočítá diskontní sazbu cenného papíru v procentech.

#### Syntaxe

DISC(Smlouva; Splatnost; Cena; Výkupní cena [;Základ])

Smlouva je datum nákupu cenného papíru.

Splatnost je datum, dokdy je cenný papír splatný (kdy vyprší).

Cena je cena cenného papíru za 100 měnových jednotek nominální hodnoty.

Výkupní cena je výkupní cena cenného papíru za 100 měnových jednotek nominální hodnoty.

Metoda (volitelné) se vybírá ze seznamu možností a určuje, jak se počítá rok.

Metoda | Výpočty
0 nebo nezadáno | Metoda US (NASD), 12 měsíců po 30 dnech
1 | Přesný počet dní v měsíci, přesný počet dní v roce.
2 | Přesný počet dní v měsíci, rok má 360 dní.
3 | Přesný počet dní v měsíci, rok má 365 dní.
4 | Evropská metoda, 12 měsíců po 30 dnech

#### Příklad

Cenný papír je koupen dne 2001-01-25; datum splatnosti je 2001-11-15. Cena (cena při nákupu) činí 97, výkupní cena je 100. Jak vysoká bude diskontní sazba při použití denního úročení (metoda 3)?

=DISC("2001-01-25";"2001-11-15";97;100;3) vrátí asi 0.0372 neboli 3.72 procent.

## DURATION

Spočítá dobu trvání (počet roků) pro cenný papír s fixní úrokovou sazbou.

#### Syntaxe

DURATION(Smlouva; Splatnost; Kupón; Výnos; Frekvence [; Základ])

Smlouva je datum nákupu cenného papíru.

Splatnost je datum, dokdy je cenný papír splatný (kdy vyprší).

Kupón je roční úroková míra kupónu (nominální úroková míra)

Výnos je roční výnos cenného papíru.

Frekvence je počet výplat úroků za rok (1, 2 nebo 4).

Metoda (volitelné) se vybírá ze seznamu možností a určuje, jak se počítá rok.

Metoda | Výpočty
0 nebo nezadáno | Metoda US (NASD), 12 měsíců po 30 dnech
1 | Přesný počet dní v měsíci, přesný počet dní v roce.
2 | Přesný počet dní v měsíci, rok má 360 dní.
3 | Přesný počet dní v měsíci, rok má 365 dní.
4 | Evropská metoda, 12 měsíců po 30 dnech

#### Příklad

Cenný papír byl nakoupen 2001-01-01; datum splatnosti je 2006-01-01. Nominální úroková sazba je 8 %. Výnos je 9,0 %. Úrok je vyplácen pololetně (frekvence je 2). S použitím výpočtu denní bilance úroku (základ 3), jaká je doba trvání?

=DURATION("2001-01-01";"2006-01-01";0,08;0,09;2;3) vrátí 4,2 roku.

## EFFECT

Vrátí roční čistou úrokovou sazbu pro nominální úrokovou sazbu.

Nominální úroky jsou chápány jako výše úroků splatných ke konci kalkulačního období. Efektivní úrok se zvyšuje s počtem plateb. Jinými slovy, úrok se často platí ve splátkách (například měsíčně nebo čtvrtletně) před koncem kalkulačního období.

#### Syntaxe

EFFECT(Nom; P)

Nom je nominální úrok.

P je počet období výplat úroků za rok.

#### Příklad

Roční nominální úroková sazba je 9,75 %. Jsou definována čtyři období výpočtu úroku. Jaká je skutečná úroková sazba (efektivní sazba)?

=EFFECT(9.75%;4) = 10.11% Roční efektivní sazba je tedy 10,11 %.

## EFFECT_ADD

Spočítá efektivní roční úrokovou míru na základě nominální roční úrokové míry a počtu úrokových plateb za rok.

Funkce, jejichž název končí na _ADD nebo _EXCEL2003, vrací stejné výsledky jako odpovídající funkce (bez přípony) programu Microsoft Excel 2003. Chcete-li získat výsledky podle mezinárodních standardů, použijte funkce bez přípon.

#### Syntaxe

EFFECT_ADD(Nominální míra; N za rok)

Nominální míra je roční nominální úroková míra.

N za rok je počet úrokových plateb za rok.

#### Příklad

Jaká je efektivní roční úroková sazba při nominální sazbě 5,25 % a čtvrtletních platbách?

=EFFECT_ADD(0.0525;4) vrátí 0.053543 nebo 5.3543%.

## IRR

Vypočítá vnitřní výnosové procento investice. Hodnoty reprezentují hodnoty peněžního toku v pravidelných intervalech, alespoň jedna hodnota musí být záporná (platby) a alespoň jedna hodnota musí být kladná (příjmy).

Pokud se platby uskutečňují v nepravidelných intervalech, použijte funkci XIRR.

#### Syntaxe

IRR(Hodnoty [; Odhad])

Hodnoty představují matici s hodnotami.

Odhad (nepovinné) je odhad hodnoty. Pro výpočet vnitřního výnosového procenta se použije iterační metoda. Pokud počítáte pouze s několika málo hodnotami, měli byste zadat počáteční odhad, aby iterace fungovala.

Tato funkce ignoruje veškerý text a prázdné buňky v oblasti dat. Jestliže se zdá, že funkce vrací chybné výsledky, vyhledejte v oblastech dat text. Textový obsah můžete zvýraznit pomocí zvýrazňování hodnot.

#### Příklad

Za předpokladu, že buňky obsahují hodnoty A1=-10000, A2=3500, A3=7600 and A4=1000, vrátí vzorec =IRR(A1:A4) výsledek 11,33 %.

Z důvodu použité iterační metoděy může IRR selhat a vrátit Error 523, s chybovou zprávou "Chyba: Výpočet nekonverguje" ve stavovém řádku. V takovém případě zkuste jinou hodnotu pro Odhad.

## ISPMT

Spočítá úrokovou míru při konstantní míře amortizace.

#### Syntaxe

ISPMT(Míra; Období; Celkem období; Investice)

Míra stanoví úrokovou míru za období.

Období je počet splátek pro výpočet úroku.

Celkem období je celkový počet období se splátkami.

Invest je investovaný obnos.

#### Příklad

Pro investici 120 000 měnových jednotek s dvouletým termínem a měsíčních splátkách je při roční úrokové míře 12% požadován úrok po 1,5 roce.

=ISPMT(1%;18;24;120000) = -300 měnových jednotek. Měsíční úrok po 1,5 roce činí 300 měnových jednotek.

## PV

Vrátí současnou hodnotu investice vycházející z posloupnosti pravidelných plateb.

Pomocí této funkce lze vypočítat finanční částku, kterou je při pevné sazbě třeba investovat, abyste v průběhu určitého období dostávali určitou částku (roční splátku). Také lze určit, jaká částka má zůstat po uplynutí daného období. Určete také, zda se má částka vyplácet na začátku, nebo na konci každého období.

Vložte tyto hodnoty buď jako čísla, nebo jako výrazy či odkazy. Je-li například ročně placen úrok ve výši 8% , ale vy chcete použít pouze období jeden měsíc, vložte 8%/12 jako Sazbu a LibreOffice Calc automaticky spočítá správnou hodnotu.

#### Syntaxe

PV(Sazba; NPER; PMT [;FV [; Typ]])

Sazba určuje úrokovou sazbu za období.

NPer je celkový počet období (období s platbou).

Pmt je pravidelná platba uskutečněná za období.

FV (nepovinné) určuje budoucí hodnotu zbývající poté, co se uskuteční poslední platba.

Typ (nepovinné) značí datum splatnosti pro platby. Typ = 1 znamená splatnost na začátku období a Type = 0 (výchozí) znamená splatnost na konci období.

Pokud jsou parametry funkcí LibreOffice Calc označeny jako "nepovinné", je možné je vynechat, pokud za nimi nenásledují žádné další parametry. Např. pokud má funkce čtyři parametry a poslední dva jsou označeny jako "nepovinné", je možné vynechat parametr 4 nebo parametry 3 a 4, ale není možné vynechat samotný parametr 3.

#### Příklad

Jaká je současná hodnota investice při měsíčních platbách pěti set měnových jednotek a roční úrokové míře 8 %? Platební období je 48 měsíců. Na jeho konci má zůstat 20 000 měnových jednotek.

=PV(8%/12;48;500;20000) = -35,019.37 měnových jednotek. Za těchto podmínek musíte dnes vložit 35,019.37 měnových jednotek, abyste obdrželi měsíčně 500 měnových jednotek po dobu 48 měsíců a aby na konci zůstalo 20,000 měnových jednotek. Kontrolní výpočet ukazuje, že 48 x 500 měnových jednotek + 20,000 měnových jednotek = 44,000 měnových jednotek. Rozdíl mezi tímto obnosem a 35,000 měnovými jednotkami vkladu představuje úroky.

Pokud místo těchto hodnot zadáte do vzorce odkazy, je možné vypočítat libovolný počet citlivostních analýz. Upozornění: Odkazy na konstanty musí být definovány jako absolutní odkazy. Příklady použití tohoto typu naleznete v odpisových funkcích.

## RECEIVED

Spočítá částku vyplacenou k danému datu splatnosti cenného papíru s pevným úrokem.

#### Syntaxe

RECEIVED(Smlouva; Splatnost; Investice; Diskontní sazba [; Základ])

Smlouva je datum nákupu cenného papíru.

Splatnost je datum, dokdy je cenný papír splatný (kdy vyprší).

Investice je nakoupený obnos.

Diskontní sazba je procentuální diskontní sazba při nákupu cenného papíru.

Metoda (volitelné) se vybírá ze seznamu možností a určuje, jak se počítá rok.

Metoda | Výpočty
0 nebo nezadáno | Metoda US (NASD), 12 měsíců po 30 dnech
1 | Přesný počet dní v měsíci, přesný počet dní v roce.
2 | Přesný počet dní v měsíci, rok má 360 dní.
3 | Přesný počet dní v měsíci, rok má 365 dní.
4 | Evropská metoda, 12 měsíců po 30 dnech

#### Příklad

Datum vypořádání: 15. února 1999. Datum splatnosti: 15. května 1999. Investovaná částka: 1 000 měnových jednotek. Diskontní sazba: 5,75 procent. Základ: denní zůstatek/360 = 2.

Částka vyplacená k datu splatnosti se počítá takto:

=RECEIVED("1999-02-15";"1999-05-15";1000;0,0575;2) vrátí 1014,420266.

## SYD

Vrátí hodnotu aritmetického degresivního odpisu.

Pomocí této funkce lze spočítat hodnotu odpisu za určené období z celkové doby odpisů objektu. Aritmeticky stanovená sazba degresivního odpisu snižuje v každém období hodnotu odpisu o pevnou částku.

#### Syntaxe

SYD(Cena;Zůstatek;Životnost;Období)

Cena je počáteční hodnota majetku.

Zůstatek je hodnota majetku po odpisech.

Životnost je období, během kterého je majetek odepisován.

Období určuje období, za které se odpisy počítají.

#### Příklad

Video přehrávač, jehož pořizovací cena byla 50 000 měnových jednotek, má být ročně odepisován po následujících 5 let. Zůstatková hodnota má být 10 000 měnových jednotek. Chcete spočítat odpis za první rok.

=SYD(50000;10000;5;1)=13,333.33 měnových jednotek. Odpis za první rok činí 13,333.33 měnových jednotek.

Pro přehled o odpisových sazbách je nejlepší definovat odpisovou tabulku. Vložíte-li vedle sebe různé odpisové vzorce, které jsou k dispozici v LibreOffice Calc, můžete potom rozhodnout, která forma odpisů je nejvhodnější. Vytvořte následující tabulku:

| A | B | C | D | E
1 | Počáteční cena | Hodnota zůstatku | Životnost | Období | Odpisy SYD
2 | 50 000 měnových jednotek | 10 000 měnových jednotek | 5 | 1 | 13 333,33 měnových jednotek
3 |  |  |  | 2 | 10 666,67 měnových jednotek
4 |  |  |  | 3 | 8 000,00 měnových jednotek
5 |  |  |  | 4 | 5 333,33 měnových jednotek
6 |  |  |  | 5 | 2 666,67 měnových jednotek
7 |  |  |  | 6 | 0,00 měnových jednotek
8 |  |  |  | 7 |
9 |  |  |  | 8 |
10 |  |  |  | 9 |
11 |  |  |  | 10 |
12 |  |  |  |  |
13 | >0 |  |  | Celkem | 40 000,00 měnových jednotek

Vzorec v buňce E2 je následující:

=SYD($A$2;$B$2;$C$2;D2)

Tento vzorec je duplikován ve sloupci E až po buňku E11 (označte buňku E2 a pomocí myši přetáhněte dolů pravý dolní roh).

Buňka E13 obsahuje vzorec, který se používá ke kontrole součtu hodnot odpisu. Používá funkci SUMIF. Záporné hodnoty v buňkách E8:E11 nesmí být brány v úvahu. Podmínka >0 je obsažena v buňce A13. Vzorec v buňce E13 je následující:

=SUMIF(E2:E11;A13)

Nyní můžete zadat odpisy pro desetileté období, pro Zůstatkovou hodnotu 1 měnové jednotky, vložit jiné pořizovací náklady apod.

Finanční funkce - Část 2

Finanční funkce - Část 3

Funkce podle kategorie