ScriptForge.Array service (SF_Array)

Innhald
Innhaldsliste 🔎︎

# ScriptForge.Array-teneste

Inneheld ei samling metodar for å handsama og transformera matriser av éin dimensjon (vektorar) og matriser med to dimensjonar (matriser). Dette inkluderer å setja operasjonar, sortera, importera til og eksportere frå tekstfiler.

Matyriser med meir enn to dimensjonar kan ikkje brukast med metodane i denne tenesta. Einaste unnataket er metoden CountDims, som godtar matriser med kor mange dimensjonar som helst.

Matrise-element kan innehalda kva verdi som helst, også (under)matriser.

## Oppkall av tenester

Før du kan bruka tenesta Array, må du henta inn biblioteket ScriptForge ved hjelp av

          GlobalScope.BasicLibraries.LoadLibrary("ScriptForge")

Lastinga av biblioteket vil laga objektet SF_Array som kan brukast for å kalla opp metodane i tenesta Array.

Desse kodesnuttane viser dei ulike måtane å kalla opp metodar på i tenesta Array. Metoden Append er brukt som eksempel:

          SF_Array.Append(...)

          Dim arr    :    arr = SF_Array
          arr.Append(...)

          Dim arr    :    arr = CreateScriptService("Array")
          arr.Append(...)

Metoden CreateScriptService er berre tilgjengeleg etter at du har lasta inn biblioteket CreateScriptService.

Metodar
Append AppendColumn AppendRow Contains ConvertToDictionary CountDims Difference ExportToTextFile ExtractColumn ExtractRow | Flatten ImportFromCSVFile IndexOf Insert InsertSorted Intersection Join2D Prepend PrependColumn PrependRow | RangeInit Reverse Shuffle Slice Sort SortColumns SortRows Transpose TrimArray Union Unique

Det første argumentet i dei fleste metodane er kva matriseopbjekt som skal vurderast. Den vert alltid sendt med referanse og vert ikkje endra. Metodar som «Append», «Prepend» osv. returnerer eit nytt matrise-objekt etter utføringa.

## Append

Legg elementa som er oppførte til som argument på slutten av inndatamatrisa.

### Syntaks:

          SF_Array.Append(Array_1D As Variant, arg0 As Variant, [arg1 As Variant], ...) As Variant

### Parametrar:

Array_1D: matrisa som finst frå før, kan vera tom.

arg0, …: ei liste over element som skal føyast til i Array_1D.

### Eksempel:

          Sub Example_Append()
          Dim a As Variant
              a = SF_Array.Append(Array(1, 2, 3), 4, 5)
                  ' (1, 2, 3, 4, 5)
          End Sub

## AppendColumn

Set inn ein ny kolonne til høgre i ei todimensjonal matrise. Den nye matrisa har dei same nedre grensene som den opphavlege todimensjonale matrisa.

### Syntaks:

          SF_Array.AppendColumn(Array_2D As Variant, New_Column As Variant) As Variant

### Parametrar:

Array_2D: matrisa som finst frå før, kan vera tom. the pre-existing array, may be empty. Viss denne matrisa har berre éin dimensjon, vert denne rekna som den første kolonnen i den nye todimensjonale matrisa.

Ny_kolonne: ein eindimensional matrise med like mange element som det er rader i Array_2D.

### Eksempel:

          Sub Example_AppendColumn()
          Dim a As Variant, b As variant
              a = SF_Array.AppendColumn(Array(1, 2, 3), Array(4, 5, 6))
                  ' ((1, 4), (2, 5), (3, 6))
              b = SF_Array.AppendColumn(a, Array(7, 8, 9))
                  ' ((1, 4, 7), (2, 5, 8), (3, 6, 9))
              c = SF_Array.AppendColumn(Array(), Array(1, 2, 3))
                  ' ∀ i ∈ {0 ≤ i ≤ 2} : b(0, i) ≡ i
          End Sub

## AppendRow

Legg til ei ny rad nedst i ei todimensjonal matrise. Den nye matrisa har dei same nedre grensene som den opphavlege matrisa.

### Syntaks:

          SF_Array.AppendRow(Array_2D As Variant, Row As Variant) As Variant

### Parametrar:

Array_2D: matrisa som finst frå før, kan vera tom. Viss denne matrisa har berre éin dimensjon, vert denne rekna som den første rada i den nye todimensjonale matrisa.

Rad: ei eindimensjonal matrise med like mange element som det er kolonnar i Array_2D.

### Eksempel:

          Sub Example_AppendRow()
          Dim a As Variant, b As variant
              a = SF_Array.AppendRow(Array(1, 2, 3), Array(4, 5, 6))
                  '  ((1, 2, 3), (4, 5, 6))
              b = SF_Array..AppendRow(Array(), Array(1, 2, 3))
                  ' ∀ i ∈ {0 ≤ i ≤ 2} : b(i, 0) ≡ i
          End Sub

## Contains

Sjå etter om ei eindimensjonal matrise inneheld eit bestemt tal, ein bestemt tekst eller dato. Tekstsamanlikningar kan skilja mellom store og små bokstavar.
Sorterte inndatamatriser må fyllast ut homogent, det vil seia at alle elementa må vera skalarar av same type (Tomme- og Null-element kan ikkje brukast).
Det er uråd å vita på førehand kva resultatet av metoden vert når matrisa er sagt å vera sortert utan at ho er det.
Det vert utført eit binærsøk når matrisa er sortert, elles vert ho skanna frå øvst til nedst og Tomme element og Nullelement vert ignorerte.

### Syntaks:

          SF_Array.Contains(Array_1D, ToFind As Variant, [CaseSensitive As Boolean], [SortOrder As String]) As Boolean

### Parametrar:

Array_1D: matrisa som skal skannast.

ToFind: eit tal, ein dato eller ein streng som skal finnast.

CaseSensitive : Only for string comparisons, default = Usann.

Sorteringsrekkjefølgje : "ASC", "DESC" eller "" (= ikkje sortert, standard)

### Eksempel:

          Sub Example_Contains()
          Dim a As Variant
              a = SF_Array.Contains(Array("A","B","c","D"), "C", SortOrder := "ASC") ' True
              SF_Array.Contains(Array("A","B","c","D"), "C", CaseSensitive := True) ' False
          End Sub

## ConvertToDictionary

Lagrar innhaldet av ei matrise med to kolonnar i eit ScriptForge.Dictionary-objekt.
Nøkkelen vert henta ut frå den første kolonnen, elementet frå den andre.

### Syntaks:

          SF_Array.ConvertToDictionary(Array_2D As Variant) As Variant

### Parametrar:

Array_1D: den første kolonnen må innehalda strengar med lengd > 0 i kva rekkjefølgje som helst.

### Eksempel:

          Sub Example_ConvertToDictionary()
          Dim a As Variant, b As Variant
              a = SF_Array.AppendColumn(Array("a", "b", "c"), Array(1, 2, 3))
              b = SF_Array.ConvertToDictionary(a)
              MsgBox b.Item("c") ' 3
          End Sub

## CountDims

Tel kor mange dimensjonar ei matrise har. Resultatet kan vera større enn to
Viss argumentet ikkje er ein streng, vert det returnert -1
Viss matrisa ikkje er initialisert, vert det returnert 0.

### Syntaks:

          SF_Array.CountDims(Array_ND As Variant) As Integer

### Parametrar:

Array_ND: matrisa som skal granskast-

### Eksempel:

          Sub Example_CountDims()
          Dim a(1 To 10, -3 To 12, 5)
              MsgBox SF_Array.CountDims(a) ' 3
          End Sub

## Difference

Bygg eit sett som ei null-basert matrise, ved å bruka differensoperatoren på dei to inndatamatrisene. Resulterande element kjem frå den første matrisa og ikkje frå den andre.<br>Den resulterande matrisa vert sortert i stigande rekkjefølgje.<br>Begge inndatamatrisene må fyllast homogent, elementa må vera skalarer av same type. Elementa Empty og Null kan ikkje brukast.<br>Tekstsamanlikning kan skilja mellom store og små bokstavar eller ikkje.

### Syntaks:

          SF_Array.Difference(Array1_1D As Variant, Array2_1D As Variant[, CaseSensitive As Boolean]) As Variant

### Parametrar:

Array1_1D : Ei eindimensjonal referansematrise der elementa vert granska for om dei kan fjernast.

Array2_1D : Ei eindimensjonal matrise der elementa vert dregne frå den første inndatamatrisa.

Store/små bokstavar: Berre viss matrisa er fylt med strengar, standard = usann.

### Eksempel:

          Sub Example_Difference()
          Dim a As Variant
              a = SF_Array.Difference(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
                  ' ("A", "B")
          End Sub

## ExportToTextFile

Skriv alle matriseelementa i nummerrekkjefølgje til ei tekstfil. Viss fila finst frå før, vert ho overskrive utan varsel.

### Syntaks:

          SF_Array.ExportToTextFile(Array_1D As Variant, FileName As String, [Encoding As String]) As Boolean

### Parametrar:

Array_1D: Matrisa som skal eksporterast. Ho må innehalda berre strengar.

Filnamn: namnet på den tekstfila som inneheld dataa. Namnet er uttrykt som gjeven av den gjeldande Filnamngjevinga-eigenskapen i tenesta SF_FileSystem. Standard = any (både URL-formatet og det gjeldande formatet brukt av operativsystemet er tillate).

Teiknsett: Det teiknsettet som må brukast. Bruk eit av namna som er lista i IANA-teiknsetta. Merk at LibreOffice kanskje ikkje har alle teiknsetta som finst. Standard er «UTF-8».

### Eksempel:

          Sub Example_ExportToTextFile()
              SF_Array.ExportToTextFile(Array("A","B","C","D"), "C:\Temp\A short file.txt")
          End Sub

## ExtractColumn

Trekk ut ein bestemt kolonne frå ei todimensjonal matrise som ei ny matrise.
Dei nedre LBound og øvre UBound grensene er dei same som dei brukte i første dimensjon av innmatrisa.

### Syntaks:

          SF_Array.ExtractColumn(Array_2D As Variant, ColumnIndex As Long) As Variant

### Parametrar:

Matrise_2D: Matrisa det skal trekkjast ut frå.

ColumnIndex : Nummeret på kolonnen som skal trekkjast ut – må vera i intervallet [LBound, UBound].

### Eksempel:

          Sub Example_ExtractColumn
             'Lagar ei 3 × 3 matrise: |1, 2, 3|
             '                      |4, 5, 6|
             '                      |7, 8, 9|
             Dim mat as Variant, col as Variant
             mat = SF_Array.AppendRow(Array(), Array(1, 2, 3))
             mat = SF_Array.AppendRow(mat, Array(4, 5, 6))
             mat = SF_Array.AppendRow(mat, Array(7, 8, 9))
             'Trekk ut den tredje kolonnen: |3, 6, 9|
             col = SF_Array.ExtractColumn(mat, 2)
          End Sub

## ExtractRow

Trekk ut ei bestemt rad som ei ny matrise frå ei to-dimensjonal matrise.
Nedre (LBound) og øvre (UBound) grense er lik grensene i den andre dimensjonen i inndatamatrisa.

### Syntaks:

          SF_Array.ExtractRow(Array_2D As Variant, RowIndex As Long) As Variant

### Parametrar:

Array_2D : Matrisa som det skal trekkjast ut frå.

RadIndeks : Nummeret på den rada som skal trekkjast ut – må vera i intervallet [LBound, UBound].

### Eksempel:

          Sub Example_ExtractRow
             ' Lagar ei 3 × 3 matrise: |1, 2, 3|
             '                      |4, 5, 6|
             '                      |7, 8, 9|
             Dim mat as Variant, row as Variant
             mat = SF_Array.AppendRow(Array(), Array(1, 2, 3))
             mat = SF_Array.AppendRow(mat, Array(4, 5, 6))
             mat = SF_Array.AppendRow(mat, Array(7, 8, 9))
             ' Trekk ut den første rada: |1, 2, 3|
             row = SF_Array.ExtractRow(mat, 0)
          End Sub

## Flatten

Stablar alle enkeltelementa i ei matrise og alle elementa i delmatrisene i éi ny matrise utan delmatriser. Tomme delmatriser vert ignorerte og delmatriser med større dimensjonar enn éin vert ikkje slegne saman.

### Syntaks:

          SF_Array.Flatten(Array_1D As Variant) As Variant

### Parametrar:

Matrise_1D: matrisa som finst frå før, kan vera tom.

### Eksempel:

          Sub Example_Flatten()
          Dim a As Variant
              a = SF_Array.Flatten(Array(Array(1, 2, 3), 4, 5))
                  ' (1, 2, 3, 4, 5)
          End Sub

Du kan bruka metoden Flatten saman med andre metodar som for eksempel Append eller Prepend for å kopla saman eit sett med 1D-matriser til éi enkelt 1D-matrise.

### Eksempel:

Neste eksempel viser korleis metodane Flatten og Append kan kombinerast for å setja saman tre matriser.

          Sub Concatenate_Example
             ' Lager tre matriser til dette eksempelet
             Dim a as Variant, b as Variant, c as Variant
             a = Array(1, 2, 3)
             b = Array(4, 5)
             c = Array(6, 7, 8, 9)
             ' Slår saman dei tre matrisene til éi 1D-matrise
             Dim arr as Variant
             arr = SF_Array.Flatten(SF_Array.Append(a, b, c))
             '(1, 2, 3, 4, 5, 6, 7, 8, 9)
          End Sub

## ImportFromCSVFile

Importer dataa frå ei kommadelt fil (CSV). Kommaet kan bytast ut med kva teikn som helst.

Det aktuelle CSV-formatet er forklart i IETF Common Format and MIME Type for CSV Files.

Kvar linje i fila inneheld ein fullstendig post (linjedeling er ikkje tillate).
Sekvensar som \n, \t, … vert uendra. Bruk SF_String, Unescape()-metoden for å administrera dei.

Metoden returnerer ei matrise med to dimensjonar der radene svarar til éin enkelt post i fila, og der kolonnane svarar til eitt felt i posten. Det vert ikkje kontrollert om felttypane er samanhengande på tvers av kolonnar. Det vert gjort ei beste gissing for å identifisera numeriske typar og datotypar.

Viss ei linje inneheld færre eller fleire felt enn den første linja i fila, vert det sett eit unntak. Tomme linjer vert ganske enkelt ignorerte. Viss fila er større enn grensa for talet på element (sjå i koden), vert det vist ei åtvaring og matrisa vert avkorta.

### Syntaks:

          SF_Array.ImportFromCSVFile(FileName As String, [Delimiter As String], [DateFormat As String]) As Variant

### Parametrar:

Filnamn: namnet på tekstfila som inneheld dataa. Namnet vert vist slik det er sett i eigenskapen FileNaming i tenesta SF_FileSystem. Standard = vilkårleg (både URL-formatet og det opphavlege operativsystemformatet er tillate).

Skiljeteikn : eitt enkelt teikn, som oftast eit komma, eit semikolon eller eit tabulatorteikn. Standard = ",".

Datoformat: Ein spesiell mekanisme handsamar datoar når Datoformat er anten «ÅÅÅÅ-MM-DD», «DD-MM-ÅÅÅÅ» eller «MM-DD-ÅÅÅÅ». Streken (-) kan bytast ut med punktum (.), skråstrek (/) eller eit mellomrom. Andre datoformat vert ignorerte. Datoar i hermeteikn ("") vert sett på som vanleg tekst.

### Eksempel:

Gjeven denne CSV-fila:

          Name,DateOfBirth,Address,City
          Anna,2002/03/31,"Rue de l'église, 21",Toulouse
          Fred,1998/05/04,"Rue Albert Einstein, 113A",Carcassonne

          Sub Example_ImportFromCSVFile()
          Dim a As Variant
              a = SF_Array.ImportFromCSVFile("C:\Temp\myFile.csv", DateFormat := "YYYY/MM/DD")
              MsgBox a(0, 3)    ' City
              MsgBox TypeName(a(1, 2))    ' Date
              MsgBox a(2, 2)    ' Rue Albert Einstein, 113A
          End Sub

## IndexOf

Sjå etter eit tal, ein streng eller ein dato i ei eindimensjonal matrise. Tekstsamanlikning kan skilja mellom store og små bokstavar, eller ikkje.<br>Viss matrisa er sortert, må ho vera utfylt homogent, altså at alle elementa må vera skalarer av same type (Empty og Null kan ikkje brukast).<br>Når matrisa er sett til å vera sortert men ikkje er det, er det uråd å vita resultatet på førehand.
Det vert brukt binært søk på sorterte matriser. Elles vert matriser ganske enkelt skanna frå topp til botn. Elementa Empty og Null vert ikkje tekne med.
Metoden returnerer LBound(input array) - 1 viss søket ikkje var vellukka.

### Syntaks:

          SF_Array.IndexOf(Array_1D, ToFind As Variant, [CaseSensitive As Boolean], [SortOrder As String]) As Long

### Parametrar:

Matrise_1D: matrisa som skal skannast.

ÅFinna: eit tal, ein dato eller ein streng som skal finnast.

Store/små : (Skil små og store bokstavar). Berre for strengsamanlikningar. Standard = Usann.

Sorteringsrekkjefølgje: "ASC", "DESC" eller "" (= ikkje sortert, standard)

### Eksempel:

          Sub Example_IndexOf()
              MsgBox SF_Array.IndexOf(Array("A","B","c","D"), "C", SortOrder := "ASC") ' 2
              MsgBox SF_Array.IndexOf(Array("A","B","c","D"), "C", CaseSensitive := True) ' -1
          End Sub

## Insert

Set inn elementa som er oppført som argument framføre ein gjeven indeks for inndatamatrisa.
Argument vert sette inn blindt. Kvart av dei kan anten vera ein skalar av kva type som helst eller ei undermatrise.

### Syntaks:

          SF_Array.Insert(Array_1D As Variant, Before As Long, arg0 As Variant, [arg1 As Variant], ...) As Variant

### Parametrar:

Matrise_1D: matrisa som finst frå før, kan vera tom.

Framføre: Indeksen som skal setjast inn framføre må vera i intervallet [LBound, UBound + 1].

arg0, …: ei liste over element som skal setjast inn i Matrise_1D.

### Eksempel:

          Sub Example_Insert()
          Dim a As Variant
              a = SF_Array.Insert(Array(1, 2, 3), 2, "a", "b")
                  ' (1, 2, "a", "b", 3)
          End Sub

## InsertSorted

Set inn eit nytt element i ei sortert matrise.
Matris må fyllast homogent, altså at alle elementa må vera skalarer av same type.
Elementa Empty og Null er ikkje tillatne.

### Syntaks:

          SF_Array.InsertSorted(Array_1D As Variant, Item As Variant, SortOrder As String, CaseSensitive As Boolean) As Variant

### Parametrar:

Matrise_1D: matrisa som skal sorterast.

Element: Skalarverdien som skal setjast inn. Av same type som matriseelementa som finst frå før.

Sorteringsrekkjefølgje: "ASC" (standard) eller "DESC".

Store/små : (Skil store og små bokstavar). Berre for samanlikning av strengar. Standard = Usann.

### Eksempel:

          Sub Example_InsertSorted()
          Dim a As Variant
              a = SF_Array.InsertSorted(Array("A", "C", "a", "b"), "B", CaseSensitive := True)
                  ' ("A", "B", "C", "a", "b")
          End Sub

## Intersection

Bygg eit sett som ei null-basert matrise ved å bruka unionmengde-operatoren på dei to inndatamatrisene. Resulterande element kjem frå begge matrisene.
Den resulterande matrisa vert sortert i stigande rekkjefølgje.
Begge inndatamatrisene må fyllast homogent, elementa må vera skalarer av same type. Elementa Empty og Null kan ikkje brukast.
Tekstsamanlikning kan skilja mellom store og små bokstavar eller ikkje.

### Syntaks:

          SF_Array.Intersection(Array1_1D As Variant, Array2_1D As Variant[, CaseSensitive As Boolean]) As Variant

### Parametrar:

Matrise1_1D : Den første inndatamatrisa.

Matrise2_1D : Den andre inndatamatrisa.

Store/små: (Skil mellom store og små bokstavar). Gjeld matriser fylt med tekstelement, standard = Usann.

### Eksempel:

          Sub Example_Intersection()
          Dim a As Variant
              a = SF_Array.Intersection(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
                  ' ("C", "b")
          End Sub

## Join2D

Føyer saman ei todimensjonal matrise med to skiljeteikn, eitt for kolonnane, eitt for radene.

### Syntaks:

          SF_Array.Join2D(Array_2D As Variant, ColumnDelimiter As String, RowDelimiter As String, Quote As Boolean) As String

### Parametrar:

Matrise_2D: Kvart element må vera anten tekst, eit tal, ein dato eller ein boolsk verdi.
Datoar vert transformerte i formatet ÅÅÅÅ-MM-DD tt:mm:ss.
Ugyldige element vert bytt ut med ein null-lengdestreng.

Kolonneskiljeteikn: Skilje mellom kolonnar (standard = Tab/Chr(9)).

Radskiljeteikn: Skil mellom radene (standard = LineFeed/Chr(10))

Hermeteikn: viss Sann vert strengen verna med doble hermeteikn ("). Standarden er Usann.

### Eksempel:

          Sub Example_Join2D()
          -                     | 1, 2, "A", [2020-02-29], 5      |
          -    SF_Array.Join_2D(| 6, 7, "this is a string", 9, 10 |, ",", "/")
          -            ' "1,2,A,2020-02-29 00:00:00,5/6,7,this is a string,9,10"
          End Sub

## Prepend

Legg dei utlista elementa til som argument i byrjinga av inndatamatrisa.

### Syntaks:

          SF_Array.Prepend(Array_1D As Variant, arg0 As Variant, [arg1 As Variant], ...) As Variant

### Parametrar:

Matrise_1D: matrisa som finst frå før, kan vera tom.

arg0, …: ei liste over element som skal setjast inn først i Matrise_1D.

### Eksempel:

          Sub Example_Prepend()
          Dim a As Variant
              a = SF_Array.Prepend(Array(1, 2, 3), 4, 5)
                  ' (4, 5, 1, 2, 3)
          End Sub

## PrependColumn

Legg til ein ny kolonne først på venstre side i ei todimensjonal matrise. Den nye matrisa har dei same nedre grensene som den opphavlege todimensjonale matrisa.

### Syntaks:

          SF_Array.PrependColumn(Array_2D As Variant, Column As Variant) As Variant

### Parametrar:

Matrise_2D: matrisa som finst frå før, kan vera tom. Viss denne matrisa har berre éin dimensjon, vert denne rekna som den første rada i den nye todimensjonale matrisa.

Kolonne: ei eindimensjonal matrise med like mange element som det er rader i Matrise_2D.

### Eksempel:

          Sub Example_PrependColumn()
          Dim a As Variant, b As variant
              a = SF_Array.PrependColumn(Array(1, 2, 3), Array(4, 5, 6))
                  ' ((4, 1), (5, 2), (6, 3))
              b = SF_Array.PrependColumn(Array(), Array(1, 2, 3))
                  ' ∀ i ∈ {0 ≤ i ≤ 2} : b(0, i) ≡ i
          End Sub

## PrependRow

Legg til ei ny rad først i ei todimensjonal matrise. Den nye matrisa har dei same nedre grensene som den opphavlege todimensjonale matrisa.

### Syntaks:

          SF_Array.PrependRow(Array_2D As Variant, Row As Variant) As Variant

### Parametrar:

Matrise_2D: matrisa som finst frå før, kan vera tom. Viss denne matrisa har berre éin dimensjon, vert denne rekna som den siste rada i den nye todimensjonale matrisa.

Rad: ein eindimensional matrise med like mange element som det er rader i Matrise_2D.

### Eksempel:

          Sub Example_PrependRow()
          Dim a As Variant, b As variant
              a = SF_Array.PrependRow(Array(1, 2, 3), Array(4, 5, 6))
                  ' ((4, 5, 6), (1, 2, 3))
              b = SF_Array.PrependRow(Array(), Array(1, 2, 3))
                  ' ∀ i ∈ {0 ≤ i ≤ 2} : b(i, 0) ≡ i
          End Sub

## RangeInit

Initialiser ei ny null-basert matrise med numeriske verdiar.

### Syntaks:

          SF_Array.RangeInit(From As [number], UpTo As [number] [, ByStep As [number]]) As Variant

### Parametrar:

Frå: verdien av det første elementet.

Opptil: Det siste elementet må ikkje overstige UpTo.

Trinnvis: Differansen mellom to etterfølgjande element (standard = 1).

### Eksempel:

          Sub Example_RangeInit()
          Dim a As Variant
              a = SF_Array.RangeInit(10, 1, -1)
                  ' (10, 9, 8, 7, 6, 5, 4, 3, 2, 1)
          End Sub

## Reverse

Returner den omvendte eindimensjonelle inndata-matrisa.

### Syntaks:

          SF_Array.Reverse(Array_1D As Variant) As Variant

### Parametrar:

Matrise_1D: matrisa som skal reverserast.

### Eksempel:

          Sub Example_Reverse()
          Dim a As Variant
              a = SF_Array.Reverse(Array("a", 2, 3, 4))
                  ' (4, 3, 2, "a")
          End Sub

## Shuffle

Returnerer ein tilfeldig permutasjon av ei eindimensjonal matrise.

### Syntaks:

          SF_Array.Shuffle(Array_1D As Variant) As Variant

### Parametrar:

Matrise_1D: matrisa som skal blandast.

### Eksempel:

          Sub Example_Shuffle()
          Dim a As Variant
              a = SF_Array.Shuffle(Array(1, 2, 3, 4))
                  ' Uføreseieleg
          End Sub

## Slice

Returner eit undersett av ei eindimensjonal matrise.

### Syntaks:

          SF_Array.Slice(Array_1D As Variant, From As Long, [UpTo As Long]) As Variant

### Parametrar:

Matrise_1D: området som skal skjerast ut.

Frå: Den lågaste indeksen i Matrise_1D av delmatrisa som skal trekkjast ut (Frå vert teken med.

Opptil : Det øverste indeks i Matrise_1D av den delmatrisa som det skal trekkjast ut frå (Opptil medrekna). Standard = øvre grense for Matrise_1D. Viss Opptil < Frå vert det returnert ei tom matrise.

### Eksempel:

          Sub Example_Slice()
          Dim a As Variant
              a = SF_Array.Slice(Array(1, 2, 3, 4, 5), 1, 3) ' (2, 3, 4)
          End Sub

## Sort

Sorter ei eindimensjonal matrise i stigande eller falande rekkjefølgje. Tekstsamanlikningar kan skilja mellom store og små bokstavar eller ikkje.
Matrisa skal vera fylt homogent, altså at elementa må vera av same type skalarar.
Elementa Empty og Null er tillatne. Til vanleg er Empty < Null < kva skalarverdi som helst.

### Syntaks:

          SF_Array.Sort(Array_1D As Variant, SortOrder As String, CaseSensitive As Boolean) As Variant

### Parametrar:

Matrise_1D: Matrisa som skal sorterast.

Sorteringsrekkjefølgje: "ASC" (standard) eller "DESC".

CaseSensitive : (Skil store og små bokstavar). Berre for samanlikning av strengar. Standard = Usann.

### Eksempel:

          Sub Example_Sort()
          Dim a As Variant
              a = SF_Array.Sort(Array("a", "A", "b", "B", "C"), CaseSensitive := True)
                  ' ("A", "B", "C", "a", "b")
          End Sub

## SortColumns

Returner ein permutasjon av kolonnar i ei todimensional matrise, sortert etter verdiane i ei gjeven rad.
Rada må vera fylt homogent, altså at alle elementa må vera skalarer av same type.
Elementa Empty og Null er tillatne. Til vanleg er Empty < Null < kva annan skalar verdi som helst.

### Syntaks:

          SF_Array.SortColumns(Array_1D As Variant, RowIndex As Long, SortOrder As String, CaseSensitive As Boolean) As Variant

### Parametrar:

Matrise_1D: Matrisa som skal sorterast.

Radindeks: Indeksen i den rada som kolonnane skal sorterast etter.

Sorteringsrekkjefølgje: "ASC" (standard) eller "DESC".

Store/små : (Skil store og små bokstavar). Berre for samanlikning av strengar. Standard = Usann.

### Eksempel:

          Sub Example_SortColumns()
          -                         | 5, 7, 3 |            ' | 7, 5, 3 |
          -    SF_Array.SortColumns(| 1, 9, 5 |, 2, "ASC") ' | 9, 1, 5 |
          -                         | 6, 1, 8 |            ' | 1, 6, 8 |
          End Sub

## SortRows

Returner ein permutasjon av kolonnar i ei todimensional matrise, sortert etter verdiane i ei gjeven rad.
Rada må vera fylt homogent, altså at alle elementa må vera skalarer av same type.
Elementa Empty og Null er tillatne. Til vanleg er Empty < Null < kva annan skalar verdi som helst.

### Syntaks:

          SF_Array.SortRows(Array_1D As Variant, ColumnIndex As Long, SortOrder As String, CaseSensitive As Boolean) As Variant

### Parametrar:

Matrise_1D: Matrisa som skal sorterast.

Radindeks: Indeksen i den rada som kolonnane skal sorterast etter.

Sorteringsrekkjefølgje: "ASC" (standard) eller "DESC".

Store/små : (Skil store og små bokstavar). Berre for samanlikning av strengar. Standard = Usann.

### Eksempel:

          Sub Example_SortRows()
          -                      | 5, 7, 3 |            ' | 1, 9, 5 |
          -    SF_Array.SortRows(| 1, 9, 5 |, 2, "ASC") ' | 5, 7, 3 |
          -                      | 6, 1, 8 |            ' | 6, 1, 8 |
          End Sub

## Transpose

Byt om rader og kolonnar i ei todimensjonal matrise.

### Syntaks:

          SF_Array.Transpose(Array_2D As Variant) As Variant

### Parametrar:

Matrise_2D: Matrisa som skal transponerast.

### Eksempel:

          Sub Example_Transpose()
          -                       | 1, 2 |  ' | 1, 3, 5 |
          -    SF_Array.Transpose(| 3, 4 |) ' | 2, 4, 6 |
          -                       | 5, 6 |
          End Sub

## TrimArray

Fjern alle Null, Empty og nul-lengde-oppføringar frå ei eindimensjonal matrise.
Strengelementa kan trimmast med funksjonen LibreOffice Basic Trim() .

### Syntaks:

          SF_Array.TrimArray(Array_1D As Variant) As Variant

### Parametrar:

Matrise_1D: matrisa som skal skannast.

### Eksempel:

          Sub Example_TrimArray()
          Dim a As Variant
              a = SF_Array.TrimArray(Array("A","B",Null," D "))
                  ' ("A","B","D")
          End Sub

## Union

Bygg eit sett som ei null-basert matrise ved å bruka unionmengde-operatoren på dei to inndatamatrisene. Resulterande element kjem frå begge matrisene.
Den resulterande matrisa vert sortert i stigande rekkjefølgje.
Begge inndatamatrisene må fyllast homogent, elementa må vera skalarer av same type. Elementa Empty og Null kan ikkje brukast.
Tekstsamanlikning kan skilja mellom store og små bokstavar eller ikkje.

### Syntaks:

          SF_Array.Union(Array1_1D As Variant, Array2_1D As Variant[, CaseSensitive As Boolean]) As Variant

### Parametrar:

Matrise1_1D : den første inndata-matrisa.

Matrise2_1D : Den andre inndatamatrisa.

Store/små bokstavar: Berre viss matrisa er fylt med strengar, standard = usann.

### Eksempel:

          Sub Example_Union()
          Dim a As Variant
              a = SF_Array.Union(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
                  ' ("A", "B", "C", "Z", "b")
          End Sub

## Unique

Bygg eit sett av unike verdiar avleidde frå inndata-matrisa.
Inndata-matrisa må vera fylt homogent, altså at alle elementa må vera skalarer av den same typen. Elementa Empty og Null er ikkje tillatne.
Tekstsamanlikningar kan skilja mellom store og små bokstavar eller ikkje.

### Syntaks:

          SF_Array.Unique(Array_1D As Variant, CaseSensitive As Boolean]) As Variant

### Parametrar:

Matrise_1D : Inndata-matrisa.

Store/små bokstavar: Berre viss matrisa er fylt med strengar, standard = usann.

### Eksempel:

          Sub Example_Unique()
          Dim a As Variant
              a = SF_Array.Unique(Array("A", "C", "A", "b", "B"), CaseSensitive := True)
                  '  ("A", "B", "C", "b")
          End Sub

Alle Basic-rutinane og -identifikatorane i ScriptForge som vert innleidde med understrek «_» er reserverte for internt bruk. Dei er ikkje tenkt brukte i Basic-makroar.

Liknande emne

Tabellfunksjonar

Oppkall av Calc-funksjonar

Tenesta ScriptForge.Dictionary