CompatibilityMode-funksjonen

Innhald
Innhaldsliste 🔎︎

# CompatibilityMode()-funksjonen

CompatibilityMode() function controls or queries runtime mode. It affects all code executed after setting or resetting the runtime mode.

Bruk denne funksjon med varsemd. Avgrens han for eksempel til dokumentkonvertering.

### Syntaks:

          CompatibilityMode(Optional Enable As Boolean) As Boolean

### Returverdi:

CompatibilityMode function always returns the mode that is active after its execution. That is if called with argument, it returns the new mode, if called without argument, it returns active mode without modifying it.

### Parametrar:

Enable: Sets or unsets new compatibility mode when the argument is present.

CompatibilityMode function relates to Option VBASupport 1, in which case it always returns True. It is unrelated to Option Compatible compiler directive.

Denne funksjonen kan påverka eller hjelpa i desse situasjonane:

- Scoping of variables.

- Køyr kommandoen RmDir i VBA-modus. I VBA vert berre tomme mapper fjerna av RmDir medan LibreOffice Basic fjernar ei mappe rekursivt.

- Endring av åtferda til Basic-kommandoen Dir. Mappeflagget (16) for kommandoen Dir betyr at berre mappene vert returnerte i LibreOffice Basic, medan normale filer og mapper vert returnerte i VBA.

- Color components calculation with the Red and Blue functions which are interchanged (The Green function is not affected).

### Eksempel:

Gjeve at det er ei mappe som IKKJE er tom i file:///home/me/Test

          Sub RemoveDir
              MsgBox CompatibilityMode() ' False

              CompatibilityMode( True )
              RmDir( "file:///home/me/Test" )
              CompatibilityMode False

              MsgBox CompatibilityMode ' False
          End Sub

With CompatibilityMode( True ) the program raises an error, otherwise the Test directory and all its content is deleted.

### Eksempel:

Endra oppførselen til Dir

        Sub VBADirCommand
            CompatibilityMode( Enable := True )   ' Shows also normal files
            Entry$ = Dir( "file:///home/me/Tmp/*.*", 16 )
            Total$ = ""
            While Entry$ <> ""
                Total$ = Total$ + Entry$ + Chr$(13)
                Entry$ = Dir
            Wend
            MsgBox Total$
            CompatibilityMode Enable := False ' Shows only directories
        End Sub

Liknande emne

Option Compatible-uttrykket

Rem-uttrykket

Endring av det variable området i lenkja Bruk av prosedyrar og funksjonar med funksjonen CompatibilityMode ().

Option Base-uttrykket

Option Explicit-uttrykket

Option VBASupport-uttrykket

Option ClassModule-uttrykket