Innhald
Innhaldsliste 🔎︎

# Tenesta ScriptForge.Dictionary

Ei ordliste er ei samling av nøkkelelementpar

- Nøkkelen er ein streng som skil mellom store og små bokstavar

- Elementa kan vera av kva type som helst

Nøklar og element kan hentast, teljast, oppdaterast og mykje meir.

Objekta LibreOffice Basic Collection har ikkje støtte for henting av nøklane.
I tillegg inneheld elementa berre primitive grunnleggjande datatypar, for eksempel datoar, tekst, tal og liknande.

## Oppkall av tenester

Eksempelet nedføre opprettar myDict som ei tom ordbok.

        GlobalScope.BasicLibraries.loadLibrary("ScriptForge")
        Dim myDict As Variant
        myDict = CreateScriptService("Dictionary")

Det vert tilrådd å frigje ressursar etter bruk:

         Set myDict = myDict.Dispose()

## Eigenskapar

Namn | Skriveverna | Type | Beskriving
Count | Ja | Long | Talet på oppføringar i ordboka
Items | Ja | Matrise med variantar | Lista over elementa som ei eindimensjonal matrise
Keys | Ja | Matrise av strengar | Lista over nøklar som ei eindimensjonal matrise

Eigenskapane Keys og Items returnerer deira respektive indhald i ei identisk rekkjefølgje. Rekkefølgja er ikkje relatert til rekkjefølgja sett ved opprettinga.

### Eksempel:

Det neste eksempelet brukar eigenskapen Keys for gå gjennom alle nøklane i myDict fleire gonger.

        Dim a As Variant, b As String
        a = myDict.Keys
        For Each b In a
            MsgBox(myDict.Item(b))
        Next b

| Metodar |
Add ConvertToArray ConvertToJson ConvertToPropertyValues | Exists ImportFromJson ImportFromPropertyValues Item | Remove RemoveAll ReplaceItem ReplaceKey

## Add

Legg eit nytt nøkkelelementpar til ordboka. Returnerer Sann viss det lukkast.

### Syntaks:

              myDict.Add(Key As String, Item As Variant) As Boolean

### Parametrar:

Nøkkel: Strengverdi som vert brukt for å identifisera elementet. Nøkkelen skil ikkje mellom store og små bokstavar.

Element: Kva verdi som helst, også ei matrise, eit Basic-objekt, eit UNO-objekt, ei ordbok og så vidare.

### Eksempel:

              Dim NewValue As Variant
              myDict.Add("NewKey", NewValue)

Kvar nøkkel må vera unik i den same ordlista. Viss nøkkelen finst frå før i ordlista, vert det sett opp ein DUPLICATEKEYERROR. Nøklar som er laga av mellomromsteikn, vil setja opp feilen INVALIDKEYERROR.

## ConvertToArray

Lagrar innhaldet i ordboka i ei to-kolonnars, null-basert matrise. Nøklane er lagra i den første kolonnen og elementa i den andre kolonnen.

Viss ordboka er tom, vil denne metoden returnere ei tom matrise.

### Syntaks:

              myDict.ConvertToArray() As Variant

### Eksempel:

            Dim myDict as Variant
            myDict = CreateScriptService("Dictionary")
            myDict.Add("a", 1)
            myDict.Add("b", 2)
            myDict.Add("c", 3)
            Dim arr as Variant
            arr = myDict.ConvertToArray()
            '(("a", 1), ("b", 2), ("c", 3))

## ConvertToJson

Konverterer innhaldet i ordboka til tekst i JSON (JavaScript Object Notation).

### Avgrensingar

Denne metoden har støtte for desse datatypane: String, Boolean, numbers, Null og Empty. Matriser som inneheld element av desse er også tillatne, kva dimensjon dei måtte ha. Datoar vert konverterte til strengar som vert brukte i matrisene. Andre datatypar vert konverterte til det dei er representert med i strengen ved hjelp av tenesta SF_String.Represent.

### Syntaks:

                myDict.ConvertToJson([Indent As Variant]) As String

### Parametrar:

Innrykk: Når Indent er eit positivt tal eller ein tekst, vert JSON-matriseelement og objektledd skrivne ut med dette innrykket. Ein negativ verdi for Indent vil leggja til nye linjer utan innrykk. Standardverdien "" for Indent vel den mest kompakte representasjonen. Bruk av eit positivt heiltal for Indent vil setja inn så mange innrykk på nivået som talet seier. NårIndent er ein streng, for eksempel Chr(9 eller Tab(1), vert tabulator-teiknet brukt for innrykk.

### Eksempel:

                myDict.Add("p0", 12.5)
                myDict.Add("p1", "a string àé""ê")
                myDict.Add("p2", DateSerial(2020,9,28))
                myDict.Add("p3", True)
                myDict.Add("p4", Array(1,2,3))
                MsgBox myDict.ConvertToJson()
                '{"p0": 12.5, "p1": "a string \u00e0\u00e9\"\u00ea", "p2": "2020-09-28", "p3": true, "p4": [1, 2, 3]}

## ConvertToPropertyValues

Lagra innhaldet i ordlista i ei matrise av PropertyValues.

Kvar oppføring er ein com.sun.star.beans.PropertyValue. Nøkkelen er lagra i Name, elementet i Value.

Viss eitt av elementa har ein type Data, vert denne konvertert til ein com.sun.star.util.DateTime-struktur. Viss eitt av elementa er ei tom matrise, vert det konvertert til Null. Sluttmatrisa er tom når ordboka er tom.

### Syntaks:

              myDict.ConvertToPropertyValues() As Variant

### Eksempel:

              Dim myDict as Variant
              myDict = CreateScriptService("Dictionary")
              ' Legg nokre eigenskapar til i ordboka
              myDict.Add("Color", "Blue")
              myDict.Add("Width", 20)
              ' Konverterer til ei matrise av objekta PropertyValue
              Dim prop as Variant
              prop = myDict.ConvertToPropertyValues()

Mange tenester og metodar i UNO-biblioteket tek inn parameterar som er representerte med strukturen PropertyValue, som er ein del av LibreOffice API-en.

## Exists

Bestemmer om det finst ein nøkkel i ordboka.

### Syntaks:

              myDict.Exists(Key As String) As Boolean

### Parametrar:

Nøkkel : Nøkkelen som skal slåast opp i ordboka.

### Eksempel:

              Dim myDict as Variant
              myDict = CreateScriptService("Dictionary")
              ' Legg nokre eigenskapar til i ordboka
              myDict.Add("Color", "Blue")
              myDict.Add("Width", 20)
              '(...)
              If Not myDict.Exists("Size") Then
                 MsgBox "You have to provide a Size value"
              End If

## ImportFromJson

Legg til innhaldet av ein streng i JSON (JavaScript Object Notation) til i den gjeldande ordboka. Returnnerer Sann viss dette lukkast.

### Avgrensingar

JSON-strengen kan innehalda tal, tekst, boolske verdiar, nullverdiar og matriser som inneheld desse typane. Han kan ikkje innehald JSON-objekt, altså underordlister.

Det vert gjort eit forsøk på å omforma tekst til dato viss elementet passa med eitt av desse mønstera: ÅÅÅÅ-MM-DD, TT:MM:SS eller ÅÅÅÅ-MM-DD TT:MM:SS.

### Syntaks:

                myDict.ImportFromJson(InputStr As String, [Overwrite As Boolean]) As Boolean

### Parametrar:

InputStr: Strengen som skal importerast.

Overskriv : Når denne er Sann, kan det finnast oppføringar med det same namnet i ordlista. Verdiane vert i tilfelle overskrive. Når denne er Usann (standard), vil like verdiar setja opp ein feil. Hugs at ordboksnøklane ikkje skil mellom store og små bokstavar, medan oppføringar i JSON-strengar gjer det.

### Eksempel:

                Dim s As String
                s = "{'firstName': 'John','lastName': 'Smith','isAlive': true,'age': 66, 'birth':  '1954-09-28 20:15:00'" _
                    & ",'address': {'streetAddress': '21 2nd Street','city': 'New York','state': 'NY','postalCode': '10021-3100'}" _
                    & ",'phoneNumbers': [{'type': 'home','number': '212 555-1234'},{'type': 'office','number': '646 555-4567'}]" _
                    & ",'children': ['Q','M','G','T'],'spouse': null}"
                s = Replace(s, "'", """")
                myDict.ImportFromJson(s, OverWrite := True)
                ' (Under)-ordbøkene «Addresse» og «Telefonnummer» (0) og (1) vert importerte som tomme strengar.

## ImportFromPropertyValues

Set inn innhaldet frå ei matrise med PropertyValue-objekta i den gjeldande ordlista. Namna i PropertyValue vert brukte som nøklar i ordlista, medan «Verdiar» inneheld dei tilsvarande verdiane. Returnerer Sann viss vellukka.

### Syntaks:

                myDict.ImportFromPropertyValues(PropertyValues As Variant [, Overwrite As Boolean]) As Boolean

### Parametrar:

EigenskapsVerdiar : Ei null-baseret eindimensional matrise som indeheld com.sun.star.beans.PropertyValue-objekt. Denne parameter kan også vera eit PropertyValue-objekt som ikkje er i ei matrise.

Overskriv : Når denne er Sann, kan det finnast oppføringar med det same namnet i ordlista. Verdiane vert i tilfelle overskrivne. Når denne er Usann (standard), vil like verdiar setja opp ein feil. Hugs at ordboksnøklane ikkje skil mellom store og små bokstavar, medan oppføringar i JSON-strengar gjer det.

### Eksempel:

                Dim vProp As New com.sun.star.beans.PropertyValue
                vProp.Name = "prop"
                vProp.Value = CDateToUnoDateTime(Now)
                myDict.ImportFromPropertyValues(vProp, Overwrite := True)

## Item

Hentar ei ordbokoppføring som finst frå før basert på nøkkelen. Returnerer verdien av elementet viss vellukka, elles vert Empty returnert.

### Syntaks:

              myDict.Item(Key As String) As Variant

### Parametrar:

Nøkkel : Skil ikkje mellom små og store bokstavar. Må finnast i ordboka, elles vert det sett ein UNKNOWNKEYERROR.

### Eksempel:

Det neste eksempelet går gjennom alle nøklane i ordboka fleire gongar og brukar metoden Item til å få tilgang til verdiane.

              Dim myDict as Variant, k as Variant, allKeys as Variant
              myDict = CreateScriptService("Dictionary")
              myDict.Add("key1", 100)
              myDict.Add("key2", 200)
              myDict.Add("key3", 300)
              allKeys = myDict.Keys
              For Each k in allKeys
                 MsgBox(myDict.Item(k))
              Next k

## Remove

Fjernar ei eksisterande ordboksoppføring basert på nøkkelen. Returnerer Sann vis det lukkast.

### Syntaks:

              myDict.Remove(Key As String) As Boolean

### Parametrar:

Nøkkel : Skil ikkje mellom små og store bokstavar. Må finnast i ordboka, elles vert det sett ein UNKNOWNKEYERROR.

### Eksempel:

              myDict.Add("key1", 100)
              myDict.Add("key2", 200)
              myDict.Add("key3", 300)
              MsgBox(myDict.Count) 'Prints "3"
              myDict.Remove("key2")
              MsgBox(myDict.Count) 'Prints "2"

## RemoveAll

Fjernar alle oppføringane i ordboka.. Returnerer Sann viss det lukkast.

### Syntaks:

              myDict.RemoveAll() As Boolean

### Eksempel:

              myDict.Add("key1", 100)
              myDict.Add("key2", 200)
              myDict.Add("key3", 300)
              MsgBox(myDict.Count) 'Prints "3"
              myDict.RemoveAll()
              MsgBox(myDict.Count) 'Prints "0"

## ReplaceItem

Fjernar ein eksisterande elementverdi basert på nøkkelen. Returnerer Sann vis det lukkast.

### Syntaks:

              myDict.ReplaceItem(Key As String, Value As Variant) As Boolean

### Parametrar:

Nøkkel: Strengverdi som representerer nøkkelen som verdien skal erstattast med. Skil ikkje mellom store og små bokstavar. Viss nøkkelen ikkje finst i ordlista, oppstår det ein UNKNOWNKEYERROR-feil.

Verdi Den nye verdien for elementet det vert referert til med Key-parameteren.

### Eksempel:

              myDict.Add("a", 1)
              MsgBox(myDict.Item("a")) 'Prints "1"
              myDict.ReplaceItem("a", 100)
              MsgBox(myDict.Item("a")) ' Prints "100"

## ReplaceKey

Erstattar ein eksisterande nøkkel i ordlista med ein ny nøkkel. Elementverdien vert ikkje endra. Returnerer Sann viss det lukkast.

### Syntaks:

              myDict.ReplaceKey(Key As String, Value As String) As Boolean

### Parametrar:

Nøkkel: Strengverdi som representerer nøkkelen som verdien skal erstattast med. Skil ikkje mellom store og små bokstavar. Viss nøkkelen ikkje finst i ordlista, oppstår det ein UNKNOWNKEYERROR-feil.

Verdi: Strengverdi for den nye nøkkelen. Skil ikkje mellom store og små bokstavar. Viss nøkkelen finst frå før i ordlista, oppstår det ein DUPLICATEKEYERROR-feil.

### Eksempel:

              myDict.Add("oldKey", 100)
              MsgBox(myDict.Item("oldKey")) 'Prints "100"
              myDict.ReplaceKey("oldKey", "newKey")
              MsgBox(myDict.Item("newKey")) ' Prints "100"

Alle Basic-rutinane og -identifikatorane i ScriptForge som vert innleidde med understrek «_» er reserverte for internt bruk. Dei er ikkje tenkt brukte i Basic-makroar.