MAKEPKG-TEMPLATE(1)

NOM
makepkg-template - utilitaire de construction de paquet

SYNOPSIS

makepkg-template [options]

DESCRIPTION

makepkg-template est un script facilitant la maintenance de plusieurs PKGBUILDs semblables. Il vous permet de transférer l'essentiel du code du PKGBUILD dans un fichier ébauche et utilise des balises pour permettre la mise à jour des PKGBUILDs locaux si l'ébauche a été modifiée.

Les ébauches de fichier peuvent contenir n'importe quelles lignes de code licites dans un PKGBUILD. Elles sont traitées comme des fichiers externes appelés par ""." ou "source", mais seront insérées dans le PKGBUILD par makepkg-template donc vous n'avez pas à vous soucier de l'ébauche de fichier pour construire le paquet.

Les balises sont des commentaires bash de la forme:

    # template start; key=value; key2=value2; ...

et

    # template end;

Les clefs usuelles sont : le nom (obligatoire) et la version. Les noms d'ébauche sont alphanumériques mais peuvent contenir "@", "+", ".", "-", ou "_".Les noms de versions peuvent comporter des chiffres ou ".".

À la création, il y a une macro tenant en une ligne qui ne nécessite aucun séparateur:

    # template input; key=value;

Au premier passage, makepkg-template remplacera cette macro automatiquement par les délimiteurs de début et de fin et le code de l'ébauche.

Il faut stocker les fichiers d'ébauche dans un seul répertoire et les noms de fichier devraient prendre le format "$nom_ebauche-$version.template", avec un lien "$nom_ebauche.template" qui pointe sur l'ébauche la plus récente. Si la version n'est pas indiquée dans le délimiteur, makepkg-template se servira automatiquement de la cible de "$nom_ebauche-$version.template" ; autrement le logiciel se servira de la version indiquée. Cela facilite la vérification des PKGBUILD non-authentifiés dont l'ébauche est, elle, authentifiée. Vous vérifiez le code ajouté à l'ébauche, puis vous lancer une commande du style :

    diff -u <(makepkg-template -o -) PKGBUILD

Les fichiers d'ébauche peuvent aussi comporter des balises engendrant une cascade de sous-ébauches à l'intérieur du PKGBUILD. Si vous utilisez des balises dans un fichier d'ébauche, veillez à indiquer la version que vous utilisez ou testez à l'aide d'une balise start/input, de façon à ce que d'autres puissent réutiliser vos ébauches.

OPTIONS

-p, --input <build script>
    Lit le script de construction du paquet au lieu du script par défaut.

-o, --output <build script>
    Enregistre le fichier actualisé sous un nouveau nom au lieu d'écraser le fichier d'entrée.

-n, --newest
    Utilise automatiquement le fichier d'ébauche le plus récent.

--template-dir <dir>
    Modifie le répertoire de recherche des fichiers d'ébauche. On peut appeler cette option plusieurs fois de suite : les fichiers appelés en dernier, s'ils sont présents dans ce répertoire, auront priorité.

EXEMPLE de FICHIER PKGBUILD

    pkgname=perl-config-simple
    pkgver=4.58
    pkgrel=1
    pkgdesc="classe de fichier de configuration simple"
    arch=('any')
    license=('PerlArtistic' 'GPL')
    depends=('perl')
    source=("http://search.cpan.org/CPAN/authors/id/S/SH/SHERZODR/Config-Simple-${pkgver}.tar.gz")
    md5sums=('f014aec54f0a1e2e880d317180fce502')
    _distname="Config-Simple"

    # template start; name=perl-module; version=1.0;
    _distdir="${_distname}-${pkgver}"
    url="https://metacpan.org/release/${_distname}"
    options+=('!emptydirs')

    build() {
            cd "$srcdir/$_distdir"
            perl Makefile.PL INSTALLDIRS=vendor
            make
    }

    check() {
            cd "$srcdir/$_distdir"
            make test
    }

    package() {
            cd "$srcdir/$_distdir"
            make DESTDIR="$pkgdir" install
    }
    # template end;

VOIR AUSSI

makepkg(8), PKGBUILD(5)

Consulter le site internet de pacman à l'adresse https://.archlinux.org/pacman/ pour de nouvelles informations sur pacman et ses outils associés.

BOGUES

Bogues ? C'est une blague ; il n'y a pas de bogues dans ce logiciel. Mais s'il y en a, envoyez un rapport de bogue contenant autant de détails que possible dans la section Pacman du système de suivi de bogues de Arch Linux.

AUTEURS

Développeurs actuels :

    • Allan McRae <allan@archlinux.org>

    • Andrew Gregory <andrew.gregory.8@gmail.com>

    • Eli Schwartz <eschwartz@archlinux.org>

    • Morgan Adamiec <morganamilo@archlinux.org>

Contributeurs antérieurs majeurs :

    • Judd Vinet <jvinet@zeroflux.org>

    • Aurelien Foret <aurelien@archlinux.org>

    • Aaron Griffin <aaron@archlinux.org>

    • Dan McGee <dan@archlinux.org>

    • Xavier Chantry <shiningxc@gmail.com>

    • Nagy Gabor <ngaba@bibl.u-szeged.hu>

    • Dave Reisner <dreisner@archlinux.org>

Pour des contributeurs supplémentaires, utiliser git shortlog -s sur le dépôt pacman.git.

TRADUCTION
La traduction française de cette page de manuel a été créée par Jean-Jacques Brioist <jean.brioist@numericable.fr>

Cette traduction est une documentation libre ; veuillez vous reporter à la GNU General Public License version 3 (https://www.gnu.org/licenses/gpl-3.0.html) concernant les conditions de copie et de distribution. Il n'y a aucune RESPONSABILITÉ LÉGALE.

Si vous découvrez un bogue dans la traduction de cette page de manuel, veuillez envoyer un message à debian-l10n-french@lists.debian.org.